home *** CD-ROM | disk | FTP | other *** search
/ Input 64 / Input_64_87-07_1987_Verlag_Heinz_Weise_de.d64 / kopfrechnen (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  4KB  |  157 lines
  1. 100 rem*****kopfrechentrainer*********
  2. 110 rem
  3. 120 rem     fuer commodore 64/128
  4. 130 rem
  5. 140 rem h.stender,haendelstr.8,3160 lehrte
  6. 150 rem
  7. 160 rem rechenuebungsprogramm fuer
  8. 170 rem
  9. 180 rem grundrechenarten
  10. 190 rem
  11. 200 print"[147]"
  12. 210 poke53280,6:poke53281,6:n=20
  13. 220 for j=1 to 39:print"[191]";:next:print
  14. 230 fori=1 to 20
  15. 240 print"[191]";
  16. 250 printspc(37)"[191]"
  17. 260 nexti
  18. 270 for i=1 to 39:print"[191]";:nexti
  19. 280 print"":print:print
  20. 290 print"[191] rechenuebungsprogramm fuer schueler"
  21. 300 print"[191] -----------------------------------"
  22. 310 print
  23. 320 print"[191] es werden";n;"aufgaben mit allen"
  24. 330 print"[191] vier grundrechenarten gestellt."
  25. 340 print"[191] du tippst die antwort in die tas-"
  26. 350 print"[191] tatur und dann die <return>-taste.":print
  27. 360 print"[191] die antworten werden mit richtig"
  28. 370 print"[191] oder falsch bewertet und gezaehlt."
  29. 380 print"[191] so kannst du selbst die fortschritte"
  30. 390 print"[191] sehen.":print:print
  31. 400 print"[191] und uebrigens....viel spass!!!":print:print
  32. 410 print"[191]       1987 heinrich stender"
  33. 420 x=10
  34. 430 gosub1200
  35. 440 print"[147]":f=0:r=0:c$=" = "
  36. 450 rem-------------------------------
  37. 460 rem                   auswahlmodul
  38. 470 rem-------------------------------
  39. 480 d0=val(left$(ti$,2))*3600+val(mid$(ti$,3,2))*60+val(right$(ti$,2))
  40. 490 for i=1 to val(right$(ti$,2))
  41. 500 z=rnd(1)
  42. 510 next i
  43. 520 for i=1 to n
  44. 530 y=int(4*rnd(1)+1)
  45. 540 onygosub910,980,1050,1130
  46. 550 y=int(4*rnd(1)+1)
  47. 560 onygosub1270,1370,1470,1570
  48. 570 ifc=dthenr=r+1:print:print:print"richtig":goto800
  49. 580 print"[147]falsch":f=f+1
  50. 590 print:print"";a;a$;b;c$;c
  51. 600 goto 800
  52. 610 next i
  53. 620 rem-------------------------------
  54. 630 rem                bewertungsmodul
  55. 640 rem-------------------------------
  56. 650 d1=val(left$(ti$,2))*3600+val(mid$(ti$,3,2))*60+val(right$(ti$,2))
  57. 660 d2=d1-d0-n*5
  58. 670 print"[147]"
  59. 680 print"anzahl   richtig   falsch"
  60. 690 print"-------+---------+--------"
  61. 700 printtab(3);n;
  62. 710 printtab(12);r;
  63. 720 printtab(21);f
  64. 730 print:print
  65. 740 w = int(1000*r/n)/10
  66. 750 print"das sind ";w;"% richtige antworten"
  67. 760 print:print"in";d2;"sekunden"
  68. 770 print:print
  69. 780 end
  70. 790 rem-------------------------------
  71. 800 rem                   anzeigemodul
  72. 810 rem-------------------------------
  73. 820 print""
  74. 830 print"anzahl   richtig   falsch"
  75. 840 print"-------+---------+--------"
  76. 850 printtab(3);i;
  77. 860 printtab(12);r;
  78. 870 printtab(21);f
  79. 880 x=5:gosub 1200
  80. 890 goto 610
  81. 900 rem-------------------------------
  82. 910 rem                 multiplikation
  83. 920 rem-------------------------------
  84. 930 a=int(9*rnd(1)+3)
  85. 940 b=int(18*rnd(1)+2)
  86. 950 c=a*b:a$=" * "
  87. 960 return
  88. 970 rem-------------------------------
  89. 980 rem                       addition
  90. 990 rem-------------------------------
  91. 1000 a=int(800*rnd(1)+9)
  92. 1010 b=int(200*rnd(1)+1)
  93. 1020 c=a+b:a$=" + "
  94. 1030 return
  95. 1040 rem-------------------------------
  96. 1050 rem                    subtraktion
  97. 1060 rem-------------------------------
  98. 1070 a=int(999*rnd(1)+9)
  99. 1080 b=int(220*rnd(1)+1)
  100. 1090 c=a-b:ifc<0then1070
  101. 1100 a$=" - "
  102. 1110 return
  103. 1120 rem-------------------------------
  104. 1130 rem                       division
  105. 1140 rem-------------------------------
  106. 1150 a=int(19*rnd(1)+1)
  107. 1160 b=int(7*rnd(1)+3)
  108. 1170 c=a/b:if(int(c)<>c)or(c=1)then 1150
  109. 1180 a$=" : ":return
  110. 1190 rem-------------------------------
  111. 1200 rem                      zeitmodul
  112. 1210 rem-------------------------------
  113. 1220 x1=val(left$(ti$,2))*3600+val(mid$(ti$,3,2))*60+val(right$(ti$,2))
  114. 1230 x2=val(left$(ti$,2))*3600+val(mid$(ti$,3,2))*60+val(right$(ti$,2))
  115. 1240 if(x2-x1)<x then 1230
  116. 1250 return
  117. 1260 rem-------------------------------
  118. 1270 rem                      . + b = c
  119. 1280 rem-------------------------------
  120. 1290 print"[147]"a$;b;" = ";c
  121. 1300 print"";
  122. 1310 open1,0
  123. 1320 input#1,b$
  124. 1330 close1
  125. 1340 if val(b$)=a then d=c
  126. 1350 return
  127. 1360 rem -----------------------------
  128. 1370 rem                     a + . = c
  129. 1380 rem -----------------------------
  130. 1390 print"[147]";a;a$;"     = ";c
  131. 1400 print"";
  132. 1410 open1,0
  133. 1420 input#1,b$
  134. 1430 close1
  135. 1440 if val(b$)=b then d=c
  136. 1450 return
  137. 1460 rem -----------------------------
  138. 1470 rem                     a + b = .
  139. 1480 rem -----------------------------
  140. 1490 print"[147]";a;a$;b;" = ";
  141. 1500 print"";
  142. 1510 open1,0
  143. 1520 input#1,b$
  144. 1530 close1
  145. 1540 if val(b$)=c then d=c
  146. 1550 return
  147. 1560 rem ------------------------------
  148. 1570 rem                     c = . + b
  149. 1580 rem ------------------------------
  150. 1590 print"[147]";c;" =    ";a$;b
  151. 1600 print"";
  152. 1610 open1,0
  153. 1620 input#1,b$
  154. 1630 close1
  155. 1640 if val(b$)=a then d=c
  156. 1650 return
  157.