home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c083 / 21.ddi / START16.PAK / C0W.ASM < prev    next >
Encoding:
Assembly Source File  |  1993-12-02  |  13.5 KB  |  390 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      C0W.ASM -- Start Up Code For Windows                    |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 6.0
  7. ; 
  8. ;       Copyright (c) 1991, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.                 locals
  13.  
  14.                 __C0__ = 1
  15. include         RULES.ASI
  16.  
  17.                 ASSUME CS:_TEXT, DS:DGROUP
  18.  
  19.                 public  __acrtused              ;satisfy MS for now
  20. __acrtused      equ     0
  21.                 public  __WINMAINCALL           ; used internally
  22.                 public  __INITAPPCALLED         ; used internally
  23.  
  24. extrn           WINMAIN:DIST
  25. extrn           INITAPP:far
  26. extrn           INITTASK:far
  27. extrn           FATALEXIT:far
  28. extrn           WAITEVENT:far
  29. extrn           LOCKSEGMENT:far
  30. extrn           UNLOCKSEGMENT:far
  31. extrn           GETWINFLAGS:far
  32. extrn           _exit:DIST
  33. extrn           __exitbuf:DIST
  34. extrn           __exitfopen:DIST
  35. extrn           __exitopen:DIST
  36. extrn           __setupio:near                  ;required!
  37. extrn           __ExceptInit:DIST
  38.  
  39.                 public __DestructorCount        ;Offset to global destructor count
  40. __DestructorCount EQU  10H
  41.                 public __Exception_list         ;Offset to global exception list
  42. __Exception_list  EQU  14H
  43. NULL            segment
  44.                 db      16 dup (0)              ;Windows
  45.                 db       4 dup (0)              ;destructor count
  46.                 db       2 dup (0)              ;exception list
  47.                 db       4 dup (0)              ;exception vptr
  48.                 db       6 dup (0)              ;reserved
  49.                 db       2 dup (0)              ;VBX control jump vector
  50.                                                 ;MUST be at SS:20h
  51.                 db       2 dup (0)              ;reserved
  52.                 ends
  53.  
  54. _CVTSEG         segment
  55.                 public __RealCvtVector
  56. __RealCvtVector label word
  57.                 ends
  58.  
  59. _SCNSEG         segment
  60.                 public __ScanTodVector
  61. __ScanTodVector label word
  62.                 ends
  63.  
  64. _FPSEG          segment
  65.                 public __FPVector
  66. __FPVector      dd      0
  67.                 ends
  68.  
  69. _DATA           segment
  70.                 public _errno
  71. _errno          dw      0
  72.                 public __protected
  73. __protected     dw      0
  74.                 public __8086
  75. __8086          dw      0
  76.                 public __8087
  77. __8087          dw      0
  78.                 public __psp
  79. __psp           dw      0
  80.                 public __hInstance
  81. __hInstance     dw      0
  82.                 public __hPrev
  83. __hPrev         dw      0
  84.                 public __pszCmdline
  85. __pszCmdline    dw      0
  86.                 public __cmdShow
  87. __cmdShow       dw      0
  88.                 public __version
  89. __version       label word
  90.                 public __osversion
  91. __osversion     label word
  92.                 public __osmajor
  93. __osmajor       db      0
  94.                 public __osminor
  95. __osminor       db      0
  96.                 public __osmode         ;Used for OS/2 protected mode by MS,
  97. __osmode        db      0               ;currently set to 0 under Windows
  98.                 public __WinAllocFlag   ;Used by malloc to get additional flags
  99. __WinAllocFlag  dw      0               ;to pass to GlobalAlloc (for DLL use)
  100.                 public __LockWIN87EM    ;Used do lock down WIN87EM to avoid
  101. __LockWIN87EM   dw      1               ;DLL unload ordering problem
  102.  
  103. CopyRight       db      'Borland C++ - Copyright 1993 Borland Intl.',0
  104.                 ends
  105.  
  106. _TEXT           segment
  107.  
  108. Main            proc near
  109.  
  110. ;Windows initialization.  Sets up registers and stack.
  111.  
  112.                 push    bx cx es
  113.                 xor     ax,ax
  114.                 push    ax
  115.                 call    __ExceptInit
  116.                 pop     ax
  117.                 pop     es cx bx
  118.  
  119.                 ;INITTASK returns:
  120.                 ;  'Failure:
  121.                 ;    AX = zero if it failed
  122.                 ;  Success:
  123.                 ;    AX = 1
  124.                 ;    CX = stack limit
  125.                 ;    DX = cmdShow parameter to CreateWindow
  126.                 ;    ES:BX = -> DOS format command line (ES = PSP address)
  127.                 ;    SI = hPrevinstance
  128.                 ;    DI = hinstance
  129.                 call    INITTASK
  130.                 or      ax,ax
  131.                 jnz     @@OK
  132.                 jmp     @@Fail
  133. @@OK:           mov     word ptr ss:[__Exception_list], -1
  134.                 mov     __psp,es
  135.                 mov     word ptr __pszCmdline,bx
  136.                 mov     __hPrev,si
  137.                 mov     __hInstance,di
  138.                 mov     __cmdShow,dx
  139.  
  140. IF LDATA EQ false
  141.                 mov     ax,-1
  142.                 push    ax
  143.                 call    LOCKSEGMENT
  144. ENDIF
  145.  
  146. ;Clear _BSS, uninitialized data area
  147.  
  148. IFNDEF  __HUGE__
  149.                 xor     ax, ax
  150.                 push    ds
  151.                 pop     es
  152.                 mov     di,offset DGROUP:BeginBSS
  153.                 mov     cx,offset DGROUP:EndBSS
  154.                 sub     cx,di
  155.                 cld
  156.                 rep
  157.                 stosb
  158. ENDIF
  159.  
  160. ;Init the Windows App
  161.  
  162.                 xor     ax,ax
  163.                 push    ax
  164.                 call    WAITEVENT
  165.                 push    __hInstance
  166.                 call    INITAPP
  167. __INITAPPCALLED:or      ax,ax
  168.                 jnz     @@InitOK
  169.                 jmp     @@Fail
  170. @@InitOK:
  171.  
  172. ;Determine DOS version
  173.  
  174.                 mov     ah, 30h
  175.                 int     21h
  176.                 mov     __version, ax   ; save minor and major revision
  177.  
  178. ;Determine whether we are in protected mode
  179.  
  180.                 call    GETWINFLAGS
  181.                 test    ax,1            ; WF_PMODE = 1
  182.                 jz      @@realmode      ; Note:  GETWINFLAGS returns a long,
  183.                                         ; so if WF_PMODE changed it could be
  184.                                         ; in the high word.
  185.                 mov     __protected, 8  ; Eight is for convenience.
  186. @@realmode:
  187.  
  188. ;Test for 8086/8087 presence
  189.  
  190.                 test    ax,0400h        ; WF_8087 = 0x0400
  191.                 jz      @@no8087
  192.                 mov     __8087, 1
  193. @@no8087:
  194.                 and     ax,08h+04h+02h  ; WF_CPU486|WF_CPU386|WF_CPU286 
  195.                 shr     ax,1            ; Convert to 4 or 2 or 1 or 0
  196.                 test    ax,0004h        ; Have 4, 486 done
  197.                 jnz     @@NoAdjust
  198.                 or      ax,ax           ; Have 0, 8086 done
  199.                 jz      @@NoAdjust      
  200.                 inc     ax              ; Have 2 or 1, need 3 or 2
  201. @@NoAdjust:
  202.                 mov     __8086,ax       ; Set CPU Type
  203.  
  204.  
  205. ;Call our initialization functions, including C++ static constructors.
  206.  
  207.                 mov     ax,ds
  208.                 mov     es,ax
  209.                 mov     si,offset DGROUP:InitStart      ;si = start of table
  210.                 mov     di,offset DGROUP:InitEnd        ;di = end of table
  211.                 call    Initialize
  212.  
  213. ;Set up and call WinMain
  214.  
  215.                 push    __hInstance
  216.                 push    __hPrev
  217.                 push    __psp
  218.                 push    word ptr __pszCmdline
  219.                 push    __cmdShow
  220. __WINMAINCALL:  call    WINMAIN
  221.                 push    ax
  222.                 call    _exit
  223.  
  224. ;---------------------------------------------------------------------------
  225. ;       _cleanup()      call all #pragma exit cleanup routines.
  226. ;       _checknull()    check for null pointer zapping copyright message
  227. ;       _terminate(int) exit program with error code
  228. ;       _restorezero()  restore interrupt vectors
  229. ;
  230. ;       These functions are called by exit(), _exit(), _cexit(),
  231. ;       and _c_exit().
  232. ;---------------------------------------------------------------------------
  233.  
  234. ;       Call cleanup routines
  235.  
  236. __cleanup       PROC    DIST
  237.                 PUBLIC  __cleanup
  238.  
  239.                 mov     ax,ds
  240.                 mov     es,ax
  241.                 push    si
  242.                 push    di
  243.                 mov     si,offset DGROUP:ExitStart
  244.                 mov     di,offset DGROUP:ExitEnd
  245.                 call    Cleanup
  246.                 pop     di
  247.                 pop     si
  248.                 ret
  249. __cleanup       ENDP
  250.  
  251. ;       Check for null pointers before exit.  NO-OP on Windows.
  252.  
  253. __checknull     PROC    DIST
  254.                 PUBLIC  __checknull
  255.                 ret
  256. __checknull     ENDP
  257.  
  258. ;       Restore grabbed interrupt vectors.  NO-OP on Windows.
  259.  
  260. __restorezero     PROC    DIST
  261.                 PUBLIC  __restorezero
  262.                 ret
  263. __restorezero     ENDP
  264.  
  265. ;       Exit to DOS
  266.  
  267. __terminate     PROC    DIST
  268.                 PUBLIC  __terminate
  269.  
  270. IF LDATA EQ false
  271.                 mov     ax,-1
  272.                 push    ax
  273.                 call    UNLOCKSEGMENT
  274. ENDIF
  275.                 mov     bp,sp
  276.                 mov     al,[bp+cPtrSize]
  277.                 mov     ah,4ch                  ;exit
  278.                 int     21h
  279. __terminate     ENDP
  280.  
  281. @@Fail:         mov     al,0ffh
  282.                 push    ax
  283.                 call    _exit
  284.  
  285.                 mov     ah,4ch                  ;exit
  286.                 int     21h
  287.                 endp
  288.  
  289. ;       Return default data segment in AX
  290.  
  291. __GetDGROUP     PROC    FAR
  292.                 PUBLIC  __GetDGROUP
  293.                 mov     ax, ss
  294.                 ret
  295.                 endp
  296.  
  297. ;------------------------------------------------------------------
  298. ;  Loop through a startup/exit (SE) table,
  299. ;  calling functions in order of priority.
  300. ;  ES:SI is assumed to point to the beginning of the SE table
  301. ;  ES:DI is assumed to point to the end of the SE table
  302. ;  First 64 priorities are reserved by Borland
  303. ;------------------------------------------------------------------
  304. PNEAR           EQU     0
  305. PFAR            EQU     1
  306. NOTUSED         EQU     0ffh
  307.  
  308. SE              STRUC
  309. calltype        db      ?                       ; 0=near,1=far,ff=not used
  310. priority        db      ?                       ; 0=highest,ff=lowest
  311. addrlow         dw      ?
  312. addrhigh        dw      ?
  313. SE              ENDS
  314.  
  315. Initialize      proc near
  316. @@Start:        mov     ax,100h                 ;start with lowest priority
  317.                 mov     dx,di                   ;set sentinel to end of table
  318.                 mov     bx,si                   ;bx = start of table
  319.  
  320. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  321.                 je      @@EndOfTable            ;yes, exit the loop
  322.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  323.                 je      @@Next
  324.                 mov     cl, es:[bx.priority]    ;move priority to CX
  325.                 xor     ch, ch
  326.                 cmp     cx,ax                   ;check the priority
  327.                 jae     @@Next                  ;too high?  skip
  328.                 mov     ax,cx                   ;keep priority
  329.                 mov     dx,bx                   ;keep index in dx
  330. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  331.                 jmp     @@TopOfTable
  332.  
  333. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  334.                 je      @@Done                  ;yes, quit
  335.                 mov     bx,dx                   ;bx = highest priority item
  336.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  337.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  338.                 push    es                      ;save es
  339.                 je      @@NearCall
  340.  
  341. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  342.                 pop     es                      ;restore es
  343.                 jmp     short @@Start
  344.  
  345. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  346.                 pop     es                      ;restore es
  347.                 jmp     short @@Start
  348.  
  349. @@Done:         ret
  350.                 endp
  351.  
  352. Cleanup         proc near
  353. @@Start:        mov     ah,0                    ;start with highest priority
  354.                 mov     dx,di                   ;set sentinel to end of table
  355.                 mov     bx,si                   ;bx = start of table
  356.  
  357. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  358.                 je      @@EndOfTable            ;yes, exit the loop
  359.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  360.                 je      @@Next
  361.                 cmp     es:[bx.priority],ah     ;check the priority
  362.                 jb      @@Next                  ;too low?  skip
  363.                 mov     ah,es:[bx.priority]     ;keep priority
  364.                 mov     dx,bx                   ;keep index in dx
  365. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  366.                 jmp     @@TopOfTable
  367.  
  368. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  369.                 je      @@Done                  ;yes, quit
  370.                 mov     bx,dx                   ;bx = highest priority item
  371.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  372.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  373.                 push    es                      ;save es
  374.                 je      @@NearCall
  375.  
  376. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  377.                 pop     es                      ;restore es
  378.                 jmp     short @@Start
  379.  
  380. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  381.                 pop     es                      ;restore es
  382.                 jmp     short @@Start
  383.  
  384. @@Done:         ret
  385.                 endp
  386.  
  387.                 ends
  388.  
  389.                 end Main
  390.