home *** CD-ROM | disk | FTP | other *** search
/ PC World 2003 March / PCWorld_2003-03_cd.bin / Software / Topware / activeperl / ActivePerl / Perl / lib / Pod / Find.pm < prev    next >
Encoding:
Perl POD Document  |  2002-11-25  |  14.4 KB  |  502 lines
  1. #############################################################################  
  2. # Pod/Find.pm -- finds files containing POD documentation
  3. #
  4. # Author: Marek Rouchal <marek@saftsack.fs.uni-bayreuth.de>
  5. # 
  6. # Copyright (C) 1999-2000 by Marek Rouchal (and borrowing code
  7. # from Nick Ing-Simmon's PodToHtml). All rights reserved.
  8. # This file is part of "PodParser". Pod::Find is free software;
  9. # you can redistribute it and/or modify it under the same terms
  10. # as Perl itself.
  11. #############################################################################
  12.  
  13. package Pod::Find;
  14.  
  15. use vars qw($VERSION);
  16. $VERSION = 0.22;   ## Current version of this package
  17. require  5.005;   ## requires this Perl version or later
  18. use Carp;
  19.  
  20. #############################################################################
  21.  
  22. =head1 NAME
  23.  
  24. Pod::Find - find POD documents in directory trees
  25.  
  26. =head1 SYNOPSIS
  27.  
  28.   use Pod::Find qw(pod_find simplify_name);
  29.   my %pods = pod_find({ -verbose => 1, -inc => 1 });
  30.   foreach(keys %pods) {
  31.      print "found library POD `$pods{$_}' in $_\n";
  32.   }
  33.  
  34.   print "podname=",simplify_name('a/b/c/mymodule.pod'),"\n";
  35.  
  36.   $location = pod_where( { -inc => 1 }, "Pod::Find" );
  37.  
  38. =head1 DESCRIPTION
  39.  
  40. B<Pod::Find> provides a set of functions to locate POD files.  Note that
  41. no function is exported by default to avoid pollution of your namespace,
  42. so be sure to specify them in the B<use> statement if you need them:
  43.  
  44.   use Pod::Find qw(pod_find);
  45.  
  46. =cut
  47.  
  48. use strict;
  49. #use diagnostics;
  50. use Exporter;
  51. use File::Spec;
  52. use File::Find;
  53. use Cwd;
  54.  
  55. use vars qw(@ISA @EXPORT_OK $VERSION);
  56. @ISA = qw(Exporter);
  57. @EXPORT_OK = qw(&pod_find &simplify_name &pod_where &contains_pod);
  58.  
  59. # package global variables
  60. my $SIMPLIFY_RX;
  61.  
  62. =head2 C<pod_find( { %opts } , @directories )>
  63.  
  64. The function B<pod_find> searches for POD documents in a given set of
  65. files and/or directories. It returns a hash with the file names as keys
  66. and the POD name as value. The POD name is derived from the file name
  67. and its position in the directory tree.
  68.  
  69. E.g. when searching in F<$HOME/perl5lib>, the file
  70. F<$HOME/perl5lib/MyModule.pm> would get the POD name I<MyModule>,
  71. whereas F<$HOME/perl5lib/Myclass/Subclass.pm> would be
  72. I<Myclass::Subclass>. The name information can be used for POD
  73. translators.
  74.  
  75. Only text files containing at least one valid POD command are found.
  76.  
  77. A warning is printed if more than one POD file with the same POD name
  78. is found, e.g. F<CPAN.pm> in different directories. This usually
  79. indicates duplicate occurrences of modules in the I<@INC> search path.
  80.  
  81. B<OPTIONS> The first argument for B<pod_find> may be a hash reference
  82. with options. The rest are either directories that are searched
  83. recursively or files.  The POD names of files are the plain basenames
  84. with any Perl-like extension (.pm, .pl, .pod) stripped.
  85.  
  86. =over 4
  87.  
  88. =item C<-verbose =E<gt> 1>
  89.  
  90. Print progress information while scanning.
  91.  
  92. =item C<-perl =E<gt> 1>
  93.  
  94. Apply Perl-specific heuristics to find the correct PODs. This includes
  95. stripping Perl-like extensions, omitting subdirectories that are numeric
  96. but do I<not> match the current Perl interpreter's version id, suppressing
  97. F<site_perl> as a module hierarchy name etc.
  98.  
  99. =item C<-script =E<gt> 1>
  100.  
  101. Search for PODs in the current Perl interpreter's installation 
  102. B<scriptdir>. This is taken from the local L<Config|Config> module.
  103.  
  104. =item C<-inc =E<gt> 1>
  105.  
  106. Search for PODs in the current Perl interpreter's I<@INC> paths. This
  107. automatically considers paths specified in the C<PERL5LIB> environment
  108. as this is prepended to I<@INC> by the Perl interpreter itself.
  109.  
  110. =back
  111.  
  112. =cut
  113.  
  114. # return a hash of the POD files found
  115. # first argument may be a hashref (options),
  116. # rest is a list of directories to search recursively
  117. sub pod_find
  118. {
  119.     my %opts;
  120.     if(ref $_[0]) {
  121.         %opts = %{shift()};
  122.     }
  123.  
  124.     $opts{-verbose} ||= 0;
  125.     $opts{-perl}    ||= 0;
  126.  
  127.     my (@search) = @_;
  128.  
  129.     if($opts{-script}) {
  130.         require Config;
  131.         push(@search, $Config::Config{scriptdir})
  132.             if -d $Config::Config{scriptdir};
  133.         $opts{-perl} = 1;
  134.     }
  135.  
  136.     if($opts{-inc}) {
  137.         if ($^O eq 'MacOS') {
  138.             # tolerate '.', './some_dir' and '(../)+some_dir' on Mac OS
  139.             my @new_INC = @INC;
  140.             for (@new_INC) {
  141.                 if ( $_ eq '.' ) {
  142.                     $_ = ':';
  143.                 } elsif ( $_ =~ s|^((?:\.\./)+)|':' x (length($1)/3)|e ) {
  144.                     $_ = ':'. $_;
  145.                 } else {
  146.                     $_ =~ s|^\./|:|;
  147.                 }
  148.             }
  149.             push(@search, grep($_ ne File::Spec->curdir, @new_INC));
  150.         } else {
  151.             push(@search, grep($_ ne File::Spec->curdir, @INC));
  152.         }
  153.  
  154.         $opts{-perl} = 1;
  155.     }
  156.  
  157.     if($opts{-perl}) {
  158.         require Config;
  159.         # this code simplifies the POD name for Perl modules:
  160.         # * remove "site_perl"
  161.         # * remove e.g. "i586-linux" (from 'archname')
  162.         # * remove e.g. 5.00503
  163.         # * remove pod/ if followed by *.pod (e.g. in pod/perlfunc.pod)
  164.  
  165.         # Mac OS:
  166.         # * remove ":?site_perl:"
  167.         # * remove :?pod: if followed by *.pod (e.g. in :pod:perlfunc.pod)
  168.  
  169.         if ($^O eq 'MacOS') {
  170.             $SIMPLIFY_RX =
  171.               qq!^(?i:\:?site_perl\:|\:?pod\:(?=.*?\\.pod\\z))*!;
  172.         } else {
  173.             $SIMPLIFY_RX =
  174.               qq!^(?i:site(_perl)?/|\Q$Config::Config{archname}\E/|\\d+\\.\\d+([_.]?\\d+)?/|pod/(?=.*?\\.pod\\z))*!;
  175.         }
  176.     }
  177.  
  178.     my %dirs_visited;
  179.     my %pods;
  180.     my %names;
  181.     my $pwd = cwd();
  182.  
  183.     foreach my $try (@search) {
  184.         unless(File::Spec->file_name_is_absolute($try)) {
  185.             # make path absolute
  186.             $try = File::Spec->catfile($pwd,$try);
  187.         }
  188.         # simplify path
  189.         # on VMS canonpath will vmsify:[the.path], but File::Find::find
  190.         # wants /unixy/paths
  191.         $try = File::Spec->canonpath($try) if ($^O ne 'VMS');
  192.         $try = VMS::Filespec::unixify($try) if ($^O eq 'VMS');
  193.         my $name;
  194.         if(-f $try) {
  195.             if($name = _check_and_extract_name($try, $opts{-verbose})) {
  196.                 _check_for_duplicates($try, $name, \%names, \%pods, $opts{-verbose});
  197.             }
  198.             next;
  199.         }
  200.         my $root_rx = $^O eq 'MacOS' ? qq!^\Q$try\E! : qq!^\Q$try\E/!;
  201.         File::Find::find( sub {
  202.             my $item = $File::Find::name;
  203.             if(-d) {
  204.                 if($dirs_visited{$item}) {
  205.                     warn "Directory '$item' already seen, skipping.\n"
  206.                         if($opts{-verbose});
  207.                     $File::Find::prune = 1;
  208.                     return;
  209.                 }
  210.                 else {
  211.                     $dirs_visited{$item} = 1;
  212.                 }
  213.                 if($opts{-perl} && /^(\d+\.[\d_]+)\z/s && eval "$1" != $]) {
  214.                     $File::Find::prune = 1;
  215.                     warn "Perl $] version mismatch on $_, skipping.\n"
  216.                         if($opts{-verbose});
  217.                 }
  218.                 return;
  219.             }
  220.             if($name = _check_and_extract_name($item, $opts{-verbose}, $root_rx)) {
  221.                 _check_for_duplicates($item, $name, \%names, \%pods, $opts{-verbose});
  222.             }
  223.         }, $try); # end of File::Find::find
  224.     }
  225.     chdir $pwd;
  226.     %pods;
  227. }
  228.  
  229. sub _check_for_duplicates {
  230.     my ($file, $name, $names_ref, $pods_ref, $verbose) = @_;
  231.     if ($$names_ref{$name}) {
  232.         warn "Duplicate POD found (shadowing?): $name ($file)\n",
  233.              "    Already seen in ",
  234.             join(' ', grep($$pods_ref{$_} eq $name, keys %$pods_ref)),"\n"
  235.                         if $verbose;
  236.     }
  237.     else {
  238.         $$names_ref{$name} = 1;
  239.     }
  240.     $$pods_ref{$file} = $name;
  241. }
  242.  
  243. sub _check_and_extract_name {
  244.     my ($file, $verbose, $root_rx) = @_;
  245.  
  246.     # check extension or executable flag
  247.     # this involves testing the .bat extension on Win32!
  248.     unless(-f $file && -T _ && ($file =~ /\.(pod|pm|plx?)\z/i || -x $file )) {
  249.       return undef;
  250.     }
  251.  
  252.     return undef unless contains_pod($file,$verbose);
  253.  
  254.     # strip non-significant path components
  255.     # TODO what happens on e.g. Win32?
  256.     my $name = $file;
  257.     if(defined $root_rx) {
  258.         $name =~ s!$root_rx!!s;
  259.         $name =~ s!$SIMPLIFY_RX!!os if(defined $SIMPLIFY_RX);
  260.     }
  261.     else {
  262.         if ($^O eq 'MacOS') {
  263.             $name =~ s/^.*://s;
  264.         } else {
  265.             $name =~ s:^.*/::s;
  266.         }
  267.     }
  268.     _simplify($name);
  269.     $name =~ s!/+!::!g; #/
  270.     if ($^O eq 'MacOS') {
  271.         $name =~ s!:+!::!g; # : -> ::
  272.     } else {
  273.         $name =~ s!/+!::!g; # / -> ::
  274.     }
  275.     $name;
  276. }
  277.  
  278. =head2 C<simplify_name( $str )>
  279.  
  280. The function B<simplify_name> is equivalent to B<basename>, but also
  281. strips Perl-like extensions (.pm, .pl, .pod) and extensions like
  282. F<.bat>, F<.cmd> on Win32 and OS/2, or F<.com> on VMS, respectively.
  283.  
  284. =cut
  285.  
  286. # basic simplification of the POD name:
  287. # basename & strip extension
  288. sub simplify_name {
  289.     my ($str) = @_;
  290.     # remove all path components
  291.     if ($^O eq 'MacOS') {
  292.         $str =~ s/^.*://s;
  293.     } else {
  294.         $str =~ s:^.*/::s;
  295.     }
  296.     _simplify($str);
  297.     $str;
  298. }
  299.  
  300. # internal sub only
  301. sub _simplify {
  302.     # strip Perl's own extensions
  303.     $_[0] =~ s/\.(pod|pm|plx?)\z//i;
  304.     # strip meaningless extensions on Win32 and OS/2
  305.     $_[0] =~ s/\.(bat|exe|cmd)\z//i if($^O =~ /mswin|os2/i);
  306.     # strip meaningless extensions on VMS
  307.     $_[0] =~ s/\.(com)\z//i if($^O eq 'VMS');
  308. }
  309.  
  310. # contribution from Tim Jenness <t.jenness@jach.hawaii.edu>
  311.  
  312. =head2 C<pod_where( { %opts }, $pod )>
  313.  
  314. Returns the location of a pod document given a search directory
  315. and a module (e.g. C<File::Find>) or script (e.g. C<perldoc>) name.
  316.  
  317. Options:
  318.  
  319. =over 4
  320.  
  321. =item C<-inc =E<gt> 1>
  322.  
  323. Search @INC for the pod and also the C<scriptdir> defined in the
  324. L<Config|Config> module.
  325.  
  326. =item C<-dirs =E<gt> [ $dir1, $dir2, ... ]>
  327.  
  328. Reference to an array of search directories. These are searched in order
  329. before looking in C<@INC> (if B<-inc>). Current directory is used if
  330. none are specified.
  331.  
  332. =item C<-verbose =E<gt> 1>
  333.  
  334. List directories as they are searched
  335.  
  336. =back
  337.  
  338. Returns the full path of the first occurrence to the file.
  339. Package names (eg 'A::B') are automatically converted to directory
  340. names in the selected directory. (eg on unix 'A::B' is converted to
  341. 'A/B'). Additionally, '.pm', '.pl' and '.pod' are appended to the
  342. search automatically if required.
  343.  
  344. A subdirectory F<pod/> is also checked if it exists in any of the given
  345. search directories. This ensures that e.g. L<perlfunc|perlfunc> is
  346. found.
  347.  
  348. It is assumed that if a module name is supplied, that that name
  349. matches the file name. Pods are not opened to check for the 'NAME'
  350. entry.
  351.  
  352. A check is made to make sure that the file that is found does 
  353. contain some pod documentation.
  354.  
  355. =cut
  356.  
  357. sub pod_where {
  358.  
  359.   # default options
  360.   my %options = (
  361.          '-inc' => 0,
  362.          '-verbose' => 0,
  363.          '-dirs' => [ File::Spec->curdir ],
  364.         );
  365.  
  366.   # Check for an options hash as first argument
  367.   if (defined $_[0] && ref($_[0]) eq 'HASH') {
  368.     my $opt = shift;
  369.  
  370.     # Merge default options with supplied options
  371.     %options = (%options, %$opt);
  372.   }
  373.  
  374.   # Check usage
  375.   carp 'Usage: pod_where({options}, $pod)' unless (scalar(@_));
  376.  
  377.   # Read argument
  378.   my $pod = shift;
  379.  
  380.   # Split on :: and then join the name together using File::Spec
  381.   my @parts = split (/::/, $pod);
  382.  
  383.   # Get full directory list
  384.   my @search_dirs = @{ $options{'-dirs'} };
  385.  
  386.   if ($options{'-inc'}) {
  387.  
  388.     require Config;
  389.  
  390.     # Add @INC
  391.     if ($^O eq 'MacOS' && $options{'-inc'}) {
  392.         # tolerate '.', './some_dir' and '(../)+some_dir' on Mac OS
  393.         my @new_INC = @INC;
  394.         for (@new_INC) {
  395.             if ( $_ eq '.' ) {
  396.                 $_ = ':';
  397.             } elsif ( $_ =~ s|^((?:\.\./)+)|':' x (length($1)/3)|e ) {
  398.                 $_ = ':'. $_;
  399.             } else {
  400.                 $_ =~ s|^\./|:|;
  401.             }
  402.         }
  403.         push (@search_dirs, @new_INC);
  404.     } elsif ($options{'-inc'}) {
  405.         push (@search_dirs, @INC);
  406.     }
  407.  
  408.     # Add location of pod documentation for perl man pages (eg perlfunc)
  409.     # This is a pod directory in the private install tree
  410.     #my $perlpoddir = File::Spec->catdir($Config::Config{'installprivlib'},
  411.     #                    'pod');
  412.     #push (@search_dirs, $perlpoddir)
  413.     #  if -d $perlpoddir;
  414.  
  415.     # Add location of binaries such as pod2text
  416.     push (@search_dirs, $Config::Config{'scriptdir'})
  417.       if -d $Config::Config{'scriptdir'};
  418.   }
  419.  
  420.   # Loop over directories
  421.   Dir: foreach my $dir ( @search_dirs ) {
  422.  
  423.     # Don't bother if can't find the directory
  424.     if (-d $dir) {
  425.       warn "Looking in directory $dir\n" 
  426.         if $options{'-verbose'};
  427.  
  428.       # Now concatenate this directory with the pod we are searching for
  429.       my $fullname = File::Spec->catfile($dir, @parts);
  430.       warn "Filename is now $fullname\n"
  431.         if $options{'-verbose'};
  432.  
  433.       # Loop over possible extensions
  434.       foreach my $ext ('', '.pod', '.pm', '.pl') {
  435.         my $fullext = $fullname . $ext;
  436.         if (-f $fullext && 
  437.          contains_pod($fullext, $options{'-verbose'}) ) {
  438.           warn "FOUND: $fullext\n" if $options{'-verbose'};
  439.           return $fullext;
  440.         }
  441.       }
  442.     } else {
  443.       warn "Directory $dir does not exist\n"
  444.         if $options{'-verbose'};
  445.       next Dir;
  446.     }
  447.     if(-d File::Spec->catdir($dir,'pod')) {
  448.       $dir = File::Spec->catdir($dir,'pod');
  449.       redo Dir;
  450.     }
  451.   }
  452.   # No match;
  453.   return undef;
  454. }
  455.  
  456. =head2 C<contains_pod( $file , $verbose )>
  457.  
  458. Returns true if the supplied filename (not POD module) contains some pod
  459. information.
  460.  
  461. =cut
  462.  
  463. sub contains_pod {
  464.   my $file = shift;
  465.   my $verbose = 0;
  466.   $verbose = shift if @_;
  467.  
  468.   # check for one line of POD
  469.   unless(open(POD,"<$file")) {
  470.     warn "Error: $file is unreadable: $!\n";
  471.     return undef;
  472.   }
  473.   
  474.   local $/ = undef;
  475.   my $pod = <POD>;
  476.   close(POD) || die "Error closing $file: $!\n";
  477.   unless($pod =~ /\n=(head\d|pod|over|item)\b/s) {
  478.     warn "No POD in $file, skipping.\n"
  479.       if($verbose);
  480.     return 0;
  481.   }
  482.  
  483.   return 1;
  484. }
  485.  
  486. =head1 AUTHOR
  487.  
  488. Marek Rouchal E<lt>marek@saftsack.fs.uni-bayreuth.deE<gt>,
  489. heavily borrowing code from Nick Ing-Simmons' PodToHtml.
  490.  
  491. Tim Jenness E<lt>t.jenness@jach.hawaii.eduE<gt> provided
  492. C<pod_where> and C<contains_pod>.
  493.  
  494. =head1 SEE ALSO
  495.  
  496. L<Pod::Parser>, L<Pod::Checker>, L<perldoc>
  497.  
  498. =cut
  499.  
  500. 1;
  501.  
  502.