home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / C / SASC6571.LZX / source / cback.a < prev    next >
Encoding:
Text File  |  1996-12-24  |  24.9 KB  |  751 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4.  
  5.         INCLUDE        "exec/types.i"
  6.         INCLUDE        "exec/alerts.i"
  7.         INCLUDE        "exec/nodes.i"
  8.         INCLUDE        "exec/lists.i"
  9.         INCLUDE        "exec/ports.i"
  10.         INCLUDE        "exec/libraries.i"
  11.         INCLUDE        "exec/tasks.i"
  12.         INCLUDE        "exec/memory.i"
  13.         INCLUDE        "exec/execbase.i"
  14.         INCLUDE        "libraries/dos.i"
  15.         INCLUDE        "libraries/dosextens.i"
  16.         INCLUDE        "workbench/startup.i"
  17.         INCLUDE        "exec/funcdef.i"
  18.         INCLUDE        "exec/exec_lib.i"
  19.         INCLUDE        "libraries/dos_lib.i"
  20.  
  21. MEMFLAGS    EQU        MEMF_CLEAR+MEMF_PUBLIC
  22. AbsExecBase EQU 4
  23.  
  24. TINY    EQU     0
  25. callsys macro
  26.         CALLLIB _LVO\1
  27.         endm
  28.         
  29.         xdef        __startup
  30.         xdef        _XCEXIT               ; exit(code) is standard way to leave C.
  31.         xdef         @_XCEXIT
  32.         
  33.         xref        LinkerDB              ; linker defined base value
  34.         xref        _BSSBAS               ; linker defined base of BSS
  35.         xref        _BSSLEN               ; linker defined length of BSS
  36.  
  37.         xref        __main                ; Name of C program to start with.
  38.         xref        __fpinit              * initialize floating point
  39.         xref        __fpterm              * terminate floating point
  40.  
  41. *        library references
  42.  
  43.         csect       _NOMERGE,0,0,0,4
  44.         xref        __savecli
  45.         xref        __freecli
  46.         xref        FindTask
  47.  
  48. __startup:
  49. start:
  50.         movem.l d1-d6/a0-a6,-(a7)
  51. REGSIZE EQU     (6+7)*4
  52.         lea     REGSIZE(a7),A5         * determine old stack pointer
  53.         move.l  a0,a2                  * save command pointer
  54.         move.l  d0,d2                  * and command length
  55.         lea     LinkerDB,a4            * load base register
  56.  
  57.         move.l  AbsExecBase.W,a6
  58.         move.l  a6,SysBase(A4)
  59.  
  60. *------        Clear out our BSS section
  61.         lea     _BSSBAS,a3             * get base of BSS
  62.         moveq   #0,d1
  63.         move.l  #_BSSLEN,d0            * get length of BSS in longwords
  64.         bra.s   clr_lp                 * and clear for length given
  65. clr_bss move.l  d1,(a3)+
  66. clr_lp  dbf     d0,clr_bss
  67.         move.l  a7,_StackPtr(A4)       * Save stack ptr
  68.  
  69. *------ get the address of our task
  70.         move.l        ThisTask(a6),A3
  71.  
  72. *-----  clear any pending signals
  73.         moveq        #0,d0
  74.         move.l       #$00003000,d1
  75.         callsys      SetSignal
  76.  
  77. *------ are we running as a son of Workbench?
  78.         move.l       pr_CurrentDir(A3),__curdir(A4)
  79.         tst.l        pr_CLI(A3)
  80.         beq          fromWorkbench
  81.  
  82. *=======================================================================
  83. *====== CLI Startup Code ===============================================
  84. *=======================================================================
  85.  
  86. fromCLI:
  87. *------        attempt to open DOS library:
  88.         bsr.w        openDOS
  89.  
  90. *------ Duplicate the current directory for the called process
  91.         move.l        __curdir(A4),D1
  92.         move.l        DOSBase(A4),A6
  93.         callsys       DupLock
  94.         move.l        D0,__curdir(A4)
  95.  
  96. *------ Save the current CLI info including path for child to use
  97.         pea            cli
  98.         jsr            __savecli(pc)   
  99.         addq.l         #4,a7
  100.  
  101. *------ find command name:
  102.         move.l        pr_CLI(A3),a0
  103.         add.l         a0,a0                        ; bcpl pointer conversion
  104.         add.l         a0,a0
  105.         move.l        cli_CommandName(a0),a1
  106.         add.l         a1,a1                        ; bcpl pointer conversion
  107.         add.l         a1,a1
  108.  
  109. *------        collect parameters:
  110.         move.l        d2,d0                        ; get command line length
  111.         moveq.l       #0,d1
  112.         move.b        (a1)+,d1
  113.         move.l        A1,D4                        ;save our pointer
  114.         move.l        d1,d3
  115.         add.l         d1,d1                        ; double length since we copy it twice
  116.         add.l         d1,d0                        ; add length of command name
  117.         addq.l        #5,d0                        ; allow for space after command        
  118.         addq.l        #4,d0                        ; As well as for the roundup
  119. *                          ; changed from 5 to 9 for quotes
  120. *                                         
  121. *------        We have the length of the command string to be copied.
  122. *------        Allocate space for it.
  123. *------        Round up to the nearest 4 bytes
  124.         lsl.l         #2,d0
  125.         add.l         memsize(A4),d0
  126.         move.l        d0,memsize(A4)
  127.  
  128. ************************************************************************
  129. ************************************************************************
  130. ******** Allocate and copy over the code to do the magic stuff *********
  131. ************************************************************************
  132. ************************************************************************
  133.  
  134.         lea           memlist(A4),A0
  135.         move.l        AbsExecBase.W,a6
  136.         callsys       AllocEntry                ;get a place to put the code
  137. *        btst.l        #31,d0                     ;did we get the memory we asked for?
  138. *        beq           cliexit                    ;no, can't do anything then
  139.         move.l        D0,A1
  140.         move.l        D0,-(A7)                  ;remember the chunk we allocated
  141.  
  142. *------ Now we copy the code over
  143.         movea.l       ML_SIZE+ME_ADDR(A1),A1   ;locate our allocated block
  144.  
  145. *------        Copy over the command line to the allocated area
  146.         lea           commandbuf-copybeg(A1),A3
  147.  
  148. *------        At this point, we have:
  149. *                A0 - Work pointer
  150. *                A1 - Pointer to Allocated memory block
  151. *                A2 - Pointer to program name
  152. *                A3 - Pointer to target buffer
  153. *                A3 - Pointer to our process structure
  154. *                D0 - Work register
  155. *                D1 - Work register
  156. *                D2 - length of command name
  157. *                D3 - length of program name
  158. *                D4 - Pointer to program name
  159.  
  160.         move.l        d2,argslen                 ; save length of args
  161.         move.l        d3,proglen                 ; save length of prog
  162.         
  163.         movea.l       D4,A0                      ; Load program name
  164.         move.l        D3,D0                      ;      and length
  165.         move.b        #'"',(a3)+
  166.         bra.s         cpy1
  167. cpycmd: move.b        (A0)+,(A3)+                ; copy over the command name
  168. cpy1:   dbf           d0,cpycmd
  169.         move.b        #'"',(a3)+
  170.         move.b        #' ',(A3)+                 ; add the space delimiter
  171.  
  172.         move.l        A2,A0                      ; Load command text
  173.         move.l        D2,D0                      ;      and length
  174.         bra.s         cpy2
  175. cpylin: move.b        (A0)+,(A3)+
  176. cpy2:   dbf           d0,cpylin
  177.         clr.b         (A3)+
  178.  
  179. *------        Now copy over the program name
  180.         move.l        A3,_ProgramName(A4)
  181.         move.l        D4,A0
  182.         move.l        D3,D0
  183.         bra.s         cpy3
  184. cpypgm: move.b        (A0)+,(A3)+
  185. cpy3:   dbf           D0,cpypgm
  186.         clr.b         (A3)                        ;don't forget trailing null on name
  187.  
  188. *------ First we want to put it into our seglist
  189.         lea           segexit-copybeg(A1),A2
  190.         move.l        A2,_XCEXIT+2(A4)            ;patch the jump instruction
  191.         lea           start-4(PC),A2
  192.    
  193. *        Now we have:    A1 to our new fake segment
  194. *                        A2 to the start of the real seglist
  195.         move.l        #(copyend-copybeg)/4,(A1)+
  196.         move.l        A1,D3
  197.         lsr.l         #2,D3                        ;convert it to a bptr to the list
  198.         move.l        (A2),(A1)+                   ;save our next segment pointer
  199.         clr.l         (A2)                         ;and kill it from the chain
  200. *------ We have the seglist
  201.  
  202.         lea           AutoLoader(PC),A2
  203.         move.l        #(copyend-AutoLoader)-1,D0
  204. copyit  move.b        (A2)+,(A1)+
  205.         dbf           d0,copyit
  206.  
  207. *------        See if they want to do some I/O
  208.         tst.l        _BackGroundIO(A4)
  209.         beq          noio
  210.         lea          current_window(A4),A0
  211.         move.l       A0,D1
  212.         move.l       #1005,D2
  213.         move.l       DOSBase(A4),A6
  214.         callsys      Open
  215.         move.l       d0,_Backstdout(A4)
  216. noio:
  217.  
  218. *------ If under 2.0 Flush cache and get ProgramDir
  219.    
  220.         moveq        #36,d0
  221.         cmp.w        $14(a6),d0
  222.         bgt.b        nov36
  223.         
  224.         move.l       DOSBase(A4),A6
  225.         jsr          -$258(a6)                  ;GetProgramDir
  226.         move.l       d0,d1
  227.         callsys       DupLock
  228.         move.l       d0,ProgramDir(a4)
  229.  
  230.         move.l       AbsExecBase.w,A6
  231.         moveq        #-1,d0
  232.         callsys      CacheClearU
  233.  
  234. nov36:
  235.         
  236.         move.l       AbsExecBase.w,A6
  237.  
  238.         callsys        Forbid
  239.  
  240. *------ Attach the task to do the dirty work
  241.         move.l        __procname(A4),D1        ; Name of task to start
  242.         move.l        __priority(A4),D2        ; Priority of background task
  243.         move.l        __stack(A4),D4           ; Stack size of created task
  244.  
  245.         move.l        DOSBase(A4),A6
  246.         callsys       CreateProc
  247.         move.l        A6,A3                    ; restore dosbase to close it
  248.         tst.l         D0
  249.         bne           ok
  250.  
  251. *------ Serious problems.  For some reason the CreateProc failed.
  252. *------ We need to free the AlocEntry memory and go home
  253.         move.l        (A7)+,A2
  254.         movea.l       ML_SIZE+ME_ADDR(A2),A1   ;locate our allocated block
  255. *------ Also must get rid of current directory
  256.         move.l        __curdir(A4),D1
  257.         callsys       UnLock
  258.  
  259.         move.l        A2,A0
  260.         move.l        AbsExecBase.w,A6
  261.         callsys       FreeEntry
  262.         move.l        #104,D0
  263.         bra           cliexit
  264.  
  265. ok:
  266. *------ The task started ok, attach the memory we allocated to
  267. *------        its task control block
  268.         move.l        D0,A2
  269.  
  270.         move.l        (a7)+,A1                ;locate the memory we allocated
  271.         lea           -pr_MsgPort(A2),A2
  272.         lea           TC_MEMENTRY(A2),A0
  273.  
  274.  
  275. *        ADDTAIL
  276.         LEA           LH_TAIL(A0),A0
  277.         MOVE.L        LN_PRED(A0),D0
  278.         MOVE.L        A1,LN_PRED(A0)
  279.         MOVE.L        A0,(A1)
  280.         MOVE.L        D0,LN_PRED(A1)
  281.         MOVE.L        D0,A0
  282.         MOVE.L        A1,(A0)
  283.  
  284.         move.l        #0,D0
  285.  
  286. cliexit:
  287.         move.l        AbsExecBase.w,A6
  288.         callsys       Permit
  289.         move.l        A3,A1
  290.         move.l        AbsExecBase.w,A6
  291.         callsys       CloseLibrary
  292.         movem.l       (a7)+,d1-d6/a0-a6
  293.         rts
  294.  
  295. *=======================================================================
  296. *====== Workbench Startup Code =========================================
  297. *=======================================================================
  298.  
  299. fromWorkbench:
  300.         move.l        a7,d0                         
  301.         sub.l         TC_SPLOWER(a3),d0
  302.  
  303. *------ Set __base for stack checking
  304.         move.l       a7,d1
  305.         sub.l        d0,d1               * get top of stack
  306.         add.l        #128,D1             * allow for parms overflow
  307.         move.l       D1,__base(A4)       * save for stack checking
  308.         
  309.         cmp.l         __stack(a4),d0
  310.         bcc.s        nochange        
  311.  
  312. *-- current stack is not as big as __stack says it needs
  313. *-- to be. Allocate a new one.
  314.         move.l        __stack(a4),d0
  315.         add.l         #128,d0           * extra room
  316.         move.l        d0,newstacksize(a4)
  317.  
  318.         move.l        #MEMFLAGS,d1
  319.         callsys       AllocMem
  320.         tst.l         d0
  321.         beq.w         return
  322.         
  323.         move.l        d0,newstack(a4)
  324.         add.l         #128,d0           * extra room
  325.         move.l        d0,__base(a4)
  326.         
  327.         add.l         __stack(a4),d0
  328.         move.l        d0,d1
  329.         
  330. *-- If we're running under 2.0, call StackSwap to set up
  331. *-- the new stack. Otherwise, just jam the new value into
  332. *-- A7.        
  333.         cmpi.w        #36,$14(a6)
  334.         blt.s         no20
  335.  
  336.         move.l        d0,mystk_Pointer(a4)
  337.         move.l        d1,mystk_Upper(a4)
  338.         sub.l         newstacksize(a4),d1
  339.         lea           mystk_Lower(a4),a0
  340.         move.l        d1,(a0)
  341.         callsys       StackSwap
  342.         bra.s         nochange
  343.            
  344. no20:   move.l        d0,a7
  345.                 
  346. nochange:
  347.  
  348. *------ Save the current stack. We'll reset it to here to
  349. *------ Run the autoterminators.
  350.         move.l        a7,newst_Pointer(a4)
  351.         move.l        a7,newst_Upper(a4)
  352.         lea           newst_Lower(a4),a0
  353.         move.l        __base(a4),(a0)
  354.         cmpi.w        #36,$14(a6)
  355.         blt.s         no20b
  356.         callsys       StackSwap
  357.         
  358. no20b:
  359.  
  360.  
  361. *------ open the DOS library:
  362.         bsr.w         openDOS
  363.  
  364.         
  365. *------ we are now set up.  wait for a message from our starter
  366.         bsr.w         waitmsg
  367.         move.l        d0,_WBenchMsg(A4)
  368.         move.l        d0,-(SP)
  369. *
  370.         move.l        d0,a2                            ; get first argument
  371.         move.l        sm_ArgList(a2),d0
  372.         beq.s         do_cons
  373.         move.l        DOSBase(A4),a6
  374.         move.l        d0,a0
  375.         move.l        wa_Lock(a0),d1
  376.         callsys       DupLock
  377.         move.l        d0,__curdir(A4)
  378.         move.l        d0,d1
  379.         callsys       CurrentDir
  380. do_cons:
  381.         move.l        sm_ToolWindow(a2),d1             ; get the window argument
  382.         beq.s         do_main
  383.         move.l        #MODE_OLDFILE,d2
  384.         callsys       Open
  385.         move.l        d0,stdin(A4)
  386.         beq.s         do_main
  387.         lsl.l         #2,d0
  388.         move.l        d0,a0
  389.         move.l        fh_Type(a0),pr_ConsoleTask(A3)
  390. do_main:
  391.         move.l        _WBenchMsg(A4),a0                ; get address of workbench message
  392.         move.l        a0,-(a7)                         ; push argv
  393.         pea           NULL(A4)                         ; push argc
  394.         move.l        sm_ArgList(a0),a0                ; get address of arguments
  395.         move.l        wa_Name(a0),_ProgramName(A4)     ; get name of program
  396.  
  397.         lea           xcexit(PC),A2
  398.         move.l        A2,_XCEXIT+2(A4)                 ;patch the jump instruction
  399.  
  400.         moveq         #36,d0
  401.         cmp.w         $14(a6),d0
  402.         bgt.b         nov36b
  403.         
  404.         move.l        AbsExecBase.w,A6
  405.         moveq         #-1,d0
  406.         callsys       CacheClearU
  407. nov36b:
  408.  
  409. *------ For startup from workbench, there is no reason to go through
  410. *------ The fancy stuff to make the startup work.  Just run the
  411. *------ Code directly
  412.         jsr           __fpinit(PC)
  413.         tst.l         d0
  414.         bne.w         exit2
  415.         jsr           __main
  416.         moveq.l       #0,d0
  417.         bra.w         exit2
  418.         
  419.  
  420. ************************************************************************
  421. ************************************************************************
  422. *************                                              *************
  423. ************* Start of code that is copied to fake segment *************
  424. *************                                              *************
  425. ************************************************************************
  426. ************************************************************************
  427.  
  428. copybeg:
  429.         DC.L        (copyend-copybeg)/4
  430. next:   DC.L        0
  431. AutoLoader:
  432.         move.l        a7,d0
  433.         movem.l       d1-d6/a0-a6,-(a7)
  434.         move.l        d0,a5
  435.         move.l        AbsExecBase.w,a6
  436.         lea           LinkerDB,A4                ; load base register
  437.         move.l        a7,_StackPtr(A4)
  438.  
  439.         bsr.w         openDOS
  440.         suba.l        a1,a1
  441.  
  442.         suba.l        a1,a1
  443.         callsys       FindTask
  444.         move.l        d0,A3
  445.  
  446.         move.l        TC_SPLOWER(A3),__base(A4)        ; set base of stack
  447.         add.l         #128,__base(A4)          ;allow for parms overflow
  448.  
  449.         move.l        pr_SegList(A3),a0        ;locate the segment list
  450.         add.l         A0,A0
  451.         add.l         A0,A0                    ;and convert to an APTR
  452.         move.l        12(A0),A1                ;so we can access the segments
  453.         add.l         A1,A1
  454.         add.l         A1,A1
  455.  
  456.         move.l        (A1),seglist(A4)        ;save the remainder for later
  457.         move.l        (A1),12(A0)             ;cut off our segment
  458.  
  459.         move.l        __curdir(A4),D1
  460.         move.l        DOSBase(A4),a6
  461.         callsys       CurrentDir
  462.  
  463.         move.l        ProgramDir(a4),d1
  464.         beq.s         noprogramdir
  465.         jsr           -$252(a6)                ;SetProgramDir
  466.  
  467. noprogramdir:
  468.  
  469. *------ Open Nil: and set up it's input buffer so 
  470. *------ ReadArgs will work.
  471.         lea           nil(pc),a0
  472.         move.l        a0,d1
  473.         move.l        #MODE_OLDFILE,d2
  474.         callsys       Open
  475.         move.l        d0,pr_CIS(a3)
  476.         add.l         d0,d0
  477.         add.l         d0,d0
  478.         move.l        d0,a2
  479.         move.l        argslen(pc),d2
  480.         move.l        d2,fh_End(a2)
  481.         move.l        #0,fh_Pos(a2)        
  482.         
  483.         move.l        AbsExecBase.w,a6
  484.         move.l        d2,d0
  485.         moveq.l       #0,d1
  486.         callsys       AllocMem
  487.         tst.l         d0
  488.         beq.b         segexit
  489.  
  490.         move.l        d0,a0
  491.         lea           commandbuf(pc),a1
  492.         adda.l        proglen(pc),a1
  493.         addq.l        #3,a1               * 3 - is for quotes and trailing space
  494.         subq.l        #1,d2
  495.         blt.b         donecpy
  496. cpy:
  497.         move.b        (a1)+,(a0)+
  498.         dbf           d2,cpy        
  499.             
  500. donecpy:
  501.         lsr.l         #2,d0
  502.         move.l        d0,fh_Buf(a2)
  503.         
  504. *------ Use the cli that our creator set up for us.
  505.         move.l        cli(pc),pr_CLI(a3)
  506.  
  507.         jsr           __fpinit
  508.         tst.l         d0
  509.         bne.s         segexit
  510.         pea           commandbuf(PC)
  511.         jsr           __main                        ; call C entrypoint
  512.         addq          #4,A7
  513.  
  514.  
  515. *------ Unlock the directory we set up for them
  516. segexit:
  517.         move.l        DOSBase(A4),a6
  518.         move.l        __curdir(A4),D1
  519.         callsys       UnLock
  520.  
  521.         moveq.l       #0,d0                        ; set successful status
  522. xcexit:
  523. exit2:
  524.  
  525.         tst.l         _WBenchMsg(A4)
  526.         beq.s         swapdone
  527.         
  528. *-- Set the stack to the first NEW stack we allocated
  529. *-- So C++ destructors can run with a large stack if required
  530.         move.l        newst_Lower(a4),__base(a4)        
  531.         move.l        AbsExecBase.W,A6
  532.         cmpi.w        #36,$14(a6)
  533.         blt.s         noswap1
  534.         lea           newst_Lower(a4),a0
  535.         callsys       StackSwap
  536.         bra.b         swapdone
  537. noswap1:
  538.         move.l        newst_Pointer(a4),a7
  539. swapdone:
  540.         move.l        _ONEXIT(A4),d0         ; exit trap function?
  541.         beq.s         exit3
  542.         move.l        d0,a0
  543.         jsr           (a0)
  544.  
  545. exit3:
  546.  
  547. *------ These must not be PC relative calls since this code is copied
  548.         jsr           __fpterm
  549.  
  550. done_1c:
  551.  
  552. *-- Swap back to original stack
  553. *-- If we're running under 2.0, call StackSwap
  554. *-- Otherwise, just jam the new value into a7
  555.         move.l        AbsExecBase.W,A6
  556.         cmpi.w        #36,$14(a6)
  557.         blt.s         noswap
  558.         tst.l         mystk_Lower(a4)
  559.         beq.s         noswap
  560.  
  561.         lea           mystk_Lower(a4),a0
  562.         subq.l        #4,mystk_Pointer(a4)      * make room for the ret code  
  563.         callsys       StackSwap
  564.            
  565. noswap:  
  566.  
  567.         move.l        _StackPtr(a4),a7          * restore stack ptr
  568.  
  569.  
  570. *------ if we ran from CLI, skip workbench cleanup:
  571.         tst.l         _WBenchMsg(A4)
  572.         beq.s         exitToDOS
  573.         move.l        newstacksize(a4),d0
  574.         beq.s         exit4
  575.         move.l        newstack(a4),a1
  576.         move.l        AbsExecBase.W,A6
  577.         callsys       FreeMem
  578. exit4:
  579.         move.l        DOSBase(A4),a6
  580.         move.l        stdin(A4),d1
  581.         beq.s         done_4
  582.         callsys       Close
  583.  
  584. done_4:
  585.         tst.l         ProgramDir(a4)
  586.         beq.s         noprogdir
  587.         moveq.l       #0,d1
  588.         jsr           -$252(a6)                ;SetProgramDir
  589.         move.l        ProgramDir(a4),d1
  590.         callsys       UnLock
  591.  
  592.  
  593. noprogdir:
  594.  
  595. *------ return the startup message to our parent
  596. *        we forbid so workbench can't UnLoadSeg() us
  597. *        before we are done:
  598.         move.l        __curdir(a4),d1
  599.         beq.s         done_5
  600.         callsys       UnLock
  601.  
  602. done_5:
  603.         move.l        AbsExecBase.w,A6
  604.         callsys       Forbid
  605.         move.l        _WBenchMsg(A4),a1
  606.         callsys       ReplyMsg
  607.         move.l        DOSBase(a4),a1
  608.         bra.b         noCIS
  609.  
  610. *------ this rts sends us back to DOS:
  611. exitToDOS:
  612.         jsr           __freecli
  613.         
  614.         move.l        AbsExecBase.W,a6
  615.         sub.l         a1,a1
  616.         callsys       FindTask
  617.         move.l        d0,a0
  618.         
  619.         move.l        pr_CIS(a0),d1      * test for our input file handle
  620.         beq.b         noCIS
  621.  
  622.         clr.l         pr_CIS(a0)
  623.         move.l        d1,d2
  624.         add.l         d1,d1
  625.         add.l         d1,d1
  626.         move.l        d1,a2
  627.         
  628. *------ First free the buffer we allocated
  629.         move.l        fh_Buf(a2),d1
  630.         add.l         d1,d1
  631.         add.l         d1,d1
  632.         move.l        d1,a1
  633.         move.l        argslen(pc),d0
  634.         callsys       FreeMem
  635.  
  636. *------ Restore fields to 0 
  637.         clr.l         fh_Buf(a2)
  638.         clr.l         fh_End(a2)
  639.  
  640. *------ Close Nil:        
  641.         move.l        d2,d1
  642.         move.l        DOSBase(A4),a6
  643.         callsys       Close
  644.  
  645. *------ They are done so unload them
  646.         move.l        seglist(A4),D1
  647.         move.l        DOSBase(A4),a6
  648.         callsys       UnLoadSeg
  649.  
  650.         move.l        a6,a1
  651.  
  652. noCIS:
  653.         move.l        AbsExecBase.w,a6
  654.         callsys       CloseLibrary                ; close Dos library
  655.  
  656. return:
  657.         movem.l       (a7)+,d1-d6/a0-a6
  658.         rts
  659.  
  660. *-----------------------------------------------------------------------
  661. *  Open the DOS library:
  662.  
  663. openDOS
  664.                 lea          DOSName(A4),A1
  665.                 moveq.l      #0,D0
  666.                 callsys      OpenLibrary
  667.                 move.l       D0,DOSBase(A4)
  668.                 beq          noDOS
  669.                 rts
  670. *-----------------------------------------------------------------------
  671. noDOS:
  672.                 moveq.l      #100,d0
  673.                 bra          exit2
  674.  
  675. cli:            dc.l         0
  676. argslen:        dc.l         0
  677. proglen:        dc.l         0
  678. nil:            dc.b         'NIL:',0,0
  679.                 
  680. copyend:
  681. commandbuf:
  682.  
  683. ************************************************************************
  684. ************************************************************************
  685. **************                                            **************
  686. ************** End of code that is copied to fake segment **************
  687. **************                                            **************
  688. ************************************************************************
  689. ************************************************************************
  690.  
  691. *-----------------------------------------------------------------------
  692. * This routine gets the message that workbench will send to us
  693. * called with task id in A3
  694.  
  695. waitmsg:
  696.                 lea        pr_MsgPort(A3),a0          ; our process base
  697.                 callsys    WaitPort
  698.                 lea        pr_MsgPort(A3),a0          ; our process base
  699.                 callsys    GetMsg
  700.                 rts
  701.  
  702.         csect        __MERGED,1,0,0,4
  703.  
  704. *------        These externals control the task that is started
  705.         xref        _BackGroundIO                ; flag to indicate background task
  706. *                                                ; wants to do I/O
  707.         xref        __stack                      ; stack space for created task
  708.         xref        __procname                   ; name of process to be created
  709.         xref        __priority                   ; priority to create process at
  710.  
  711.         xref        MathBase
  712.         xref        MathTransBase
  713. *
  714.         xdef        NULL,SysBase,DOSBase,_Backstdout
  715.  
  716.     xref        _FPERR
  717.         xref        _WBenchMsg
  718.         xref        __curdir
  719.         xref        _OSERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  720.         xref        _SIGINT
  721.         xref        _ProgramName,_StackPtr,__base
  722. *
  723. memlist        ds.b        LN_SIZE
  724.                dc.w        1
  725.                dc.l        MEMF_PUBLIC
  726. memsize        dc.l        copyend-copybeg
  727.  
  728. _XCEXIT      
  729. @_XCEXIT       dc.w        $4ef9
  730.                dc.l        0
  731. seglist        dc.l        0
  732. NULL           dc.l        0                ;
  733. DOSBase        dc.l        0
  734. SysBase        dc.l        0
  735. dosCmdLen      dc.l        0
  736. dosCmdBuf      dc.l        0
  737. stdin          dc.l        0
  738. _Backstdout    dc.l        0                ;filehandle for I/O
  739. ProgramDir     dc.l        0
  740. DOSName        dc.b        'dos.library',0
  741. current_window dc.b        '*',0
  742. mystk_Lower    dc.l        0
  743. mystk_Upper    dc.l        0
  744. mystk_Pointer  dc.l        0
  745. newst_Lower    dc.l        0
  746. newst_Upper    dc.l        0
  747. newst_Pointer  dc.l        0
  748. newstack       dc.l        0                   * pointer to new stack (if needed)
  749. newstacksize   dc.l        0                   * size of new stack
  750.                END
  751.