home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD2.iso / Programming / Assembler / dse-src6.dms / in.adf / DMZ.LZH / PRG7.3 < prev    next >
Encoding:
Text File  |  1999-10-01  |  3.0 KB  |  126 lines
  1. OPENLIBRARY:    EQU    -408
  2. CLOSELIBRARY:    EQU    -414
  3. OPENSCREEN:    EQU    -198
  4. CLOSESCREEN:    EQU    -66
  5. OPENWINDOW:    EQU    -204
  6. CLOSEWINDOW:    EQU    -72
  7. PRINTITEXT:    EQU    -216
  8. GETMSG:        EQU    -372
  9.  
  10. START:        MOVE.L    $4.W,A6
  11.         LEA.L    INTNAME(PC),A1
  12.         JSR    OPENLIBRARY(A6)        ; Öppna intuition
  13.         MOVE.L    D0,INTBASE        ; Spar intbase
  14.         BEQ.S    EXIT
  15.         MOVE.L    D0,A6
  16.  
  17.         BSR.L    SCROPEN            ; Öppna skärm
  18.         BSR.L    WINOPEN            ; Öppna fönster
  19.         LEA.L    TXT_PARS(PC),A1
  20.         MOVE.W    #196,D0            ; X-position
  21.         MOVE.W    #66,D1            ; Y-position
  22.         BSR.L    PRINT            ; Skriv text
  23.  
  24.         MOVE.L    $4.W,A6
  25. EVENTWAIT:    MOVE.L    WIN_HANDLE(PC),A0
  26.         MOVE.L    86(A0),A0        ; Pekare till message-
  27.         JSR    GETMSG(A6)        ; struktur
  28.         TST.L    D0            ; Någon event?
  29.         BEQ.S    EVENTWAIT
  30.  
  31.         MOVE.L    D0,A1
  32.         MOVE.L    20(A1),D0        ; Hämta event-flaggor
  33.         BTST    #9,D0            ; CloseWindow klickad?
  34.         BEQ.S    EVENTWAIT
  35.         MOVE.L    INTBASE(PC),A6
  36.  
  37.         BSR.L    WINCLOSE        ; Stäng fönster
  38.         BSR.L    SCRCLOSE        ; Stäng skärm
  39.  
  40.         MOVE.L    A6,A1
  41.         MOVE.L    $4.W,A6
  42.         JSR    CLOSELIBRARY(A6)    ; Stäng intuition
  43. EXIT:        RTS
  44.  
  45. SCROPEN:    LEA.L    SCR_PARS(PC),A0
  46.         JSR    OPENSCREEN(A6)
  47.         MOVE.L    D0,SCR_HANDLE        ; Spar skärm ID
  48.         RTS
  49.  
  50. SCRCLOSE:    MOVE.L    SCR_HANDLE(PC),A0
  51.         JSR    CLOSESCREEN(A6)
  52.         RTS
  53.  
  54. WINOPEN:    LEA.L    WIN_PARS(PC),A0
  55.         JSR    OPENWINDOW(A6)
  56.         MOVE.L    D0,WIN_HANDLE        ; Spar fönster ID
  57.         RTS
  58.  
  59. WINCLOSE:    MOVE.L    WIN_HANDLE(PC),A0
  60.         JSR    CLOSEWINDOW(A6)
  61.         RTS
  62.  
  63. PRINT:        MOVE.L    WIN_HANDLE(PC),A0
  64.         MOVE.L    50(A0),A0        ; RastPort-pekare
  65.         JSR    PRINTITEXT(A6)        ; Skriv ut text
  66.         RTS
  67.  
  68. INTNAME:    DC.B    'intuition.library',0
  69. EVEN
  70. INTBASE:    DC.L    0
  71.  
  72. SCR_PARS:
  73. SCR_XPOS:    DC.W    0            ; X position
  74. SCR_YPOS:    DC.W    0            ; Y position
  75. SCR_WIDTH:    DC.W    640            ; Skärmbredd
  76. SCR_HEIGHT:    DC.W    200            ; Skärmhöjd
  77. SCR_DEPTH:    DC.W    2            ; Antal bitplan
  78. SCR_TXTCOL:    DC.B    0            ; Textfärg
  79. SCR_BKGCOL:    DC.B    1            ; Bakgrundsfärg
  80. SCR_VMODE:    DC.W    $8000            ; Flaggor
  81. SCR_TYPE:    DC.W    15            ; Bildtyp
  82. SCR_FONT:    DC.L    0            ; Fontpekare
  83. SCR_TITLE:    DC.L    SCRNAME            ; Pekare till namn
  84. SCR_GADGETS:    DC.L    0            ; Pekare till gadgets
  85. SCR_BITMAP:    DC.L    0            ; Pekare till bitmap
  86.  
  87. SCRNAME:    DC.B    'Assembler-skolan',0    ; Skärmnamn
  88. EVEN
  89.  
  90. WIN_PARS:
  91. WIN_XPOS:    DC.W    10            ; X position
  92. WIN_YPOS:    DC.W    20            ; Y position
  93. WIN_WIDTH:    DC.W    620            ; Fönsterbredd
  94. WIN_HEIGHT:    DC.W    170            ; Fönsterhöjd
  95. WIN_TXTCOL:    DC.B    2            ; Textfärg
  96. WIN_BKGCOL:    DC.B    1            ; Bakgrundsfärg
  97. WIN_IDCMP:    DC.L    $00000200        ; Rapportflaggor
  98. WIN_FLAGS:    DC.L    $0000100F        ; Flaggor
  99. WIN_GADGETS:    DC.L    0            ; Pekare till gadgets
  100. WIN_CHECKMARK:    DC.L    0            ; Pekare till symbol
  101. WIN_TITLE:    DC.L    WINNAME            ; Pekare till namn
  102. SCR_HANDLE:    DC.L    0            ; Skärm ID
  103. WIN_BITMAP:    DC.L    0            ; Pekare till bitmap
  104. WIN_MINWIDTH:    DC.W    310            ; Minsta bredd
  105. WIN_MINHEIGHT:    DC.W    85            ; Minsta höjd
  106. WIN_MAXWIDTH:    DC.W    640            ; Största bredd
  107. WIN_MAXHEIGHT:    DC.W    190            ; Största höjd
  108. WIN_TYPE:    DC.W    15            ; Fönstertyp
  109.  
  110. WINNAME:    DC.B    'Vårt fönster',0    ; Fönsternamn
  111. EVEN
  112.  
  113. WIN_HANDLE:    DC.L    0            ; Fönster ID
  114.  
  115. TXT_PARS:
  116. TXT_TXTCOL:    DC.B    1            ; Textfärg
  117. TXT_BKGCOL:    DC.B    3            ; Bakgrundsfärg
  118. TXT_MODE:    DC.B    1,0            ; Text mode
  119. TXT_XPOS:    DC.W    6            ; X-position
  120. TXT_YPOS:    DC.W    10            ; Y-position
  121. TXT_FONT:    DC.L    0            ; Fontpekare
  122. TXT_STRING:    DC.L    TXTTEXT            ; Textpekare
  123. TXT_END:    DC.L    0            ; Nästa text
  124.  
  125. TXTTEXT:    DC.B    'Vi testar PrintIText. Gruf!',0
  126.