100 REM*****KOPFRECHENTRAINER*********
110 REM
120 REM     FUER COMMODORE 64/128
130 REM
140 REM H.STENDER,HAENDELSTR.8,3160 LEHRTE
150 REM
160 REM RECHENUEBUNGSPROGRAMM FUER
170 REM
180 REM GRUNDRECHENARTEN
190 REM
200 PRINT"[147]"
210 POKE53280,6:POKE53281,6:N=20
220 FOR J=1 TO 39:PRINT"[191]";:NEXT:PRINT
230 FORI=1 TO 20
240 PRINT"[191]";
250 PRINTSPC(37)"[191]"
260 NEXTI
270 FOR I=1 TO 39:PRINT"[191]";:NEXTI
280 PRINT"":PRINT:PRINT
290 PRINT"[191] RECHENUEBUNGSPROGRAMM FUER SCHUELER"
300 PRINT"[191] -----------------------------------"
310 PRINT
320 PRINT"[191] ES WERDEN";N;"AUFGABEN MIT ALLEN"
330 PRINT"[191] VIER GRUNDRECHENARTEN GESTELLT."
340 PRINT"[191] DU TIPPST DIE ANTWORT IN DIE TAS-"
350 PRINT"[191] TATUR UND DANN DIE <RETURN>-TASTE.":PRINT
360 PRINT"[191] DIE ANTWORTEN WERDEN MIT RICHTIG"
370 PRINT"[191] ODER FALSCH BEWERTET UND GEZAEHLT."
380 PRINT"[191] SO KANNST DU SELBST DIE FORTSCHRITTE"
390 PRINT"[191] SEHEN.":PRINT:PRINT
400 PRINT"[191] UND UEBRIGENS....VIEL SPASS!!!":PRINT:PRINT
410 PRINT"[191]       1987 HEINRICH STENDER"
420 X=10
430 GOSUB1200
440 PRINT"[147]":F=0:R=0:C$=" = "
450 REM-------------------------------
460 REM                   AUSWAHLMODUL
470 REM-------------------------------
480 D0=VAL(LEFT$(TI$,2))*3600+VAL(MID$(TI$,3,2))*60+VAL(RIGHT$(TI$,2))
490 FOR I=1 TO VAL(RIGHT$(TI$,2))
500 Z=RND(1)
510 NEXT I
520 FOR I=1 TO N
530 Y=INT(4*RND(1)+1)
540 ONYGOSUB910,980,1050,1130
550 Y=INT(4*RND(1)+1)
560 ONYGOSUB1270,1370,1470,1570
570 IFC=DTHENR=R+1:PRINT:PRINT:PRINT"RICHTIG":GOTO800
580 PRINT"[147]FALSCH":F=F+1
590 PRINT:PRINT"";A;A$;B;C$;C
600 GOTO 800
610 NEXT I
620 REM-------------------------------
630 REM                BEWERTUNGSMODUL
640 REM-------------------------------
650 D1=VAL(LEFT$(TI$,2))*3600+VAL(MID$(TI$,3,2))*60+VAL(RIGHT$(TI$,2))
660 D2=D1-D0-N*5
670 PRINT"[147]"
680 PRINT"ANZAHL   RICHTIG   FALSCH"
690 PRINT"-------+---------+--------"
700 PRINTTAB(3);N;
710 PRINTTAB(12);R;
720 PRINTTAB(21);F
730 PRINT:PRINT
740 W = INT(1000*R/N)/10
750 PRINT"DAS SIND ";W;"% RICHTIGE ANTWORTEN"
760 PRINT:PRINT"IN";D2;"SEKUNDEN"
770 PRINT:PRINT
780 END
790 REM-------------------------------
800 REM                   ANZEIGEMODUL
810 REM-------------------------------
820 PRINT""
830 PRINT"ANZAHL   RICHTIG   FALSCH"
840 PRINT"-------+---------+--------"
850 PRINTTAB(3);I;
860 PRINTTAB(12);R;
870 PRINTTAB(21);F
880 X=5:GOSUB 1200
890 GOTO 610
900 REM-------------------------------
910 REM                 MULTIPLIKATION
920 REM-------------------------------
930 A=INT(9*RND(1)+3)
940 B=INT(18*RND(1)+2)
950 C=A*B:A$=" * "
960 RETURN
970 REM-------------------------------
980 REM                       ADDITION
990 REM-------------------------------
1000 A=INT(800*RND(1)+9)
1010 B=INT(200*RND(1)+1)
1020 C=A+B:A$=" + "
1030 RETURN
1040 REM-------------------------------
1050 REM                    SUBTRAKTION
1060 REM-------------------------------
1070 A=INT(999*RND(1)+9)
1080 B=INT(220*RND(1)+1)
1090 C=A-B:IFC<0THEN1070
1100 A$=" - "
1110 RETURN
1120 REM-------------------------------
1130 REM                       DIVISION
1140 REM-------------------------------
1150 A=INT(19*RND(1)+1)
1160 B=INT(7*RND(1)+3)
1170 C=A/B:IF(INT(C)<>C)OR(C=1)THEN 1150
1180 A$=" : ":RETURN
1190 REM-------------------------------
1200 REM                      ZEITMODUL
1210 REM-------------------------------
1220 X1=VAL(LEFT$(TI$,2))*3600+VAL(MID$(TI$,3,2))*60+VAL(RIGHT$(TI$,2))
1230 X2=VAL(LEFT$(TI$,2))*3600+VAL(MID$(TI$,3,2))*60+VAL(RIGHT$(TI$,2))
1240 IF(X2-X1)<X THEN 1230
1250 RETURN
1260 REM-------------------------------
1270 REM                      . + B = C
1280 REM-------------------------------
1290 PRINT"[147]"A$;B;" = ";C
1300 PRINT"";
1310 OPEN1,0
1320 INPUT#1,B$
1330 CLOSE1
1340 IF VAL(B$)=A THEN D=C
1350 RETURN
1360 REM -----------------------------
1370 REM                     A + . = C
1380 REM -----------------------------
1390 PRINT"[147]";A;A$;"     = ";C
1400 PRINT"";
1410 OPEN1,0
1420 INPUT#1,B$
1430 CLOSE1
1440 IF VAL(B$)=B THEN D=C
1450 RETURN
1460 REM -----------------------------
1470 REM                     A + B = .
1480 REM -----------------------------
1490 PRINT"[147]";A;A$;B;" = ";
1500 PRINT"";
1510 OPEN1,0
1520 INPUT#1,B$
1530 CLOSE1
1540 IF VAL(B$)=C THEN D=C
1550 RETURN
1560 REM ------------------------------
1570 REM                     C = . + B
1580 REM ------------------------------
1590 PRINT"[147]";C;" =    ";A$;B
1600 PRINT"";
1610 OPEN1,0
1620 INPUT#1,B$
1630 CLOSE1
1640 IF VAL(B$)=A THEN D=C
1650 RETURN