home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / selectionbox.itk < prev    next >
Text File  |  1999-02-24  |  19KB  |  555 lines
  1. #
  2. # Selectionbox
  3. # ----------------------------------------------------------------------
  4. # Implements a selection box composed of a scrolled list of items and
  5. # a selection entry field.  The user may choose any of the items displayed
  6. # in the scrolled list of alternatives and the selection field will be
  7. # filled with the choice.  The user is also free to enter a new value in
  8. # the selection entry field.  Both the list and entry areas have labels.
  9. # A child site is also provided in which the user may create other widgets
  10. # to be used in conjunction with the selection box.
  11. # 
  12. # ----------------------------------------------------------------------
  13. #  AUTHOR: Mark L. Ulferts               EMAIL: mulferts@spd.dsccc.com
  14. #
  15. #  @(#) $Id: selectionbox.itk,v 1.1 1998/07/27 18:49:50 stanton Exp $
  16. # ----------------------------------------------------------------------
  17. #            Copyright (c) 1995 DSC Technologies Corporation
  18. # ======================================================================
  19. # Permission to use, copy, modify, distribute and license this software 
  20. # and its documentation for any purpose, and without fee or written 
  21. # agreement with DSC, is hereby granted, provided that the above copyright 
  22. # notice appears in all copies and that both the copyright notice and 
  23. # warranty disclaimer below appear in supporting documentation, and that 
  24. # the names of DSC Technologies Corporation or DSC Communications 
  25. # Corporation not be used in advertising or publicity pertaining to the 
  26. # software without specific, written prior permission.
  27. # 
  28. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  29. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  30. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  31. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  32. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  33. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  34. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  35. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  36. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  37. # SOFTWARE.
  38. # ======================================================================
  39.  
  40. #
  41. # Default resources.
  42. #
  43. option add *Selectionbox.borderWidth 2 widgetDefault
  44.  
  45. option add *Selectionbox.itemsLabel Items widgetDefault
  46. option add *Selectionbox.itemsLabelPos nw widgetDefault
  47. option add *Selectionbox.itemsOn yes widgetDefault
  48.  
  49. option add *Selectionbox.selectionLabel Selection widgetDefault
  50. option add *Selectionbox.selectionLabelPos nw widgetDefault
  51. option add *Selectionbox.selectionOn yes widgetDefault
  52.  
  53. option add *Selectionbox.vscrollMode static widgetDefault
  54. option add *Selectionbox.hscrollMode none widgetDefault
  55. option add *Selectionbox.scrollMargin 3 widgetDefault
  56. option add *Selectionbox.margin 7 widgetDefault
  57.  
  58. option add *Selectionbox.width 260 widgetDefault
  59. option add *Selectionbox.height 320 widgetDefault
  60.  
  61. #
  62. # Usual options.
  63. #
  64. itk::usual Selectionbox {
  65.     keep -activebackground -activerelief -background -borderwidth -cursor \
  66.      -elementborderwidth -foreground -highlightcolor -highlightthickness \
  67.      -insertbackground -insertborderwidth -insertofftime -insertontime \
  68.      -insertwidth -jump -labelfont -selectbackground -selectborderwidth \
  69.      -selectforeground -textbackground -textfont -troughcolor
  70. }
  71.  
  72. # ------------------------------------------------------------------
  73. #                            SELECTIONBOX
  74. # ------------------------------------------------------------------
  75. class iwidgets::Selectionbox {
  76.     inherit itk::Widget
  77.  
  78.     constructor {args} {}
  79.     destructor {}
  80.  
  81.     itk_option define -childsitepos childSitePos Position center
  82.     itk_option define -margin margin Margin 7
  83.     itk_option define -itemson itemsOn ItemsOn true
  84.     itk_option define -selectionon selectionOn SelectionOn true
  85.     itk_option define -width width Width 260
  86.     itk_option define -height height Height 320
  87.  
  88.     public method childsite {}
  89.     public method get {}
  90.     public method curselection {}
  91.     public method clear {component}
  92.     public method insert {component index args}
  93.     public method delete {first {last {}}}
  94.     public method size {}
  95.     public method scan {option args}
  96.     public method nearest {y}
  97.     public method index {index}
  98.     public method selection {option args}
  99.     public method selectitem {}
  100.  
  101.     private method _packComponents {{when later}}
  102.  
  103.     private variable _repacking {}     ;# non-null => _packComponents pending
  104. }
  105.  
  106. #
  107. # Provide a lowercased access method for the Selectionbox class.
  108. # 
  109. proc ::iwidgets::selectionbox {pathName args} {
  110.     uplevel ::iwidgets::Selectionbox $pathName $args
  111. }
  112.  
  113. # ------------------------------------------------------------------
  114. #                        CONSTRUCTOR
  115. # ------------------------------------------------------------------
  116. body iwidgets::Selectionbox::constructor {args} {
  117.     component hull configure -borderwidth 0
  118.     
  119.     # 
  120.     # Create an internal frame to contain the components.
  121.     #
  122.     itk_component add frame {
  123.     frame $itk_interior.frame
  124.     } {
  125.     keep -background -cursor
  126.     }
  127.     pack $itk_component(frame) -fill both -expand yes
  128.     pack propagate $itk_component(frame) no
  129.     
  130.     #
  131.     # Create the child site widget.
  132.     #
  133.     itk_component add childsite {
  134.     frame $itk_interior.sbchildsite
  135.     } {
  136.     keep -background -cursor
  137.     }
  138.     set itk_interior $itk_component(childsite)
  139.     
  140.     #
  141.     # Create the items list.
  142.     #
  143.     itk_component add items {
  144.     iwidgets::Scrolledlistbox $itk_component(frame).items -selectmode single \
  145.         -visibleitems 1x1
  146.     } {
  147.     keep -activebackground -activerelief -background -borderwidth \
  148.         -cursor -dblclickcommand -elementborderwidth -exportselection \
  149.         -foreground -highlightcolor \
  150.         -highlightthickness -hscrollmode -items -jump -labelfont \
  151.         -labelmargin -relief -repeatdelay -repeatinterval \
  152.         -sbwidth -scrollmargin -selectbackground -selectborderwidth \
  153.         -selectforeground -textbackground -textfont -troughcolor \
  154.         -vscrollmode
  155.     
  156.     rename -labeltext -itemslabel itemsLabel Text
  157.     rename -labelpos -itemslabelpos itemsLabelPos Position
  158.     rename -selectioncommand -itemscommand itemsCommand Command
  159.     }
  160.     configure -itemscommand [code $this selectitem]
  161.     
  162.     itk_component add margin {
  163.     frame $itk_component(frame).margin
  164.     } {
  165.     keep -background -cursor
  166.     }
  167.     
  168.     #
  169.     # Create the selection entry.
  170.     #
  171.     itk_component add selection {
  172.     iwidgets::Entryfield $itk_component(frame).selection 
  173.     } {
  174.     keep -background -borderwidth -cursor -exportselection \
  175.             -foreground -highlightcolor \
  176.         -highlightthickness -insertbackground -insertborderwidth \
  177.         -insertofftime -insertontime -insertwidth -labelfont \
  178.         -labelmargin -relief -selectbackground -selectborderwidth \
  179.         -selectforeground -textbackground -textfont
  180.     
  181.     rename -labeltext -selectionlabel selectionLabel Text
  182.     rename -labelpos -selectionlabelpos selectionLabelPos Position
  183.     rename -command -selectioncommand selectionCommand Command
  184.     }
  185.     
  186.     #
  187.     # Explicitly handle configs that may have been ignored earlier.
  188.     #
  189.     eval itk_initialize $args
  190.  
  191.     # 
  192.     # When idle, pack the components.
  193.     #
  194.     _packComponents
  195. }   
  196.  
  197. # ------------------------------------------------------------------
  198. #                           DESTRUCTOR
  199. # ------------------------------------------------------------------
  200. body iwidgets::Selectionbox::destructor {} {
  201.     if {$_repacking != ""} {after cancel $_repacking}
  202. }
  203.  
  204. # ------------------------------------------------------------------
  205. #                             OPTIONS
  206. # ------------------------------------------------------------------
  207.  
  208. # ------------------------------------------------------------------
  209. # OPTION: -childsitepos
  210. #
  211. # Specifies the position of the child site in the selection box.
  212. # ------------------------------------------------------------------
  213. configbody iwidgets::Selectionbox::childsitepos {
  214.     _packComponents 
  215. }
  216.  
  217. # ------------------------------------------------------------------
  218. # OPTION: -margin
  219. #
  220. # Specifies distance between the items list and selection entry.
  221. # ------------------------------------------------------------------
  222. configbody iwidgets::Selectionbox::margin {
  223.     set pixels [winfo pixels $itk_component(margin) \
  224.             $itk_option(-margin)]
  225.     
  226.     $itk_component(margin) configure -width $pixels -height $pixels
  227. }
  228.  
  229. # ------------------------------------------------------------------
  230. # OPTION: -itemson
  231. #
  232. # Specifies whether or not to display the items list.
  233. # ------------------------------------------------------------------
  234. configbody iwidgets::Selectionbox::itemson {
  235.     if {$itk_option(-itemson)} {
  236.     _packComponents 
  237.     } else {
  238.     pack forget $itk_component(items)
  239.     }
  240. }
  241.  
  242. # ------------------------------------------------------------------
  243. # OPTION: -selectionon
  244. #
  245. # Specifies whether or not to display the selection entry widget.
  246. # ------------------------------------------------------------------
  247. configbody iwidgets::Selectionbox::selectionon {
  248.     if {$itk_option(-selectionon)} {
  249.     _packComponents
  250.     } else {
  251.     pack forget $itk_component(selection)
  252.     }
  253. }
  254.  
  255. # ------------------------------------------------------------------
  256. # OPTION: -width
  257. #
  258. # Specifies the width of the selection box.  The value may be 
  259. # specified in any of the forms acceptable to Tk_GetPixels.  
  260. # ------------------------------------------------------------------
  261. configbody iwidgets::Selectionbox::width {
  262.     set pixels \
  263.             [winfo pixels $itk_component(frame) $itk_option(-width)]
  264.     
  265.     $itk_component(frame) config -width $pixels
  266. }
  267.  
  268. # ------------------------------------------------------------------
  269. # OPTION: -height
  270. #
  271. # Specifies the height of the selection box.  The value may be 
  272. # specified in any of the forms acceptable to Tk_GetPixels.  
  273. # ------------------------------------------------------------------
  274. configbody iwidgets::Selectionbox::height {
  275.     set pixels \
  276.             [winfo pixels $itk_component(frame) $itk_option(-height)]
  277.     
  278.     $itk_component(frame) config -height $pixels
  279. }
  280.  
  281. # ------------------------------------------------------------------
  282. #                            METHODS
  283. # ------------------------------------------------------------------
  284.  
  285. # ------------------------------------------------------------------
  286. # METHOD: childsite
  287. #
  288. # Returns the path name of the child site widget.
  289. # ------------------------------------------------------------------
  290. body iwidgets::Selectionbox::childsite {} {
  291.     return $itk_component(childsite)
  292. }
  293.  
  294. # ------------------------------------------------------------------
  295. # METHOD: get 
  296. #
  297. # Returns the current selection.
  298. # ------------------------------------------------------------------
  299. body iwidgets::Selectionbox::get {} {
  300.     return [$itk_component(selection) get]
  301. }
  302.  
  303. # ------------------------------------------------------------------
  304. # METHOD: curselection
  305. #
  306. # Returns the current selection index.
  307. # ------------------------------------------------------------------
  308. body iwidgets::Selectionbox::curselection {} {
  309.     return [$itk_component(items) curselection]
  310. }
  311.  
  312. # ------------------------------------------------------------------
  313. # METHOD: clear component
  314. #
  315. # Delete the contents of either the selection entry widget or items
  316. # list.
  317. # ------------------------------------------------------------------
  318. body iwidgets::Selectionbox::clear {component} {
  319.     switch $component {
  320.     selection {
  321.         $itk_component(selection) clear
  322.     }
  323.     
  324.     items {
  325.         delete 0 end
  326.     }
  327.     
  328.     default {
  329.         error "bad clear argument \"$component\": should be\
  330.            selection or items"
  331.     }
  332.     }
  333. }
  334.  
  335. # ------------------------------------------------------------------
  336. # METHOD: insert component index args
  337. #
  338. # Insert element(s) into either the selection or items list widget.
  339. # ------------------------------------------------------------------
  340. body iwidgets::Selectionbox::insert {component index args} {
  341.     switch $component {
  342.     selection {
  343.         eval $itk_component(selection) insert $index $args
  344.     }
  345.     
  346.     items {
  347.         set index [index $index]
  348.         configure -items [eval linsert {$itk_option(-items)} $index $args]
  349.     }
  350.     
  351.     default {
  352.         error "bad insert argument \"$component\": should be\
  353.            selection or items"
  354.     }
  355.     }
  356. }
  357.  
  358. # ------------------------------------------------------------------
  359. # METHOD: delete first ?last?
  360. #
  361. # Delete one or more elements from the items list box.  The default 
  362. # is to delete by indexed range. If an item is to be removed by name, 
  363. # it must be preceeded by the keyword "item". Only index numbers can 
  364. # be used to delete a range of items. 
  365. # ------------------------------------------------------------------
  366. body iwidgets::Selectionbox::delete {first {last {}}} {
  367.     set first [index $first]
  368.     
  369.     if {$last != {}} {
  370.     set last [index $last]
  371.     } else {
  372.     set last $first
  373.     }
  374.     
  375.     if {[llength $itk_option(-items)] > 0} {
  376.     if {$first <= $last} {
  377.         configure -items [lreplace $itk_option(-items) $first $last]
  378.     } else {
  379.         error "first index must not be greater than second"
  380.     }
  381.     }
  382. }
  383.  
  384. # ------------------------------------------------------------------
  385. # METHOD: size 
  386. #
  387. # Returns a decimal string indicating the total number of elements 
  388. # in the items list.
  389. # ------------------------------------------------------------------
  390. body iwidgets::Selectionbox::size {} {
  391.     return [$itk_component(items) size]
  392. }
  393.  
  394. # ------------------------------------------------------------------
  395. # METHOD: scan option args 
  396. #
  397. # Implements scanning on items list.
  398. # ------------------------------------------------------------------
  399. body iwidgets::Selectionbox::scan {option args} {
  400.     eval $itk_component(items) scan $option $args
  401. }
  402.  
  403. # ------------------------------------------------------------------
  404. # METHOD: nearest y
  405. #
  406. # Returns the index to the nearest listbox item given a y coordinate.
  407. # ------------------------------------------------------------------
  408. body iwidgets::Selectionbox::nearest {y} {
  409.     return [$itk_component(items) nearest $y]
  410. }
  411.  
  412. # ------------------------------------------------------------------
  413. # METHOD: index index
  414. #
  415. # Returns the decimal string giving the integer index corresponding 
  416. # to index.
  417. # ------------------------------------------------------------------
  418. body iwidgets::Selectionbox::index {index} {
  419.     return [$itk_component(items) index $index]
  420. }
  421.  
  422. # ------------------------------------------------------------------
  423. # METHOD: selection option args
  424. #
  425. # Adjusts the selection within the items list.
  426. # ------------------------------------------------------------------
  427. body iwidgets::Selectionbox::selection {option args} {
  428.     eval $itk_component(items) selection $option $args
  429.  
  430.     selectitem
  431. }
  432.  
  433. # ------------------------------------------------------------------
  434. # METHOD: selectitem
  435. #
  436. # Replace the selection entry field contents with the currently 
  437. # selected items value.
  438. # ------------------------------------------------------------------
  439. body iwidgets::Selectionbox::selectitem {} {
  440.     $itk_component(selection) clear
  441.     set numSelected [$itk_component(items) selecteditemcount]
  442.  
  443.     if {$numSelected == 1} {
  444.     $itk_component(selection) insert end \
  445.         [$itk_component(items) getcurselection]
  446.     } elseif {$numSelected > 1} {
  447.     $itk_component(selection) insert end \
  448.         [lindex [$itk_component(items) getcurselection] 0]
  449.     }
  450.  
  451.     $itk_component(selection) icursor end
  452. }
  453.  
  454. # ------------------------------------------------------------------
  455. # PRIVATE METHOD: _packComponents ?when?
  456. #
  457. # Pack the selection, items, and child site widgets based on options.
  458. # If "when" is "now", the change is applied immediately.  If it is 
  459. # "later" or it is not specified, then the change is applied later, 
  460. # when the application is idle.
  461. # ------------------------------------------------------------------
  462. body iwidgets::Selectionbox::_packComponents {{when later}} {
  463.     if {$when == "later"} {
  464.     if {$_repacking == ""} {
  465.         set _repacking [after idle [code $this _packComponents now]]
  466.     }
  467.     return
  468.     } elseif {$when != "now"} {
  469.     error "bad option \"$when\": should be now or later"
  470.     }
  471.  
  472.     set _repacking ""
  473.  
  474.     switch $itk_option(-childsitepos) {
  475.     n {
  476.         pack configure $itk_component(childsite) -side top \
  477.             -in $itk_component(frame)
  478.         
  479.         pack configure $itk_component(items) -side top \
  480.             -after $itk_component(childsite) 
  481.         pack configure $itk_component(margin) -side top \
  482.             -after $itk_component(items) 
  483.         pack configure $itk_component(selection) -side top \
  484.             -after $itk_component(margin)
  485.     }
  486.     
  487.     w {
  488.         pack configure $itk_component(frame) -side right
  489.         pack configure $itk_component(childsite) -side left \
  490.             -before $itk_component(frame) \
  491.             -in $itk_component(hull)
  492.         
  493.         pack configure $itk_component(items) -side top
  494.         pack configure $itk_component(margin) -side top \
  495.             -after $itk_component(items)
  496.         pack configure $itk_component(selection) -side top \
  497.             -after $itk_component(margin)
  498.     }
  499.     
  500.     s {
  501.         pack configure $itk_component(items) -side top
  502.         pack configure $itk_component(margin) -side top \
  503.             -after $itk_component(items)
  504.         pack configure $itk_component(selection) -side top \
  505.             -after $itk_component(margin)
  506.         pack configure $itk_component(childsite) -side top \
  507.             -after $itk_component(selection) \
  508.             -in $itk_component(frame)
  509.     }
  510.     
  511.     e {
  512.         pack configure $itk_component(frame) -side left
  513.         pack configure $itk_component(childsite) -side right \
  514.             -before $itk_component(frame) \
  515.             -in $itk_component(hull)
  516.         
  517.         pack configure $itk_component(items) -side top
  518.         pack configure $itk_component(margin) -side top \
  519.             -after $itk_component(items)
  520.         pack configure $itk_component(selection) -side top \
  521.             -after $itk_component(margin)
  522.     }
  523.     
  524.     center {
  525.         pack configure $itk_component(items) -side top
  526.         pack configure $itk_component(childsite) -side top \
  527.             -after $itk_component(items) \
  528.             -in $itk_component(frame)
  529.         pack configure $itk_component(margin) -side top \
  530.             -after $itk_component(childsite)
  531.         pack configure $itk_component(selection) -side top \
  532.             -after $itk_component(margin)
  533.     }
  534.     
  535.     default {
  536.         error "bad childsitepos option \"$itk_option(-childsitepos)\":\
  537.            should be n, e, s, w, or center"
  538.     }
  539.     }
  540.     
  541.     if {$itk_option(-itemson)} {
  542.     pack configure $itk_component(items) -fill both -expand yes
  543.     } else {
  544.     pack forget $itk_component(items)
  545.     }
  546.     
  547.     if {$itk_option(-selectionon)} {
  548.     pack configure $itk_component(selection) -fill x
  549.     } else {
  550.     pack forget $itk_component(selection)
  551.     }
  552.     
  553.     raise $itk_component(childsite)
  554. }
  555.