home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / PROGRAMS / UTILS / DOS_HELP / ADVMSDOS.ZIP / MARK.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-06-19  |  6.4 KB  |  254 lines
  1.     name    mark
  2.     page    55,132
  3.     title    'MARK --- set attribute of file'
  4.  
  5. ;
  6. ; MARK --- Utility to set attribute of file.
  7. ; Copyright (C) 1983 Ray Duncan
  8. ;
  9. ; Requires PC-DOS or MS-DOS 2.0 or greater for execution.
  10. ;
  11. ; Program is called by command of the form: 
  12. ;
  13. ;         C>MARK  path\file.ext  /x
  14. ;
  15. ; where x=R for read-only, H for hidden,
  16. ; or N for normal (all attrib bits off).  
  17. ; 
  18. ; To assemble, link, and convert this program into 
  19. ; an EXE file, follow these steps:
  20. ;
  21. ;    C>MASM MARK;
  22. ;     C>LINK MARK;
  23. ;
  24.  
  25. cr    equ    0dh        ;ASCII carriage return
  26. lf    equ    0ah        ;ASCII line feed
  27. eom    equ    '$'        ;end of message flag 
  28.  
  29. command    equ    80h        ;Command line buffer
  30.  
  31. rd_only    equ     01h        ;file attributes
  32. hidden    equ    02h        
  33. system    equ    04h
  34. volume    equ    08h
  35. subdir    equ    10h
  36. archive    equ    20h
  37.  
  38.  
  39. cseg    segment    para public 'CODE'
  40.  
  41.     assume    cs:cseg,ds:data,es:data,ss:stack
  42.  
  43.  
  44. mark    proc    far        ;entry point from PC-DOS
  45.  
  46.     push    ds        ;save DS:0000 for final
  47.     xor    ax,ax        ;return to PC-DOS
  48.     push    ax
  49.     mov    ax,data        ;make our data segment addressable
  50.     mov    es,ax        ;via the ES register
  51.     call    infile        ;get path and name for
  52.                 ;file to be modified. 
  53.     jnc    mark1        ;jump if filename was ok
  54.     mov    dx,offset msg1    ;filename absent or illegal,
  55.     call    error        ;print error message and exit
  56.     ret
  57.  
  58. mark1:                ;filename was ok, now try
  59.     call    get_switch    ;and find the switch
  60.     jnc    mark2        ;jump if switch was ok
  61.     mov    dx,offset msg7    ;missing switch, print error
  62.     call    error        ;message and exit
  63.     ret            
  64.  
  65. mark2:                ;found legal switch, now 
  66.     push    dx        ;save addr of success message
  67.     mov    ax,es        ;make our data segment addressable
  68.     mov    ds,ax        ;via the DS register
  69.                 ;CX=attrib bits, 
  70.                 ; already set by "get_switch"
  71.                 ;DS:DX=addr of filename
  72.     mov    dx,offset input_name
  73.     mov    ah,43h        ;function 43h=CHMOD
  74.     mov     al,01        ;AL=01 for set attrib
  75.     int    21h        ;make request to PC-DOS
  76.     jnc    mark3        ;if CY=0 jump, successful call
  77.                 ;if CY=1 call failed,     
  78.     pop    dx        ;clean up stack, and
  79.     mov    dx,offset msg2    ;print error message
  80.     call    error
  81.     ret
  82.  
  83. mark3:                ;attribute was modified,
  84.     mov    dx,offset msg3    ;print 1st part of success message
  85.     mov    ah,9
  86.     int    21h
  87.                 ;print filename
  88.     mov    dx,offset input_name
  89.     call    pasciiz 
  90.     pop    dx        ;print last part of success msg.
  91.           mov    ah,9        
  92.     int    21h        
  93.     
  94.     ret            ;final exit to PC-DOS
  95. mark    endp
  96.  
  97.  
  98. pasciiz    proc    near        ;print the ASCIIZ string
  99.                 ;whose offset is in DX on
  100.                 ;the standard output device.
  101.                 ;Regs AX, BX also destroyed.
  102.     mov    bx,dx        ;let BX=offset of string
  103. pasciiz1:
  104.     mov    dl,[bx]        ;get next char from string
  105.     or    dl,dl        ;if char.=zero,end of string
  106.     jz    pasciiz9    ;jump if end
  107.     cmp    dl,'A'        ;if it is an upper-case alpha
  108.     jb    pasciiz2    ;character,fold to lower case
  109.     cmp    dl,'Z'        ;Note: Inclusive Or of an alpha
  110.     ja    pasciiz2    ;ASCII character with 20h has the
  111.     or    dl,20h        ;effect of folding to lower case.
  112. pasciiz2:
  113.     mov    ah,2        ;function 2=output char.
  114.     int    21h        ;request output by PC-DOS
  115.     inc    bx        ;advance to next string position
  116.     jmp    short pasciiz1
  117. pasciiz9:            ;done with string output,
  118.     ret            ;return to caller
  119. pasciiz endp
  120.  
  121.  
  122. infile    proc    near        ;Capture the name of a file
  123.                 ;from the command tail buffer
  124.                 ;where it was left by PC-DOS,
  125.                 ;transferring it into a local
  126.                 ;buffer in the form of an
  127.                 ;ASCIIZ string.
  128.  
  129.                 ;DS:SI <-  addr of command tail
  130.     mov    si,offset command
  131.                 ;ES:DI <-  addr of local buffer
  132.     mov    di,offset input_name
  133.     cld            ;make sure direction flag cleared
  134.     lodsb            ;first check count byte to make
  135.     or    al,al        ;sure command tail is present
  136.     jz    infile4        ;return error status if not.
  137. infile1:            ;scan over leading blanks to
  138.     lodsb            ;find the path and filename
  139.     cmp    al,cr        ;if we run into carriage return,
  140.     jz    infile4        ;filename is missing so exit.
  141.     cmp    al,20h        ;if this char is a blank,
  142.     jz    infile1        ;keep scanning.
  143. infile2:            ;found 1st char of name, 
  144.     stosb            ;transfer the name to local buffer.
  145.     lodsb            ;check next character, found
  146.     cmp    al,cr        ;end of string yet?
  147.     je    infile3        ;yes if either carriage return
  148.     cmp    al,20h     
  149.     jne    infile2
  150. infile3:            ;path and filename successfully 
  151.     xor    al,al        ;transferred to local buffer,
  152.     stosb            ;store 0 byte at end of string
  153.     clc            ;and exit with Carry flag =0
  154.     ret
  155. infile4:            ;some type of error was detected
  156.     stc            ;so exit with Carry flag =1
  157.     ret
  158. infile    endp
  159.  
  160.  
  161. get_switch proc    near        ;Scan the input line for a "/"
  162.                 ;delimiting a switch, then make
  163.                 ;sure it is legal.  
  164.                 ;Return CY=0 if legal switch, and
  165.                 ;CX=attrib byte, DX=msg addr
  166.                 ;Return CY=1 if switch no good 
  167.     mov    si,offset command+1  ; DS:SI = addr of command line
  168. get_switch1:            ;look for "/" character
  169.     lodsb
  170.     cmp    al,cr        ;if we run into a carriage return,
  171.     jz    get_switch9     ;switch missing so take error exit.
  172.     cmp    al,'/'    
  173.     jne    get_switch1    ;not '/' yet, keep looking.
  174.     lodsb            ;found '/', pick up next char.
  175.     or    al,20h        ;and fold to lower case.
  176.     cmp    al,'r'        ;R = read only
  177.     jne    get_switch2     ;not R, jump
  178.     mov    cx,rd_only    ;R so set read only attrib bit
  179.     mov    dx,offset msg5
  180.     ret            ;return CY=0 for success
  181. get_switch2:            ;check for H=hidden
  182.     cmp    al,'h'
  183.     jne    get_switch3    ;not H, jump
  184.     mov    cx,hidden    ;H so set hidden attrib bit
  185.     mov    dx,offset msg4
  186.     ret            ;return CY=0 for success
  187. get_switch3:            ;check for N=normal
  188.     cmp    al,'n'
  189.     jne    get_switch9    ;not N,jump to error exit
  190.     mov    cx,0        ;clear all attrib bits
  191.     mov    dx,offset msg6
  192.     ret            ;return CY=0 for success
  193. get_switch9:            ;missing or illegal switch,
  194.     stc            ;return CY flag=1 as alarm
  195.     ret
  196. get_switch endp
  197.  
  198.  
  199. error    proc    near        ;print error message
  200.     mov    ax,data        ;make sure data area addressable
  201.     mov    ds,ax
  202.     mov    ah,9        ;print error type
  203.     int    21h
  204.     mov    dx,offset helpmsg
  205.     mov    ah,9        ;also print HELP information
  206.     int    21h
  207.     ret            ;back to caller
  208. error    endp
  209.  
  210.  
  211. cseg    ends
  212.  
  213.  
  214. data    segment    para public 'DATA'
  215.  
  216. input_name db    64 dup (0)    ;buffer for path and file name
  217.  
  218. msg1    db    cr,lf
  219.     db    'Missing file name.',eom
  220.  
  221. msg2    db    cr,lf
  222.     db    'File not found.',eom
  223.  
  224. msg3    db    cr,lf
  225.     db    'Attribute of file ',eom
  226.  
  227. msg4    db    ' has been set to Hidden.'
  228.     db    cr,lf,eom
  229.  
  230. msg5    db    ' has been set to Read-Only.'
  231.     db    cr,lf,eom
  232.  
  233. msg6    db    ' has been set to Normal.'
  234.     db    cr,lf,eom
  235.  
  236. msg7    db    cr,lf
  237.     db    'Missing or illegal switch.',eom
  238.  
  239. helpmsg    db    '  Command should be in the form: '
  240.     db    cr,lf,lf
  241.     db    '  MARK filename /x'
  242.     db    cr,lf,lf
  243.     db    'x=N for normal, R for read-only, H for hidden.'
  244.     db    cr,lf,eom
  245.  
  246. data    ends
  247.  
  248.  
  249. stack    segment    para stack 'STACK'
  250.     db    64 dup (?) 
  251. stack    ends
  252.  
  253.     end    mark
  254.