home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / basic / library / gwbasic / friendly / info.bas < prev    next >
Encoding:
BASIC Source File  |  1994-05-25  |  26.9 KB  |  295 lines
  1. 10 WIDTH 80:SCREEN 0,0,0:COLOR 7,0:GOSUB 13100:IF RIGHT$(DATE$,2)<"81" THEN GOSUB 5000
  2. 30 MK1$="$$#####,.##":MK2$="$$#######,.##":MK6$="######":MK3$="$$######,.##":DIM C$(6),AC$(12,2),EX$(12),ZQ(12):GOSUB 905:ON ERROR GOTO 32:OPEN"FW.BAT" FOR INPUT AS #1:CLOSE#1:HK$="YES":GOSUB 900:GOTO 120
  3. 32 CLOSE:RESUME 120
  4. 120 GOSUB 13100:ZQ=" CHECK REGISTER ":GOSUB 2230:COLOR 4:LOCATE 5,24:PRINT"Routines Available In This Program"
  5. 130 LOCATE 7,26:COLOR 0,7:PRINT" A ":LOCATE 9,26:PRINT" B ":LOCATE 11,26:PRINT" C ":LOCATE 13,26:PRINT" D ":LOCATE 15,26:PRINT" E ":LOCATE 17,26:PRINT" F ":LOCATE 19,26:PRINT"F10":LOCATE 7,32:COLOR 2,0:PRINT"General Information"
  6. 131 LOCATE 9,32:PRINT"Create New Account":LOCATE 11,32:PRINT"Enter Transactions":LOCATE 13,32:PRINT"Reconcile Account":LOCATE 15,32:PRINT"Listing of Transactions":LOCATE 17,32:PRINT"System Maintenance":LOCATE 19,32:PRINT"Return To FriendlyWare Menu"
  7. 160 LOCATE ,,0:GOSUB 13000:IF FKEY=10 THEN 230 ELSE IF Z<"A" OR Z>"F" THEN 160 ELSE ON ASC(Z)-64 GOTO 300,2610,190,200,1249,3529
  8. 190 GOSUB 4340:CHAIN"NEWE.003",720,ALL
  9. 200 GOSUB 4340:CHAIN"NEWE.003",2520,ALL
  10. 230 'ERROR TRAP FOR MENU#3 RETURN
  11. 240 CLEAR:ON ERROR GOTO 241:RUN"menu3"
  12. 241 CLEAR:ON ERROR GOTO 242:RUN"menu2"
  13. 242 CLEAR:ON ERROR GOTO 243:RUN"menu1"
  14. 243 RUN
  15. 300 GOSUB 13100:ZQ=" GENERAL INFORMATION ":GOSUB 2230
  16. 305 PRINT:PRINT
  17. 310 PRINT TAB(10)"Check register will allow up to"CX" outstanding transactions
  18. 311 PRINT TAB(10)"per account. Checks must be reconciled when this limit is
  19. 312 PRINT TAB(10)"reached. You may have up to 12 accounts on file at one time.
  20. 313 PRINT
  21. 314 PRINT TAB(10)"You may begin a new year from an old account by using the
  22. 315 PRINT TAB(10)"Begin New Year option in System Maintenance. This will carry
  23. 316 PRINT TAB(10)"over your current account balance from last year. If later you
  24. 317 PRINT TAB(10)"make a change to your old account, you can use Begin New Year
  25. 318 PRINT TAB(10)"to carry over the new balance without loss of data.
  26. 319 PRINT
  27. 320 PRINT TAB(10)"You may select different data drives and specify use on hard
  28. 321 PRINT TAB(10)"or fixed disk systems.
  29. 322 PRINT
  30. 323 PRINT TAB(10)"Check Register saves data files in ASCII format allowing you
  31. 324 PRINT TAB(10)"to edit these files with any text editor. (DOS Edlin program)
  32. 325 PRINT:COLOR 15
  33. 326 PRINT TAB(10)"This line should be highlighted. Please adjust your monitor if
  34. 327 PRINT TAB(10)"needed."
  35. 350 LOCATE 25,27:COLOR 14,0:PRINT"Strike Any Key To Continue";:COLOR 7:GOSUB 13000:GOTO 120
  36. 530 COLOR 7:CLS:LOCATE 2,7:PRINT"CHECK   DATE          NAME or SOURCE"SPC(11)" DEPOSIT   CHECK AMT.";:LOCATE 3,3:PRINT"╒══════╤════════╤"STRING$(30,205)"╤═════════════╤═════════════╕";
  37. 540 FOR I=4 TO 20:LOCATE I,3:PRINT"│":LOCATE I,10:PRINT"│":LOCATE I,19:PRINT"│":LOCATE I,50:PRINT"│":LOCATE I,64:PRINT"│":LOCATE I,78:PRINT"│":NEXT
  38. 550 PRINT"  ╘══════╧════════╧"STRING$(30,205)"╧═════════════╧═════════════╛";:LOCATE 1,60::RETURN
  39. 569 LOCATE 23,1:PRINT SPC(79);
  40. 570 LOCATE 24,1:PRINT SPC(79);
  41. 571 LOCATE 25,1:PRINT SPC(79);:RETURN
  42. 580 GOSUB 570:LOCATE 25,7:COLOR 14:PRINT"F1";:COLOR 7:PRINT" - To Start Over";:LOCATE 25,28:COLOR 14:PRINT"F2";:IF Z2<>" - For Next Page" THEN COLOR 19,0 ELSE COLOR 7:
  43. 581 PRINT Z2;:LOCATE 25,56:COLOR 14:PRINT"F10";:COLOR 7:PRINT" - Return To Menu";:LOCATE 1,1:RETURN
  44. 600 GOSUB 2230:LOCATE 5,31:COLOR 4:PRINT"Accounts Available:":COLOR 6:FOR I=1 TO 12:LOCATE (I+7),33:PRINT CHR$(I+64)". "AC$(I,1);:IF AC$(I,1)<>"" THEN PRINT" 19";
  45. 601 PRINT AC$(I,2):NEXT:COLOR 2:LOCATE 21:ZS="Enter Line Of Account Number You Wish To Use:":GOSUB 3582
  46. 620 COLOR 0,7:LOCATE 6,28:PRINT" Current data drive is "XT$:COLOR 7,0:LOCATE 22:ZS="If You Don't See The Account You Want, It Is Not On File.":GOSUB 3582:LOCATE 23:ZS="Return To MENU <F10> And Choose Another Option.":GOSUB 3582
  47. 630 LOCATE 25:COLOR 0,7:ZS=" Strike <F10> To Return To Menu ":GOSUB 3582:COLOR 7,0:RETURN
  48. 640 COLOR 7,0:LOCATE X,4:PRINT SPC(6):LOCATE X,11:PRINT SPC(8):LOCATE X,20:PRINT SPC(25):LOCATE X,51:PRINT SPC(13):LOCATE X,65:PRINT SPC(13)
  49. 650 LOCATE X,4:PRINT C$(2):LOCATE X,11:PRINT C$(4):LOCATE X,20:PRINT C$(5):IF C$(1)="D" OR C$(1)="Z" THEN LOCATE X,51 ELSE LOCATE X,65
  50. 660 A#=VAL(C$(3)):PRINT USING MK2$;A#:RETURN
  51. 670 FOR X=4 TO 20
  52. 680 IF EOF(1) THEN 840 ELSE INPUT#1,C$(1),C$(2),C$(3),C$(4),C$(5),C$(6)
  53. 690 IF LEN(C$(1))=0 OR VAL(LEFT$(C$(4),2))<MOS OR VAL(LEFT$(C$(4),2))>MOE THEN 680
  54. 691 IF TY THEN 760 ELSE IF C$(1)="C" AND OC THEN 781 ELSE IF C$(1)="D" AND OD THEN 782 ELSE IF C$(1)="X" AND CC THEN 781 ELSE IF C$(1)="Z" AND CD THEN 782 ELSE IF C$(1)="B" AND SC THEN GOSUB 640:BCM#=BCM#+VAL(C$(3)):GOTO 790
  55. 750 IF VT THEN IF C$(1)="V" THEN GOSUB 640:GOTO 790 ELSE 680
  56. 760 IF A=6 THEN IF C$(A)=A$ THEN IF CT THEN ELSE IF DT THEN 782 ELSE 680 ELSE 680
  57. 761 IF CT AND INSTR(1,C$(A),A$)>0 THEN ELSE IF DT AND INSTR(1,C$(A),A$)>0 THEN 782 ELSE 680
  58. 781 GOSUB 640:OCM#=OCM#+VAL(C$(3)):GOTO 790
  59. 782 GOSUB 640:ODM#=ODM#+VAL(C$(3))
  60. 790 NEXT X:ENDF=0:RETURN
  61. 800 OCM#=0:ODM#=0:BCM#=0:RETURN
  62. 810 COLOR 2:LOCATE 22,7:PRINT"Total Bank Charges ";:PRINT USING MK3$;BCM#
  63. 820 LOCATE 23,7:PRINT"Total Deposits     ";:PRINT USING MK3$;ODM#;
  64. 830 LOCATE 23,50:PRINT"Total Checks  ";:PRINT USING MK3$;OCM#;:COLOR 3:RETURN
  65. 840 FOR XX=X TO 20:LOCATE XX,4:PRINT SPC(6):LOCATE XX,11:PRINT SPC(8):LOCATE XX,20:PRINT SPC(25):LOCATE XX,51:PRINT SPC(13):LOCATE XX,65:PRINT SPC(13):NEXT XX:ENDF=1:RETURN
  66. 900 FL$="check.003":GOSUB 4410:CLOSE:OPEN"O",#1,"check.003":FOR I=1 TO 12:FOR J=1 TO 2:WRITE#1,AC$(I,J):NEXT J,I:WRITE#1,XT$,HK$:CLOSE#1:RETURN
  67. 905 CLOSE:OPEN "I",1,"check.003":FOR I=1 TO 12:FOR J=1 TO 2:INPUT#1,AC$(I,J):NEXT J,I:INPUT#1,XT$,HK$:CLOSE:RETURN
  68. 910 GOSUB 1232:WRITE#1,ACTNO$,ACTNM$,ACTBAL#,LSTDT$,CCAMT#,CCK,OCAMT#,OCK,CDAMT#,CDP,ODAMT#,ODP,BCAMT#,BC,LASTCHECK$:FOR I=1 TO 12:WRITE#1,EX$(I):NEXT:CLOSE:RETURN
  69. 915 GOSUB 1230:INPUT#1,ACTNO$,ACTNM$,ACTBAL#,LSTDT$,CCAMT#,CCK,OCAMT#,OCK,CDAMT#,CDP,ODAMT#,ODP,BCAMT#,BC,LASTCHECK$:FOR I=1 TO 12:INPUT#1,EX$(I):NEXT:CLOSE:RETURN
  70. 925 FL$=ACTNO$+".O"+CYR$:GOSUB 1235:CLOSE:FL$=ACTNO$+".C"+CYR$:GOSUB 1235:CLOSE:DK$=" Check Register Diskette ":GOSUB 2260:RETURN
  71. 930 CYR$=AC$(B,2):FL$=AC$(B,1)+".A"+CYR$:DK$=FL$+" Data Diskette ":GOSUB 2260:GOSUB 915:RETURN
  72. 1225 FL$=ACTNO$+".O"+CYR$:GOSUB 1230:RETURN
  73. 1226 FL$=ACTNO$+".C"+CYR$:GOSUB 1230:RETURN
  74. 1230 GOSUB 4390:CLOSE:OPEN"I",#1,XT$+FL$:RETURN
  75. 1232 IF HK$="" THEN GOSUB 4360
  76. 1233 CLOSE:OPEN"O",#1,XT$+FL$:RETURN
  77. 1235 IF HK$="" THEN GOSUB 4360
  78. 1236 CLOSE:OPEN XT$+FL$ FOR APPEND AS #1:RETURN
  79. 1249 GOSUB 13100:ERASE C$:DIM C$(6)
  80. 1250 ZQ=" LISTINGS ":GOSUB 600:B$="L":GOSUB 3460:IF FKEY=10 THEN 3070 ELSE IF AC$(B,1)="" THEN 1250
  81. 1260 GOSUB 930
  82. 1270 GOSUB 2230:LOCATE 7,10:COLOR 0,7:PRINT" A ":LOCATE 9,10:PRINT" B ":LOCATE 11,10:PRINT" C ":LOCATE 13,10:PRINT" D ":LOCATE 15,10:PRINT" E ":LOCATE 7,50:PRINT" F ":LOCATE 9,50:PRINT" G ":LOCATE 11,50:PRINT" H "
  83. 1271 LOCATE 13,50:PRINT" I ":LOCATE 15,50:PRINT" J ":LOCATE 17,30:PRINT"F10":COLOR 2,0
  84. 1273 LOCATE 7,15:PRINT"Outstanding Checks":LOCATE 9,15:PRINT"Cancelled Checks":LOCATE 11,15:PRINT"Voided Transactions":LOCATE 13,15:PRINT"Checks by Expense Code":LOCATE 15,15:PRINT"Checks by Recipient"
  85. 1275 LOCATE 7,55:PRINT"Bank Charges":LOCATE 9,55:PRINT"Outstanding Deposits":LOCATE 11,55:PRINT"Cancelled Deposits":LOCATE 13,55:PRINT"Outstanding Transactions":LOCATE 15,55:PRINT"Cancelled Transactions":LOCATE 17,35:PRINT"Return To Check Register Menu"
  86. 1320 B$="J":GOSUB 3460:IF FKEY=10 THEN 3070 ELSE FC=B
  87. 1322 ZQ(1)="January":ZQ(2)="Febuary":ZQ(3)="March":ZQ(4)="April":ZQ(5)="May":ZQ(6)="June":ZQ(7)="July":ZQ(8)="August":ZQ(9)="September":ZQ(10)="October":ZQ(11)="November":ZQ(12)="December"
  88. 1330 CLS:FOR I=1 TO 12:LOCATE I+3,33:PRINT CHR$(ASC("A")+(I-1))") "ZQ(I):NEXT I:LOCATE 17,33:PRINT"M) Entire year
  89. 1333 LOCATE 23,22:PRINT"Begin Listings From Which Month <A-M>";:B$="M":GOSUB 3460:IF FKEY=10 THEN 1270 ELSE IF B=13 THEN MOS=1:MOE=12:GOTO 1340 ELSE MOS=B
  90. 1334 COLOR 0,7:LOCATE 23,22:PRINT" From "ZQ(MOS)" To Which Month <"CHR$(ASC("A")+(MOS-1))"-M> ";:COLOR 7,0:PRINT"      ":B$="M":GOSUB 3460:IF FKEY=10 THEN 1270 ELSE IF B=13 THEN MOE=12 ELSE IF B<MOS THEN 1334 ELSE MOE=B
  91. 1340 Z2=" - For Next Page"
  92. 1349 OC=0:OD=0:CC=0:CD=0:SC=0:VT=0:TY=0:DT=0:CT=0:A=0
  93. 1350 ON FC GOTO 1360,1400,1440,1470,1560,1710,1740,1770,1870,1900
  94. 1360 ZP=" OUTSTANDING CHECKS ":GOSUB 1932:GOSUB 1225:OC=1
  95. 1380 GOSUB 1931:ON FKEY GOTO 1360,1380
  96. 1400 ZP=" CANCELLED CHECKS ":GOSUB 1932:GOSUB 1226:CC=1
  97. 1420 GOSUB 1931:ON FKEY GOTO 1400,1420
  98. 1440 ZP=" VOIDED TRANSACTIONS ":GOSUB 1932:GOSUB 1226:VT=1
  99. 1460 GOSUB 1931:ON FKEY GOTO 1440,1460
  100. 1470 CLS:LOCATE 1,35:PRINT"Expense Codes":FOR I=1 TO 12:LOCATE I+2,30:PRINT I". "EX$(I):NEXT
  101. 1480 LOCATE 20,27:COLOR 14:PRINT"Enter Expense Code: ";:FLEN=2:X=20:Y=47:GOSUB 3260:IF FKEY=10 THEN 1270 ELSE IF VAL(B$)<1 OR VAL(B$)>12 THEN 1480 ELSE A$=STR$(VAL(B$))
  102. 1490 ZP=" OUTSTANDING CHECKS by EXPENSE CODE ":GOSUB 1932:GOSUB 1225:OC=1:CC=1:TY=1:CT=1:A=6
  103. 1510 GOSUB 670:GOSUB 810:IF ENDF AND RIGHT$(FL$,3)="O"+CYR$ THEN Z2=" - For Cancelled Checks" ELSE Z2=" - For Next Page"
  104. 1530 GOSUB 580:GOSUB 2320:IF FKEY=10 THEN 1270 ELSE IF FKEY=1 THEN 1470 ELSE IF ENDF THEN IF RIGHT$(FL$,3)="O"+CYR$ THEN GOSUB 1226 ELSE 1270 ELSE 1510
  105. 1550 LOCATE 1,20:PRINT SPC(41):ZP=" CANCELLED CHECKS by EXPENSE CODE ":GOSUB 2235:GOTO 1510
  106. 1560 GOSUB 530:ZP=" OUTSTANDING CHECKS by RECIPIENT ":GOSUB 2235:GOSUB 800:GOSUB 1225:OC=1:CC=1:TY=1:CT=1:A=5
  107. 1590 GOSUB 570:LOCATE 25,21:COLOR 14:FLEN=25:PRINT"Enter Name: ";:COLOR 7:X=25:Y=33:GOSUB 3260:IF FKEY=10 THEN 1270 ELSE IF LEN(B$)<1 THEN 1590 ELSE A$=B$:GOSUB 580
  108. 1600 COLOR 15,0:GOSUB 670:GOSUB 810:IF ENDF AND RIGHT$(FL$,3)="O"+CYR$ THEN Z2=" - For Cancelled Checks" ELSE Z2=" - For Next Page":COLOR 3,0
  109. 1610 GOSUB 580:GOSUB 2320:IF FKEY=10 THEN 1270 ELSE IF FKEY=1 THEN 1560 ELSE IF ENDF THEN IF RIGHT$(FL$,3)="O"+CYR$ THEN GOSUB 1226 ELSE 1270 ELSE 1600
  110. 1630 LOCATE 1,20:PRINT SPC(40):ZP=" CANCELLED CHECKS by RECIPIENT ":GOSUB 2235:GOTO 1600
  111. 1710 ZP=" BANK CHARGES ":GOSUB 1932:GOSUB 1226:SC=1
  112. 1730 GOSUB 1931:ON FKEY GOTO 1710,1730
  113. 1740 ZP=" OUTSTANDING DEPOSITS ":GOSUB 1932:GOSUB 1225:OD=1:VT=1
  114. 1760 GOSUB 1931:ON FKEY GOTO 1740,1760
  115. 1770 ZP=" CANCELLED DEPOSITS ":GOSUB 1932:GOSUB 1226:CD=1
  116. 1790 GOSUB 1931:ON FKEY GOTO 1770,1790
  117. 1870 ZP=" OUTSTANDING TRANSACTIONS ":GOSUB 1932:GOSUB 1225:OC=1:OD=1
  118. 1890 GOSUB 1931:ON FKEY GOTO 1870,1890
  119. 1900 ZP=" CANCELLED TRANSACTIONS ":GOSUB 1932:GOSUB 1226:CC=1:CD=1:SC=1
  120. 1930 GOSUB 1931:ON FKEY GOTO 1900,1930
  121. 1931 GOSUB 670:GOSUB 810:GOSUB 2320:IF FKEY=10 OR ENDF THEN RETURN 1270 ELSE RETURN
  122. 1932 GOSUB 530:GOSUB 580:GOSUB 800:GOSUB 2235:RETURN
  123. 2190 CLS:LOCATE 9:ZS="You May Have Only 12 Accounts On File At One Time.":GOSUB 3582:LOCATE 10:ZS="To Use More Accounts You Must Delete Old Accounts first.":GOSUB 3582:GOTO 350
  124. 2230 COLOR 7,0:CLS:COLOR 13:Y=((80-LEN(ZQ))/2)-2:LOCATE 1,Y:PRINT"┌"STRING$(LEN(ZQ)+2,196)"┐":LOCATE 3,Y:PRINT"└"STRING$(LEN(ZQ)+2,196)"┘":LOCATE 2,Y:PRINT"│ ";:COLOR 0,7:PRINT ZQ;:COLOR 13,0:PRINT" │":COLOR 7:RETURN
  125. 2235 Y=((80-LEN(ZP))/2):LOCATE 1,Y:COLOR 0,7:PRINT ZP;:COLOR 7,0:RETURN
  126. 2260 IF HK$<>"" OR DK$=" Check Register Diskette " THEN RETURN
  127. 2262 CLS:LOCATE 9,2:COLOR 3,0:PRINT"╔"STRING$(76,205)"╗":FOR I=10 TO 14:LOCATE I,2:PRINT"║":LOCATE I,79:PRINT"║":NEXT:LOCATE 15,2:PRINT"╚"STRING$(76,205)"╝"
  128. 2270 LOCATE 11:ZS="Insert "+DK$
  129. 2271 IF FDY=0 AND DK$<>" Check Register Diskette " THEN ZS=ZS+" Into Drive "+XT$ ELSE ZS=ZS+" Into Your Primary Disk Drive "
  130. 2272 COLOR 0,7:GOSUB 3582
  131. 2273 COLOR 14,0:LOCATE 13:ZS="Strike Any Key When Ready":GOSUB 3582:COLOR 3:GOTO 13000
  132. 2300 LOCATE 24,1:PRINT SPC(79);:COLOR 15:LOCATE 24:ZS="Entrys Will Not Be Saved If You Escape Now":GOSUB 3582
  133. 2310 LOCATE 25,1:PRINT SPC(79);:LOCATE 25:ZS="Is That OK? <Y/N>":GOSUB 3582:COLOR 7:GOTO 2340
  134. 2320 GOSUB 13000:IF FKEY=10 OR FKEY=1 OR FKEY=2 THEN RETURN ELSE 2320
  135. 2340 YES=0:GOSUB 13000:IF Z="Y" THEN YES=1:RETURN ELSE IF Z="N" THEN RETURN ELSE 2340
  136. 2400 ZH="":B$="":LOCATE X,Y,1:PRINT USING MK1$;0;
  137. 2440 GOSUB 13000:IF FKEY OR Z=CHR$(13) THEN 2540 ELSE IF Z=CHR$(8) THEN IF LEN(ZH)<1 THEN 2440 ELSE 2500
  138. 2460 IF LEN(ZH)>6 OR Z<"0" OR Z>"9" THEN 2440 ELSE ZH=ZH+Z
  139. 2490 LOCATE X,Y,1:PRINT USING MK1$;VAL(ZH)/100;:GOTO 2440
  140. 2500 LOCATE X,Y:PRINT SPC(7);:ZH=LEFT$(ZH,LEN(ZH)-1):GOTO 2490
  141. 2540 ZA=SPACE$(7):RSET ZA=ZH:ZA=STR$(VAL(ZA)/100):B$=ZA
  142. 2550 LOCATE ,,0:RETURN
  143. 2610 GOSUB 13100:FOR I=1 TO 12:IF AC$(I,1)="" THEN DK$=" A New Data Diskette ":GOSUB 2260 ELSE NEXT:GOTO 2190
  144. 2620 ZQ=" SET UP NEW CHECKING ACCOUNT ":GOSUB 2230
  145. 2625 LOCATE 6,1:PRINT TAB(10)"Each account that you use must have a unique account number.":PRINT TAB(10)"To start a new year from an old account you should use the":PRINT TAB(10)"BEGIN NEW YEAR ACCOUNT option in System Maintenance."
  146. 2630 PRINT TAB(10)"You may stop at any time by depressing the ";:COLOR 14:PRINT"<F10>";:COLOR 7:PRINT" key"
  147. 2640 LOCATE 23,20:PRINT"Strike ";:COLOR 14:PRINT"ENTER";:COLOR 7,0:PRINT" After Each Data Line Is Completed";
  148. 2650 LOCATE 13,10:COLOR 7:PRINT"Enter Account Number:               _______":X=13:Y=46:FLEN=7:GOSUB 3260:IF FKEY=10 THEN 3070 ELSE IF B$=" " OR B$="" THEN 2650 ELSE D$=SPACE$(8)
  149. 2661 D$=SPACE$(8):LSET D$=B$:FOR I=1 TO 7:E$=MID$(D$,I,1):IF (E$>="0" AND E$<="9") OR (E$>="A" AND E$<="Z") OR E$=" " THEN NEXT:GOTO 2670
  150. 2662 GOSUB 570:LOCATE 25,1:PRINT"The Name You Choose Must Contain Numbers and Letters ONLY. Please Try Again.";:GOTO 2650
  151. 2670 E$=SPACE$(8):LSET E$=B$:FOR I=1 TO 12:IF AC$(I,1)<>E$ THEN NEXT:GOTO 2690
  152. 2680 GOSUB 569:LOCATE 25,9:COLOR 31,0:PRINT"The Number You Chose Is Already In Use. Please Select Another";:COLOR 7:GOTO 2650
  153. 2690 ACTNO$=D$:GOSUB 569:LOCATE 23,23:PRINT"Strike ";:COLOR 14:PRINT"ENTER";:COLOR 7:PRINT" After Each Line Is Completed";
  154. 2700 LOCATE 15,10,1:COLOR 7:PRINT"Enter Account Name:     ___________________":X=15:Y=34:FLEN=20:GOSUB 3260:IF FKEY=10 THEN 3070 ELSE IF B$="" OR B$=" " THEN 2700 ELSE ACTNM$=B$
  155. 2730 LOCATE 17,10,1:COLOR 7:PRINT"Enter Beginning Balance:":X=17:Y=42:FLEN=7:GOSUB 2400:IF FKEY=10 THEN 3070 ELSE IF B$="" OR B$=" " THEN 2730 ELSE ACTBAL#=VAL(B$)
  156. 2760 LOCATE 19,10,1:COLOR 7:PRINT"Enter Current Year Of Account:         19__":X=19:Y=51:FLEN=2:GOSUB 3260:IF FKEY=10 THEN 3070 ELSE IF VAL(B$)<80 OR VAL(B$)>99 THEN 2760 ELSE CYR$=B$
  157. 2800 GOSUB 2230:LOCATE 10,20:COLOR 7,0:PRINT"Account Number:":LOCATE 10,46:COLOR 10:PRINT USING"\     \";ACTNO$:COLOR 7:LOCATE 12,20:PRINT"Account Name:":LOCATE 12,33:COLOR 10:B$=SPACE$(20):RSET B$=ACTNM$:PRINT B$
  158. 2810 LOCATE 14,20:COLOR 7:PRINT"Opening Balance:":LOCATE 14,42:COLOR 10:PRINT USING MK1$;ACTBAL#:COLOR 7:LOCATE 16,20:PRINT"Current Year:":LOCATE 16,49:COLOR 10:PRINT"19"CYR$;:COLOR 7
  159. 2820 GOSUB 569:LOCATE 19,3:COLOR 7:PRINT"Select Option:":LOCATE 21,15:COLOR 14:PRINT" F1 ";:COLOR 7:PRINT"-If You Wish To Accept Data As Entered";
  160. 2830 LOCATE 22,15:COLOR 14:PRINT" F2 ";:COLOR 7:PRINT"-If You Prefer To Reenter Above Data":LOCATE 23,15:COLOR 14:PRINT" F10 ";:COLOR 7:PRINT"-To Cancel This Routine And Return To CHECK REGISTER MENU";
  161. 2840 GOSUB 2320:IF FKEY=10 THEN GOSUB 2300:IF YES THEN 3070 ELSE GOSUB 570:GOTO 2840 ELSE IF FKEY=2 THEN 2620
  162. 2859 FOR I=1 TO 12:EX$(I)=STRING$(20,95):NEXT
  163. 2870 GOSUB 13400:GOSUB 2320:IF FKEY=2 THEN 2870 ELSE IF FKEY=10 THEN GOSUB 2300:IF YES THEN 3070 ELSE GOSUB 570:GOTO 2870
  164. 3000 FL$=ACTNO$+".A"+CYR$:LSTDT$=DATE$:CCAMT#=0:CCK=0:OCAMT#=0:OCK=0:CDAMT#=0:CDP=0:ODAMT#=0:ODP=0:BCAMT#=0:BC=0
  165. 3010 GOSUB 910:GOSUB 925:CLOSE:FOR I=1 TO 12:IF LEN(AC$(I,1))<1 THEN AC$(I,1)=ACTNO$:AC$(I,2)=CYR$ ELSE NEXT
  166. 3050 GOSUB 900:CLS:LOCATE 19,12:COLOR 0,7:PRINT" Your New Checking Account Files Are Ready For Data Entry ":GOTO 350
  167. 3070 CLOSE:DK$=" Check Register Diskette ":GOSUB 2260:GOTO 120
  168. 3220 BEEP:LOCATE 25,10:COLOR 14:PRINT" If You Escape Now, Any Changes Made Will Be Lost. Is That OK? <Y/N>";:COLOR 7:GOSUB 2340:GOTO 571
  169. 3260 B$="":LOCATE X,Y,1
  170. 3270 GOSUB 13000:IF Z=CHR$(34) THEN ELSE IF Z=CHR$(13) THEN 2550 ELSE IF Z=CHR$(8) THEN IF LEN(B$)>0 THEN PRINT CHR$(29)" "CHR$(29);:B$=LEFT$(B$,LEN(B$)-1) ELSE ELSE IF Z<" " THEN ELSE IF LEN(B$)>=FLEN THEN ELSE B$=B$+Z:PRINT Z;
  171. 3271 IF FKEY THEN RETURN ELSE 3270
  172. 3460 LOCATE ,,0:GOSUB 13000:IF FKEY=10 THEN RETURN ELSE IF Z<"A" OR Z>B$ THEN 3460 ELSE B=ASC(Z)-64:RETURN
  173. 3529 GOSUB 13100:ERASE C$:DIM C$(6)
  174. 3530 ZQ=" SYSTEM MAINTENANCE ":GOSUB 2230:LOCATE 5,10:COLOR 4:PRINT"Transaction options:";
  175. 3540 LOCATE 7,26:COLOR 0,7:PRINT" A ":LOCATE 9,26:PRINT" B ":LOCATE 11,26:PRINT" C ":LOCATE 13,26:PRINT" D ":LOCATE 15,26:PRINT" E ":LOCATE 17,26:PRINT" F ":LOCATE 19,26:PRINT"F10"
  176. 3541 LOCATE 7,31:COLOR 2,0:PRINT"Begin New Year":LOCATE 9,31:PRINT"Delete Old Account":LOCATE 11,31:PRINT"Expenditure Code Table":LOCATE 13,31:PRINT"Account Master File Data"
  177. 3543 LOCATE 15,31:PRINT"Rebalance Account":LOCATE 17,31:PRINT"Select Data Drive":LOCATE 19,31:PRINT"Return To Check Register Menu"
  178. 3544 COLOR 14:LOCATE 21,28:PRINT"Current Data Drive Is "XT$:LOCATE 22,23:PRINT"Program Is Configured For ";:IF HK$="YES" THEN PRINT"Hard Disk" ELSE PRINT"Floppy Disk"
  179. 3570 COLOR 3,0:B$="F":GOSUB 3460:IF FKEY=10 THEN 3070
  180. 3580 ON B GOTO 3590,13300,3740,3900,4010,13200
  181. 3582 LOCATE ,(80-LEN(ZS))/2:PRINT ZS;:RETURN
  182. 3590 FOR XA=1 TO 12:IF LEN(AC$(XA,1))<1 THEN ELSE NEXT:GOTO 3735
  183. 3591 ZQ=" BEGIN NEW YEAR ":GOSUB 600
  184. 3592 B$="L":GOSUB 3460:IF FKEY=10 THEN 3530 ELSE IF LEN(AC$(B,1))<1 THEN 3592
  185. 3593 GOSUB 930:GOSUB 2230
  186. 3594 CYR$=RIGHT$(STR$(VAL(AC$(B,2))+1),2):FOR A=1 TO 12:IF AC$(A,2)=CYR$ AND AC$(A,1)=AC$(B,1) THEN ELSE NEXT:AC$(XA,1)=AC$(B,1):AC$(XA,2)=CYR$
  187. 3595 ACTBAL#=ACTBAL#-CCAMT#-BCAMT#+CDAMT#+ODAMT#-OCAMT#:LSTDT$=DATE$:CCAMT#=0:CCK=0:OCAMT#=0:OCK=0:CDAMT#=0:CDP=0:ODAMT#=0:ODP=0:BCAMT#=0:BC=0:ACTNO$=AC$(B,1):FL$=ACTNO$+".A"+CYR$:DK$=FL$+" Data Diskette "
  188. 3597 IF HK$="" THEN LOCATE 12:ZS="Do you wish to place new year account on a different diskette? <Y/N>":GOSUB 3582:GOSUB 2340:IF YES THEN GOSUB 2260
  189. 3600 GOSUB 910:GOSUB 925:GOSUB 900:CLS:LOCATE 19,12:COLOR 0,7:PRINT" Your New Year Account Files Are Ready For Data Entry ":GOTO 3990
  190. 3735 CLS:LOCATE 7:ZS="You have 12 accounts on file already. You must delete an":GOSUB 3582
  191. 3736 LOCATE 8:ZS="old account to make room for new year account.":GOSUB 3582:GOTO 3990
  192. 3740 ZQ=" EXPENDITURE CODES TABLE ":GOSUB 600
  193. 3750 B$="L":GOSUB 3460:IF FKEY=10 THEN 3530 ELSE IF LEN(AC$(B,1))<1 THEN 3750
  194. 3760 GOSUB 930
  195. 3770 GOSUB 13400
  196. 3870 GOSUB 2320:IF FKEY=10 THEN GOSUB 3220:IF YES THEN 3530 ELSE 3870
  197. 3880 ON FKEY GOTO 3890,3770
  198. 3890 GOSUB 910:GOTO 3530
  199. 3900 ZQ=" ACCOUNT MASTER FILE DATA ":GOSUB 600
  200. 3910 B$="L":GOSUB 3460:IF FKEY=10 THEN 3530 ELSE IF LEN(AC$(B,1))<1 THEN 3910
  201. 3920 GOSUB 930:GOSUB 2230
  202. 3940 LOCATE 4,13:PRINT ACTNM$:LOCATE 4,56:PRINT ACTNO$" 19"CYR$:LOCATE 5,13:PRINT"Last Update Date: ":LOCATE 7,13:PRINT"Number Of Cancelled Checks: ":LOCATE 8,13:PRINT"Amount On Cancelled Checks: ":LOCATE 10,13:PRINT"Number Of Outstanding Checks: "
  203. 3950 LOCATE 11,13:PRINT"Amount On Outstanding Checks: ":LOCATE 13,13:PRINT"Number Of Cancelled Deposits: ":LOCATE 14,13:PRINT"Amount On Cancelled Deposits: ":LOCATE 16,13:PRINT"Number Of Outstanding Deposits: ";
  204. 3960 LOCATE 17,13:PRINT"Amount On Outstanding Deposits: ":LOCATE 19,13:PRINT"Number Of Bank Charges: ":LOCATE 20,13:PRINT"Amount On Bank Charges: "
  205. 3961 LOCATE 22,13:PRINT"Opening Account Balance: ":LOCATE 23,13:PRINT"Balance Before Outstanding Transactions:":LOCATE 24,13:PRINT"Current Account Balance:";
  206. 3970 LOCATE 5,58:PRINT LSTDT$:LOCATE 7,62:PRINT USING MK6$;CCK:LOCATE 8,57:PRINT USING MK2$;CCAMT#:LOCATE 10,62:PRINT USING MK6$;OCK:LOCATE 11,57:PRINT USING MK2$;OCAMT#:LOCATE 13,62:PRINT USING MK6$;CDP:LOCATE 14,57:PRINT USING MK2$;CDAMT#;
  207. 3980 LOCATE 16,62:PRINT USING MK6$;ODP:LOCATE 17,57:PRINT USING MK2$;ODAMT#:LOCATE 19,62:PRINT USING MK6$;BC:LOCATE 20,57:PRINT USING MK2$;BCAMT#:LOCATE 23,57:PRINT USING MK2$;ACTBAL#-CCAMT#-BCAMT#+CDAMT#
  208. 3981 LOCATE 22,57:PRINT USING MK2$;ACTBAL#:LOCATE 23,57:PRINT USING MK2$;ACTBAL#-CCAMT#-BCAMT#+CDAMT#:LOCATE 24,57:PRINT USING MK2$;ACTBAL#-CCAMT#-BCAMT#+CDAMT#+ODAMT#-OCAMT#;
  209. 3990 LOCATE 25,27:COLOR 0,7:PRINT" Strike Any Key To Continue ";:COLOR 7,0:GOSUB 13000:GOTO 3530
  210. 4010 ZQ=" REBALANCE ACCOUNT ":GOSUB 600
  211. 4020 B$="L":GOSUB 3460:IF FKEY=10 THEN 3530 ELSE IF LEN(AC$(B,1))<1 THEN 4020
  212. 4040 GOSUB 930:GOSUB 2230:LOCATE 12,20:PRINT"This routine I have to do all by myself.":LOCATE 14,11:PRINT"If you have alot of checks on file, this may take a while.";:GOSUB 13500
  213. 4180 ZQ=" "+ACTNM$+" ":GOSUB 2230:LOCATE 1,66:PRINT ACTNO$" 19"CYR$:LOCATE 4,24:PRINT"ACCOUNT BALANCE AS OF: "LSTDT$;
  214. 4190 LOCATE 7,6:PRINT"Initial Opening Balance       "STRING$(27,249);:LOCATE 7,68:PRINT USING MK2$;ACTBAL#;:LOCATE 9,11:PRINT"All Cancelled Deposits To Date":LOCATE 9,45:PRINT USING MK1$;CDAMT#:LOCATE 11,11:PRINT"All Cancelled Checks To Date";
  215. 4200 LOCATE 11,56:PRINT USING MK2$;CCAMT#:LOCATE 13,11:PRINT"All Bank Charges To Date":LOCATE 13,56:PRINT USING MK2$;BCAMT#;
  216. 4210 LOCATE 15,6:PRINT"Balance Before Outstanding Transactions  "STRING$(16,249):LOCATE 15,68:PRINT USING MK2$;ACTBAL#+CDAMT#-CCAMT#-BCAMT#:LOCATE 17,11:PRINT"All Outstanding Deposits":LOCATE 17,46:PRINT USING MK2$;ODAMT#;
  217. 4220 LOCATE 19,11:PRINT"All Outstanding Checks":LOCATE 19,56:PRINT USING MK2$;OCAMT#:LOCATE 21,6:PRINT"Current Account Balance  "STRING$(32,249):LOCATE 21,68:PRINT USING MK2$;(ACTBAL#+ODAMT#-OCAMT#-CCAMT#+CDAMT#-BCAMT#);:GOTO 3990
  218. 4340 OPEN"I",#3,"LOGO.COM":CLOSE#3:RETURN
  219. 4360 OKFLG=0:OPEN"I",#3,XT$+"LOGO.COM":CLOSE#3
  220. 4361 IF OKFLG THEN RETURN ELSE ERROR 201
  221. 4390 OPEN"I",#3,XT$+FL$:CLOSE#3:RETURN
  222. 4410 OPEN"check.003" FOR INPUT AS #3:CLOSE:RETURN
  223. 4420 CLOSE#3:OKFLG=1:ER1=0
  224. 4422 IF ERR=201 THEN ER1=3:GOTO 4550
  225. 4430 IF ERL=4410 THEN ER1=1:GOTO 4550
  226. 4440 IF ERL=4340 THEN ER1=1:GOTO 4550
  227. 4480 IF ERL=4390 THEN ER1=2:GOTO 4550
  228. 4481 IF ERL=4360 THEN RESUME 4361
  229. 4520 IF ERR=71 THEN ER1=4:GOTO 4550
  230. 4530 IF ERR=53 THEN ER1=1:GOTO 4550
  231. 4531 IF ERR=72 THEN ER1=6:GOTO 4550
  232. 4532 IF ERR=70 THEN ER1=7:GOTO 4550
  233. 4540 ON ERROR GOTO 0:END
  234. 4550 COLOR 30:ON ER1 GOTO 4580,4590,4600,4610,4620,4621,4622
  235. 4560 RESUME 4570
  236. 4570 RETURN
  237. 4580 ZE="Please Insert CHECK REGISTER DISKETTE":GOTO 4630
  238. 4590 ZE="Please Insert DATA DISKETTE For "+FL$:GOTO 4630
  239. 4600 ZE="You May Not Use This Diskette For Data Storage":GOTO 4630
  240. 4610 ZE="Disk Is Not Ready. Insert Diskette And Close Door":GOTO 4630
  241. 4620 ZE="Please Insert"+DK$:GOTO 4630
  242. 4621 ZE="Disk Media Error. Data May Be Unusable":GOTO 4630
  243. 4622 ZE="Disk Is Write Protected. Be Sure You Have Correct Disk":GOTO 4630
  244. 4630 LOCATE 24,(80-LEN(ZE))/2:PRINT ZE;:LOCATE 25,20:COLOR 14:PRINT"Strike Any Key When Ready  <ESC> To Abort";:COLOR 3
  245. 4650 GOSUB 13000:IF Z=CHR$(27) THEN 4680 ELSE GOSUB 570
  246. 4670 IF ER1=3 THEN RESUME 4360 ELSE RESUME
  247. 4680 GOSUB 570
  248. 4700 LOCATE 24,12:PRINT"If You Escape, Any Changes Or Entries Will Not Be Saved!";:BEEP:LOCATE 25,32:PRINT"Is That OK?<Y/N>";
  249. 4720 GOSUB 13000:IF Z="Y" THEN RUN 30 ELSE IF Z<>"N" THEN 4720 ELSE GOSUB 570:GOTO 4550
  250. 4999 BEEP:Z="":Z1="":LOCATE XLIN,XPOS:PRINT SPC(8);:LOCATE XLIN,XPOS:PRINT Z2;:RETURN
  251. 5000 Z2="":CLS:LOCATE 5,20,1:PRINT "Please Enter Today's Date  (m-d-y) ";:XLIN=CSRLIN:XPOS=POS(0)
  252. 5030 GOSUB 4999
  253. 5040 GOSUB 13000:IF Z="." OR Z=" " OR Z="/" OR Z="-" THEN 5110 ELSE IF Z=CHR$(8) THEN IF LEN(Z1)<1 THEN 5000 ELSE GOSUB 4999:GOTO 5040
  254. 5041 IF Z<"0" OR Z>"9" OR LEN(Z1)>1 THEN 5040 ELSE Z1=Z1+Z:LOCATE XLIN,XPOS:PRINT Z1;:GOTO 5040
  255. 5110 MM=VAL(Z1):IF MM<1 OR MM>12 THEN 5030 ELSE IF LEN(Z1)<>2 THEN Z1="0"+Z1
  256. 5130 Z2=Z1+"-":Z1="":LOCATE XLIN,XPOS:PRINT Z2;
  257. 5140 GOSUB 13000:IF Z="." OR Z=" " OR Z="/" OR Z="-" THEN 5220 ELSE IF Z=CHR$(8) THEN IF LEN(Z1)<1 THEN 5000 ELSE GOSUB 4999:GOTO 5140
  258. 5190 IF Z<"0" OR Z>"9" OR LEN(Z1)>1 THEN 5140 ELSE Z1=Z1+Z:LOCATE XLIN,POS(0):PRINT Z;:GOTO 5140
  259. 5220 DD=VAL(Z1):IF DD<1 OR DD>31 THEN GOSUB 4999:GOTO 5140 ELSE IF LEN(Z1)<>2 THEN Z1="0"+Z1
  260. 5240 Z2=Z2+Z1+"-":Z1="":LOCATE XLIN,XPOS:PRINT Z2;
  261. 5250 GOSUB 13000:IF Z=CHR$(13) THEN 5350 ELSE IF Z=CHR$(8) THEN IF LEN(Z1)<1 THEN Z2=LEFT$(Z2,3):GOSUB 4999:GOTO 5140 ELSE GOSUB 4999:GOTO 5250
  262. 5270 IF Z<"0" OR Z>"9" OR LEN(Z1)>1 THEN 5250 ELSE Z1=Z1+Z:LOCATE XLIN,POS(0):PRINT Z;:GOTO 5250
  263. 5350 YY=VAL(Z1):IF YY<80 OR YY>99 THEN GOSUB 4999:GOTO 5250
  264. 5360 Z2=Z2+Z1:LOCATE XLIN,XPOS:PRINT Z2;:DATE$=Z2$:RETURN
  265. 13000 SPF=0:TBF=0:FKEY=0:DEF SEG=&H40:POKE &H1A,PEEK(&H1C)
  266. 13010 POKE &H17,(PEEK(&H17) OR 96):Z=INKEY$:IF Z="" THEN 13010 ELSE ZZ=RIGHT$(Z,1):IF LEN(Z)>1 THEN IF ZZ<";" OR ZZ>"D" THEN 13010 ELSE FKEY=ASC(ZZ)-58:RETURN ELSE RETURN
  267. 13100 DEFINT A-Y:DEFSTR Z:ON ERROR GOTO 4420:DEF SEG=&H40:IF (PEEK(&H13)+(PEEK(&H14)*256))<196 THEN CX=150:RETURN ELSE CX=300:RETURN
  268. 13200 GOSUB 4340
  269. 13210 ZQ=" DATA DRIVE MAINTENANCE ":GOSUB 2230:COLOR 14:LOCATE 4,28:PRINT"Current Data Drive Is "XT$:LOCATE 6,23:PRINT"Program Is Configured For ";:IF HK$="YES" THEN PRINT"Hard Disk" ELSE PRINT"Floppy Disk"
  270. 13222 COLOR 12:LOCATE 8,28:PRINT"These Are Your Options:":LOCATE 10,27:COLOR 0,7:PRINT" A ":LOCATE 12,27:PRINT" B ":LOCATE 14,27:PRINT" C ":LOCATE 16,27:PRINT" D ":LOCATE 18,27:PRINT" E ":LOCATE 20,27:PRINT"F10"
  271. 13224 LOCATE 10,33:COLOR 2,0:PRINT"Set Data Drive To A:":LOCATE 12,33:PRINT"Set Data Drive To B:":LOCATE 14,33:PRINT"Set Data Drive To C:":LOCATE 16,33:PRINT"Set Data Drive To D:":LOCATE 18,33:PRINT"Set For ";
  272. 13225 IF HK$<>"YES" THEN PRINT"Hard Disk" ELSE PRINT"Floppy Disk
  273. 13227 LOCATE 20,33:PRINT"Return To Menu"
  274. 13230 B$="L":GOSUB 3460:IF FKEY=10 THEN 3530 ELSE IF B>5 THEN 13230 ELSE IF B=5 THEN IF HK$="YES" THEN HK$="" ELSE HK$="YES" ELSE XT$=CHR$(B+64)+":"
  275. 13240 GOSUB 900:GOTO 13210
  276. 13300 ZQ=" DELETE OLD ACCOUNT ":GOSUB 600
  277. 13310 B$="L":GOSUB 3460:IF FKEY=10 THEN 3530 ELSE IF LEN(AC$(B,1))<0 THEN 13310 ELSE AC$(B,1)="":AC$(B,2)=""
  278. 13320 DK$=" Check Register Diskette ":GOSUB 900:CLS:GOTO 3530
  279. 13400 GOSUB 2230:LOCATE 4,20:PRINT"Descriptions:":FOR I=1 TO 12:LOCATE I+5,25:PRINT USING "##. ";I;:PRINT EX$(I):NEXT:LOCATE 18,1:PRINT STRING$(80,196):LOCATE 19,8:PRINT"These Codes Are To Catagorize Types Of Expenses - Enter On Any Line";
  280. 13410 GOSUB 569:LOCATE 23,26:COLOR 14:PRINT"ENTER";:COLOR 7:PRINT" After entering Each Line":LOCATE 24,26:COLOR 14:PRINT"F1 ";:COLOR 7:PRINT"    To Advance To Next Line";
  281. 13420 LOCATE 25,26:COLOR 14:PRINT"F10";:COLOR 7:PRINT"    To Skip Remaining Lines";
  282. 13430 FOR C=1 TO 12:X=(C+5):Y=29:FLEN=20:GOSUB 3260:IF FKEY=10 THEN 13450 ELSE IF FKEY=1 THEN 13445 ELSE IF LEN(B$)<1 THEN LOCATE X,(29+LEN(B$)):PRINT SPC(FLEN-LEN(B$));:EX$(C)="" ELSE EX$(C)=B$
  283. 13445 NEXT C
  284. 13450 GOSUB 569:LOCATE 22,13:COLOR 7,0:PRINT"Select option:";
  285. 13460 LOCATE 23,28:COLOR 14:PRINT" F1 ";:COLOR 7:PRINT"-To Conclude Entries";:LOCATE 24,28:COLOR 14:PRINT" F2 ";:COLOR 7:PRINT"-To Reenter Data";:LOCATE 25,28:COLOR 14:PRINT" F10";:COLOR 7:PRINT" -To Return To MENU";:RETURN
  286. 13500 CCK=0:CCAMT#=0:OCK=0:OCAMT#=0:CDP=0:CDAMT#=0:ODP=0:ODAMT#=0:BC=0:BCAMT#=0:ACTBB#=0:LSTDT$=DATE$:FL$=ACTNO$+".C"+CYR$:GOSUB 1230
  287. 13520 IF EOF(1) THEN 13570 ELSE INPUT#1,C$(1),C$(2),C$(3),C$(4),C$(5),C$(6)
  288. 13530 IF C$(1)="X" THEN CCK=CCK+1:CCAMT#=CCAMT#+VAL(C$(3)) ELSE IF C$(1)="Z" THEN CDP=CDP+1:CDAMT#=CDAMT#+VAL(C$(3)) ELSE IF C$(1)="B" THEN BC=BC+1:BCAMT#=BCAMT#+VAL(C$(3))
  289. 13560 GOTO 13520
  290. 13570 FL$=ACTNO$+".O"+CYR$:GOSUB 1230
  291. 13580 IF EOF(1) THEN 13620 ELSE INPUT#1,C$(1),C$(2),C$(3),C$(4),C$(5),C$(6)
  292. 13590 IF C$(1)="C" THEN OCK=OCK+1:OCAMT#=OCAMT#+VAL(C$(3)) ELSE IF C$(1)="D" THEN ODP=ODP+1:ODAMT#=ODAMT#+VAL(C$(3))
  293. 13610 GOTO 13580
  294. 13620 FL$=ACTNO$+".A"+CYR$:GOSUB 910:RETURN
  295.