home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / Assembler / dse-src6.dms / in.adf / DMZ.LZH / PRG7.4 < prev    next >
Encoding:
Text File  |  1999-10-01  |  3.2 KB  |  147 lines
  1. OPENLIBRARY:    EQU    -408
  2. CLOSELIBRARY:    EQU    -414
  3. OPENSCREEN:    EQU    -198
  4. CLOSESCREEN:    EQU    -66
  5. OPENWINDOW:    EQU    -204
  6. CLOSEWINDOW:    EQU    -72
  7.  
  8. GETRP:        MACRO                ; Hämta RastPort
  9.         MOVE.L    WIN_HANDLE(PC),A1
  10.         MOVE.L    50(A1),A1
  11.         ENDM
  12.  
  13. PACOL:        MACRO                ; Sätt pennfärg
  14.         MOVE.W    #?1,D0
  15.         JSR    -342(A6)
  16.         ENDM
  17.  
  18. PMOVE:        MACRO                ; Flytta penna
  19.         MOVE.W    #?1,D0
  20.         MOVE.W    #?2,D1
  21.         JSR    -240(A6)
  22.         ENDM
  23.  
  24. PDRAW:        MACRO                ; Dra linje
  25.         MOVE.W    #?1,D0
  26.         MOVE.W    #?2,D1
  27.         JSR    -246(A6)
  28.         ENDM
  29.  
  30. PRECT:        MACRO                ; Fyll rektangel
  31.         MOVE.W    #?1,D0
  32.         MOVE.W    #?2,D1
  33.         MOVE.W    #?3,D2
  34.         MOVE.W    #?4,D3
  35.         JSR    -306(A6)
  36.         ENDM
  37.  
  38. START:        MOVE.L    $4.W,A6
  39.         LEA.L    INTNAME(PC),A1
  40.         JSR    OPENLIBRARY(A6)        ; Öppna intuition
  41.         MOVE.L    D0,INTBASE        ; Spar intbase
  42.         BEQ.L    EXIT
  43.         MOVE.L    D0,A6
  44.  
  45.         BSR.L    SCROPEN            ; Öppna skärm
  46.         BSR.L    WINOPEN            ; Öppna fönster
  47.  
  48.         MOVE.L    $4.W,A6
  49.         LEA.L    GFXNAME(PC),A1
  50.         JSR    OPENLIBRARY(A6)        ; Öppna graphics
  51.         MOVE.L    D0,GFXBASE        ; Spar gfxbase
  52.         BEQ.L    GFXERROR
  53.         MOVE.L    D0,A6
  54.  
  55.         GETRP                ; Hämta RastPort
  56.         PACOL    2            ; Pennfärg 2
  57.         PMOVE    20,20            ; Flytta pennan
  58.         PDRAW    200,100            ; Rita triangel
  59.         PDRAW    250,50
  60.         PDRAW    20,20
  61.         PACOL    3            ; Pennfärg 3
  62.         PRECT    300,50,400,150        ; Rita rektangel
  63.  
  64. KBDPRESS:    BTST    #0,$BFEC01        ; Tangent nedtryckt?
  65.         BEQ.S    KBDPRESS
  66.  
  67.         MOVE.L    A6,A1
  68.         MOVE.L    $4.W,A6
  69.         JSR    CLOSELIBRARY(A6)    ; Stäng graphics
  70.  
  71. GFXERROR:    MOVE.L    INTBASE(PC),A6
  72.         BSR.L    WINCLOSE        ; Stäng fönster
  73.         BSR.L    SCRCLOSE        ; Stäng skärm
  74.  
  75.         MOVE.L    A6,A1
  76.         MOVE.L    $4.W,A6
  77.         JSR    CLOSELIBRARY(A6)    ; Stäng intuition
  78. EXIT:        RTS
  79.  
  80. SCROPEN:    LEA.L    SCR_PARS(PC),A0
  81.         JSR    OPENSCREEN(A6)
  82.         MOVE.L    D0,SCR_HANDLE        ; Spar skärm ID
  83.         RTS
  84.  
  85. SCRCLOSE:    MOVE.L    SCR_HANDLE(PC),A0
  86.         JSR    CLOSESCREEN(A6)
  87.         RTS
  88.  
  89. WINOPEN:    LEA.L    WIN_PARS(PC),A0
  90.         JSR    OPENWINDOW(A6)
  91.         MOVE.L    D0,WIN_HANDLE        ; Spar fönster ID
  92.         RTS
  93.  
  94. WINCLOSE:    MOVE.L    WIN_HANDLE(PC),A0
  95.         JSR    CLOSEWINDOW(A6)
  96.         RTS
  97.  
  98. INTNAME:    DC.B    'intuition.library',0
  99. EVEN
  100. INTBASE:    DC.L    0
  101. GFXNAME:    DC.B    'graphics.library',0
  102. EVEN
  103. GFXBASE:    DC.L    0
  104.  
  105. SCR_PARS:
  106. SCR_XPOS:    DC.W    0            ; X position
  107. SCR_YPOS:    DC.W    0            ; Y position
  108. SCR_WIDTH:    DC.W    640            ; Skärmbredd
  109. SCR_HEIGHT:    DC.W    200            ; Skärmhöjd
  110. SCR_DEPTH:    DC.W    2            ; Antal bitplan
  111. SCR_TXTCOL:    DC.B    0            ; Textfärg
  112. SCR_BKGCOL:    DC.B    1            ; Bakgrundsfärg
  113. SCR_VMODE:    DC.W    $8000            ; Flaggor
  114. SCR_TYPE:    DC.W    15            ; Bildtyp
  115. SCR_FONT:    DC.L    0            ; Fontpekare
  116. SCR_TITLE:    DC.L    SCRNAME            ; Pekare till namn
  117. SCR_GADGETS:    DC.L    0            ; Pekare till gadgets
  118. SCR_BITMAP:    DC.L    0            ; Pekare till bitmap
  119.  
  120. SCRNAME:    DC.B    'Assembler-skolan',0    ; Skärmnamn
  121. EVEN
  122.  
  123. WIN_PARS:
  124. WIN_XPOS:    DC.W    10            ; X position
  125. WIN_YPOS:    DC.W    20            ; Y position
  126. WIN_WIDTH:    DC.W    620            ; Fönsterbredd
  127. WIN_HEIGHT:    DC.W    170            ; Fönsterhöjd
  128. WIN_TXTCOL:    DC.B    2            ; Textfärg
  129. WIN_BKGCOL:    DC.B    1            ; Bakgrundsfärg
  130. WIN_IDCMP:    DC.L    $00000200        ; Rapportflaggor
  131. WIN_FLAGS:    DC.L    $0000100F        ; Flaggor
  132. WIN_GADGETS:    DC.L    0            ; Pekare till gadgets
  133. WIN_CHECKMARK:    DC.L    0            ; Pekare till symbol
  134. WIN_TITLE:    DC.L    WINNAME            ; Pekare till namn
  135. SCR_HANDLE:    DC.L    0            ; Skärm ID
  136. WIN_BITMAP:    DC.L    0            ; Pekare till bitmap
  137. WIN_MINWIDTH:    DC.W    310            ; Minsta bredd
  138. WIN_MINHEIGHT:    DC.W    85            ; Minsta höjd
  139. WIN_MAXWIDTH:    DC.W    640            ; Största bredd
  140. WIN_MAXHEIGHT:    DC.W    190            ; Största höjd
  141. WIN_TYPE:    DC.W    15            ; Fönstertyp
  142.  
  143. WINNAME:    DC.B    'Vårt fönster',0    ; Fönsternamn
  144. EVEN
  145.  
  146. WIN_HANDLE:    DC.L    0            ; Fönster ID
  147.