home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 1.ddi / FIGETPUT.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  4.1 KB  |  127 lines
  1.   ' ************************************************
  2.   ' **  Name:          FIGETPUT                   **
  3.   ' **  Type:          Toolbox                    **
  4.   ' **  Module:        FIGETPUT.BAS               **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' Reads itself (FIGETPUT.BAS) into a string,
  9.   ' converts characters to uppercase, counts occurrences of
  10.   ' the characters "A" through "Z," and saves the
  11.   ' result in a file named FIGETPUT.TST.
  12.   '
  13.   ' USAGE:           No command line parameters
  14.   ' .MAK FILE:       (none)
  15.   ' PARAMETERS:      filename
  16.   ' VARIABLES:       count%()   Tally array for the 26 alpha characters
  17.   '                  fileName$  Name of file to be processed
  18.   '                  a$         Contents of the file
  19.   '                  i%         Looping index
  20.   '                  c%         ASCII value of each file byte
  21.   
  22.   ' Functions
  23.     DECLARE FUNCTION FileGet$ (fileName$)
  24.   
  25.   ' Subprograms
  26.     DECLARE SUB FilePut (fileName$, a$)
  27.   
  28.   ' Dimension array of counts for each ASCII code "A" to "Z"
  29.     DIM count%(65 TO 90)
  30.   
  31.   ' Read in the file (must be no greater than 32767 bytes long)
  32.     a$ = FileGet$("FIGETPUT.BAS")
  33.   
  34.   ' Convert to uppercase
  35.     a$ = UCASE$(a$)
  36.   
  37.   ' Count the letters
  38.     FOR i% = 1 TO LEN(a$)
  39.         c% = ASC(MID$(a$, i%, 1))
  40.         IF c% >= 65 AND c% <= 90 THEN
  41.             count%(c%) = count%(c%) + 1
  42.         END IF
  43.     NEXT i%
  44.   
  45.   ' Output the results
  46.     CLS
  47.     PRINT "Alphabetic character count for FIGETPUT.BAS"
  48.     PRINT
  49.     FOR i% = 65 TO 90
  50.         PRINT CHR$(i%); " -"; count%(i%),
  51.     NEXT i%
  52.   
  53.   ' Write out the new file
  54.     FilePut "FIGETPUT.TST", a$
  55.   
  56.   ' All done
  57.     END
  58.  
  59.   ' ************************************************
  60.   ' **  Name:          FileGet$                   **
  61.   ' **  Type:          Function                   **
  62.   ' **  Module:        FIGETPUT.BAS               **
  63.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  64.   ' ************************************************
  65.   '
  66.   ' Returns a string containing the contents of a file.
  67.   ' Maximum file length is 32767 bytes.
  68.   '
  69.   ' EXAMPLE OF USE:  a$ = FileGet$(fileName$)
  70.   ' PARAMETERS:      fileName$     Name of file to be accessed
  71.   ' VARIABLES:       fileNumber    Next available free file number
  72.   '                  length&       Length of file
  73.   '                  a$            String for binary read of file
  74.   ' MODULE LEVEL
  75.   '   DECLARATIONS:  DECLARE FUNCTION FileGet$ (fileName$)
  76.   '
  77.     FUNCTION FileGet$ (fileName$) STATIC
  78.         fileNumber = FREEFILE
  79.         OPEN fileName$ FOR BINARY AS #fileNumber
  80.         length& = LOF(fileNumber)
  81.         IF length& <= 32767 THEN
  82.             a$ = SPACE$(length&)
  83.             GET #fileNumber, , a$
  84.             FileGet$ = a$
  85.             a$ = ""
  86.         ELSE
  87.             PRINT "FileGet$()... file too large"
  88.             SYSTEM
  89.         END IF
  90.         CLOSE #fileNumber
  91.     END FUNCTION
  92.  
  93.   ' ************************************************
  94.   ' **  Name:          FilePut                    **
  95.   ' **  Type:          Subprogram                 **
  96.   ' **  Module:        FIGETPUT.BAS               **
  97.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  98.   ' ************************************************
  99.   '
  100.   ' Writes contents of a$ into a binary file named fileName$.
  101.   '
  102.   ' EXAMPLE OF USE:  FilePut fileName$, a$
  103.   ' PARAMETERS:      fileName$  Name of file to be written
  104.   '                  a$         Bytes to be placed in the file
  105.   ' VARIABLES:       fileNumber Next available free file number
  106.   ' MODULE LEVEL
  107.   '   DECLARATIONS:  DECLARE SUB FilePut (fileName$, a$)
  108.   '
  109.     SUB FilePut (fileName$, a$) STATIC
  110.       
  111.       ' Find available file number
  112.         fileNumber = FREEFILE
  113.       
  114.       ' Truncate any previous contents
  115.         OPEN fileName$ FOR OUTPUT AS #fileNumber
  116.         CLOSE #fileNumber
  117.       
  118.       ' Write string to file
  119.         OPEN fileName$ FOR BINARY AS #fileNumber
  120.         PUT #fileNumber, , a$
  121.       
  122.       ' All done
  123.         CLOSE #fileNumber
  124.       
  125.     END SUB
  126.  
  127.