home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 1.ddi / FILEINFO.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  11.5 KB  |  332 lines
  1.   ' ************************************************
  2.   ' **  Name:          FILEINFO                   **
  3.   ' **  Type:          Toolbox                    **
  4.   ' **  Module:        FILEINFO.BAS               **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' Collection of subprograms and functions for accessing
  9.   ' directory information about files.
  10.   '
  11.   ' USAGE:           No command line parameters
  12.   ' REQUIREMENTS:    MIXED.QLB/.LIB
  13.   ' .MAK FILE:       (none)
  14.   ' PARAMETERS:      (none)
  15.   ' VARIABLES:       path$      Path to files for gathering directory
  16.   '                             information; wildcard characters accepted
  17.   '                  dta$       Disk transfer area buffer string
  18.   '                  result%    Code returned as result of directory search
  19.   '                  file       Structure of type FileDataType
  20.   '                  n%         File count
  21.   
  22.   ' File search attribute bits
  23.     CONST ISNORMAL = 0
  24.     CONST ISREADONLY = 1
  25.     CONST ISHIDDEN = 2
  26.     CONST ISSYSTEM = 4
  27.     CONST ISVOLUMELABEL = 8
  28.     CONST ISSUBDIRECTORY = 16
  29.     CONST ISARCHIVED = 32
  30.   
  31.   ' Here we'll search for normal files and subdirectories
  32.     CONST FILEATTRIBUTE = ISNORMAL + ISSUBDIRECTORY
  33.   
  34.     TYPE RegTypeX
  35.         ax    AS INTEGER
  36.         bx    AS INTEGER
  37.         cx    AS INTEGER
  38.         dx    AS INTEGER
  39.         bp    AS INTEGER
  40.         si    AS INTEGER
  41.         di    AS INTEGER
  42.         flags AS INTEGER
  43.         ds    AS INTEGER
  44.         es    AS INTEGER
  45.     END TYPE
  46.   
  47.     TYPE FileDataType
  48.         finame    AS STRING * 12
  49.         year      AS INTEGER
  50.         month     AS INTEGER
  51.         day       AS INTEGER
  52.         hour      AS INTEGER
  53.         minute    AS INTEGER
  54.         second    AS INTEGER
  55.         attribute AS INTEGER
  56.         size      AS LONG
  57.     END TYPE
  58.   
  59.   ' Subprograms
  60.     DECLARE SUB INTERRUPTX (intnum%, inreg AS RegTypeX, outreg AS RegTypeX)
  61.     DECLARE SUB FindFirstFile (path$, dta$, result%)
  62.     DECLARE SUB FindNextFile (dta$, result%)
  63.     DECLARE SUB GetFileData (dta$, file AS FileDataType)
  64.   
  65.   ' Data structures
  66.     DIM file AS FileDataType
  67.   
  68.   ' For demonstration purposes, list current directory
  69.     CLS
  70.     path$ = "*.*"
  71.   
  72.   ' Always start by finding the first match
  73.     FindFirstFile path$, dta$, result%
  74.   
  75.   ' Check that the path$ got us off to a good start
  76.     IF result% THEN
  77.         PRINT "Error: FindFirstFile - found no match for path$"
  78.         SYSTEM
  79.     END IF
  80.   
  81.   ' List all the files in this directory
  82.     DO
  83.         IF n% MOD 19 = 0 THEN
  84.             CLS
  85.             PRINT TAB(4); "File"; TAB(18); "Date"; TAB(29); "Time";
  86.             PRINT TAB(39); "Size"; TAB(48); "Attributes"
  87.             PRINT
  88.         END IF
  89.         GetFileData dta$, file
  90.         PRINT file.finame;
  91.         PRINT USING "  ##/##/####"; file.month, file.day, file.year;
  92.         PRINT USING "  ##:##:##"; file.hour, file.minute, file.second;
  93.         PRINT USING "  ########"; file.size;
  94.         PRINT SPACE$(6);
  95.         PRINT "&H";
  96.         PRINT RIGHT$("0" + HEX$(file.attribute), 2)
  97.         n% = n% + 1
  98.         FindNextFile dta$, result%
  99.         IF n% MOD 19 = 0 THEN
  100.             PRINT
  101.             PRINT "Press any key to continue"
  102.             DO
  103.             LOOP WHILE INKEY$ = ""
  104.         END IF
  105.     LOOP UNTIL result%
  106.     PRINT
  107.     PRINT n%; "files found"
  108.  
  109.   ' ************************************************
  110.   ' **  Name:          FindFirstFile              **
  111.   ' **  Type:          Subprogram                 **
  112.   ' **  Module:        FILEINFO.BAS               **
  113.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  114.   ' ************************************************
  115.   '
  116.   ' Finds first file that matches the path$.
  117.   '
  118.   ' EXAMPLE OF USE:  FindFirstFile path$, dta$, result%
  119.   ' PARAMETERS:      path$      Complete path, including wildcard characters if
  120.   '                             desired, for the directory search
  121.   '                  dta$       Disk transfer area buffer space
  122.   '                  result%    Returned result code for the search
  123.   ' VARIABLES:       reg        Structure of type RegTypeX
  124.   '                  thePath$   Null terminated version of path$
  125.   '                  sgmt%      Current DTA address segment
  126.   '                  ofst%      Current DTA address offset
  127.   ' MODULE LEVEL
  128.   '   DECLARATIONS:  File search attribute bits
  129.   '                     CONST ISNORMAL = 0
  130.   '                     CONST ISREADONLY = 1
  131.   '                     CONST ISHIDDEN = 2
  132.   '                     CONST ISSYSTEM = 4
  133.   '                     CONST ISVOLUMELABEL = 8
  134.   '                     CONST ISSUBDIRECTORY = 16
  135.   '                     CONST ISARCHIVED = 32
  136.   '
  137.   '                     CONST FILEATTRIBUTE = ISNORMAL + ISSUBDIRECTORY
  138.   '
  139.   '                     TYPE RegTypeX
  140.   '                        ax    AS INTEGER
  141.   '                        bx    AS INTEGER
  142.   '                        cx    AS INTEGER
  143.   '                        dx    AS INTEGER
  144.   '                        bp    AS INTEGER
  145.   '                        si    AS INTEGER
  146.   '                        di    AS INTEGER
  147.   '                        flags AS INTEGER
  148.   '                        ds    AS INTEGER
  149.   '                        es    AS INTEGER
  150.   '                     END TYPE
  151.   '
  152.   '   DECLARE SUB INTERRUPTX (intnum%, inreg AS RegTypeX, outreg AS RegTypeX)
  153.   '   DECLARE SUB FindFirstFile (path$, dta$, result%)
  154.   '
  155.     SUB FindFirstFile (path$, dta$, result%) STATIC
  156.       
  157.       ' Initialization
  158.         DIM reg AS RegTypeX
  159.       
  160.       ' The path must be a null terminated string
  161.         thePath$ = path$ + CHR$(0)
  162.       
  163.       ' Get current DTA address
  164.         reg.ax = &H2F00
  165.         INTERRUPTX &H21, reg, reg
  166.         sgmt% = reg.es
  167.         ofst% = reg.bx
  168.       
  169.       ' Set dta address
  170.         dta$ = SPACE$(43)
  171.         reg.ax = &H1A00
  172.         reg.ds = VARSEG(dta$)
  173.         reg.dx = SADD(dta$)
  174.         INTERRUPTX &H21, reg, reg
  175.       
  176.       ' Find first file match
  177.         reg.ax = &H4E00
  178.         reg.cx = FILEATTRIBUTE
  179.         reg.ds = VARSEG(thePath$)
  180.         reg.dx = SADD(thePath$)
  181.         INTERRUPTX &H21, reg, reg
  182.       
  183.       ' The carry flag tells if a file was found or not
  184.         result% = reg.flags AND 1
  185.       
  186.       ' Reset the original DTA
  187.         reg.ax = &H1A00
  188.         reg.ds = sgmt%
  189.         reg.dx = ofst%
  190.         INTERRUPTX &H21, reg, reg
  191.       
  192.     END SUB
  193.  
  194.   ' ************************************************
  195.   ' **  Name:          FindNextFile               **
  196.   ' **  Type:          Subprogram                 **
  197.   ' **  Module:        FILEINFO.BAS               **
  198.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  199.   ' ************************************************
  200.   '
  201.   ' Locates next file. FindFirstFile must be called
  202.   ' before this subprogram is called.
  203.   '
  204.   ' EXAMPLE OF USE: FindNextFile dta$, result%
  205.   ' PARAMETERS:      dta$       Previously filled-in Disk Transfer Area
  206.   '                             buffer string
  207.   '                  result%    Result code for the search
  208.   ' VARIABLES:       reg        Structure of type RegTypeX
  209.   '                  thePath$   Null terminated version of path$
  210.   '                  sgmt%      Current DTA address segment
  211.   '                  ofst%      Current DTA address offset
  212.   ' MODULE LEVEL
  213.   '   DECLARATIONS:  CONST ISNORMAL = 0
  214.   '                  CONST ISREADONLY = 1
  215.   '                  CONST ISHIDDEN = 2
  216.   '                  CONST ISSYSTEM = 4
  217.   '                  CONST ISVOLUMELABEL = 8
  218.   '                  CONST ISSUBDIRECTORY = 16
  219.   '                  CONST ISARCHIVED = 32
  220.   '
  221.   '                  CONST FILEATTRIBUTE = ISNORMAL + ISSUBDIRECTORY
  222.   '
  223.   '                     TYPE RegTypeX
  224.   '                        ax    AS INTEGER
  225.   '                        bx    AS INTEGER
  226.   '                        cx    AS INTEGER
  227.   '                        dx    AS INTEGER
  228.   '                        bp    AS INTEGER
  229.   '                        si    AS INTEGER
  230.   '                        di    AS INTEGER
  231.   '                        flags AS INTEGER
  232.   '                        ds    AS INTEGER
  233.   '                        es    AS INTEGER
  234.   '                     END TYPE
  235.   '
  236.   '   DECLARE SUB INTERRUPTX (intnum%, inreg AS RegTypeX, outreg AS RegTypeX)
  237.   '   DECLARE SUB FindNextFile (dta$, result%)
  238.   '
  239.     SUB FindNextFile (dta$, result%) STATIC
  240.       
  241.       ' Initialization
  242.         DIM reg AS RegTypeX
  243.       
  244.       ' Be sure dta$ was built (FindFirstFile should have been called)
  245.         IF LEN(dta$) <> 43 THEN
  246.             result% = 2
  247.             EXIT SUB
  248.         END IF
  249.       
  250.       ' Get current DTA address
  251.         reg.ax = &H2F00
  252.         INTERRUPTX &H21, reg, reg
  253.         sgmt% = reg.es
  254.         ofst% = reg.bx
  255.       
  256.       ' Set dta address
  257.         reg.ax = &H1A00
  258.         reg.ds = VARSEG(dta$)
  259.         reg.dx = SADD(dta$)
  260.         INTERRUPTX &H21, reg, reg
  261.       
  262.       ' Find next file match
  263.         reg.ax = &H4F00
  264.         reg.cx = FILEATTRIBUTE
  265.         reg.ds = VARSEG(thePath$)
  266.         reg.dx = SADD(thePath$)
  267.         INTERRUPTX &H21, reg, reg
  268.       
  269.       ' The carry flag tells whether a file was found or not
  270.         result% = reg.flags AND 1
  271.       
  272.       ' Reset the original DTA
  273.         reg.ax = &H1A00
  274.         reg.ds = sgmt%
  275.         reg.dx = ofst%
  276.         INTERRUPTX &H21, reg, reg
  277.       
  278.     END SUB
  279.  
  280.   ' ************************************************
  281.   ' **  Name:          GetFileData                **
  282.   ' **  Type:          Subprogram                 **
  283.   ' **  Module:        FILEINFO.BAS               **
  284.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  285.   ' ************************************************
  286.   '
  287.   ' Extracts the file directory information from a Disk
  288.   ' Transfer Area (dta$) that has been filled in by a
  289.   ' call to either FindFirstFile or FindNextFile.
  290.   '
  291.   ' EXAMPLE OF USE:  GetFileData dta$, file
  292.   ' PARAMETERS:      dta$       Disk Transfer Area buffer string passed back from
  293.   '                             either FindFirstFile or FindNextFile
  294.   ' VARIABLES:       tim&       Time stamp of the file
  295.   '                  dat&       Date stamp of the file
  296.   '                  f$         Filename during extraction
  297.   ' MODULE LEVEL
  298.   '   DECLARATIONS:  TYPE FileDataType
  299.   '                     finame    AS STRING * 12
  300.   '                     year      AS INTEGER
  301.   '                     month     AS INTEGER
  302.   '                     day       AS INTEGER
  303.   '                     hour      AS INTEGER
  304.   '                     minute    AS INTEGER
  305.   '                     second    AS INTEGER
  306.   '                     attribute AS INTEGER
  307.   '                     size      AS LONG
  308.   '                  END TYPE
  309.   '
  310.   '                  DECLARE SUB GetFileData (dta$, file AS FileDataType)
  311.   '
  312.     SUB GetFileData (dta$, file AS FileDataType) STATIC
  313.       
  314.         file.attribute = ASC(MID$(dta$, 22, 1))
  315.         tim& = CVI(MID$(dta$, 23, 2))
  316.         IF tim& < 0 THEN
  317.             tim& = tim& + 65536
  318.         END IF
  319.         file.second = tim& AND &H1F
  320.         file.minute = (tim& \ 32) AND &H3F
  321.         file.hour = (tim& \ 2048) AND &H1F
  322.         dat& = CVI(MID$(dta$, 25, 2))
  323.         file.day = dat& AND &H1F
  324.         file.month = (dat& \ 32) AND &HF
  325.         file.year = ((dat& \ 512) AND &H1F) + 1980
  326.         file.size = CVL(MID$(dta$, 27, 4))
  327.         f$ = MID$(dta$, 31) + CHR$(0)
  328.         file.finame = LEFT$(f$, INSTR(f$, CHR$(0)) - 1)
  329.       
  330.     END SUB
  331.  
  332.