home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 1995 November / PCWK1195.iso / inne / dos / fraktale / frasr192.exe / NEWTON.ASM < prev    next >
Encoding:
Assembly Source File  |  1994-04-09  |  5.8 KB  |  349 lines
  1. ; NEWTON.ASM : Procedure NewtonFractal() from FRACTINT.
  2. ; Lee Daniel Crocker, 4/23/89.
  3. ;
  4. ; Tabs: 8
  5. ;
  6. ; Modifications:
  7. ;   BT = Bert Tyler
  8. ;   TW = Timothy Wegner
  9. ;   RD = Robert Day
  10. ;   MP = Mark Peterson
  11. ;
  12. ; Note: newton.asm was totally rewritten by Lee Crocker for FRACTINT 10.0
  13. ;    for integration with the newly structured fractal engine in calcmand.c
  14. ;    and fractals.c. The current routine consists of the inner orbit
  15. ;    calculation, with the supporting code removed. Early versions of
  16. ;    newton.asm contained a complete newton fractal function.
  17. ;
  18. ; Assembled by Microsoft Macro Assembler 5.1, for use with Microsoft C 5.1.
  19. ;
  20.  
  21. ; Required for compatibility if Turbo ASM (BT 5/20/89)
  22.  
  23. IFDEF ??version
  24. MASM51
  25. QUIRKS
  26. ENDIF
  27.  
  28. .model    medium, c
  29.  
  30. public    NewtonFractal2
  31. public    invertz2
  32.  
  33. .data
  34.     extrn    coloriter:dword, maxcolor:word, degree:word, basin:word
  35.     extrn    row:word, col:word
  36.  
  37.     extrn    dx0:dword, dy0:dword
  38.     extrn    dx1:dword, dy1:dword
  39.  
  40.     extrn    old:qword, new:qword, d1overd:qword, roverd:qword
  41.     extrn    threshold:qword, floatmin:qword, floatmax:qword
  42.     extrn    f_radius:qword, f_xcenter:qword, f_ycenter:qword
  43.     extrn    roots:word, tempsqrx:qword
  44.  
  45. statw    dw    ?
  46.  
  47. .code
  48.  
  49. public    NewtonFractal2
  50. NewtonFractal2 proc
  51.  
  52. ;
  53. ; cpower(&old, degree-1, &tmp)
  54. ;
  55.     mov    ax, degree
  56.     dec    ax
  57.  
  58.     fld    old + 8
  59.     fld    old
  60. ;
  61. ; cpower() is expanded inline here.
  62. ;
  63.     shr    ax, 1
  64.     jnc    load1            ; if (exp & 1)
  65.  
  66.     fld    st(1)
  67.     fld    st(1)
  68.     jmp    short looptop        ; tmp = old
  69. load1:
  70.     fldz
  71.     fld1                ; else tmp = [1,0]
  72. looptop:
  73.     cmp    ax, 0
  74.     je    loopexit        ; while (exp)
  75.  
  76.     fld    st(2)            ; RD 5/7/89: Calculate xt^2 - yt^2
  77.     fadd    st, st(4)        ; by using (xt+yt)*(xt-yt), which
  78.     fld    st(3)            ; trades one multiplication for an
  79.     fsub    st, st(5)        ; addition.  This trick saves a
  80.     fmul                ; whopping 1.2% of time.
  81.  
  82.     fld    st(4)
  83.     fmul    st, st(4)
  84.     fadd    st, st            ; yt = 2 * xt * yt
  85.  
  86.     fstp    st(5)            ; tmp.y = yt
  87.     fstp    st(3)            ; tmp.x = xt
  88.  
  89.     shr    ax, 1
  90.     jnc    looptop         ; if (exp & 1)
  91.  
  92.     fld    st(2)
  93.     fmul    st, st(1)
  94.     fld    st(4)
  95.     fmul    st, st(3)
  96.     fsub                ; tmp.x = xt * tmp.x - yt * tmp.y
  97.  
  98.     fld    st(3)
  99.     fmul    st, st(3)
  100.     fld    st(5)
  101.     fmul    st, st(3)
  102.     fadd                ; tmp.y = xt * tmp.y + yt * tmp.x
  103.     fstp    st(3)
  104.     fstp    st(1)
  105.  
  106.     jmp    short looptop
  107. loopexit:
  108.     fstp    st(2)
  109.     fstp    st(2)
  110. ;
  111. ; End of complex_power() routine.  Result is in ST, ST(1)
  112. ;
  113. ;
  114. ; complex_mult(tmp, old, &new);
  115. ;
  116.     fld    old + 8
  117.     fld    old
  118.  
  119.     fld    st(3)        ; tmp.y
  120.     fmul    st, st(1)   ; old.x
  121.     fld    st(3)        ; tmp.x
  122.     fmul    st, st(3)   ; old.y
  123.     fadd
  124.     fld    st(3)        ; tmp.x
  125.     fmul    st, st(2)   ; old.x
  126.     fld    st(5)        ; tmp.y
  127.     fmul    st, st(4)   ; old.y
  128.     fsub
  129. ;
  130. ; if (DIST1(new) < THRESHOLD) {
  131. ;
  132.     fld1
  133.     fsubr    st, st(1)
  134.     fmul    st, st
  135.     fld    st(2)        ; new.y
  136.     fmul    st, st
  137.     fadd
  138.     fcomp    threshold
  139.     fstsw    statw
  140.     mov    ax, statw
  141.     sahf
  142.     jnc    notless
  143. ;
  144. ; if (fractype == NEWTBASIN) {
  145. ;
  146.     mov    ax, basin
  147.     cmp    ax, 0
  148.     je    notbasin
  149.  
  150.     mov    bx, roots
  151.     mov    dx, -1            ; tempcolor = -1
  152.     sub    cx, cx
  153. dloop:
  154.     fld    qword ptr [bx]    ; roots[i].x
  155.     fsub    st, st(3)    ; old.x
  156.     fmul    st, st
  157.     fld    qword ptr [bx+8]; roots[i].y
  158.     fsub    st, st(5)    ; old.y
  159.     fmul    st, st
  160.     fadd
  161.     fcomp    threshold
  162.     fstsw    statw
  163.     mov    ax, statw
  164.     sahf                ; if (distance(roots[i],old) < threshold)...
  165.     jnc    nl2
  166.  
  167. ; TW commented out next few lines and add dx,ax to eliminate newtbasin
  168. ; color shades per Phil Wilson's request 12/03/89
  169.  
  170. ; TW put it back in in response to another use as an option! 7/7/90
  171.     mov    dx, cx
  172.     cmp    basin,2            ; basin==2 is flag for stripes
  173.     jne    nostripes
  174.     mov    ax, word ptr coloriter
  175.     and    ax, 1
  176.     shl    ax, 1
  177.     shl    ax, 1
  178.     shl    ax, 1
  179.  
  180.     and    dx, 7
  181.     add    dx, ax
  182. nostripes:
  183.     inc    dx            ; tempcolor = 1+(i&7)+((color&1)<<3)
  184.     jmp    short nfb        ; break
  185. nl2:
  186.     add    bx, 16
  187.     inc    cx
  188.     cmp    cx, degree
  189.     jl    dloop
  190. nfb:
  191.     mov    ax, dx
  192.     cmp    dx, -1
  193.     jne    notm1
  194.     mov    ax, maxcolor        ; if (tmpcolor == -1)...
  195. notm1:
  196.     mov    word ptr coloriter, ax
  197.     mov    word ptr coloriter+2, 0
  198. notbasin:
  199.     mov    ax, 1
  200.     jmp    nlexit
  201. notless:
  202.     fld    d1overd
  203.     fmul    st(2), st        ; new.y *= d1overd
  204.     fmul
  205.     fld    roverd
  206.     fadd                ; new.x = d1overd * new.x + roverd
  207.  
  208.     fld    st(5)        ; tmp.y
  209.     fmul    st, st
  210.     fld    st(5)        ; tmp.x
  211.     fmul    st, st
  212.     fadd
  213.     fcom    floatmin
  214.     fstsw    statw
  215.     mov    ax, statw
  216.     sahf                ; if (mod(tmp) < FLT_MIN) {
  217.     jnc    cont
  218.     mov    ax, 1
  219.     fstp    st
  220.     jmp    nlexit
  221. cont:
  222.     fld1
  223.     fdivr
  224.     fst    st(4)        ; old.y
  225.     fstp    st(3)        ; old.x
  226.  
  227.     fld    st(4)        ; tmp.x
  228.     fmul    st, st(1)   ; new.x
  229.     fld    st(6)        ; tmp.y
  230.     fmul    st, st(3)   ; new.y
  231.     fadd
  232.     fmulp    st(3), st   ; old.x
  233.  
  234.     fld    st(4)        ; tmp.x
  235.     fmul    st, st(2)   ; new.y
  236.     fld    st(6)        ; tmp.y
  237.     fmul    st, st(2)   ; new.x
  238.     fsub
  239.     fmulp    st(4), st   ; old.y    ; old = new / tmp
  240.  
  241. ; MP Orbit Bug Fix 11/1/90
  242. ;    fstp    new
  243. ;    fstp    new + 8
  244. ;    fstp    old
  245. ;    fstp    old + 8
  246.     fstp    st
  247.     fstp    st
  248.     fst    new
  249.     fstp    old
  250.     fst    new + 8
  251.     fstp    old + 8
  252.  
  253.     mov    ax, 0
  254.     jmp    nlx2
  255.  
  256. nlexit:
  257.  
  258. ;MP Orbit Bug Fix 11/1/90
  259. ;    fstp    new
  260. ;    fstp    new + 8
  261.     fstp    st
  262.     fstp    st
  263.     fstp    new
  264.     fstp    new + 8
  265.  
  266. nlx2:
  267.     fstp    st
  268.     fstp    st
  269.  
  270.     ret
  271. NewtonFractal2 endp
  272. ;
  273. ;
  274. ;
  275. public    invertz2
  276. invertz2 proc    uses si, zval:word    ; TW 11/03/89 changed zval to near
  277.  
  278.     fld    f_xcenter
  279.     fld    f_ycenter
  280.  
  281.     mov    bx, col
  282.     shl    bx, 1
  283.     shl    bx, 1
  284.     shl    bx, 1
  285.  
  286.     mov    cx, row
  287.     shl    cx, 1
  288.     shl    cx, 1
  289.     shl    cx, 1
  290.  
  291.     mov    ax, ds
  292.     lds    si, dx0
  293.     add    si, bx
  294.     fld    qword ptr [si]
  295.     mov    ds, ax
  296.     lds    si, dx1
  297.     add    si, cx
  298.     fld    qword ptr [si]
  299.     fadd
  300.     fsub    st, st(2)
  301.  
  302.     mov    ds, ax
  303.     lds    si, dy0
  304.     add    si, cx
  305.     fld    qword ptr [si]
  306.     mov    ds, ax
  307.     lds    si, dy1
  308.     add    si, bx
  309.     fld    qword ptr [si]
  310.     fadd
  311.     fsub    st, st(2)
  312.  
  313.     mov    ds, ax
  314.     fld    st(1)
  315.     fmul    st, st
  316.     fld    st(1)
  317.     fmul    st, st
  318.     fadd
  319.  
  320.     fcom    floatmin
  321.     fstsw    statw
  322.     mov    ax, statw
  323.     sahf
  324.     jnc    inl1
  325.  
  326.     fstp    st
  327.     fld    floatmax
  328.     jmp    icom
  329. inl1:
  330.     fld    f_radius
  331.     fdivr
  332. icom:
  333.     fst    tempsqrx
  334.  
  335.     fmul    st(2), st
  336.     fmul
  337.     faddp    st(2), st
  338.     faddp    st(2), st
  339.  
  340. ;    lds    si, zval    ; TW 11/03/89 zval is now a near pointer
  341.     mov    si, zval    ; TW
  342.     fstp    qword ptr [si+8]
  343.     fstp    qword ptr [si]
  344.  
  345.     ret
  346. invertz2 endp
  347.  
  348. END
  349.