home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / PROGRAMS / UTILS / DOS_HELP / ADVMSDOS.ZIP / MOVE.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-06-19  |  4.3 KB  |  139 lines
  1.         name    move
  2.         page    55,132
  3.         title   'MOVE --- transfer file between subdirectories'
  4.  
  5. ;
  6. ; MOVE --- rename and/or transfer file between subdirectories
  7. ; Requires PC-DOS or MS-DOS 2.0 or greater.
  8. ;
  9. ; Copyright (c) 1984 by Ray Duncan
  10. ;
  11. ; Used in the form:
  12. ;
  13. ;       A>MOVE path\filespec1 path\filespec2 
  14. ; 
  15. ; For example, to move the file MYFILE.DAT from the root 
  16. ; directory to the subdirectory  \SUBX, you would enter:
  17. ;
  18. ;       A>MOVE  \MYFILE.DAT  \SUBX\MYFILE.DAT
  19. ;
  20. ; Of course, the file itself is not really "moved", its 
  21. ; name is just removed from one directory and inserted into
  22. ; another directory.  Can't be used to move files between drives.
  23. ;
  24. ; To assemble, link, and convert this program into 
  25. ; an EXE file, follow these steps:
  26. ;
  27. ;    C>MASM MOVE;
  28. ;     C>LINK MOVE;
  29. ;
  30.  
  31. cr      equ     0dh             ;ASCII carriage return
  32. lf      equ     0ah             ;ASCII line feed
  33. blank   equ     20h             ;ASCII space code
  34. eom     equ     '$'             ;end of string marker
  35.  
  36.  
  37. ; Here we define a dummy segment containing labels
  38. ; for the default file control block and the command tail buffer,
  39. ; so that the main program can access those locations.
  40. ;
  41. psp     segment para public 'PSP'  
  42.  
  43.         org     05ch
  44. fcb     label   byte            ;default file control block
  45.  
  46.         org     080h
  47. command label   byte            ;default command buffer
  48.  
  49. psp     ends
  50.  
  51.  
  52. cseg    segment para public 'CODE'
  53.  
  54.         assume  cs:cseg,ds:psp,es:data,ss:stack
  55.  
  56.  
  57. move    proc    far             ;entry point from PC-DOS
  58.  
  59.         push    ds              ;save DS:0000 for final
  60.         xor     ax,ax           ;return to PC-DOS
  61.         push    ax
  62.         mov     ax,data         ;make our data segment
  63.         mov     es,ax           ;addressable via ES register.
  64.         mov     ah,30h          ;check version of PC-DOS.       
  65.         int     21h
  66.         cmp     al,2
  67.         jae     move1           ;proceed, DOS 2.0 or greater.
  68.         mov     dx,offset msg3  ;DOS 1.x --- print error message
  69.         mov     ax,es           ;and exit. First fix up DS register 
  70.         mov     ds,ax           ;so error message is addressable.
  71.         jmp     move4
  72.  
  73. move1:  mov     cl,command      ;get length of name
  74.         mov     ch,0
  75.         push    cx              ;save length
  76.         mov     si,offset command+1  ; move from
  77.         mov     di,offset fname      ; move to
  78.         rep movsb               ;transfer names
  79.         mov     ax,es           ;now set DS register
  80.         mov     ds,ax   
  81.  
  82.     assume     ds:data
  83.  
  84.         mov     di,offset fname ;scan for first name
  85.         pop     cx              ;length of string
  86.         mov     al,blank        ;skip leading blanks
  87.         repz scasb      
  88.         jz      move3           ;jump, it was all blanks
  89.         mov     dx,di           ;DS:DX=start of old name
  90.         dec     dx
  91.         repnz scasb             ;scan to next blank.
  92.         jcxz    move3           ;no 2nd blank, so 2nd name missing
  93.                                 ;ES:DI = start of new name
  94.         mov     byte ptr [di-1],0 ;make first name an ASCIIZ string
  95.         mov     ah,56h          ;call rename function
  96.         int     21h             
  97.         jc      move2           ;jump, rename failed
  98.         ret                     ; return to dos
  99.  
  100. move2:  mov     dx,offset msg1
  101.         jmp     move4
  102.  
  103. move3:  mov     dx,offset msg2  ;missing filename
  104.  
  105. move4:  mov     ah,9            ;print the string whose address
  106.         int     21h             ;is in DX.
  107.         ret                     ;then return to DOS.
  108.  
  109. move    endp
  110.  
  111.  
  112. cseg    ends
  113.  
  114.  
  115. data    segment para public 'DATA'
  116.  
  117. fname           db      80 dup (0)
  118.  
  119. msg1            db      cr,lf
  120.                 db      'Move failed.'
  121.                 db      cr,lf,eom
  122.  
  123. msg2            db      cr,lf
  124.                 db      'Missing filename.'
  125.                 db      cr,lf,eom
  126.  
  127. msg3            db      cr,lf
  128.                 db      'Requires DOS version 2 or greater.'
  129.                 db      cr,lf,eom
  130.  
  131. data    ends    
  132.  
  133.  
  134. stack   segment para stack 'STACK'
  135.         db      64 dup (?)
  136. stack   ends
  137.  
  138.         end     move
  139.