home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 7 / 07.iso / c / c083 / 21.ddi / START16.PAK / C0D.ASM < prev    next >
Encoding:
Assembly Source File  |  1993-12-02  |  14.0 KB  |  388 lines
  1. ;[]------------------------------------------------------------[]
  2. ;|      C0D.ASM -- Start Up Code For Windows DLLs               |
  3. ;[]------------------------------------------------------------[]
  4.  
  5. ;
  6. ;       C/C++ Run Time Library - Version 6.0
  7. ; 
  8. ;       Copyright (c) 1991, 1992 by Borland International
  9. ;       All Rights Reserved.
  10. ; 
  11.  
  12.                 locals
  13.  
  14.                 __C0__ = 1
  15. include         RULES.ASI
  16.  
  17.                 ASSUME CS:_TEXT, DS:DGROUP
  18.  
  19.                 public  __acrtused              ;satisfy MS for now
  20. __acrtused      equ     0
  21.  
  22.  
  23.                 extrn LIBMAIN:far       ;the C routine to be called
  24.                 extrn LOCALINIT:far     ;Windows heap init routine
  25.                 extrn LOCKSEGMENT:far
  26.                 extrn UNLOCKSEGMENT:far
  27.                 extrn GETWINFLAGS:far
  28.                 extrn __WEP:far
  29.                 extrn __cexit:DIST
  30.                 extrn __setupio:near    ;required!
  31.  
  32.                 public LibEntry         ;Entry point for the DLL
  33.                 publicdll WEP
  34.  
  35. NULL            segment
  36.                 db      16 dup (0)              ;Windows
  37.                 db       4 dup (0)              ;destructor count
  38.                 db       2 dup (0)              ;exception list
  39.                 db       4 dup (0)              ;exception vptr
  40.                 db       6 dup (0)              ;reserved
  41.                 db       2 dup (0)              ;VBX control jump vector
  42.                                                 ;MUST be at SS:20h
  43.                 db       2 dup (0)              ;reserved
  44.                 ends
  45.  
  46. _CVTSEG         segment
  47.                 public __RealCvtVector
  48. __RealCvtVector label word
  49.                 ends
  50.  
  51. _SCNSEG         segment
  52.                 public __ScanTodVector
  53. __ScanTodVector label word
  54.                 ends
  55.  
  56. _FPSEG          segment
  57.                 public __FPVector
  58. __FPVector      dd      0
  59.                 ends
  60.  
  61. _DATA           segment
  62.                 public _errno
  63. _errno          dw      0
  64.                 public __protected
  65. __protected     dw      0
  66.                 public __8086
  67. __8086          dw      0
  68.                 public __8087
  69. __8087          dw      0
  70.                 public __version
  71. __version       label word
  72.                 public __osversion
  73. __osversion     label word
  74.                 public __osmajor
  75. __osmajor       db      0
  76.                 public __osminor
  77. __osminor       db      0
  78.                 public __osmode         ;Used for OS/2 protected mode by MS,
  79. __osmode        db      0               ;currently set to 0 under Windows
  80.                 public __hInstance
  81. __hInstance     dw      0
  82.                 public __WinAllocFlag   ;Used by malloc for additional flags
  83. __WinAllocFlag  dw      2000h           ;to pass to GlobalAlloc (used in DLLs)
  84.                                         ;default value is GMEM_SHARE
  85.                 public __LockWIN87EM    ;Used do lock down WIN87EM to avoid
  86. __LockWIN87EM   dw      1               ;DLL unload ordering problem
  87.  
  88. _abend          dw      1               ;If LibEntry is called gets set to
  89.                                         ;normal state (0).  If it is 1 then
  90.                                         ;exit routines are not performed
  91.                                         ;Gets set to 1 if DLL is terminated
  92.                                         ;by a call to abort() or _exit().
  93.  
  94. CopyRight       db      'Borland C++ - Copyright 1991 Borland Intl.',0
  95.                 ends
  96.  
  97. _TEXT           segment
  98.  
  99. LibEntry        proc far
  100.                 mov     __hInstance, di ;save SI and DI
  101.                 push    si
  102.  
  103.                 push    di              ;handle of the module instance
  104.                 push    ds              ;library data segment
  105.                 push    cx              ;heap size
  106.                 push    es              ;command line segment
  107.                 push    si              ;command line offset
  108.  
  109.                 ;if we have some heap then initialize it
  110.                 jcxz    @@Init          ;jump if no heap specified
  111.  
  112.                 ;call the Windows function LocalInit() to set up the heap
  113.                 ;LocalInit((LPSTR)start, WORD cbHeap);
  114.  
  115.                 push    ds              ;Heap segment
  116.                 xor     ax,ax
  117.                 push    ax              ;Heap start offset in segment
  118.                 push    cx              ;Heap end offset in segment
  119.                 call    LOCALINIT
  120.                 xchg    ax,cx
  121.                 jcxz    @@JmpExit       ;quit if it failed
  122.                 jmp     short @@Init
  123. @@JmpExit:      jmp     @@Exit
  124.  
  125. @@Init:
  126.  
  127. IF LDATA EQ false
  128.                 mov     ax,-1
  129.                 push    ax
  130.                 call    LOCKSEGMENT
  131. ENDIF
  132.  
  133.                 ;Clear _BSS, uninitialized data area
  134.  
  135.                 xor     ax, ax
  136.                 push    ds
  137.                 pop     es
  138.                 mov     di,offset DGROUP:BeginBSS
  139.                 mov     cx,offset DGROUP:EndBSS
  140.                 sub     cx,di
  141.                 cld
  142.                 rep
  143.                 stosb
  144.  
  145. ;Determine DOS version
  146.  
  147.                 mov     ah, 30h
  148.                 int     21h
  149.                 mov     __version, ax   ; save minor and major revision
  150.  
  151. ;Determine whether we are in protected mode
  152.  
  153.                 call    GETWINFLAGS
  154.                 test    ax,1            ; WF_PMODE = 1
  155.                 jz      @@realmode      ; Note:  GETWINFLAGS returns a long,
  156.                                         ; so if WF_PMODE changed it could be
  157.                                         ; in the high word.
  158.                 mov     __protected, 8  ; Eight is for convenience.
  159. @@realmode:
  160.  
  161. ;Test for 8087 presence
  162.  
  163.                 test    ax,0400h        ; WF_8087 = 0x0400
  164.                 jz      @@no8087
  165.                 mov     __8087, 1
  166. @@no8087:
  167.                 and     ax,08h+04h+02h  ; WF_CPU486|WF_CPU386|WF_CPU286 
  168.                 shr     ax,1            ; Convert to 4 or 2 or 1 or 0
  169.                 test    ax,0004h        ; Have 4, 486 done
  170.                 jnz     @@NoAdjust
  171.                 or      ax,ax           ; Have 0, 8086 done
  172.                 jz      @@NoAdjust      
  173.                 inc     ax              ; Have 2 or 1, need 3 or 2
  174. @@NoAdjust:
  175.                 mov     __8086,ax       ; Set CPU Type
  176.  
  177. ;Call our initialization functions, including C++ static constructors.
  178.  
  179.                 mov     ax,ds
  180.                 mov     es,ax
  181.                 mov     si,offset DGROUP:InitStart      ;si = start of table
  182.                 mov     di,offset DGROUP:InitEnd        ;di = end of table
  183.  
  184.                 call    Initialize
  185.                 mov     _abend, 0                       ; Set LibEntry called
  186.  
  187.                 ;invoke the C routine to do any special initialization
  188. @@Main:         call    LIBMAIN         ;invoke the 'C' routine (result in AX)
  189.                 mov     di, __hInstance ;restore SI and DI
  190.                 pop     si
  191.                 ret
  192.  
  193. @@Exit:         mov ax, 0               ;set return code
  194.                 pop si                  ;remove arguments to LIBMAIN
  195.                 pop es                  ;  since we didn't call it.
  196.                 pop cx
  197.                 pop ds
  198.                 pop di
  199.                 pop si                  ;restore saved SI.  DI is restored
  200.                 ret                     ;  by removing arguments to LIBMAIN
  201.                 endp
  202.  
  203. ;---------------------------------------------------------------------------
  204. ;       _cleanup()      call all #pragma exit cleanup routines.
  205. ;       _checknull()    check for null pointer zapping copyright message
  206. ;       _terminate(exitcode, quick)     exit program with error code
  207. ;       _restorezero()  restore interrupt vectors
  208. ;
  209. ;       These functions are called by exit(), _exit(), _cexit(),
  210. ;       and _c_exit().
  211. ;---------------------------------------------------------------------------
  212.  
  213. ;       Call cleanup routines
  214.  
  215. __cleanup       PROC    DIST
  216.                 PUBLIC  __cleanup
  217.  
  218.                 mov     ax,ds
  219.                 mov     es,ax
  220.                 push    si
  221.                 push    di
  222.                 mov     si,offset DGROUP:ExitStart
  223.                 mov     di,offset DGROUP:ExitEnd
  224.                 call    Cleanup
  225.                 pop     di
  226.                 pop     si
  227.                 ret
  228. __cleanup       ENDP
  229.  
  230. ;       Check for null pointers before exit.  NO-OP on Windows.
  231.  
  232. __checknull     PROC    DIST
  233.                 PUBLIC  __checknull
  234.                 ret
  235. __checknull     ENDP
  236.  
  237. ;       Restore grabbed interrupt vectors.  NO-OP on Windows.
  238.  
  239. __restorezero     PROC    DIST
  240.                 PUBLIC  __restorezero
  241.                 ret
  242. __restorezero     ENDP
  243.  
  244. ;       Exit to DOS
  245. ;
  246. ; Usage:        void _terminate(int exitcode, int quick);
  247.  
  248. __terminate     PROC    DIST
  249.                 PUBLIC  __terminate
  250.  
  251.                 mov     bp,sp
  252.                 mov     al,[bp+cPtrSize]        ; get exitcode
  253.                 mov     ah,4ch
  254.                 int     21h
  255.                 ret
  256.                 endp
  257.  
  258. WEP             proc    windows pascal far nParam:WORD
  259.                 push    si
  260.                 push    di
  261.  
  262.                 cmp     _abend, 0
  263.                 jne     @@error
  264.                 push    nParam
  265.                 call    __WEP
  266.                 push    ax
  267.                 call    __cexit         ; perform cleanup without exiting
  268.  
  269. @@unlock:
  270.  
  271. IF LDATA EQ false
  272.                 mov     ax,-1
  273.                 push    ax
  274.                 call    UNLOCKSEGMENT
  275. ENDIF
  276.  
  277.                 pop     ax
  278.                 pop     di
  279.                 pop     si
  280.                 ret
  281.  
  282. @@error:
  283.                 push    1
  284.                 jmp     @@unlock
  285.  
  286.                 endp
  287.  
  288. ;       Return default data segment in AX
  289.  
  290. __GetDGROUP     PROC    FAR
  291.                 PUBLIC  __GetDGROUP
  292.                 mov     ax, DGROUP
  293.                 ret
  294.                 endp
  295.  
  296. ;------------------------------------------------------------------
  297. ;  Loop through a startup/exit (SE) table,
  298. ;  calling functions in order of priority.
  299. ;  ES:SI is assumed to point to the beginning of the SE table
  300. ;  ES:DI is assumed to point to the end of the SE table
  301. ;  First 64 priorities are reserved by Borland
  302. ;------------------------------------------------------------------
  303. PNEAR           EQU     0
  304. PFAR            EQU     1
  305. NOTUSED         EQU     0ffh
  306.  
  307. SE              STRUC
  308. calltype        db      ?                       ; 0=near,1=far,ff=not used
  309. priority        db      ?                       ; 0=highest,ff=lowest
  310. addrlow         dw      ?
  311. addrhigh        dw      ?
  312. SE              ENDS
  313.  
  314. Initialize      proc near
  315. @@Start:        mov     ax,100h                 ;start with lowest priority
  316.                 mov     dx,di                   ;set sentinel to end of table
  317.                 mov     bx,si                   ;bx = start of table
  318.  
  319. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  320.                 je      @@EndOfTable            ;yes, exit the loop
  321.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  322.                 je      @@Next
  323.                 mov     cl, es:[bx.priority]    ;move priority to CX
  324.                 xor     ch, ch
  325.                 cmp     cx,ax                   ;check the priority
  326.                 jae     @@Next                  ;too high?  skip
  327.                 mov     ax,cx                   ;keep priority
  328.                 mov     dx,bx                   ;keep index in dx
  329. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  330.                 jmp     @@TopOfTable
  331.  
  332. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  333.                 je      @@Done                  ;yes, quit
  334.                 mov     bx,dx                   ;bx = highest priority item
  335.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  336.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  337.                 push    es                      ;save es
  338.                 je      @@NearCall
  339.  
  340. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  341.                 pop     es                      ;restore es
  342.                 jmp     short @@Start
  343.  
  344. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  345.                 pop     es                      ;restore es
  346.                 jmp     short @@Start
  347.  
  348. @@Done:         ret
  349.                 endp
  350.  
  351. Cleanup         proc near
  352. @@Start:        mov     ah,0                    ;start with highest priority
  353.                 mov     dx,di                   ;set sentinel to end of table
  354.                 mov     bx,si                   ;bx = start of table
  355.  
  356. @@TopOfTable:   cmp     bx,di                   ;and the end of the table?
  357.                 je      @@EndOfTable            ;yes, exit the loop
  358.                 cmp     es:[bx.calltype],NOTUSED;check the call type
  359.                 je      @@Next
  360.                 cmp     es:[bx.priority],ah     ;check the priority
  361.                 jb      @@Next                  ;too low?  skip
  362.                 mov     ah,es:[bx.priority]     ;keep priority
  363.                 mov     dx,bx                   ;keep index in dx
  364. @@Next:         add     bx,SIZE SE              ;bx = next item in table
  365.                 jmp     @@TopOfTable
  366.  
  367. @@EndOfTable:   cmp     dx,di                   ;did we exhaust the table?
  368.                 je      @@Done                  ;yes, quit
  369.                 mov     bx,dx                   ;bx = highest priority item
  370.                 cmp     es:[bx.calltype],PNEAR  ;is it near or far?
  371.                 mov     es:[bx.calltype],NOTUSED;wipe the call type
  372.                 push    es                      ;save es
  373.                 je      @@NearCall
  374.  
  375. @@FarCall:      call    DWORD PTR es:[bx.addrlow]
  376.                 pop     es                      ;restore es
  377.                 jmp     short @@Start
  378.  
  379. @@NearCall:     call    WORD PTR es:[bx.addrlow]
  380.                 pop     es                      ;restore es
  381.                 jmp     short @@Start
  382.  
  383. @@Done:         ret
  384.                 endp
  385.  
  386.                 ends
  387.                 end LibEntry
  388.