Loadstar 2/002.d81/planet of robots

Commodore BASIC | 1984-01-01 | 24.5 KB | 797 lines

1 ifpeek(52016)<>32orpeek(52040)<>245thenload"linput.pr",8,1
2 rem planet of the robots
3 rem by daniel tobias
4 rem c64 version 1.1
5 rem 6/12/84
7 na$="[208]lanet of the [210]obots"
8 poke 53280,7:poke53281,1:print"[144]"
9 s=54272:fori=.to24:pokes+i,.:next
10 print"":li=52016
15 dim lv%(100,8),ld$(100,1),r%(100),id$(50),il%(50),pr(50),iw(50),l%(100)
17 dim wd$(100),w%(100,1),fw%(1)
18 dimv%(3),h%(2),o%(1),a(1)
20 gosub 18000:gosub 19000
60 print"[147]"
100 rem start
108 xx=1
110 ifxx=1thengosub1000
120 gosub500
125 xx=xx+1:ifxx>5thenxx=1
130 iffw%(0)=0thenprint"[215]hat?":goto110
140 onfw%(0)gosub2000,3000,4000,5000,5500,6000,7000,8000,9000,9500
142 iffw%(0)>10thenonfw%(0)-10gosub13000,13500,14500,15000,15500,16000,16500
143 iffw%(0)=18thengosub10000
145 iffw%(0)=99then300
150 t=t+1
160 goto110
200 rem convert to lower case
220 for ip=1tolen(i$)
230 ch$=mid$(i$,ip,1)
240 ifch$>="[193]"andch$<="[218]"theni$=left$(i$,ip-1)+chr$(asc(ch$)-128)+mid$(i$,ip+1)
260 next ip
270 return
300 rem end
305 print"[144]"
310 print "[211]top after"t"turns."
312 input"play again";pa$:ifpa$="y"orpa$="[217]"orpa$="[183]"thenrun
320 print
330 print"[147]load"chr$(34)"hello"chr$(34)",8":print"run":poke631,13:poke632,13
332 poke198,2:end
500 rem handle input
505 fw%(0)=0:fw%(1)=0
510 print"-->";:sysli,b$:i$=b$+"":print
515 if i$="" then 510
518 gosub 200
520 wd$="":a=1
530 if mid$(i$,a,1)=" " then 600
540 wd$=wd$+mid$(i$,a,1)
550 a=a+1:ifa<=len(i$)then530
600 rem found word
610 forb=1tonw:ifwd$(b)=wd$thengosub650
620 nextb:wd$="":a=a+1
630 ifa>len(i$)thenreturn
640 goto530
650 forc=0to1
660 ifw%(b,c)>=0thenfw%(c)=w%(b,c)
670 nextc
680 return
1000 rem print description
1002 ifld$(l,0)="s"thengosub12000
1005 print
1010 printld$(l,l%(l))
1011 ifl=28andj=0thenprint"[212]here is a door with bars."
1012 ifl=28andj<>0thenprint"[212]he bars are broken, leaving a way out."
1014 print
1015 l%(l)=1
1020 print"[207]pen pathways: ";:fora=1to8:iflv%(l,a)<>0thenprintdn$(a)" ";
1025 nexta
1030 print
1040 print"[214]isible objects:"
1045 x=0
1050 fora=1toni
1060 if il%(a)=lthenprint" "id$(a);:x=1
1062 ifil%(a)=landpr(a)>0andr%(l)=1thenprint" ([208]rice $"pr(a)")";
1065 if il%(a)=lthenprint
1070 nexta
1080 ifx=0thenprint"[212]here are none."
1082 if r%(l)<>0thenprint
1085 ifr%(l)=1thenprint"[195]lerk robot here."
1090 ifr%(l)>20andr%(l)<29thenprint"[199]uard robot here."
1110 if r%(l)=3thenprint"[194]erzerk robot here!"
1120 ift-e>=100thenprint"[217]ou are getting hungry!"
1480 print
1490 return
2000 rem move
2005 iffw%(1)<101orfw%(1)>108thenprint"[199]o where?":return
2010 x=lv%(l,fw%(1)-100)
2020 ifx<0orx>nlthenprint"[206]ot defined yet.":return
2025 ifl=28andi$="break out"then15000
2030 ifx=0thenprint"[217]ou can't go that way.":return
2035 ifr%(l)=3thenprint"[210]obot: [212]rying to escape, huh?  [201]t won't"
2037 ifr%(l)=3thenprint"work!  [218]ap! [217]ou're dead!":goto300
2040 ifx=6andil%(7)<>0thenprint"[210]obot: [201]'m sorry, but the dress code"
2041 ifx=6andil%(7)<>0thenprint"  requires that you wear a tie.":return
2042 ifl=6andr<>0thenprint"[210]obot: [201]'m sorry.  [217]ou are a bad credit"
2043 ifl=6andr<>0thenprint"  risk.  [217]ou can't enter.":return
2045 ifr%(l)=20+fw%(1)-100then2500
2060 rem
2065 ifl=39andx=39andrnd(0)<.35thenpl=1-pl:x=35:ifpl=0thenx=40
2080 ifx=17thenprint"[210]obot: [211]orry, this information booth is   out of order."
2085 ifx=17thenreturn
2087 ifld$(x,0)="[211]"thengosub12000:return
2090 ifl=36andx=37theninput"[197]nter combination";a$
2095 ifl=36andx=37andval(a$)<>cm%thenprint"[211]orry. [215]rong!":return
2100 ifx=38then14000
2200 l=x:xx=1:return
2500 rem id card
2510 ifil%(12)=0thenprint"[210]obot: [201].[196]. accepted.  [217]ou can pass."
2520 ifil%(12)=0thenprint"  [199]ood day, [205]r. [211]mith.":goto2060
2530 print"[210]obot: [201]'m sorry, but you can't go that   way without an [201].[196]. card."
2540 return
3000 rem pick up
3005 iffw%(1)=0orfw%(1)>nithenprint"[206]o such thing here.":return
3006 ifil%(fw%(1))=0thenprint"[217]ou are already carrying it!":return
3007 ifil%(fw%(1))<>lthenprint"[206]o such thing here.":return
3009 ifpr(fw%(1))>0andr%(l)=1thenprint"[210]obot: [217]ou can't take that without"
3010 ifpr(fw%(1))>0andr%(l)=1thenprint"  paying for it!  [208]lease buy it if you"
3011 ifpr(fw%(1))>0andr%(l)=1thenprint"  want it.":return
3013 hf=0
3015 ifwt+iw(fw%(1))>150andiw(fw%(1))<=150then hf=1
3017 if hf=1 then print "[212]oo heavy.  [217]ou must drop something     first.":return
3020 ifiw(fw%(1))>150thenprint"[212]oo heavy for you to lift.":return
3030 ifiw(fw%(1))<0thenprint"[201]t is securely fastened.":return
3040 il%(fw%(1))=0:wt=wt+iw(fw%(1))
3045 print "[207][203]."
3050 iffw%(1)=10thenm=abs(m)
3060 return
4000 rem drop
4010 iffw%(1)<1orfw%(1)>nithenprint"[217]ou are not carrying one.":return
4020 ifil%(fw%(1))<>0thenprint"[217]ou are not carrying one.":return
4030 il%(fw%(1))=l:wt=wt-iw(fw%(1))
4040 print "[207][203]."
4042 ifl=39thenprint"[201]t slides into a crevice in the ruins   and is lost."
4043 ifl=39thenil%(fw%(1))=-1
4045 iffw%(1)=10thenm=-abs(m)
4050 return
5000 rem look
5005 iffw%(1)>0then8000
5010 xx=1
5020 l%(l)=0
5030 return
5500 rem inv
5505 x=0
5510 print "[217]ou are carrying:"
5520 fora=1toni
5525 ifa=10then5540
5530 ifil%(a)=0thenprint" "id$(a):x=1
5540 nexta
5545 ifm>0thenprint"[160]$"m"in cash.":x=1
5550 ifx=0thenprint"[206]othing."
5560 return
6000 rem save game
6010 print"[197]nter filename. ([196]efault: planet.save)":inputf$
6015 iff$=""thenf$="planet.save"
6017 open15,8,15:print#15,"s:"f$:close15
6020 open2,8,2,f$+",s,w"
6040 print#2,l:forb=1toni:print#2,il%(b):nextb:print#2,wt:print#2,t
6050 forb=1tonl:print#2,r%(b):nextb:print#2,m:print#2,e
6060 forb=1toni:print#2,pr(b):nextb
6070 print#2,cm%:print#2,r:print#2,j
6080 print#2,pw:print#2,rm
6090 close2
6100 print "[207][203].":return
6500 rem load game
6510 print"[197]nter filename. ([196]efault: planet.save)":inputf$
6515 iff$=""thenf$="planet.save"
6520 open15,8,15
6530 open2,8,2,f$+",s,r"
6540 gosub 6900
6550 input#2,l:forb=1toni:input#2,il%(b):nextb:input#2,wt:input#2,t
6560 forb=1tonl:input#2,r%(b):nextb:input#2,m:input#2,e
6565 forb=1toni:input#2,pr(b):nextb
6570 input#2,cm%:input#2,r:input#2,j
6575 ifj<>0thenlv%(28,8)=27
6580 input#2,pw:input#2,rm
6590 close2:close15
6600 return
6900 input#15,a$,b$,c$,d$
6910 ifval(a$)>0thenprint"[199]ame not found.":fora=1to100:nexta:run
6920 return
7000 rem weigh
7010 ifil%(2)<>landil%(2)<>0thenprint"[212]here is no scale.":return
7020 iffw%(1)=2thenprint"[217]ou can't weigh it on itself!":return
7030 iffw%(1)<1orfw%(1)>nithenprint"[212]here is no such item here.":return
7040 ifil%(fw%(1))<>landil%(fw%(1))<>0thenprint"[212]here is no such item here.":return
7050 print"[201]t weighs"iw(fw%(1))"pounds."
7060 return
8000 rem read/examine
8005 iffw%(1)=200thenprint"[212]he bars look rusty and weak.":return
8010 iffw%(1)<1orfw%(1)>nithenprint"[206]o such thing here.":return
8020 ifil%(fw%(1))<>landil%(fw%(1))<>0thenprint"[206]o such thing here.":return
8030 iffw%(1)=5thenprint"[212]he sign says: [201]nsert $2.50.":return
8050 iffw%(1)=10thenprint"[212]hey are mostly dollar coins, but there"
8055 iffw%(1)=10thenprint"are some $2.50 pieces.":return
8060 iffw%(1)=4thenprint"[201]t has many peripherals, including a    modem.":return
8070 iffw%(1)=8thenprint"[201]t is [212]he [193]dventures of [211]uper[210]obot.":return
8080 iffw%(1)=12thenprint"[201]t belonged to secret agent [194]ill [211]mith,"
8085 iffw%(1)=12thenprint"who had the highest security clearance.":return
8090 iffw%(1)=14thenprint"[212]hey appear to be the fragments of a"
8095 iffw%(1)=14thenprint"butcher's knife.":return
8100 iffw%(1)=11then8200
8110 iffw%(1)=13then8300
8190 print"[206]othing interesting.":return
8200 print"[212]itle: [200]ow to [205]ake [212]he [205]ost of [195]omputer   [206]etworks":print
8210 print"[217]ou can access the government's public"
8215 print"information data files through any"
8217 print"modem-equipped computer.  [212]o do this,   simply type:"
8220 print "  [204][207][193][196]"chr$(34)"[212][197][210][205]6400"chr$(34)",8,1"
8230 print"[212]hen, you select the government network by typing:"
8235 print"  [199][207][214][212]"
8240 print"[206]ow, you are asked the name of the file"
8245 print"you want.  [198]iles you have access to"
8247 print"include '[208][207][208]', which contains the"
8250 print"current population of the [213][211][193].  [200]ave    fun!"
8260 print:return
8300 print"          [212][160][207][160][208][160][160][160][211][160][197][160][195][160][210][160][197][160][212]"
8310 print"[212]o: [215]orkers on [208]roject [195]hronos"
8320 print:print"[212]he current combination to the door of"
8323 print"room "rm" is posted on the government"
8326 print"computer network in the file titled"
8328 print"'[195][200][210][207][206][207][211]'.  [212]he password to the file is":print"'"pw$(pw);"'."
8330 return
8500 rem trial/jail
8510 print "* [193] police robot arrives. *"
8515 print
8520 print"[208]olice: [217]ou are under arrest.  [217]ou have"
8530 print"  a right to refrain from inputting"
8533 print"  anything; anything you input may be"
8536 print"  held against you in court."
8540 print"[144]* [217]ou are taken to a courtroom.      *"
8545 print"* [212]he judge and jury are all robots. *"
8550 print
8560 print:print"[202]udge: [217]ou are charged with ";
8580 ifch=1thenprint"[193]ssault of":print"  a [210]obot. ";
8590 ifch<>1thenprint"[212]heft of":print"  services.";
8600 print"  [200]ow do you plead?"
8605 print
8610 print "[196]efendant: ";:sysli,b$:i$=b$+"":print
8615 print
8620 gosub200:iflen(i$)>=6thenifleft$(i$,6)="guilty"then8900
8630 print"[202]udge: [212]he [196]istrict [193]ttorney will now     present his case."
8635 print
8640 print"* [212]he [196].[193]. is also a robot. *"
8645 print
8650 print"[196].[193].: [201] will now call upon the ";
8660 ifr%(l)=1thenprint"clerk "
8665 ifr%(l)<>1thenprint"guard "
8670 print" robot, serial #"int(rnd(1)*999999)" to testify."
8672 print
8677 ifch<>1then8700
8680 print"[210]obot: [212]his man assaulted me with a":ifil%(9)=0thenprint" ray gun ";
8685 if il%(9)<>0thenprint" knife ";
8690 print"only"int(rnd(1)*59)"minutes,"rnd(1)*59:print"  seconds ago."
8692 print
8695 print"[196].[193].: [201] rest my case."
8696 print
8697 goto8800
8700 rem (NULL)heft of (NULL)ervices
8710 print"[210]obot: [212]his man had a meal at the"
8712 print"  restaurant in which [201] work, and would   not pay."
8715 print
8720 print"[196].[193].: [215]hen did this happen?"
8725 print
8730 print"[210]obot: [202]ust"int(rnd(1)*59)" minutes, "rnd(1)*59:print"  seconds ago."
8735 print
8740 print"[196].[193].: [201] rest my case."
8745 print
8800 rem your reply
8810 print"[202]udge: [215]hat does the defendant have to    say for himself?"
8815 print
8820 print"[196]efendant: ";:sysli,b$:i$=b$+"":print
8822 print
8825 print"[202]udge: [212]he jury will now reach a          verdict."
8827 fora=1to1500:nexta:print
8830 print"[202]ury: [212]he word of a robot is more"
8833 print"  reliable than that of a mere human."
8836 print"  [212]herefore, we find the defendant        guilty as charged."
8840 print
8900 rem sentencing
8905 se=2
8910 ifch=1thenprint"[202]udge: [217]ou are hereby sentenced to death  by electrocution."
8915 ifch=1thenprint:print"* [217]ou are taken to an execution chamber * and killed.":goto300
8920 print"[202]udge: [217]ou are hereby sentenced to "
8923 print" "se"years in prison.  [194]ailiff, please"
8926 print"  remove the prisoner.  [206]ext case!"
8930 print:l=28
8940 fora=1toni:ifil%(a)=0thenil%(a)=29
8942 nexta
8945 m=-abs(m)
8950 xx=1:return
9000 rem shoot
9010 ifil%(9)<>0thenprint"[215]ith what?":return
9020 ifr%(l)=0thenprint"[206]othing to shoot at.":return
9030 ifr%(l)<>3thenprint"[212]he robot's force field repels the ray.":ch=1:goto8500
9040 print"[212]he defect which caused the robot to"
9045 print"malfunction also affected its normally"
9050 print"invulnerable force field.  [217]our shot    destroys it."
9060 r%(l)=0
9070 return
9500 rem buy
9501 iffw%(1)<1orfw%(1)>nithenprint"[206]o such thing here.":return
9503 ifil%(fw%(1))=0thenprint"[217]ou are already carrying it.":return
9505 ifil%(fw%(1))<>lthenprint"[206]o such thing here.":return
9510 ifpr(fw%(1))=0thenprint"[212]here is no price on it.":return
9520 p=pr(fw%(1))
9525 ifm<=0thenprint"[217]ou do not have any money!":return
9530 ifp>mthenprint"[217]ou do not have enough money!":return
9540 m=m-p
9550 pr(fw%(1))=0
9560 goto3000
10000 rem computer
10002 ifil%(4)<>lthenprint"[206]o such thing here.":return
10005 print"[210]obot: [215]hen you are finished, type        '[207][198][198]' to shut it off.":print
10007 print"[200]it return to turn computer on. ";:sysli,b$:print
10010 sys65409
10020 print"   **** commodore 6400 basic v32 ****"
10025 print"64m ram system 38911206 basic bytes free":print"ready."
10030 sysli,b$:i$=b$+"":print
10035 fora=1tolen(i$):ifmid$(i$,a,1)=" "theni$=left$(i$,a-1)+mid$(i$,a+1)
10037 nexta
10040 if i$="load"+chr$(34)+"term6400"+chr$(34)+",8,1" then 10100
10045 ifi$="off"thenxx=1:goto10500
10047 print
10050 i=int(rnd(1)*5)+1
10055 onigosub10060,10065,10070,10075,10080:print"ready.":goto10030
10060 print"?syntax  error":return
10065 print"?unbalanced coordinate  error":return
10070 print"?improper delimiter  error":return
10075 print"?unformatted reference  error":return
10080 print"?unindexable address  error":return
10100 rem modem
10110 goto30500
10120 print"[215]elcome to the [213].[211]. [199]ovt [196]atabase!":print"[212]ype '[207][198][198]'[160]to log off."
10140 input"[206]ame of file to access";i$:gosub200:ifi$="off"then10550
10150 ifi$="pop"then10600
10160 ifi$="chronos"then10200
10170 print"[206]o such file!":goto10140
10200 rem chronos
10210 input"[195]lassified!  [208]assword";i$
10220 ifi$<>pw$(pw)thenprint"[201]mproper password!":goto10140
10230 print"[208]roject [195]hronos combination:"cm%"."
10240 goto 10140
10500 rem exit computer
10505 xx=1
10510 poke53280,7:poke53281,1:print"[147]"
10517 print""
10520 return
10550 print"[204]ogging off [199][207][214][212] system -- [200]ave a good  day!"
10555 fori=1tornd(.)*10+5:printchr$(rnd(.)*256);:forp=1tornd(.)*200:next:next
10560 print:print"[195]arrier[160]tone[160]lost!"
10570 print:print"[158][194]ack to [212][197][210][205]6400.  [217]our choices:"
10575 print" (1) [193]ccess another system"
10580 print" (2) [197]xit to [194][193][211][201][195]"
10585 print" (3) [197]xit and [212]urn [195]omputer [207]ff"
10587 i$=""
10590 print:input"[217]our choice";i$
10595 ifval(i$)=0then10590
10597 onval(i$)goto30025,30200,10500
10598 goto10590
10600 print"[212]he current population of the [213].[211].[193]."
10610 print"according to census figures as of"
10620 print"7/6/2121: [197]xactly 0 persons,  23,241,203robots."
10630 print:goto10120
11000 rem restaurant
11010 print"[210]obot: [200]ere is the menu:"
11020 print"  (1) [205]arsburger"
11025 print"      $120"
11030 print"  (2) [199]reen [199]oop ([211]pecial of the week!"
11035 print"      $140"
11040 print"  (3) [195]aviar and [195]hampagne"
11045 print"      $350"
11047 print"([200]it [210][197][212][213][210][206][146] if you don't wish to order.)":i$=""
11050 input"[217]our order (by number)";i$
11060 ifi$=""thenreturn
11070 ifval(i$)<1orval(i$)>3then11050
11080 print:print"[217]ou are served."
11090 print"[205]mm. [201]t tastes good."
11095 e=t
11100 print:print"[210]obot: [217]our check, sir."
11120 print:print"[217]ou do not have enough money!"
11130 ch=0:goto8500
12000 rem subway
12005 l=lv%(l,6)
12010 print"[217]ou enter at the "ld$(l,1):print"station."
12015 print
12020 iflv%(l,1)=0theni=2:goto12050
12030 iflv%(l,2)=0theni=1:goto12050
12040 print"[215]hich train ([206]orthbound or [211]outhbound)":inputi$
12045 i=2:ifleft$(i$,1)="[206]"orleft$(i$,1)="n"theni=1
12050 l=lv%(l,i)
12060 print"[206]ext station: "ld$(l,1)
12065 iflv%(l,i)=0thenprint"[197]nd of the line.":l=lv%(l,8):xx=1:return
12070 print
12080 input"[196]o you want to get off here";i$
12085 ifleft$(i$,1)="[217]"orleft$(i$,1)="y"thenl=lv%(l,8):xx=1:return
12090 print:goto12050
13000 rem call robot
13002 ifr%(l)=0thenprint"[206]obody to call.":return
13003 ifr%(l)<>1then13200
13010 ifl=6then11000
13020 ifl=34then13300
13030 ifl=36then13400
13040 ifl=3thenprint"[210]obot: [215]ould you like to try out the    [195]ommodore 6400"
13045 ifl=3theninputi$:ifleft$(i$,1)="[217]"orleft$(i$,1)="y"then10000
13047 ifl=3thenreturn
13050 print"[210]obot: [195]an [201] help you?"
13060 inputi$
13065 ifi$=""then13060
13070 gosub520
13080 iffw%(0)=10thengosub9500:return
13085 iffw%(1)=4andl=3then10000
13090 print"[210]obot: [201] am not programmed to handle      queries of this type."
13190 return
13200 rem guard and berzerk robots
13210 ifr%(l)=3thenprint"[212]he robot kills you while you are trying";
13215 ifr%(l)=3thenprint"to communicate with it!":goto300
13220 print"[210]obot: [217]es?"
13230 inputi$
13240 print"[210]obot: [201] am unauthorized to handle        queries of this nature."
13250 return
13300 rem university
13310 print"[210]obot: [215]hat room number do you want?":inputi$
13320 ifval(i$)<>rmthenprint"[210]obot: [211]orry, that room is not open.":return
13330 print:print"[212]he wall slides open, and you are"
13333 print"briskly carried on a platform floating"
13336 print"inches above the floor, through several"
13338 print"hallways.  [217]ou come to a stop."
13340 l=36:xx=1:return
13400 rem hall
13410 print"[210]obot: [196]o you want to return to the":input"lobby";i$
13420 ifleft$(i$,1)="[217]"orleft$(i$,1)="y"thenl=34:xx=1
13430 return
13500 rem play game
13505 print
13510 print"[195]ost:[160]$2.50"
13520 ifm<2.5thenprint"[217]ou can't afford it.":return
13530 print:print"[212]he machine is out of order.  [201]t takes"
13540 print"your money, but does not play.  [217]ou"
13550 print"pound on it, but nothing happens, and   you don't get your money back."
13560 m=m-2.5
13570 return
14000 rem time machine
14010 print"[217]ou are in the time machine!"
14020 print"[206]ow, set the controls:"
14030 input"[217]ear";y
14040 input"[205]onth";i$:input"[196]ay";i$:input"[200]our";i$:input"[205]inute";i$
14045 input"[211]econd";i$
14050 print:print"[212]he machine whirrs..."
14060 fora=1to1000:nexta
14070 print"[217]ou have arrived!"
14080 ify>=1970andy<2001thenprint"[194]ack in the 20th century at last!  [217]ou  win!"
14085 ify>=1970andy<2001then300
14090 ify>=2001thenprint"[215]hy did you go to the future again?  [201]"
14095 ify>=2001thenprint"didn't program any adventure game for"
14096 ify>=2001thenprint"that century, and the time machine is"
14098 ify>=2000thenprint"out of power.  [217]ou're on your own.":goto300
14100 ify<1970andy>=1901thenprint"[215]ell, at least you made it to the 20th"
14110 ify<1970andy>1901thenprint"century, but you'll have to wait a"
14120 ify<1970andy>1901thenprint"while for [195]ommodore computers to be     invented."
14130 ify<1970andy>1901then300
14140 print"[217]ou end up in the year"y".  [201] didn't"
14150 print"program any adventure for that century,"
14160 print"and the time machine is out of power,   so you are on your own."
14170 goto300
14500 rem eat
14502 iffw%(1)=0andl=6then11000
14510 iffw%(1)<1orfw%(1)>nithenprint"[197]at what?":return
14520 ifil%(fw%(1))<>0thenprint"[197]at what?":return
14530 ifiw(fw%(1))>2thenprint"[196]on't be ridiculous!":return
14540 iffw%(1)=3thenprint"[205]mm. [212]hat was good.":e=t:goto14565
14545 print"[195]homp [195]homp [195]homp"
14550 print"[201]t could have used a little salt."
14560 ift-e>150thenprint"[206]ot very nutritious.  [217]ou7re still      hungry."
14565 il%(fw%(1))=-1
14567 iffw%(1)=10thenm=0
14570 return
15000 rem break out of jail
15010 ifl<>28thenprint"[215]hat?":return
15020 print"[212]he rusty, weakened bars give way and   there is an opening out."
15030 lv%(28,8)=27:j=1
15040 return
15500 rem attack
15510 ifil%(9)=0then9000
15515 ifr%(l)=0thenprint"[206]othing to attack.":return
15520 ifil%(1)<>0thenprint"[217]ou have no hope of fighting a tough"
15525 ifil%(1)<>0thenprint"metal robot with your bare hands.":return
15530 print"[212]he knife shatters against the robot's  tough side."
15535 il%(1)=-1:il%(14)=l
15538 ifr%(l)=3thenprint"[212]he robot kills you.":goto300
15540 ch=1:goto8500
16000 rem open
16010 print"[193]ll the doors open and close"
16020 print"automatically, so there is no need to   open or close them."
16030 return
16500 rem help
16510 print:print"[211]ome available commands:"
16530 print" [201][206][214]":print" [199][197][212] [object]":print" [194][213][217] [object]":print" [196][210][207][208] [object]"
16540 print" [197][216][193][205][201][206][197] [object]":print" [195][193][204][204][160][210][207][194][207][212]":"[160][193][212][212][193][195][203][160][210][207][194][207][212]":"[160][211][200][207][207][212][160][210][207][194][207][212]"
16545 print"[160][204][207][207][203]"
16550 print:return
18000 rem opening titles
18010 print "[147]"
18020 print:print:print:print:print
18030 print:print:print"     **** [208]lanet of the [210]obots ****"
18040 print
18050 print"        [195]ommodore 64 [214]ersion 1.1"
18060 print:print"   [195]opyright ([195]) 1984 by [196]aniel [212]obias"
18070 print:input"         [201]nstructions ([217]/[206]) ";i$
18080 if left$(i$,1)="[206]" or left$(i$,1)="n" then return
18500 rem instructions
18510 print"[147]"
18520 print"[193] time warp has suddenly transported":print
18530 print"you into the future, where a war using":print
18550 print"neutron bombs and bacteriological"
18560 print:print"warfare has completely wiped out the":print
18570 print"human race.  [200]owever, the computers":print
18580 print"and robots don't know this, and keep":print
18585 print"going about their business as if nothing":print"has happened.":print
18587 print"*** [200]it return to continue ***";:sysli,b$:print"[147]"
18590 print"[217]ou explore the world you are thrust"
18595 print:print"into using simple sentences, in the"
18600 print:print"standard adventure-game fashion, such"
18610 print:print"as [193][212][212][193][195][203][160][210][207][194][207][212][160]or [197][216][193][205][201][206][197][160][195][207][201][206]."
18620 print:print"[201]f a robot is in the room, you may"
18625 print:print"attempt to talk to it by typing [195][193][204][204]"
18630 print:print"[210][207][194][207][212], but positive results are not":print:print"guaranteed!"
18635 print:print"*** [200]it return to continue. ***";:sysli,b$:print"[147]"
18640 print"[199][207][160][206][207][210][212][200] may be abbreviated [206], and the"
18650 print:print"same may be done with the other compass"
18660 print:print"directions."
18670 print:print"[212]he object is to get back to the 20th"
18680 print:print"century.  [199]ood luck!"
18690 print:print"[211]ome utility commands:"
18700 print"  [209][213][201][212] exits game":print"  [211][193][214][197] saves game in progress to disk."
18710 print:print"*** [200]it return to start. ***";:sysli,b$:print"[147]":return
18999 return
19000 rem initialize
19002 print"[147][208]lease wait.  [201]nitializing data."
19005 fora=1to8:readdn$(a):nexta
19020 a=1
19025 forb=0to1:readld$(a,b):nextb:ifld$(a,0)<>""thena=a+1:goto19025
19027 nl=a-1
19030 fora=1tonl:forb=1to8:readlv%(a,b):nextb:readr%(a):nexta
19040 fora=1tonl:l%(a)=0:nexta
19050 a=1
19060 readid$(a),il%(a),iw(a),pr(a):ifil%(a)<>-999thena=a+1:goto19060
19065 ni=a-1
19067 fora=1to10:readpw$(a):nexta
19070 a=1
19075 readwd$(a),w%(a,0),w%(a,1):ifwd$(a)<>""thena=a+1:goto19075
19080 nw=a-1
19085 l=1:t=1
19087 w=0:m=-119
19088 e=0:j=0:r=0
19090 print "[147]":input"[204]oad game from disk ([217]/[206]) ";i$
19093 pw=int(rnd(0)*10)+1
19096 cm%=int(rnd(0)*9999):rm=int(rnd(0)*900)+100
19100 ifleft$(i$,1)="[217]"orleft$(i$,1)="y"thengosub6500
19110 f=.0596064645
19120 fori=.to3:readp:v%(i)=p/f+.5:next:fori=.to2:readp:h%(i)=p/f+.5:next
19125 fori=.to1:readp:o%(i)=p/f+.5:next:fori=.to1:readp:a(i)=int(p/f+.5):next
19130 return
20000 rem data
20005 data"[206][160]","[211] ","[197] ","[215] ","[213] ","[196] ","[201][206] ","[207][213][212]"
20040 data"[144][217]ou are in the parking lot of a shoppingmall. [193] road is to the east."
20045 data"[144][217]ou're in parking lot to mall."
20050 data"[217]ou are in the shopping mall.  [212]here is a computer store here."
20055 data"[217]ou're in mall at computer store."
20060 data"[217]ou are in the computer store.","[217]ou're in computer store."
20070 data"[212]o the west is a comic book store.  [212]o  the east is a restaurant."
20075 data"[217]ou're by comic store and restaurant."
20080 data"[212]his is a store catering to comic book  collectors."
20085 data"[217]ou are in comic store."
20090 data"[217]ou are in a restaurant.","[217]ou're in restaurant."
20100 data"[212]o the west is an arcade, and to the    east is a grocery store."
20105 data"[217]ou're by arcade and grocery."
20110 data"[217]ou are in an arcade.","[217]ou're in arcade."
20120 data"[212]o the west is a butcher shop, and to   the east a clothing store."
20125 data"[217]ou're by butcher and clothing store."
20130 data"[217]ou are in a butcher shop.","[217]ou're in butcher shop."
20140 data"[217]ou are in a clothing store.","[217]ou're in clothing store."
20150 data"[217]ou are in a grocery.","[217]ou're in grocery."
20160 data"[144][217]ou are on a [206]-[211] road.  [212]here is a      shopping mall to the west."
20165 data"[144][217]ou're on road by mall."
20170 data"[144][212]he road goes 100 ft., then stops at an impenetrable pile of debris."
20175 data"[144][217]ou're at debris."
20180 data"[144][217]ou are next to an information booth,   manned by a robot."
20185 data"[144][217]ou're at info booth."
20190 data"[144][217]ou are in a phone booth.  [212]he cash box has burst open."
20195 data"[144][217]ou're in phone booth."
20200 data"[201]","[201]"
20210 data"[217]ou are in the library.","[217]ou're in library."
20220 data"[144][212]o the west is a library, and the city  hall is to the east."
20225 data"[144][217]ou're by library and city hall."
20230 data"[217]ou are in the lobby of the city hall.  [212]here is a stairway here."
20235 data"[217]ou're in city hall lobby."
20240 data"[144][212]he road ends here.  [212]here is a subway  entrance here."
20245 data"[144][217]ou're by subway station."
20247 data"[211]","[195]ity [200]all"
20250 data"[217]ou are in a hallway leading towards    offices to the east."
20255 data"[217]ou're in hallway."
20260 data"[212]here are offices to the north and      south."
20265 data"[217]ou're between two offices."
20270 data"[217]ou are in an office","[217]ou're in office."
20280 data"[217]ou are in an office","[217]ou're in office."
20290 data"[217]ou are in a hallway in the jail.  [193]    closet is to the north."
20295 data"[217]ou're in jail hallway."
20300 data"[217]ou are in a jail cell.","[217]ou're in jail cell."
20310 data"[156][217]ou are in a closet.","[156][217]ou're in closet."
20320 data"[211]","[205]arket [211]treet"
20330 data"[211]","[205]etro [213]niversity"
20340 data"[211]","[197]ndsville"
20350 data"[156][217]ou are on a street which is blocked in both directions by debris."
20355 data"[156][217]ou're on blocked street."
20360 data"[156][217]ou are in the main lobby of the [205]etro  [213]niversity building."
20365 data"[156][217]ou're in university lobby."
20370 data"[144][217]ou are on a plain where a bomb blast   has destroyed the town."
20375 data"[144][217]ou're on plain by subway stop."
20380 data"[156][217]ou are in front of a door.","[156][217]ou're in front of door."
20390 data"[156][217]ou are in the laboratory of [208]roject    [195]hronos.[146]"
20395 data"[156][217]ou're in lab.[146]"
20400 data"[212]","[212]"
20405 data"[144][217]ou are on plain.","[144][217]ou are on plain."
20410 data"[217]ou are by a phone booth.","[217]ou're by phone booth."
20990 data"",""
21000 rem movement,robots
21010 data0,0,13,0,0,0,2,0,0
21020 data7,4,0,0,0,0,3,1,0
21030 data0,0,0,0,0,0,0,2,1
21040 data2,0,6,5,0,0,0,0,0
21050 data0,0,0,0,0,0,0,4,1
21060 data0,0,0,0,0,0,0,4,1
21070 data9,2,12,8,0,0,0,0,0
21080 data0,0,0,0,0,0,0,7,0
21090 data0,7,11,10,0,0,0,0,0
21100 data0,0,0,0,0,0,0,9,0
21110 data0,0,0,0,0,0,0,9,1
21120 data0,0,0,0,0,0,0,7,1
21130 data14,15,0,1,0,0,0,0,0
21140 data0,13,0,0,0,0,0,0,0
21150 data13,19,0,0,0,0,17,0,0
21160 data0,0,0,0,0,0,0,40,0
21170 data0,0,0,0,0,0,0,15,1
21180 data0,0,0,0,0,0,0,19,0
21190 data15,21,20,18,0,0,0,0,0
21200 data0,0,0,0,23,27,0,19,26
21210 data19,0,0,0,0,22,0,0,3
21215 data0,30,0,0,0,0,0,21,0
21220 data0,0,24,0,0,20,0,0,23
21230 data26,25,0,23,0,0,0,0,0
21240 data0,0,0,0,0,0,0,24,3
21245 data0,0,0,0,0,0,0,24,0
21250 data29,28,0,0,20,0,0,0,25
21260 data0,0,0,0,0,0,0,0,0
21270 data0,0,0,0,0,0,0,27,0
21280 data22,31,0,0,0,0,0,33,0
21290 data30,32,0,0,0,0,0,34,0
21300 data31,0,0,0,0,0,0,35,0
21310 data0,0,0,0,0,30,0,0,0
21320 data0,0,0,0,0,31,0,0,1
21330 data39,39,39,39,0,32,0,0,0
21340 data0,0,0,0,0,0,37,0,1
21350 data0,0,0,0,0,0,38,36,0
21360 data0,0,0,0,0,0,0,0,0
21370 data39,39,39,39,0,0,0,0,0
21380 data39,39,39,39,0,0,16,0,0
23000 rem items
23030 data"[194]utcher's [203]nife",10,5,0
23033 data"[211]cale",10,140,0
23036 data"[198]ood [208]ills",12,.5,10
23040 data"[195]ommodore 6400 [195]omputer",3,15,5000
23050 data"[214]ideo game machine",8,-1,0
23060 data"[211]uit of clothes",11,2,995
23070 data"[212]ie",11,.15,20
23090 data"[195]omic",5,.3,6
23100 data"[210]ay [199]un",14,1,0
23110 data"[195]oins",16,2,0
23120 data"[194]ook",18,1,0
23130 data"[201].[196]. [195]ard",29,.05,0
23140 data"[204]etter",26,.05,0
23150 data"[211]hattered pieces of metal",-1,5,0
23160 data"[212]ime [205]achine",37,2000,0
23990 data"",-999,-999,-999
23995 datasesame,snark,quark,peartree,moonshine,shoe,turkey,christmas
23997 datahalloween,robotwar
24000 rem words
24010 datan,1,101
24020 datas,1,102
24030 datae,1,103
24040 dataw,1,104
24050 datau,1,105
24060 datad,1,106
24070 datain,1,107
24080 dataout,1,108
24090 dataget,2,-1
24100 datatake,2,-1
24140 datago,1,-1
24160 datadrop,3,-1
24170 datalook,4,-1
24180 datainv,5,-1
24190 dataquit,99,-1
24200 datasave,6,-1
24210 datarobot,-1,200
24220 databuy,10,-1
24230 dataweigh,7,-1
24240 dataread,8,-1
24250 dataexamine,8,-1
24260 dataknife,-1,1
24270 datascale,-1,2
24280 datapills,-1,3
24290 datacommodore,-1,4
24295 data6400,-1,4
24300 datacomputer,-1,4
24310 datacall,11,-1
24315 datatalk,11,-1
24317 dataspeak,11,-1
24320 datagame,-1,5
24330 dataplay,12,-1
24340 datasuit,-1,6
24350 datatie,-1,7
24360 datacomic,-1,8
24370 dataeat,13,-1
24380 databreak,14,-1
24390 dataescape,14,-1
24400 datagun,-1,9
24410 datacoins,-1,10
24420 datamoney,-1,10
24425 datacash,-1,10
24430 databook,-1,11
24440 datashoot,9,-1
24445 datazap,9,-1
24450 dataattack,15,-1
24455 datakill,15,-1
24460 datai.d.,-1,12
24465 dataid,-1,12
24470 datacard,-1,12
24480 dataletter,-1,13
24490 datapieces,-1,14
24500 dataopen,16,-1
24510 datahelp,17,-1
24515 dataon,18,-1
24520 databars,-1,200
24895 rem *****unabbreviated:
24900 datanorth,1,101
24905 datasouth,1,102
24910 dataeast,1,103
24915 datawest,1,104
24920 dataup,1,105
24925 datadown,1,106
24930 datainventory,5,-1
24935 dataenter,1,107
24940 dataexit,1,108
24990 data"",-999,-999
30000 pokes+5,.:pokes+6,240:pokes+12,.:pokes+13,240:pokes+3,8:pokes+10,8
30005 pokes+24,15:t$="123456789*0#"
30010 f=.059604645:poke53280,.:poke53281,.
30012 print"[147][158][212][197][210][205]6400  300 [203]ilobaud [212]erminal [208]ackage"
30013 print"[158][195]opyright ([195])[160]2063 by [204]oadstar [211]oftware"
30014 print"[212]ype '[207][198][198]' to return to [194][193][211][201][195]."
30025 p$="1-800-555-0749":goto30150
30030 print"[196]ialing:  ";:gosub30135:pokes+24,8
30035 fori=1tolen(p$):a$=mid$(p$,i,1):printa$;:forj=1tolen(t$)
30040 ifa$<>mid$(t$,j,1)thennext:next:goto30025
30045 p=j-1:j=len(t$):next:v%=p/3:h%=p-3*v%:p1%=h%(h%):p2%=v%(v%):gosub30080:next
30050 pokes+24,15:gosub30090:gosub30115
30055 print:print"300 [203]ilobaud [195]onnect[154]":fori=1to500:next:goto10120
30060 data697,770,852,941:rem vertical touch-tone pitches
30065 data1209,1336,1477:rem horizontal touch-tone pitches
30070 data1070,1270:rem originate modem space, mark
30075 data2025,2225:rem answer modem space, mark
30080 pokes,p1%and255:pokes+1,p1%/256:pokes+7,p2%and255:pokes+8,p2%/256
30085 pokes+4,65:pokes+11,65:forp=1to50:next:pokes+4,.:pokes+11,.:return
30090 t1%=7430:t2%=7000:pokes+24,.:pokes+24,15::forp=1to2:pokes+4,17:fori=1to60
30095 pokes,t1%and255:pokes+1,t1%/256
30100 pokes,t2%and255:pokes+1,t2%/256:next
30105 pokes+4,.:fori=1to1000-2500*(p=1):next:next:pokes+24,.:pokes+24,15
30110 pokes+24,.:fori=1to20:next:pokes+24,15:pokes+24,.:pokes+24,15:return
30115 t1=a(.):t2%=o%(.):pokes+24,4
30120 pokes,t1-256*int(t1/256):pokes+1,t1/256:pokes+4,65:fori=1to800:next
30125 pokes+7,t2%and255:pokes+8,t2%/256:pokes+11,65:fori=1to500:next:pokes+24,.
30130 pokes+4,.:pokes+11,.:return
30135 t%=7217:pokes+24,.:pokes+24,15:pokes+24,.:pokes+24,15
30140 pokes,t%and255:pokes+1,t%/256:forp=1to200:pokes+4,16:pokes+4,17:next
30145 pokes+4,16:return
30150 input"[211]ystem to access";i$:gosub200:ifi$="off"then30200
30155 fori=1to1000:next:ifi$<>"govt"thenprint"[213]nknown system":goto30150
30160 print"[156][199][207][214][212]:  [213].[211]. [199]ovt. [196]atabase":print"[208]hone [206]umber:  "p$
30165 print"[129][201]s this correct ([217]/[206])?[160]";
30170 poke198,.:wait198,1:geti$:ifi$="[206]"ori$="n"thenprint"[206]ope.":print"":goto30150
30175 ifi$<>"[217]"andi$<>"y"then30165
30180 print"[217]eah!":goto30030
30200 poke53270,4:fori=1to2000:next:goto10010
30500 print:print"searching for term6400":close8:close15:open8,8,8,"#"
30502 open15,8,15,"u1:8 0 18 0":print#15,"u1:8 0 18 0"
30505 fori=1to1000:next:print"loading"
30510 fori=1to4:print#15,"u1:8 0 "int(rnd(1)*30+3);.:forj=1tornd(1)*2000+1000
30515 next:next:close8:close15:goto30000