home *** CD-ROM | disk | FTP | other *** search
/ PC World 2000 December / PCWorld_2000-12_cd.bin / Komunikace / Comanche / comanche.exe / lib / iwidgets2.2.0 / scripts / scrolledtext.itk < prev    next >
Text File  |  1999-02-24  |  26KB  |  777 lines
  1. #
  2. # Scrolledtext
  3. # ----------------------------------------------------------------------
  4. # Implements a scrolled text widget with additional options to manage
  5. # the vertical scrollbar.  This includes options to control the method
  6. # in which the scrollbar is displayed, i.e. statically or  dynamically.
  7. # Options also exist for adding a label to the scrolled text area and
  8. # controlling its position.  Import/export of methods are provided for 
  9. # file I/O.
  10. #
  11. # ----------------------------------------------------------------------
  12. #  AUTHOR: Mark L. Ulferts               EMAIL: mulferts@spd.dsccc.com
  13. #
  14. #  @(#) $Id: scrolledtext.itk,v 1.1 1998/07/27 18:49:49 stanton Exp $
  15. # ----------------------------------------------------------------------
  16. #            Copyright (c) 1995 DSC Technologies Corporation
  17. # ======================================================================
  18. # Permission to use, copy, modify, distribute and license this software 
  19. # and its documentation for any purpose, and without fee or written 
  20. # agreement with DSC, is hereby granted, provided that the above copyright 
  21. # notice appears in all copies and that both the copyright notice and 
  22. # warranty disclaimer below appear in supporting documentation, and that 
  23. # the names of DSC Technologies Corporation or DSC Communications 
  24. # Corporation not be used in advertising or publicity pertaining to the 
  25. # software without specific, written prior permission.
  26. # 
  27. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  28. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  29. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  30. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  31. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  32. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  33. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  34. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  35. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  36. # SOFTWARE.
  37. # ======================================================================
  38.  
  39. #
  40. # Default resources.
  41. #
  42. option add *Scrolledtext.borderWidth 2 widgetDefault
  43. option add *Scrolledtext.relief sunken widgetDefault
  44. option add *Scrolledtext.scrollMargin 3 widgetDefault
  45. option add *Scrolledtext.width 0 widgetDefault
  46. option add *Scrolledtext.height 0 widgetDefault
  47. option add *Scrolledtext.visibleItems 80x24 widgetDefault
  48. option add *Scrolledtext.vscrollMode static widgetDefault
  49. option add *Scrolledtext.hscrollMode static widgetDefault
  50. option add *Scrolledtext.labelPos n widgetDefault
  51.  
  52. #
  53. # Usual options.
  54. #
  55. itk::usual Scrolledtext {
  56.     keep -activebackground -activerelief -background -borderwidth -cursor \
  57.      -elementborderwidth -foreground -highlightcolor -highlightthickness \
  58.      -insertbackground -insertborderwidth -insertofftime -insertontime \
  59.      -insertwidth -jump -labelfont -selectbackground -selectborderwidth \
  60.      -selectforeground -textbackground -textfont -troughcolor 
  61. }
  62.  
  63. # ------------------------------------------------------------------
  64. #                           SCROLLEDTEXT
  65. # ------------------------------------------------------------------
  66. class iwidgets::Scrolledtext {
  67.     inherit iwidgets::Labeledwidget
  68.  
  69.     constructor {args} {}
  70.     destructor {}
  71.  
  72.     itk_option define -scrollmargin scrollMargin Margin 3
  73.     itk_option define -sbwidth sbWidth Width 15
  74.     itk_option define -vscrollmode vscrollMode ScrollMode static
  75.     itk_option define -hscrollmode hscrollMode ScrollMode static
  76.     itk_option define -width width Width 0
  77.     itk_option define -height height Height 0
  78.     itk_option define -visibleitems visibleItems VisibleItems 80x24
  79.  
  80.     public method bbox {index} 
  81.     public method clear {} 
  82.     public method import {filename} 
  83.     public method export {filename} 
  84.     public method compare {index1 op index2} 
  85.     public method debug {args} 
  86.     public method delete {first {last {}}} 
  87.     public method dlineinfo {index} 
  88.     public method get {index1 {index2 {}}} 
  89.     public method index {index} 
  90.     public method insert {args} 
  91.     public method mark {option args} 
  92.     public method scan {option args} 
  93.     public method search {args} 
  94.     public method see {index} 
  95.     public method tag {option args} 
  96.     public method window {option args} 
  97.     public method xview {args} 
  98.     public method yview {args} 
  99.  
  100.     protected method _scrollText {wid first last} 
  101.     protected method _updateFiller {}
  102.     protected method _configureFiller {}
  103.  
  104.     private method _fillerWidth {} 
  105.     private method _vertScrollbarDisplay {mode} 
  106.     private method _horizScrollbarDisplay {mode} 
  107.  
  108.     protected variable _vmode off            ;# Vertical scroll mode
  109.     protected variable _hmode off            ;# Vertical scroll mode
  110.     protected variable _reconfigPlanned ""   ;# non-null, filler update pending
  111.  
  112.     private variable _initialized 0            ;# Initialization flag.
  113. }
  114.  
  115. #
  116. # Provide a lowercased access method for the Scrolledtext class.
  117. # 
  118. proc ::iwidgets::scrolledtext {pathName args} {
  119.     uplevel ::iwidgets::Scrolledtext $pathName $args
  120. }
  121.  
  122. # ------------------------------------------------------------------
  123. #                        CONSTRUCTOR
  124. # ------------------------------------------------------------------
  125. body iwidgets::Scrolledtext::constructor {args} {
  126.     component hull configure -borderwidth 0
  127.  
  128.     #
  129.     # Create some frames to hold both the top and bottom halfs of the 
  130.     # widget.  The top will contain both the list and vertical scroll 
  131.     # bar.  The bottom houses the horizontal scrollbar and some filler.
  132.     #
  133.     itk_component add textframe {
  134.     frame $itk_interior.textframe
  135.     } {
  136.     keep -background -cursor
  137.     }
  138.     pack $itk_component(textframe) -fill both -expand yes
  139.     
  140.     itk_component add bottomframe {
  141.     frame $itk_component(textframe).bot
  142.     } {
  143.     keep -background -cursor
  144.     }
  145.     pack $itk_component(bottomframe) -fill x -side bottom
  146.     
  147.     itk_component add hmargin {
  148.     frame $itk_component(textframe).hm
  149.     } {
  150.     keep -background -cursor
  151.     }
  152.     pack $itk_component(hmargin) -side bottom
  153.     
  154.     itk_component add topframe {
  155.     frame $itk_component(textframe).top
  156.     } {
  157.     keep -background -cursor
  158.     }
  159.     pack $itk_component(topframe) -fill both -expand yes
  160.     
  161.     #
  162.     # Frame around text.
  163.     #
  164.     itk_component add borderFrame {
  165.     frame $itk_component(topframe).borderFrame 
  166.     } {
  167.     keep -background -cursor -borderwidth -relief \
  168.          -highlightthickness -highlightcolor
  169.     rename -highlightbackground -background background Background
  170.     }
  171.  
  172.     # 
  173.     # Create the text area.
  174.     #
  175.     itk_component add text {
  176.     text $itk_component(borderFrame).text \
  177.         -borderwidth 0 -relief flat -highlightthickness 0 \
  178.         -width 1 -height 1 \
  179.             -xscrollcommand \
  180.         [code $this _scrollText $itk_component(bottomframe).horizsb] \
  181.         -yscrollcommand \
  182.         [code $this _scrollText $itk_component(topframe).vertsb]
  183.     
  184.     } {
  185.     keep -cursor -exportselection -foreground \
  186.         -insertbackground -insertborderwidth \
  187.         -insertofftime -insertontime -insertwidth -padx -pady \
  188.         -relief -selectbackground -selectborderwidth \
  189.         -selectforeground -setgrid -spacing1 -spacing2 -spacing3 \
  190.         -state -wrap
  191.  
  192.     rename -font -textfont textFont Font
  193.     rename -background -textbackground textBackground Background
  194.     }
  195.     pack $itk_component(text) -fill both -expand yes 
  196.     
  197.     #
  198.     # Create the vertical margin
  199.     #
  200.     itk_component add vmargin {
  201.     frame $itk_component(topframe).vmargin -width 0
  202.     } {
  203.     keep -background -cursor
  204.     }
  205.     
  206.     # 
  207.     # Create the vertical scroll bar.
  208.     #
  209.     itk_component add vertsb {
  210.     scrollbar $itk_component(topframe).vertsb -orient vertical \
  211.         -command [code $itk_component(text) yview]
  212.     } {
  213.     keep -activebackground -activerelief -background -borderwidth \
  214.         -cursor -elementborderwidth \
  215.         -highlightcolor -jump -highlightthickness -relief \
  216.         -repeatdelay -repeatinterval -troughcolor
  217.     rename -highlightbackground -background background Background
  218.     }
  219.     pack $itk_component(vertsb) -side right -fill y
  220.     pack $itk_component(vmargin) -side right
  221.     pack $itk_component(borderFrame) -fill both -expand yes -side left
  222.     
  223.     #
  224.     # Next the horizontal scrollbar.
  225.     #
  226.     itk_component add horizsb {
  227.     scrollbar $itk_component(bottomframe).horizsb -orient horizontal \
  228.         -command [code $itk_component(text) xview]
  229.     } {
  230.     keep -activebackground -activerelief -background -borderwidth \
  231.         -cursor -elementborderwidth \
  232.         -highlightcolor -jump -highlightthickness -relief \
  233.         -repeatdelay -repeatinterval -troughcolor
  234.     rename -highlightbackground -background background Background
  235.     }
  236.     pack $itk_component(horizsb) -side left -fill x -expand yes
  237.     
  238.     #
  239.     # Create the filler frame and compute its width.
  240.     #
  241.     itk_component add filler {
  242.     frame $itk_component(bottomframe).filler -width [_fillerWidth]
  243.     } {
  244.     keep -background -cursor
  245.     }
  246.     pack $itk_component(filler) -side right 
  247.  
  248.     #
  249.     # Explicitly handle configs that may have been ignored earlier.
  250.     #
  251.     eval itk_initialize $args
  252.     
  253.     bind $itk_component(hmargin) <Configure> [code $this _configureFiller]
  254.     bind $itk_component(vertsb) <Configure> [code $this _configureFiller]
  255.     bind $itk_component(vmargin) <Configure> [code $this _configureFiller]
  256.     bind $itk_component(horizsb) <Configure> [code $this _configureFiller]
  257.  
  258.     set _initialized 1
  259.     configure -scrollmargin $itk_option(-scrollmargin)
  260.     configure -vscrollmode $itk_option(-vscrollmode)
  261. }
  262.  
  263. # ------------------------------------------------------------------
  264. #                           DESTURCTOR
  265. # ------------------------------------------------------------------
  266. body iwidgets::Scrolledtext::destructor {} {
  267.     if {$_reconfigPlanned != ""} {after cancel $_reconfigPlanned}
  268. }
  269.  
  270. # ------------------------------------------------------------------
  271. #                             OPTIONS
  272. # ------------------------------------------------------------------
  273.  
  274. # ------------------------------------------------------------------
  275. # OPTION: -scrollmargin
  276. # Set the distance between the scrollbars and the text area.
  277. # ------------------------------------------------------------------
  278. configbody iwidgets::Scrolledtext::scrollmargin {
  279.     if {$_initialized} {
  280.     set pixels [winfo pixels $itk_component(hmargin) \
  281.         $itk_option(-scrollmargin)]
  282.     
  283.     if {$_hmode == "on"} {
  284.         $itk_component(hmargin) config -width 1 -height $pixels
  285.     }
  286.     
  287.     if {$_vmode == "on"} {
  288.         $itk_component(vmargin) config -width $pixels -height 1
  289.     }
  290.     
  291.     $itk_component(filler) config -width [_fillerWidth] -height 1
  292.     }
  293. }
  294.  
  295. # ------------------------------------------------------------------
  296. # OPTION: -sbwidth
  297. #
  298. # Set the width of the scrollbars.
  299. # ------------------------------------------------------------------
  300. configbody iwidgets::Scrolledtext::sbwidth {
  301.     if {$_initialized} {
  302.     $itk_component(vertsb) configure -width $itk_option(-sbwidth)
  303.     $itk_component(horizsb) configure -width $itk_option(-sbwidth)
  304.     }
  305. }
  306.  
  307. # ------------------------------------------------------------------
  308. # OPTION: -vscrollmode
  309. #
  310. # Enable/disable display and mode of veritcal scrollbar.
  311. # ------------------------------------------------------------------
  312. configbody iwidgets::Scrolledtext::vscrollmode {
  313.     if {$_initialized} {
  314.     switch $itk_option(-vscrollmode) {
  315.         static {
  316.         _vertScrollbarDisplay on
  317.         }
  318.         
  319.         dynamic -
  320.         none {
  321.         _vertScrollbarDisplay off
  322.         }
  323.         
  324.         default {
  325.         error "bad vscrollmode option\
  326.             \"$itk_option(-vscrollmode)\": should\
  327.             be static, dynamic, or none"
  328.         }
  329.     }
  330.     }
  331. }
  332.  
  333. # ------------------------------------------------------------------
  334. # OPTION: -hscrollmode
  335. #
  336. # Enable/disable display and mode of horizontal scrollbars.
  337. # ------------------------------------------------------------------
  338. configbody iwidgets::Scrolledtext::hscrollmode {
  339.     switch $itk_option(-hscrollmode) {
  340.     static {
  341.         _horizScrollbarDisplay on
  342.     }
  343.     
  344.     dynamic -
  345.     none {
  346.         _horizScrollbarDisplay off
  347.     }
  348.     
  349.     default {
  350.         error "bad hscrollmode option\
  351.             \"$itk_option(-hscrollmode)\": should\
  352.             be static, dynamic, or none"
  353.     }
  354.     }
  355. }
  356.  
  357. # ------------------------------------------------------------------
  358. # OPTION: -width
  359. #
  360. # Specifies the width of the scrolled text as an entire unit.
  361. # The value may be specified in any of the forms acceptable to 
  362. # Tk_GetPixels.  Any additional space needed to display the other
  363. # components such as labels, margins, and scrollbars force the text
  364. # to be compressed.  A value of zero along with the same value for 
  365. # the height causes the value given for the visibleitems option 
  366. # to be applied which administers geometry constraints in a different
  367. # manner.
  368. # ------------------------------------------------------------------
  369. configbody iwidgets::Scrolledtext::width {
  370.     if {$itk_option(-width) != 0} {
  371.     pack propagate $itk_component(shell) no
  372.     
  373.     $itk_component(text) configure -width 1
  374.     $itk_component(shell) configure \
  375.         -width [winfo pixels \
  376.         $itk_component(shell) $itk_option(-width)] 
  377.     } else {
  378.     if {$_initialized} {
  379.         configure -visibleitems $itk_option(-visibleitems)
  380.     }
  381.     }
  382. }
  383.  
  384. # ------------------------------------------------------------------
  385. # OPTION: -height
  386. #
  387. # Specifies the height of the scrolled text as an entire unit.
  388. # The value may be specified in any of the forms acceptable to 
  389. # Tk_GetPixels.  Any additional space needed to display the other
  390. # components such as labels, margins, and scrollbars force the text
  391. # to be compressed.  A value of zero along with the same value for 
  392. # the width causes the value given for the visibleitems option 
  393. # to be applied which administers geometry constraints in a different
  394. # manner.
  395. # ------------------------------------------------------------------
  396. configbody iwidgets::Scrolledtext::height {
  397.     if {$itk_option(-height) != 0} {
  398.     pack propagate $itk_component(shell) no
  399.     
  400.     $itk_component(text) configure -height 1
  401.     $itk_component(shell) configure \
  402.         -height [winfo pixels \
  403.         $itk_component(shell) $itk_option(-height)] 
  404.     } else {
  405.     if {$_initialized} {
  406.         configure -visibleitems $itk_option(-visibleitems)
  407.     }
  408.     }
  409. }
  410.  
  411. # ------------------------------------------------------------------
  412. # OPTION: -visibleitems
  413. #
  414. # Specified the widthxheight in characters and lines for the text.
  415. # This option is only administered if the width and height options
  416. # are both set to zero, otherwise they take precedence.  With the
  417. # visibleitems option engaged, geometry constraints are maintained
  418. # only on the text.  The size of the other components such as 
  419. # labels, margins, and scroll bars, are additive and independent, 
  420. # effecting the overall size of the scrolled text.  In contrast,
  421. # should the width and height options have non zero values, they
  422. # are applied to the scrolled text as a whole.  The text is 
  423. # compressed or expanded to maintain the geometry constraints.
  424. # ------------------------------------------------------------------
  425. configbody iwidgets::Scrolledtext::visibleitems {
  426.     if {[regexp {^[0-9]+x[0-9]+$} $itk_option(-visibleitems)]} {
  427.     if {($itk_option(-width) == 0) && \
  428.         ($itk_option(-height) == 0)} {
  429.         set chars [lindex [split $itk_option(-visibleitems) x] 0]
  430.         set lines [lindex [split $itk_option(-visibleitems) x] 1]
  431.         
  432.         pack propagate $itk_component(shell) yes
  433.         
  434.         $itk_component(text) configure \
  435.             -width $chars -height $lines
  436.     }
  437.     
  438.     } else {
  439.     error "bad visibleitems option\
  440.         \"$itk_option(-visibleitems)\": should be\
  441.         widthxheight"
  442.     }
  443. }
  444.  
  445. # ------------------------------------------------------------------
  446. #                            METHODS
  447. # ------------------------------------------------------------------
  448.  
  449. # ------------------------------------------------------------------
  450. # METHOD: bbox index
  451. #
  452. # Returns four element list describing the bounding box for the list
  453. # item at index
  454. # ------------------------------------------------------------------
  455. body iwidgets::Scrolledtext::bbox {index} {
  456.     return [$itk_component(text) bbox $index]
  457. }
  458.  
  459. # ------------------------------------------------------------------
  460. # METHOD clear 
  461. #
  462. # Clear the text area.
  463. # ------------------------------------------------------------------
  464. body iwidgets::Scrolledtext::clear {} {
  465.     $itk_component(text) delete 1.0 end
  466. }
  467.  
  468. # ------------------------------------------------------------------
  469. # METHOD import filename
  470. #
  471. # Load text from an existing file (import filename)
  472. # ------------------------------------------------------------------
  473. body iwidgets::Scrolledtext::import {filename} {
  474.     set f [open $filename r]
  475.     insert end [read $f]
  476.     close $f
  477. }
  478.  
  479. # ------------------------------------------------------------------
  480. # METHOD export filename
  481. #
  482. # write text to a file (export filename)
  483. # ------------------------------------------------------------------
  484. body iwidgets::Scrolledtext::export {filename} {
  485.     set f [open $filename w]
  486.     
  487.     set txt [$itk_component(text) get 1.0 end]
  488.     puts $f $txt
  489.     
  490.     flush $f
  491.     close $f
  492. }
  493.  
  494. # ------------------------------------------------------------------
  495. # METHOD compare index1 op index2
  496. #
  497. # Compare indices according to relational operator.
  498. # ------------------------------------------------------------------
  499. body iwidgets::Scrolledtext::compare {index1 op index2} {
  500.     return [$itk_component(text) compare $index1 $op $index2]
  501. }
  502.  
  503. # ------------------------------------------------------------------
  504. # METHOD debug ?boolean?
  505. #
  506. # Activates consistency checks in B-tree code associated with text
  507. # widgets.
  508. # ------------------------------------------------------------------
  509. body iwidgets::Scrolledtext::debug {args} {
  510.     eval $itk_component(text) debug $args
  511. }
  512.  
  513. # ------------------------------------------------------------------
  514. # METHOD delete first ?last?
  515. #
  516. # Delete a range of characters from the text.
  517. # ------------------------------------------------------------------
  518. body iwidgets::Scrolledtext::delete {first {last {}}} {
  519.     $itk_component(text) delete $first $last
  520. }
  521.  
  522. # ------------------------------------------------------------------
  523. # METHOD dlineinfo index
  524. #
  525. # Returns a five element list describing the area occupied by the
  526. # display line containing index.
  527. # ------------------------------------------------------------------
  528. body iwidgets::Scrolledtext::dlineinfo {index} {
  529.     return [$itk_component(text) dlineinfo $index]
  530. }
  531.  
  532. # ------------------------------------------------------------------
  533. # METHOD get index1 ?index2?
  534. #
  535. # Return text from start index to end index.
  536. # ------------------------------------------------------------------
  537. body iwidgets::Scrolledtext::get {index1 {index2 {}}} {
  538.     return [$itk_component(text) get $index1 $index2]
  539. }
  540.  
  541. # ------------------------------------------------------------------
  542. # METHOD index index
  543. #
  544. # Return position corresponding to index.
  545. # ------------------------------------------------------------------
  546. body iwidgets::Scrolledtext::index {index} {
  547.     return [$itk_component(text) index $index]
  548. }
  549.  
  550. # ------------------------------------------------------------------
  551. # METHOD insert index chars ?tagList?
  552. #
  553. # Insert text at index.
  554. # ------------------------------------------------------------------
  555. body iwidgets::Scrolledtext::insert {args} {
  556.     eval $itk_component(text) insert $args
  557. }
  558.  
  559. # ------------------------------------------------------------------
  560. # METHOD mark option ?arg arg ...?
  561. #
  562. # Manipulate marks dependent on options.
  563. # ------------------------------------------------------------------
  564. body iwidgets::Scrolledtext::mark {option args} {
  565.     return [eval $itk_component(text) mark $option $args]
  566. }
  567.  
  568. # ------------------------------------------------------------------
  569. # METHOD scan option args
  570. #
  571. # Implements scanning on texts.
  572. # ------------------------------------------------------------------
  573. body iwidgets::Scrolledtext::scan {option args} {
  574.     eval $itk_component(text) scan $option $args
  575. }
  576.  
  577. # ------------------------------------------------------------------
  578. # METHOD search ?switches? pattern index ?varName?
  579. #
  580. # Searches the text for characters matching a pattern.
  581. # ------------------------------------------------------------------
  582. body iwidgets::Scrolledtext::search {args} {
  583.     return [eval $itk_component(text) search $args]
  584. }
  585.  
  586. # ------------------------------------------------------------------
  587. # METHOD see index
  588. #
  589. # Adjusts the view in the window so the character at index is 
  590. # visible.
  591. # ------------------------------------------------------------------
  592. body iwidgets::Scrolledtext::see {index} {
  593.     $itk_component(text) see $index
  594. }
  595.  
  596. # ------------------------------------------------------------------
  597. # METHOD tag option ?arg arg ...?
  598. #
  599. # Manipulate tags dependent on options.
  600. # ------------------------------------------------------------------
  601. body iwidgets::Scrolledtext::tag {option args} {
  602.     return [eval $itk_component(text) tag $option $args]
  603. }
  604.  
  605. # ------------------------------------------------------------------
  606. # METHOD window option ?arg arg ...?
  607. #
  608. # Manipulate embedded windows.
  609. # ------------------------------------------------------------------
  610. body iwidgets::Scrolledtext::window {option args} {
  611.     return [eval $itk_component(text) window $option $args]
  612. }
  613.  
  614. # ------------------------------------------------------------------
  615. # METHOD xview
  616. #
  617. # Changes x view in widget's window.
  618. # ------------------------------------------------------------------
  619. body iwidgets::Scrolledtext::xview {args} {
  620.     return [eval $itk_component(text) xview $args]
  621. }
  622.  
  623. # ------------------------------------------------------------------
  624. # METHOD yview
  625. #
  626. # Changes y view in widget's window.
  627. # ------------------------------------------------------------------
  628. body iwidgets::Scrolledtext::yview {args} {
  629.     return [eval $itk_component(text) yview $args]
  630. }
  631.  
  632. # ------------------------------------------------------------------
  633. # PRIVATE METHOD: _fillerWidth 
  634. #
  635. # Compute the width of the filler frame based on the vertical 
  636. # scrollbar width plus the margin.
  637. # ------------------------------------------------------------------
  638. body iwidgets::Scrolledtext::_fillerWidth {} {
  639.     if {$_vmode == "on"} {
  640.     return [expr [winfo reqwidth $itk_component(vertsb)] + \
  641.         [winfo reqwidth $itk_component(vmargin)]]
  642.     } else {
  643.     return 1
  644.     }
  645. }
  646.  
  647. # ------------------------------------------------------------------
  648. # PROTECTED METHOD: _configureFiller 
  649. #
  650. # Set up to do an update of the filler if one is not all ready 
  651. # planned.
  652. # ------------------------------------------------------------------
  653. body iwidgets::Scrolledtext::_configureFiller {} {
  654.     if {$_reconfigPlanned == ""} {
  655.     set _reconfigPlanned [after idle [code $this _updateFiller]]
  656.     }
  657. }
  658.  
  659. # ------------------------------------------------------------------
  660. # PROTECTED METHOD: _updateFiller 
  661. #
  662. # Update the width of the filler following a configure event on 
  663. # a scrollbar or margin.
  664. # ------------------------------------------------------------------
  665. body iwidgets::Scrolledtext::_updateFiller {} {
  666.     $itk_component(filler) config -width [_fillerWidth] -height 1
  667.     set _reconfigPlanned ""
  668. }
  669.  
  670. # ------------------------------------------------------------------
  671. # PRIVATE METHOD: _vertScrollbarDisplay mode
  672. #
  673. # Displays the vertical scrollbar based on the input mode.
  674. # ------------------------------------------------------------------
  675. body iwidgets::Scrolledtext::_vertScrollbarDisplay {mode} {
  676.     switch $mode  {
  677.     on {
  678.         set _vmode on
  679.         
  680.         $itk_component(vmargin) config -height 1 -width \
  681.             [winfo pixels $itk_component(vmargin) \
  682.             $itk_option(-scrollmargin)]
  683.         
  684.         pack forget $itk_component(borderFrame)
  685.         pack forget $itk_component(vmargin)
  686.         pack $itk_component(vertsb) -side right -fill y
  687.         pack $itk_component(vmargin) -side right
  688.         pack $itk_component(borderFrame) -fill both -expand yes -side left 
  689.     }
  690.     
  691.     off {
  692.         set _vmode off
  693.         
  694.         pack forget $itk_component(vertsb)
  695.         
  696.         $itk_component(vmargin) config -width 1 -height 1
  697.         $itk_component(filler) config -width 1 -height 1
  698.     }
  699.     
  700.     default {
  701.         error "invalid argument \"$mode\": should be on or off"
  702.     }
  703.     }
  704. }
  705.  
  706. # ------------------------------------------------------------------
  707. # PRIVATE METHOD: _horizScrollbarDisplay mode
  708. #
  709. # Displays the horizontal scrollbar based on the input mode.
  710. # ------------------------------------------------------------------
  711. body iwidgets::Scrolledtext::_horizScrollbarDisplay {mode} {
  712.     switch $mode  {
  713.     on {
  714.         set _hmode on
  715.         
  716.         $itk_component(hmargin) config -width 1 -height \
  717.             [winfo pixels $itk_component(hmargin) \
  718.             $itk_option(-scrollmargin)]
  719.         
  720.         pack $itk_component(horizsb) -side left -fill x -expand yes
  721.     }
  722.     
  723.     off {
  724.         set _hmode off
  725.         
  726.         pack forget $itk_component(horizsb)
  727.         
  728.         $itk_component(hmargin) config -width 1 -height 1
  729.         $itk_component(filler) config -width 1 -height 1
  730.     }
  731.     
  732.     default {
  733.         error "invalid argument \"$mode\": should be on or off"
  734.     }
  735.     }
  736. }
  737.  
  738. # ------------------------------------------------------------------
  739. # PRIVATE METHOD: _scrollText wid first last
  740. #
  741. # Performs scrolling and display of scrollbars based on the first and
  742. # last text views as well as the current -vscrollmode and -hscrollmode
  743. # settings.
  744. # ------------------------------------------------------------------
  745. body iwidgets::Scrolledtext::_scrollText {wid first last} {
  746.     $wid set $first $last
  747.     
  748.     if {$wid == $itk_component(vertsb)} {
  749.     if {$itk_option(-vscrollmode) == "dynamic"} {
  750.         if {($first == 0) && ($last == 1)} {
  751.         if {$_vmode != "off"} {
  752.             _vertScrollbarDisplay off
  753.         }
  754.         
  755.         } else {
  756.         if {$_vmode != "on"} {
  757.             _vertScrollbarDisplay on
  758.         }
  759.         }
  760.     }
  761.     
  762.     } elseif {$wid == $itk_component(horizsb)} {
  763.     if {$itk_option(-hscrollmode) == "dynamic"} {
  764.         if {($first == 0) && ($last == 1)} {
  765.         if {$_hmode != "off"} {
  766.             _horizScrollbarDisplay off
  767.         }
  768.         
  769.         } else {
  770.         if {$_hmode != "on"} {
  771.             _horizScrollbarDisplay on
  772.         }
  773.         }
  774.     }
  775.     }
  776. }
  777.