home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / C / SASC6571.LZX / source / c.a < prev    next >
Encoding:
Text File  |  1996-12-24  |  42.3 KB  |  1,220 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Use the following command line to make c.o
  5. * asm -u c.a
  6. *
  7. * Use the following command line to make cres.o
  8. * asm -u -dRESIDENT -ocres.o c.a
  9. *
  10. * Use the following command line to make catch.o (standard GURU catcher)
  11. * asm -u -dCATCH -ocatch.o c.a
  12. *
  13. * Use the following command line to make catchnr.o (GURU catcher w/out requester)
  14. * asm -u -dCATCH -dNOREQ -ocatchnr.o c.a
  15. *
  16. * Use the following command line to make catchres.o (resident GURU catcher)
  17. * asm -u -dCATCH -dRESIDENT -ocatchres.o c.a
  18. *
  19. * Use the following command line to make catchresnr.o (resi GURU catcher w/out req)
  20. * asm -u -dCATCH -dRESIDENT -dNOREQ -ocatchresnr.o c.a
  21. *
  22.         IFD  CATCH
  23.           IFND NOREQ
  24. AUTOREQ         set        1
  25.           ENDC
  26.         ENDC
  27.  
  28.         INCLUDE        "exec/types.i"
  29.         INCLUDE        "exec/alerts.i"
  30.         INCLUDE        "exec/nodes.i"
  31.         INCLUDE        "exec/lists.i"
  32.         INCLUDE        "exec/ports.i"
  33.         INCLUDE        "exec/libraries.i"
  34.         INCLUDE        "exec/tasks.i"
  35.         INCLUDE        "exec/memory.i"
  36.         INCLUDE        "exec/execbase.i"
  37.         INCLUDE        "libraries/dos.i"
  38.         INCLUDE        "libraries/dosextens.i"
  39.         INCLUDE        "workbench/startup.i"
  40.         INCLUDE        "exec/funcdef.i"
  41.         INCLUDE        "exec/exec_lib.i"
  42.         INCLUDE        "libraries/dos_lib.i"
  43.  
  44.         IFD   CATCH
  45.         INCLUDE        "intuition/intuition.i"
  46. VERSION  equ    1
  47. REVISION equ    0
  48.         ENDC
  49.         
  50. MEMFLAGS        EQU        MEMF_CLEAR+MEMF_PUBLIC
  51. AbsExecBase     EQU        4
  52.  
  53. ;;;
  54. ;;;   Stack map.
  55. ;;;
  56.       OFFSET  0
  57.            ds.b    4
  58. savereg    ds.b    13*4
  59. stackbtm   ds.b    4
  60.  
  61.  
  62.  
  63. ; some usefull macros:
  64.  
  65. callsys macro
  66.         CALLLIB _LVO\1
  67.         endm
  68.         
  69.         xdef        _XCEXIT                * exit(code) is standard way to leave C.
  70.         xdef        @_XCEXIT
  71.         xdef        __startup
  72.         
  73.         xref        LinkerDB        * linker defined base value
  74.         xref        _BSSBAS                * linker defined base of BSS
  75.         xref        _BSSLEN                * linker defined length of BSS
  76.         xref        __stack
  77.  
  78.        IFD          RESIDENT
  79.         xref        RESLEN
  80.         xref        RESBASE
  81.         xref        NEWDATAL
  82.        ENDC
  83.         
  84. *       library references
  85.  
  86.         section text,code
  87.  
  88.         xref    __main                  * Name of C program to start with.
  89.         xref    __fpinit                * initialize floating point
  90.         xref    __fpterm                * terminate floating point
  91.  
  92. __startup:
  93. start:
  94.         movem.l d1-d6/a0-a6,-(a7)       * save registers
  95.  
  96.         move.l  a0,a2                   * save command pointer
  97.         move.l  d0,d2                   * and command length
  98.         lea     LinkerDB,a4             * load base register
  99.         move.l  AbsExecBase.W,a6
  100.  
  101.  
  102.         IFND        RESIDENT
  103.         lea     _BSSBAS,a3              * get base of BSS
  104.         moveq   #0,d1
  105.         move.l  #_BSSLEN,d0             * get length of BSS in longwords
  106.         bra.s   clr_lp                  * and clear for length given
  107. clr_bss move.l  d1,(a3)+
  108. clr_lp  dbf     d0,clr_bss
  109.         move.l  a7,_StackPtr(A4)        * Save stack ptr
  110.         move.l  a6,SysBase(A4)
  111.  
  112. *------ get the size of the stack, if CLI use cli_DefaultStack
  113. *------                                 if WB use a7 - TC_SPLOWER
  114.         move.l        ThisTask(a6),A3
  115.         move.l        pr_CLI(A3),d0
  116.         beq.s         fromwb
  117.         lsl.l         #2,d0
  118.         move.l        d0,a0
  119.         move.l        cli_DefaultStack(a0),d0
  120.         lsl.l         #2,d0             * # longwords -> # bytes
  121.         bra.s         dostack
  122.  
  123. fromwb:
  124.         move.l        a7,d0                         
  125.         sub.l         TC_SPLOWER(a3),d0
  126. dostack:
  127.  
  128. *------ Set __base for stack checking
  129.         move.l       a7,d1
  130.         sub.l        d0,d1               * get top of stack
  131.         add.l        #128,D1             * allow for parms overflow
  132.         move.l       D1,__base(A4)       * save for stack checking
  133.         
  134.         cmp.l         __stack(a4),d0
  135.         bcc.s        nochange        
  136.  
  137. *-- current stack is not as big as __stack says it needs
  138. *-- to be. Allocate a new one.
  139.         move.l        __stack(a4),d0
  140.         add.l         #128,d0           * extra room
  141.         move.l        d0,newstacksize(a4)
  142.  
  143.         move.l        #MEMFLAGS,d1
  144.         callsys       AllocMem
  145.         tst.l         d0
  146.         beq.w         return
  147.         
  148.         move.l        d0,newstack(a4)
  149.         add.l         #128,d0           * extra room
  150.         move.l        d0,__base(a4)
  151.         
  152.         add.l         __stack(a4),d0
  153.         move.l        d0,d1
  154.         
  155. *-- If we're running under 2.0, call StackSwap to set up
  156. *-- the new stack. Otherwise, just jam the new value into
  157. *-- A7.        
  158.         cmpi.w        #36,$14(a6)
  159.         blt.s         no20
  160.  
  161.         move.l        d0,mystk_Pointer(a4)
  162.         move.l        d1,mystk_Upper(a4)
  163.         sub.l         newstacksize(a4),d1
  164.         lea           mystk_Lower(a4),a0
  165.         move.l        d1,(a0)
  166.         callsys       StackSwap
  167.         bra.s         nochange
  168.            
  169. no20:   move.l        d0,a7
  170.                 
  171. nochange:
  172.         ENDC
  173.  
  174.  
  175.  
  176.         IFD        RESIDENT
  177.         move.l        d2,-(a7)
  178.         movem.l       a0-a2,-(a7)
  179.  
  180. *------ get the size of the stack, if CLI use cli_DefaultStack
  181. *------                                 if WB use a7 - TC_SPLOWER
  182.         move.l        ThisTask(a6),A3
  183.         move.l        pr_CLI(A3),d1
  184.         beq.s         fromwb
  185.         lsl.l         #2,d1
  186.         move.l        d1,a0
  187.         move.l        cli_DefaultStack(a0),d1
  188.         lsl.l         #2,d1             * # longwords -> # bytes
  189.         bra.s         dostack
  190.  
  191. fromwb:
  192.         move.l        a7,d1                         
  193.         sub.l         TC_SPLOWER(a3),d1
  194. dostack:
  195.         moveq        #0,d2              * use d2 as flag for newstack or not
  196.         move.l       #RESLEN,d0
  197.         cmp.l        __stack(a4),d1     * This a4 is in the original 
  198.                                         * set of data
  199.         bcc.s        nochange        
  200.         move.l        __stack(a4),d1
  201.         add.l        d1,d0              * increase size of mem for new stack
  202.         moveq        #1,d2              * set flag
  203.                 
  204. nochange:
  205.         move.l        d1,a3             * save stacksize to set up stack checking
  206.         move.l        #MEMFLAGS,d1
  207.         callsys       AllocMem
  208.         tst.l         d0
  209.         bne.s         ok1
  210.         movem.l       (a7)+,d2/a0-a2
  211.         bra.w         return
  212.  
  213. ok1:    move.l        d0,a0
  214.         move.l        d0,a2             * a2 now has difference
  215.         
  216.         move.l        d0,a1
  217.         move.l        #NEWDATAL,d0
  218.         sub.l         #RESBASE,a4
  219.  
  220.                                         * copy data over
  221. cpy:    move.l        (a4)+,(a0)+
  222.         subq.l        #1,d0
  223.         bne.s         cpy
  224.  
  225.                                         * a4 now points at number of relocs
  226.         move.l        (a4)+,d0
  227. reloc:  beq.s         nreloc
  228.         move.l        a1,a0
  229.         add.l         (a4)+,a0          * a0 now has add of reloc
  230.         add.l         (a0),a2
  231.         move.l        a2,(a0) 
  232.         move.l        a1,a2             * restore offset
  233.         subq.l        #1,d0
  234.         bra.s         reloc
  235.         
  236. nreloc: move.l        a1,a4             * set up new base register
  237.         add.l         #RESBASE,a4
  238.  
  239.         move.l        #RESLEN,realdatasize(a4)
  240.         movem.l       (a7)+,a0-a2
  241.  
  242.         move.l        a6,SysBase(A4)
  243.         tst.b         d2
  244.         movem.l       (a7)+,d2          * restore d2 
  245.         movem.l       a7,_StackPtr(A4)  * Save stack ptr (movem doesn't
  246.                                         * change flags
  247.         beq.s         nochg2
  248.  
  249. *------ set up new stack
  250.         move.l       a4,d0
  251.         sub.l        #RESBASE,d0
  252.         add.l        #RESLEN,d0
  253.         add.l        __stack(a4),d0     * here a4 will be pointing at the
  254.                                         * new data, but __stack will be the
  255.                                         * same if all goes well
  256.         move.l       d0,d1             
  257.  
  258.  
  259. *-- If we're running under 2.0, call StackSwap to set up
  260. *-- the new stack. Otherwise, just jam the new value into
  261. *-- A7.        
  262.         cmpi.w        #36,$14(a6)
  263.         blt.s         no20a
  264.  
  265.         move.l        d0,mystk_Pointer(a4)
  266.         move.l        d1,mystk_Upper(a4)
  267.         sub.l         __stack(a4),d1
  268.         lea           mystk_Lower(a4),a0
  269.         move.l        d1,(a0)
  270.         callsys       StackSwap
  271.         bra.s         doneswap
  272.            
  273. no20a:  move.l        d0,a7
  274.                 
  275. doneswap:
  276.  
  277.         move.l       __stack(a4),d0
  278.         add.l        d0,realdatasize(a4) * need to know how much to free later
  279.  
  280. nochg2:
  281. *------ Set __base for stack checking
  282.         move.l       a7,d1
  283.         sub.l        a3,d1               * get top of stack
  284.         add.l        #128,D1             * allow for parms overflow
  285.         move.l       D1,__base(A4)       * save for stack checking
  286.  
  287.         ENDC
  288.  
  289.  
  290. *------ Save the current stack. We'll reset it to here to
  291. *------ Run the autoterminators.
  292.         move.l       a7,newst_Pointer(a4)
  293.         move.l       a7,newst_Upper(a4)
  294.         lea          newst_Lower(a4),a0
  295.         move.l       __base(a4),(a0)
  296.  
  297.         cmpi.w        #36,$14(a6)
  298.         blt.s         no20b
  299.         callsys       StackSwap
  300.  
  301. no20b:
  302.  
  303.         ifd     CATCH
  304.         move.w  AttnFlags(a6),Environment+2(a4) * save copy for dump
  305.         endc
  306.  
  307.  
  308.  
  309. clrwb:
  310.         clr.l        _WBenchMsg(A4)
  311.  
  312. *-----  clear any pending signals
  313.         moveq         #0,d0
  314.         move.l        #$00003000,d1
  315.         callsys       SetSignal
  316.         
  317.  
  318.         move.l        ThisTask(a6),A3
  319.  
  320.         ifd        CATCH
  321.         move.l        A3,TaskID(a4)
  322.  
  323. *------ initialize exception handler
  324. *------ Remember to preserve the old handler first
  325.         move.l        TC_TRAPDATA(a3),oldtrapdata(A4)
  326.         move.l        TC_TRAPCODE(a3),d0              ; check current exception
  327.         move.l        d0,oldtrapcode(A4)
  328.  
  329.         move.l        d0,a1
  330.         callsys TypeOfMem
  331.         tst.l d0
  332.         bne.s        1$                               * somebody else (debugger?) has vector
  333.  
  334.         move.l        #Exception,TC_TRAPCODE(a3)      * install pointers to code
  335.         move.l        a4,TC_TRAPDATA(a3)              * ...and data
  336. 1$:
  337.         ifd         AUTOREQ
  338. *------ attempt to open Intuition library:
  339.         bsr.w                openIntui
  340.         endc
  341.         endc
  342.  
  343.  
  344. *------ attempt to open DOS library:
  345.         lea           DOSName(PC),A1
  346.         moveq.l       #0,D0
  347.         callsys       OpenLibrary
  348.         move.l        D0,DOSBase(A4)
  349.         bne.s         ok2
  350.         moveq.l       #100,d0
  351.         bra.w         exit2
  352.  
  353. ok2:
  354.  
  355. *------ are we running as a son of Workbench?
  356.         move.l        pr_CurrentDir(A3),__curdir(A4)
  357.         tst.l         pr_CLI(A3)
  358.         beq.w         fromWorkbench
  359.         
  360. *=======================================================================
  361. *====== CLI Startup Code ===============================================
  362. *=======================================================================
  363. *
  364. * Entry: D2 = command length
  365. *        A2 = Command pointer
  366. fromCLI:
  367.         ifd        CATCH
  368.         moveq         #-1,d0
  369.         move.l        d0,Starter(a4)        * non-zero means CLI
  370.         move.l        a5,StackTop(a4)
  371.         endc
  372.  
  373. *------ find command name:
  374.         move.l      pr_CLI(a3),a0
  375.         add.l       a0,a0                   * bcpl pointer conversion
  376.         add.l       a0,a0
  377.         move.l      cli_CommandName(a0),a1
  378.  
  379.         IFD         CATCH 
  380.         IFND        AUTOREQ
  381.         move.l      cli_StandardOutput(a0),GConsole(a4)   * save output fh
  382.         ENDC
  383.         ENDC
  384.         
  385.         add.l       a1,a1                   * bcpl pointer conversion
  386.         add.l       a1,a1
  387.  
  388. *------ collect parameters:
  389.         move.l      d2,d0                   * get command line length
  390.         moveq.l     #0,d1
  391.         move.b      (a1)+,d1
  392.         move.l      a1,_ProgramName(A4)
  393.         add.l       d1,d0                   * add length of command name
  394.         addq.l      #7,d0                   * allow for space after command, quotes
  395.                                             * and null terminator, as well as 
  396.         andi.w      #$fffc,D0               * force to long word boundary
  397.         move.l      d0,Commandlen(a4)
  398.    
  399.         movem.l     d1/a1,-(a7)
  400.         move.l      #MEMFLAGS,d1
  401.         callsys     AllocMem
  402.         movem.l     (a7)+,d1/a1
  403.         tst.l       d0
  404.         bne.s       ok_copy
  405.    
  406.         moveq.l     #20,d0                  * what should the return code be for out of mem?
  407.         move.l      d0,-(a7)                * put a return code on the stack
  408.         beq.w       nodofree                * Was exitToDOS
  409.    
  410. ok_copy:
  411.         move.l      d0,a0
  412.         move.l      d0,Commandbuf(a4)
  413.          
  414. *------ copy command line into memory
  415.         move.l     d2,d0                    * get command line length
  416.         subq.l     #1,d0
  417.         add.l      d1,d2
  418.    
  419. copy_line:
  420.         move.b     0(A2,D0.W),2(A0,D2.W)    * copy command line to stack
  421.         subq.l     #1,d2
  422.         dbf        d0,copy_line
  423.         move.b     #' ',2(a0,d2.w)          * add space between command and parms
  424.         subq.l     #1,d2
  425.         move.b     #'"',2(a0,d2.w)          * add end quote
  426.    
  427. copy_cmd:
  428.         move.b     0(a1,d2.w),1(a0,d2.w)    * copy command name to stack
  429.         dbf        d2,copy_cmd
  430.         move.b     #'"',(a0)
  431.         move.l     A0,-(A7)                 * push command line address
  432.         bra.s      main                     * call C entrypoint
  433.  
  434. *=======================================================================
  435. *====== Workbench Startup Code =========================================
  436. *=======================================================================
  437.  
  438. fromWorkbench:
  439.  
  440.         ifd        CATCH
  441.         move.l     TC_SPUPPER(a3),StackTop(a4)  * set top of stack
  442.         endc
  443.  
  444.  
  445. *------ we are now set up.  wait for a message from our starter
  446.         lea        pr_MsgPort(A3),a0         * our process base
  447.         callsys    WaitPort
  448.         lea        pr_MsgPort(A3),a0         * our process base
  449.         callsys    GetMsg
  450.         move.l     d0,_WBenchMsg(a4)
  451.         move.l     d0,-(SP)
  452.  
  453.         move.l     d0,a2                     * get first argument
  454.         move.l     sm_ArgList(a2),d0
  455.         beq.s      do_main
  456.         move.l     DOSBase(a4),a6
  457.         move.l     d0,a0
  458.         move.l     wa_Lock(a0),d1
  459.         callsys    DupLock
  460.         move.l     d0,__curdir(A4)
  461.         move.l     d0,d1
  462.         callsys    CurrentDir
  463.  
  464. do_main:
  465.         move.l     _WBenchMsg(A4),a0         * get address of workbench message
  466.         move.l     a0,-(a7)                  * push argv
  467.         pea        NULL(a4)                  * push argc
  468.         move.l     sm_ArgList(a0),a0         * get address of arguments
  469.         move.l     wa_Name(a0),_ProgramName(A4) * get name of program
  470.  
  471. *=============================================
  472. *------ common code --------
  473. *=============================================
  474.  
  475. main    jsr        __fpinit(PC)              * Initialize floating point and constructors
  476.         tst.l      d0
  477.         bne.s      exit2
  478.         jsr        __main(PC)                * call C entrypoint
  479.         moveq.l    #0,d0                     * set successful status
  480.         bra.s      exit2
  481. *
  482.  
  483. XCEXIT:
  484. _XCEXIT:
  485.         move.l     4(SP),d0                  * extract return code
  486. @XCEXIT:
  487. @_XCEXIT:
  488. exit2:
  489.  
  490. *-- Save Return Code on the original stack
  491.         move.l     _StackPtr(a4),a2
  492.         move.l     d0,-(a2)
  493.  
  494. *-- Set the stack to the first NEW stack we allocated
  495. *-- So C++ destructors can run with a large stack if required
  496.         move.l     newst_Lower(a4),__base(a4)        
  497.         move.l     AbsExecBase.W,A6
  498.         subq.l     #4,newst_Pointer(a4)      * make room for the ret code  
  499.         cmpi.w     #36,$14(a6)
  500.         blt.s      noswap1
  501.         lea        newst_Lower(a4),a0
  502.         callsys    StackSwap
  503.         bra.b      swapdone
  504. noswap1:
  505.         move.l     newst_Pointer(a4),a7
  506. swapdone:        
  507.         move.l     _ONEXIT(A4),d0            * exit trap function?
  508.         beq.s      exit3
  509.         move.l     d0,a0
  510.         jsr        (a0)
  511. exit3:
  512.         jsr        __fpterm(PC)              * clean up any floating point
  513.  
  514.  
  515. *-- Swap back to original stack
  516. *-- If we're running under 2.0, call StackSwap
  517. *-- Otherwise, just jam the new value into a7
  518.         move.l     AbsExecBase.W,A6
  519.         cmpi.w     #36,$14(a6)
  520.         blt.s      noswap
  521.         tst.l      mystk_Lower(a4)
  522.         beq.s      noswap
  523.  
  524.         lea        mystk_Lower(a4),a0
  525.         subq.l     #4,mystk_Pointer(a4)      * make room for the ret code  
  526.         callsys    StackSwap
  527.            
  528. noswap:  
  529.         movea.l    a2,a7                     * restore stack ptr
  530.  
  531.  
  532.         ifnd       RESIDENT
  533. *------ free the stack if we allocated one
  534.         move.l     newstacksize(a4),d0
  535.         beq.s      exit4
  536.         move.l     newstack(a4),a1
  537.         move.l     AbsExecBase.W,A6
  538.         callsys    FreeMem
  539.         endc
  540.  
  541. exit4:
  542. *------ if we ran from CLI, skip workbench cleanup:
  543.         tst.l      _WBenchMsg(A4)
  544.         beq.s      exitToDOS
  545.         move.l     DOSBase(A4),a6
  546.         move.l     __curdir(a4),d1
  547.         beq.s      done_5
  548.         callsys    UnLock
  549. done_5:
  550. *------ return the startup message to our parent
  551. *       we forbid so workbench can't UnLoadSeg() us
  552. *       before we are done:
  553.         move.l     AbsExecBase.W,A6
  554.         callsys    Forbid
  555.         move.l     _WBenchMsg(a4),a1
  556.         callsys    ReplyMsg
  557.         bra.s      nodofree
  558.  
  559. exitToDOS:
  560.         move.l     AbsExecBase.W,a6
  561.  
  562. *------ Restore the original exception handler
  563.         ifd    CATCH
  564.         move.l        ThisTask(a6),A3
  565.         move.l        oldtrapdata(A4),TC_TRAPDATA(a3)
  566.         move.l        oldtrapcode(A4),TC_TRAPCODE(a3) * check current exception
  567.          ifd         AUTOREQ
  568.           move.l        IntuiBase(a4),a1
  569.           callsys         CloseLibrary                * close Intuition library
  570.          endc
  571.         ENDC
  572.  
  573. *------ free the command line buffer
  574.         move.l     Commandlen(a4),d0
  575.         beq.s      nodofree
  576.         move.l     Commandbuf(a4),a1
  577.         callsys    FreeMem
  578.    
  579. *------ this rts sends us back to DOS:
  580. nodofree:
  581.         move.l     DOSBase(A4),a1
  582.         callsys    CloseLibrary              * close Dos library
  583.  
  584.         IFD        RESIDENT
  585.         move.l     realdatasize(a4),d0
  586.         move.l     a4,a1
  587.         sub.l      #RESBASE,a1
  588.         callsys    FreeMem
  589.         ENDC
  590.         move.l     (a7)+,d0
  591.  
  592. return:        
  593.         movem.l    (a7)+,d1-d6/a0-a6
  594.         rts
  595.  
  596. DOSName dc.b    'dos.library',0
  597.  
  598.         ifd        CATCH
  599. *-----------------------------------------------------------------------
  600. *        Open the Intuition library:
  601.  
  602. openIntui:
  603.         lea        IntuiName(PC),A1
  604.         moveq.l    #0,D0
  605.         callsys    OpenLibrary
  606.         move.l     D0,IntuiBase(A4)
  607.         beq.s      noDOS
  608.         rts
  609.  
  610. *-----------------------------------------------------------------------
  611. noDOS:
  612.         moveq.l #100,d0
  613.         bra.w    exit2
  614.  
  615.  
  616. IntuiName  dc.b        'intuition.library',0
  617.  
  618. *-----------------------------------------------------------------------
  619. *        The Exception Handler - catches GURUs and exits (semi)cleanly
  620. Exception:
  621.         movem.l    a0,-(a7)
  622.         move.l     AbsExecBase.W,a0
  623.         move.l     ThisTask(a0),a0
  624.         move.l     TC_TRAPDATA(a0),a0        * ...and data
  625.         move.l     (sp)+,ADump(a0)           * save a0
  626.         move.l     d0,ADump+4(a0)            * and d0
  627.  
  628.         move.l     (a7)+,d0                  * get exception # from stack
  629.         move.l     d0,GURUNum(a0)            * and save it
  630.         cmpi.l     #3,d0                     * ADDRESS or BUS error?
  631.         bgt.s      1$                        * no, skip adjustment
  632.         btst       #0,Environment+3(a0)      * is it 68010 or 68020?
  633.         bne.s      1$                        * 0 means NO
  634.         addq.l     #8,a7                     * adjust for 68000
  635. 1$:
  636.         move.l     2(a7),d0                  * get PC at crash
  637.         move.l     d0,GURUAddr(a0)           * and save it
  638.         move.l     ADump+4(a0),d0            * restore a0 and d0
  639.         move.l     ADump(a0),a0
  640.         move.l     #GURUExit,2(a7)           * use our own exit point
  641.         rte
  642.         
  643. *-----------------------------------------------------------------------
  644. *        The Exception exit routine - write 'PGTB' IFF chunk to file
  645. *        'SnapShot.TB' in current directory, then exit to system.
  646.  
  647. GURUExit:
  648.         movem.l    d0-d7/a0-a7,-(sp)         * save all registers
  649.         move.l     AbsExecBase.W,a6          * make sure we are working with Exec
  650.         callsys    GetCC                     * safe way - works with all CPUs
  651.         move.l     ThisTask(a6),a3
  652.         move.l     TC_TRAPDATA(a3),a4        * make sure we have a valid # in a4
  653.         move.l     d0,Flags(a4)              * save area
  654.         movem.l    (sp)+,d0-d7
  655.         movem.l    d0-d7,DDump(a4)           * save data reg contents
  656.         movem.l    (sp)+,d0-d7
  657.         movem.l    d0-d7,ADump(a4)           * save address reg contents
  658.         tst.l      StackPtr(a4)              * if there's something there
  659.         bne        GExit1                    * ...we've been here before!
  660.         lea        TempStore(a4),a0          * calculate addr of TempStore
  661.         move.l     a0,TempAddr(a4)           * ...and save for later access
  662.         move.l     A7Store(a4),d0            * make sure we have proper TOS
  663.         move.l     d0,StackPtr(a4)           * ...and save it
  664.         moveq      #0,d0
  665.         move.l     _ProgramName(a4),a0       * find length of program name
  666.  
  667.         ifd        AUTOREQ
  668.         move.l     a0,PName(a4)
  669.         endc
  670.  
  671.         subq.l     #1,a0
  672.         move.b     (a0),d0
  673.         addq.l     #4,d0                     * adjust for shift
  674.         lsr.l      #2,d0
  675.         move.l     d0,NameLen(a4)            * store length
  676.         add.l      d0,FAILlen(a4)            * and sub-chunk total
  677.  
  678.         moveq      #0,d0                     * clear d0 for use
  679.         lea        VBlankFrequency(a6),a0    * set up a0 to find correct data
  680.         move.b     (a0)+,d0                  * get just in case
  681.         move.l     d0,VBlankFreq(a4)         * ...so we can figure what
  682.         move.b     (a0),d0                   * ...type of machine
  683.         move.l     d0,PowerSupFreq(a4)       * ...we're working on
  684.  
  685.         lea        start-4(pc),a0            * get seglist ptr
  686.         moveq      #-1,d0                    * always at least 1
  687. 2$:
  688.         addq.l     #1,d0
  689.         move.l     (a0),d1                   * find end of list
  690.         beq.s      3$
  691.         lsl.l      #2,d1                     * BPTR!!!!!
  692.         move.l     d1,a0
  693.         bra.s      2$
  694. 3$:
  695.         add.l      d0,SegCount(a4)           * store # of seglist pointers
  696.         lsl.l      #1,d0                     * multiply by 2 for longword count
  697.         add.l      d0,FAILlen(a4)            * and sub-chunk length
  698.  
  699.         move.l     StackTop(a4),d0           * get top of stack
  700.         sub.l      StackPtr(a4),d0           * find number of bytes used
  701.         addq.l     #4,d0                     * adjust for longword conversion
  702.         lsr.l      #2,d0                     * convert from bytes to long
  703.         move.l     d0,StackLen(a4)           * and save
  704.         add.l      d0,s2len(a4)              * and sub-chunk total
  705.  
  706.         move.l     a5,-(sp)                  * save a5 for later
  707.         callsys    Forbid                    * don't let 'em change while we ask
  708.         move.l     MemList+LH_HEAD(a6),d0    * first node in MemList
  709. checkchip:
  710.         move.l     d0,a5                     * move node address to address reg
  711.         move.w     MH_ATTRIBUTES(a5),d4      * get node attributes
  712.         btst       #MEMB_CHIP,d4             * is it chip?
  713.         beq.s      checkfast                 * no, go on
  714.         lea        chipAvail(a4),a3
  715.         bsr.w      AddIt
  716. checkfast:
  717.         btst       #MEMB_FAST,d4             * is it fast?
  718.         beq.s      next                      * no, go on
  719.         lea        fastAvail(a4),a3
  720.         bsr.w      AddIt
  721. next:
  722.         move.l     LN_SUCC(a5),d0            * get address of next node
  723.         bne.s      checkchip                 * ...and loop back if valid
  724.         callsys    Permit                    * allow others access again
  725.         move.l     #MEMF_CHIP+MEMF_LARGEST,d1 * to find largest hunk in chip ram
  726.         callsys    AvailMem
  727.         move.l     d0,chipLargest(a4)         * store
  728.         move.l     #MEMF_FAST+MEMF_LARGEST,d1 * to find largest hunk in fast ram
  729.         callsys    AvailMem
  730.         move.l     d0,fastLargest(a4)        * store
  731.         move.l     (sp)+,a5                  * and restore a5
  732.  
  733.         ifd        AUTOREQ
  734.         moveq      #0,d0                     * PosFlag
  735.         move.l     d0,d1                     * NegFlag
  736.         move.l     d0,a0                     * 0 means use current window
  737.         lea        IText1(a4),a1             * Body Text
  738.         lea        IText5(a4),a2             * Positive Gadget Text
  739.         lea        IText6(a4),a3             * Negative Gadget Text
  740.         moveq      #1,d2
  741.         lsl.l      #8,d2                     * quick way to set Width
  742.         moveq      #76,d3                    * Height
  743.         move.l     IntuiBase(a4),a6          * get intuition library pointer
  744.         jsr        -$15c(A6)                 * callsys       AutoRequest
  745.         move.l     AbsExecBase.W,a6
  746.         tst.l      d0                        * save SnapShot?
  747.         beq.w      GExit2                    * no, just exit
  748.         endc
  749.  
  750.         move.l     DOSBase(a4),a6
  751.         lea        DumpName(a4),a0           * get name of output file
  752.         move.l     a0,d1
  753.         move.l     #MODE_NEWFILE,d2          * create new file
  754.         callsys    Open 
  755.         bne.s      4$
  756.         lea        DumpPath(a4),a0           * if error in current dir, try DF1:
  757.         move.l     a0,d1
  758.         move.l     #MODE_NEWFILE,d2
  759.         callsys    Open
  760.         bne.s      4$
  761.         move.b     #'0',DumpPath+2(a4)       * still error?  Try DF0:
  762.         lea        DumpPath(a4),a0
  763.         move.l     a0,d1
  764.         move.l     #MODE_NEWFILE,d2
  765.         callsys    Open
  766.  
  767.         ifnd        AUTOREQ
  768.         bne.s      4$                        * if no error, continue (finally!)
  769.         move.l     GConsole(a4),d1
  770.         beq.w      GExit2
  771.         lea        failmsg(a4),a0
  772.         move.l     a0,d2
  773.         move.l     #23,d3
  774.         callsys    Write
  775.         endc
  776.  
  777.         bra.w      GExit2                    * else, print msg & DIE gracefully
  778. 4$:
  779.         move.l     d0,d5                     * save file handle for Write
  780.         move.l     d0,fp(a4)                 * ...and in a safe place for later
  781.         move.l     d5,d1                     * get file handle
  782.         lea        PGTB(a4),a0               * first part of fixed
  783.         move.l     a0,d2
  784.         move.l     #chunk_len_1,d3           * length of first
  785.         callsys    Write                     * ...since it gets written over
  786.  
  787.         move.l     d5,d1                     * get file handle
  788.         move.l     _ProgramName(a4),d2       * get address of program name
  789.         move.l     NameLen(a4),d3            * get # longs in program name
  790.         lsl.l      #2,d3                     * ..and convert to bytes
  791.         callsys    Write
  792.  
  793.         move.l     d5,d1                     * get file handle
  794.         lea        Environment(a4),a0        * second part of fixed
  795.         move.l     a0,d2
  796.         move.l     #chunk_len_2,d3           * length of second part
  797.         callsys    Write
  798.  
  799.         lea        start-8(pc),a0            * address of seglist (size of seg)
  800.         move.l     (a0)+,d0                  * segsize
  801.         move.l     d0,TempStore+4(a4)        * save it
  802.         move.l     a0,TempStore(a4)          * store first number
  803.         move.l     SegCount(a4),d4
  804. 5$:
  805.         move.l     d5,d1                     * get file handle
  806.         move.l     TempAddr(a4),d2           * address of write buffer
  807.         moveq      #TempSize,d3              * size of segment pointer
  808.         callsys    Write
  809.         move.l     TempStore(a4),a0          * retrieve pointer
  810.         move.l     (a0),d0                   * get next seg pointer
  811.         lsl.l      #2,d0                     * adjust
  812.         move.l     d0,TempStore(a4)          * ..and save
  813.         move.l     d0,a0
  814.         beq.b      donesegs                  * last segment?
  815.         move.l     -4(a0),d0                 * get segsize
  816.         move.l     d0,TempStore+4(a4)        * ...and save it
  817.         subq.l     #1,d4                     * done yet?
  818.         bne.s      5$                        * no, do next
  819.  
  820. donesegs:
  821.         tst.l      _FMEM(a4)                 * do they want memory reported?
  822.         beq.s      55$                       * no, forget it
  823.         move.l     d5,d1
  824.         lea        subFMEM(a4),a0
  825.         move.l     a0,d2
  826.         move.l     #FMEMlen,d3
  827.         callsys    Write
  828.  
  829. 55$:
  830.         move.l     d5,d1                     * (get the idea?)
  831.         lea        subREGS(a4),a0            * third part of fixed
  832.         move.l     a0,d2
  833.         move.l     #chunk_len_3,d3           * length of third
  834.         callsys    Write
  835.  
  836.         move.l     StackLen(a4),d0           * get length of stack used
  837.         cmpi.l     #2048,d0                  * > 8k ?
  838.         bgt.s      6$                        * yes, dump two chunks
  839.         move.l     d5,d1
  840.         lea        STAK2(a4),a0              * whole stack chunk
  841.         move.l     a0,d2
  842.         moveq      #STAK2len,d3              * length of fixed part
  843.         callsys    Write
  844.  
  845.         move.l     d5,d1
  846.         move.l     StackPtr(a4),d2           * address of stack
  847.         move.l     StackLen(a4),d3           * get # longwords on stack
  848.         lsl.l      #2,d3                     * ..and convert to bytes
  849.         callsys    Write
  850.         bra.s      7$
  851. 6$:
  852.         move.l     d5,d1
  853.         lea        STAK3(a4),a0              * top4k chunk
  854.         move.l     a0,d2
  855.         moveq      #STAK3len,d3              * length of fixed part
  856.         callsys    Write
  857.  
  858.         move.l     d5,d1
  859.         move.l     StackTop(a4),d2           * find top of stack
  860.         sub.l      #4096,d2                  * find top-4k
  861.         move.l     #4096,d3                  * # bytes to write
  862.         callsys    Write
  863.  
  864.         move.l     d5,d1
  865.         lea        STAK4(a4),a0              * bottom4k chunk
  866.         move.l     a0,d2
  867.         moveq      #STAK4len,d3              * length of fixed part
  868.         callsys    Write
  869.  
  870.         move.l     d5,d1
  871.         move.l     StackPtr(a4),d2           * current stack address
  872.         move.l     #4096,d3                  * # bytes to write
  873.         callsys    Write
  874. 7$:
  875.         move.l     _STAKOffset(a4),d3
  876.         beq.s      8$
  877.         lsr.l      #2,d3
  878.         addq.l     #1,d3
  879.         move.l     d3,_STAKOffset(a4)
  880.         addq.l     #1,d3
  881.         move.l     d5,d1
  882.         lea        STAK5(a4),a0
  883.         move.l     a0,d2
  884.         moveq      #STAK5len,d3
  885.         callsys    Write
  886.  
  887.         move.l     d5,d1
  888.         move.l     StackPtr(a4),d2
  889.         move.l     _STAKOffset(a4),d3
  890.         subq.l     #1,d3
  891.         move.l     StackLen(a4),d4
  892.         cmp.l      d3,d4
  893.         bge.s      75$
  894.         move.l     StackLen(a4),d3
  895. 75$:
  896.         lsl.l      #2,d3
  897.         callsys    Write
  898. 8$:
  899.         tst.l      _ONGURU(A4)               * user GURU function?
  900.         beq.s      9$
  901.         move.l     d5,-(sp)
  902.         move.l     d5,d1
  903.         lea        UDAT(a4),a0
  904.         move.l     a0,d2
  905.         move.l     #UDATlen,d3
  906.         callsys    Write
  907.         move.l     d5,d1
  908.         moveq      #0,d2                     * zero offset
  909.         moveq      #1,d3                     * ...from EOF
  910.         callsys    Seek
  911.         move.l     d0,SeekStore(a4)
  912.         move.l     _ONGURU(a4),a0
  913.         jsr        (a0)
  914.         addq.l     #4,sp
  915. 9$:
  916.         move.l     fp(a4),d5
  917.         move.l     d5,d1
  918.         moveq      #0,d2                     * offset from EOF
  919.         moveq      #1,d3                     * OFFSET_END
  920.         callsys    Seek                      * Seek returns OLD position
  921.         move.l     d0,d1
  922.         andi.l     #3,d1                     * did user write even longwords?
  923.         beq.s      10$                       * Yep!        Nice Human.
  924.         move.l     d1,d6                     * Nope, save for later.
  925.         clr.l      TempStore(a4)             * clear temp storage
  926.         move.l     d5,d1
  927.         move.l     TempAddr(a4),d2
  928.         moveq      #4,d3
  929.         sub.l      d6,d3                     * find how many NULLs to pad
  930.         callsys    Write
  931.         bra.s      9$
  932. 10$:
  933.         tst.l      SeekStore(a4)             * did we write UDAT?
  934.         beq.s      11$                       * nope!
  935.         sub.l      SeekStore(a4),d0          * find length of UDAT section
  936.         lsr.l      #2,d0                     * adjust to longwords
  937.         move.l     d0,TempStore(a4)          * save UDAT length for write
  938.         move.l     d5,d1
  939.         move.l     SeekStore(a4),d2          * find where to write it
  940.         subq.l     #4,d2
  941.         moveq      #-1,d3                    * OFFSET_BEGINNING
  942.         callsys    Seek
  943.         move.l     d5,d1
  944.         move.l     TempAddr(a4),d2
  945.         move.l     #4,d3
  946.         callsys    Write                     * write length of UDAT field to file
  947. 11$:
  948.         move.l     d5,d1
  949.         moveq      #0,d2                     * offset to 'Length' field
  950.         moveq      #1,d3                     * OFFSET_END
  951.         callsys    Seek                      * make sure we are at end of file
  952.         move.l     d5,d1
  953.         moveq      #4,d2                     * offset to 'Length' field
  954.         moveq      #-1,d3                    * OFFSET_BEGINNING
  955.         callsys    Seek
  956.         subq.l     #8,d0                     * adjust total length
  957.         lsr.l      #2,d0                     * adjust to longwords
  958.         move.l     d0,TempStore(a4)          * save for write
  959.         move.l     d5,d1
  960.         move.l     TempAddr(a4),d2
  961.         move.l     #4,d3
  962.         callsys    Write                     * write 'Length' field
  963. GExit1:
  964.         move.l     fp(a4),d1
  965.         beq.s      GExit2
  966.         move.l     DOSBase(a4),a6
  967.         callsys    Close
  968.  
  969.         ifnd        AUTOREQ
  970.         move.l      GConsole(a4),d1
  971.         beq.s       GExit2
  972.         lea         success(a4),a0
  973.         move.l      a0,d2
  974.         move.l      #32,d3
  975.         callsys     Write
  976.         endc
  977.         
  978. GExit2:
  979.         move.l       TaskID(a4),a6
  980.         move.l       AbsExecBase.W,a6
  981.         moveq        #$47,d0
  982.         bra.w        exit2
  983.  
  984. *-----------------------------------------------------------------------
  985. * AddIt:        routine to add memory parts to variables
  986.  
  987. AddIt:
  988.         move.l       MH_FREE(a5),d0
  989.         add.l        d0,(a3)                 * add to available
  990.         move.l       MH_UPPER(a5),d0
  991.         sub.l        MH_LOWER(a5),d0
  992.         add.l        d0,4(a3)                * add to Max section
  993.         rts
  994.         endc
  995.  
  996.  
  997.         IFD     CATCH
  998.         section __MERGED,DATA
  999. _ONGURU        dc.l        0
  1000. IntuiBase      dc.l        0
  1001. TaskID         dc.l        0
  1002. oldtrapcode    dc.l        0
  1003. oldtrapdata    dc.l        0
  1004.  
  1005.         ifnd        AUTOREQ
  1006. GConsole        dc.l        0
  1007. failmsg         dc.b        7,'Can''t write SnapShot!',10
  1008. success         dc.b        7,'GURU caught; SnapShot written!',10
  1009.         endc
  1010.  
  1011.         cnop        0,4
  1012. _FMEM           dc.l        0
  1013. fp              dc.l        0                  * save SnapShot file pointer
  1014. DumpPath        dc.b        'DF1:'
  1015. DumpName        dc.b        'SnapShot.TB',0
  1016. SeekStore       dc.l        0
  1017. TempAddr        dc.l        0                  * Storage for &TempStore
  1018. TempStore       dc.l        0,0                * Temporary storage for BPTR -> APTR
  1019. TempSize        equ        *-TempStore
  1020.  
  1021.         cnop        0,4
  1022.         ifd        AUTOREQ
  1023. TAttr:                                         * Text attributes for font
  1024.         dc.l        TName                      * name of font
  1025.         dc.w        TOPAZ_EIGHTY               * font size
  1026.         dc.b        FS_NORMAL                  * font style
  1027.         dc.b        FPF_ROMFONT                * font preferences
  1028. TName:
  1029.         dc.b        'topaz.font',0
  1030.         cnop        0,4
  1031.  
  1032. IText1:                                        * Text definitions for AutoReq call
  1033.         dc.b        3,0,RP_JAM1,0              * front & back pens, drawmode and filler byte
  1034.         dc.w        6,4                        * XY origin relative to container TopLeft
  1035.         dc.l        TAttr                      * font pointer or NULL for default
  1036.         dc.l        ITextText1                 * pointer to text
  1037.         dc.l        IText2                     * next IntuiText structure
  1038. ITextText1:
  1039.         dc.b        'Program:',0
  1040.         cnop 0,4
  1041. IText2:
  1042.         dc.b        3,0,RP_JAM1,0
  1043.         dc.w        78,4
  1044.         dc.l        TAttr
  1045. PName   dc.l        0
  1046.         dc.l        IText3
  1047.         cnop        0,4
  1048. IText3:
  1049.         dc.b        3,0,RP_JAM1,0
  1050.         dc.w        55,16
  1051.         dc.l        TAttr
  1052.         dc.l        ITextText3
  1053.         dc.l        IText4
  1054. ITextText3:
  1055.         dc.b        'I caught a GURU!',0
  1056.         cnop 0,4
  1057. IText4:
  1058.         dc.b        3,0,RP_JAM1,0
  1059.         dc.w        20,28
  1060.         dc.l        TAttr
  1061.         dc.l        ITextText4
  1062.         dc.l        0
  1063. ITextText4:
  1064.         dc.b        'Should I make a SnapShot?',0
  1065.         cnop 0,4
  1066. IText5:
  1067.         dc.b        3,0,RP_JAM2,0
  1068.         dc.w        6,3
  1069.         dc.l        TAttr
  1070.         dc.l        ITextText5
  1071.         dc.l        0
  1072. ITextText5:
  1073.         dc.b        'YES',0
  1074.         cnop 0,4
  1075. IText6:
  1076.         dc.b        3,0,RP_JAM2,0
  1077.         dc.w        6,3
  1078.         dc.l        TAttr
  1079.         dc.l        ITextText6
  1080.         dc.l        0
  1081. ITextText6:
  1082.         dc.b        'NO',0
  1083.         endc
  1084.  
  1085.         cnop 0,4
  1086.  
  1087. *--------------------------------------------------------------------------
  1088. * New IFF chunk format -
  1089. *        PGTB = Program Traceback, header for chunk
  1090. *        FAIL = reason for and environment of crash
  1091. *        REGS = registers at time of crash, including PC and CCR
  1092. *        VERS = version, revision, name of this program
  1093. *        STAK = ENTIRE stack at time of crash or, alternately,
  1094. *                the top and bottom 4k if the stack used is > 8k
  1095. *        UDAT = optional user data dump (if _ONGURU is set to a
  1096. *                function pointer in the user's program)
  1097. *--------------------------------------------------------------------------
  1098.  
  1099. PGTB            dc.b        'PGTB'
  1100. Length          dc.l        0                * length of chunk (in longwords)
  1101.  
  1102. subFAIL         dc.b        'FAIL'
  1103. FAILlen         dc.l        9
  1104. NameLen         dc.l        0                * length of program name
  1105. chunk_len_1     equ         *-PGTB
  1106. Environment     dc.l        0                * CPU (, Math)
  1107. VBlankFreq      dc.l        0                *        PAL = 50, NTSC = 60 (approx.)
  1108. PowerSupFreq    dc.l        0                * Europe = 50,        USA = 60 (approx.)
  1109. Starter         dc.l        0                * 0 = WB, -1 = CLI
  1110. GURUNum         dc.l        0                * cause of crash (GURU #)
  1111. SegCount        dc.l        1                * # hunks in seglist
  1112. chunk_len_2     equ         *-Environment
  1113.  
  1114. subFMEM         dc.b        'FMEM'           * FMEM - free memory at crash
  1115.                 dc.l        6
  1116. chipAvail       dc.l        0                * available chip memory
  1117. chipMax         dc.l        0                *        maximum chip memory
  1118. chipLargest     dc.l        0                *        largest chip memory
  1119. fastAvail       dc.l        0                * available fast memory
  1120. fastMax         dc.l        0                *        maximum fast memory
  1121. fastLargest     dc.l        0                *        largest fast memory
  1122. FMEMlen         equ         *-subFMEM
  1123.  
  1124. subREGS         dc.b        'REGS'           * REGS - register storage field
  1125. REGSlen         dc.l        18
  1126. GURUAddr        dc.l        0                * PC at time of crash
  1127. Flags           dc.l        0                * Condition Code Register (CCR)
  1128. DDump           dc.l        0,0,0,0,0,0,0,0  * data registers
  1129. ADump           dc.l        0,0,0,0,0,0,0    * address registers
  1130. A7Store         dc.l        0
  1131.  
  1132. subVERS         dc.b        'VERS'           * VERS - program version field
  1133.                 dc.l        6
  1134.                 dc.l        VERSION          * version #
  1135.                 dc.l        REVISION         * revision #
  1136.                 dc.l        3                * length of name of program
  1137.                 IFD        RESIDENT
  1138.                 dc.b        'catchres.o',0,0 * name
  1139.                 ENDC
  1140.                 IFND        RESIDENT
  1141.                 dc.b        'catch.o   ',0,0 * name
  1142.                 ENDC
  1143.  
  1144. subSTAK         dc.b        'STAK'           * STAK - stack field
  1145. STAKlen         dc.l        4
  1146. Type            dc.l        0                * 0 = Info
  1147. StackTop        dc.l        0                * top of stack pointer
  1148. StackPtr        dc.l        0                * current Stack Pointer
  1149. StackLen        dc.l        0                * # bytes used on stack
  1150. chunk_len_3     equ         *-subREGS
  1151.  
  1152. STAK2           dc.b        'STAK'
  1153. s2len           dc.l        1                * length of subtype
  1154.                 dc.l        1                * 1 = whole stack
  1155. STAK2len        equ         *-STAK2
  1156.  
  1157. STAK3           dc.b        'STAK'
  1158.                 dc.l        1025
  1159.                 dc.l        2                * 2 = top 4k of stack
  1160. STAK3len        equ         *-STAK3
  1161.  
  1162. STAK4           dc.b        'STAK'
  1163.                 dc.l        1025
  1164.                 dc.l        3                * 3 = bottom 4k of stack
  1165. STAK4len        equ         *-STAK4
  1166.  
  1167. STAK5           dc.b        'STAK'
  1168. _STAKOffset     dc.l        0
  1169.                 dc.l        4                * 4 = user defined amount
  1170. STAK5len        equ         *-STAK5
  1171.  
  1172. UDAT            dc.b        'UDAT'
  1173.                 dc.l        0
  1174. UDATlen         equ         *-UDAT
  1175.         endc
  1176.  
  1177.  
  1178.  
  1179.         section __MERGED,BSS
  1180.  
  1181.         xdef    NULL,SysBase,DOSBase
  1182.     xref    _FPERR
  1183.  
  1184.         xref    _WBenchMsg
  1185.         xref    __curdir
  1186.         xref    _OSERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  1187.         xref    _SIGINT
  1188.         xref    _ProgramName,_StackPtr,__base
  1189.  
  1190.         ifd        CATCH
  1191.         xdef        _ONGURU,_FMEM,_STAKOffset
  1192.         endc
  1193.  
  1194.  
  1195.         
  1196. NULL          ds.b    4        
  1197. DOSBase       ds.b    4
  1198. SysBase       ds.b    4
  1199. Commandbuf    ds.b    4
  1200. Commandlen    ds.b    4
  1201. mystk_Lower   ds.b    4
  1202. mystk_Upper   ds.b    4
  1203. mystk_Pointer ds.b    4
  1204. newst_Lower   ds.b    4
  1205. newst_Upper   ds.b    4
  1206. newst_Pointer ds.b    4
  1207.  
  1208.  
  1209.  
  1210.         ifd        RESIDENT
  1211. realdatasize ds.b    4                   * size of memory allocated for data +
  1212.                                          * possible stack
  1213.         endc
  1214.         ifnd       RESIDENT
  1215. newstack     ds.b    4                   * pointer to new stack (if needed)
  1216. newstacksize ds.b    4                   * size of new stack
  1217.         endc
  1218.  
  1219.              END
  1220.