home *** CD-ROM | disk | FTP | other *** search
/ NeXTSTEP 3.3.4.17 [SPARC, PA-RISC] / nextstep33_risc.iso / NextLibrary / TeX / mf / inputs / tsetsl.mf < prev    next >
Encoding:
Text File  |  1995-02-07  |  6.0 KB  |  138 lines
  1. % Special slanted characters for ``extended ASCII character set'' fonts
  2.  
  3. % These characters were copied from {\tt greekl.mf} and {\tt italms.mf}
  4. % with character positions changed and italic corrections added to the width.
  5.  
  6. % Codes \0002--\0003, \0007--\0012, and \0017 are generated.
  7.  
  8. cmchar "Lowercase Greek alpha for extended ASCII";
  9. beginchar(oct"002",11u#,x_height#,0);
  10. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.5u#);
  11. adjust_fit(0,ic#); pickup fine.nib;
  12. pos0(hair,0); pos1(vair,-90); pos2(curve,-180); pos3(vair,-270);
  13. z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
  14. numeric theta; theta=angle(z4-z5)-90;
  15. pos4(stem,theta); pos5(stem,theta);
  16. pos6(vair,90); pos7(hair,180);
  17. rt x0r=hround(w-u); x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
  18. x6=w-u; x7+.5hair=hround(w+.5hair-eps);
  19. top y0=vround .8[bar_height,h]; bot y1r=bot y6l=-oo;
  20. y2=.5[y1,y3]; top y3r=h+oo; y7=1/4bar_height;
  21. filldraw stroke z0e{down}...pulled_arc.e(1,2) & pulled_arc.e(2,3)
  22.  ...z4e---z5e...z6e{right}...{up}z7e; % diagonal, bowl, and hook
  23. penlabels(0,1,2,3,4,5,6,7); endchar;
  24.  
  25. cmchar "Lowercase Greek beta for extended ASCII";
  26. beginchar(oct"003",9.5u#,asc_height#,desc_depth#);
  27. italcorr .5[x_height#,asc_height#]*slant-u#;
  28. adjust_fit(0,ic#); pickup fine.nib;
  29. pos0(hair,180); pos1(hair,180); pos2(vair,90);
  30. pos3(stem,0); pos4(vair,-90); pos5(hair,-180);
  31. pos6(vair,-270); pos7(curve,-360); pos8(vair,-450); pos9(hair,-540);
  32. x0=x1=x9; lft x0l=hround(1.5u-.5hair); x2=x4=x6=x8=.5w+.25u;
  33. rt x3r=hround(w-1.5u); rt x7r=hround(w-1.5u+.5curve); rt x5l=hround(x4-u);
  34. bot y0=-d; y1=top y6r=x_height; top y2r=h+oo; y3=.5[y2,y4];
  35. y5=.5[y4,y6]; top y6r-bot y4r=vstem+eps; bot y8=-oo; y7=y9=.5[y6,y8];
  36. if y6l<y4l: y6l:=y4l:=y5; fi
  37. filldraw stroke z0e---z1e...pulled_arc.e(2,3)
  38.  & pulled_arc.e(3,4)...{up}z5e;  % stem and upper bowl
  39. filldraw stroke z5e{up}...pulled_arc.e(6,7)
  40.  & pulled_arc.e(7,8)...{up}z9e;  % lower bowl
  41. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  42.  
  43. cmchar "Lowercase Greek pi for extended ASCII";
  44. beginchar(oct"007",10u#,x_height#,0);
  45. italcorr x_height#*slant+.5stem#-u#;
  46. adjust_fit(0,ic#); pi_stroke; % hook and bar
  47. pos4(hair,0); pos6(hair,0); x4=3.5u; x6=w-4u; y4=y6=y2;
  48. x5=3u; x7=w-2.5u; y5=y7=.5stem-oo;
  49. pair v[]; v1=(z4-z5) xscaled 3.14159; v2=(z6-z7) xscaled 3.14159;
  50. pos5(stem,angle v1-90); pos7(stem,angle v2-90);
  51. filldraw circ_stroke z5e{v1}...{up}z4e;  % left stem
  52. filldraw circ_stroke z7e{v2}...{up}z6e;  % right stem
  53. penlabels(1,2,3,4,5,6,7); endchar;
  54.  
  55. cmchar "Lowercase Greek lambda for extended ASCII";
  56. beginchar(oct"010",10.5u#,asc_height#,0);
  57. adjust_fit(0,0); pickup fine.nib;
  58. pos1(vair,90); lft x1=hround .1u; top y1r=h;
  59. x2=x1+2u; y2=.7[x_height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
  60. z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
  61. pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
  62. filldraw circ_stroke z1e{right}...z2e---z3e
  63.  ...{2(x4e-x3e),y4e-y3e}z4e;  % long diagonal
  64. y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
  65. x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
  66. filldraw circ_stroke z6e--z5e; % short diagonal
  67. penlabels(1,2,3,4,5,6); endchar;
  68.  
  69. cmchar "Lowercase Greek gamma for extended ASCII";
  70. beginchar(oct"011",10u#,x_height#,desc_depth#);
  71. italcorr x_height#*slant-.5u#;
  72. adjust_fit(0,ic#); pickup fine.nib;
  73. pos1(hair,180); pos2(vstem+dw,90);
  74. pos4(hair,0); pos5(vair,-90); pos6(hair,-180); pos7(hair,-180);
  75. bot y1=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
  76. bot y5r=-d-o; top y7=h;
  77. lft x1r=hround(.5u-.5hair); x2=3u; rt x4r=hround(w-2u); x5=.5[x4,x6];
  78. rt x4r-lft x6r=hround 1/3[hair,stem]+eps; rt x7l=hround(w-u);
  79. if x4l<x6l: x4l:=x6l:=x5; fi
  80. pos3(hair,angle(z4-z2)+90); x3=superness[x2,x4]; y3=superness[y4,y2];
  81. filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
  82.  ...z4e{down}...{left}z5e; % arc
  83. filldraw stroke z5e{left}...z6e{up}..{2(x7-x6),y7-y6}z7e;  % stem
  84. penlabels(1,2,3,4,5,6,7); endchar;
  85.  
  86. cmchar "Lowercase Greek delta for extended ASCII";
  87. beginchar(oct"012",8u#,asc_height#,0);
  88. italcorr .9asc_height#*slant+.5hair#-1.5u#;
  89. adjust_fit(0,ic#); pickup fine.nib;
  90. x0=-u; y0=1.05h;
  91. numeric light_flare; light_flare=2/3[vair,flare];
  92. x1=w-2u-.5light_flare; y1=h-.5light_flare;
  93. numeric theta; theta=angle (z1-z0);
  94. pos1(light_flare,theta-90); pos2(.2[vair,light_flare],-90); pos3(vair,theta);
  95. x2=x3+u; y2=h;
  96. x4=x6=.5w+.5u; top y8r=x_height+oo; z4=z8;
  97. pos6(vair,-90); pos7(stem,-180); pos8(vair,-270);
  98. pos4(stem,angle(z4-z0)+90); pos5(stem,30);
  99. z3=.5[.5[z1,z4],z0];
  100. y5+.1x_height=y7=.5[y6,y8]; bot y6=-oo;
  101. lft x7r=hround(1.4u-.5stem); rt x5r=hround(w-u);
  102. filldraw stroke z1e{z0-z1e}....z2e....z3e{(z0-z1)rotated 90}
  103.  ...z4e{z4e-.8[z4,z0]}
  104.  ....z5e{down}...pulled_arc.e(6,7) & pulled_arc.e(7,8);  % hook and bowl
  105. filldraw z1r{z1r-z0}...z1l{z0-z1l}--cycle; % bulb
  106. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  107.  
  108. cmchar "Partial differential sign for extended ASCII";
  109. beginchar(oct"017",10u#,asc_height#,0);
  110. italcorr .7asc_height#*slant+.5curve#-1.5u#;
  111. adjust_fit(0,ic#);
  112. numeric top_thickness,bot_thickness,side_thickness,pull;
  113. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  114. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  115. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  116. pull=min(.25,1.5superpull);
  117. pickup fine.nib; pos2(top_thickness,90);
  118. pos3(side_thickness,0); pos4(bot_thickness,-90);
  119. pos5(side_thickness,-180); pos6(vair,-270);
  120. lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side_thickness);
  121. x4=x6+.1u=x2+u=.5w;
  122. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  123. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  124. path p; p=pulled_super_arc.l(3,4)(pull);
  125. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  126. pos7(thin_join,0); z7l=point t of p;
  127. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  128. filldraw stroke pulled_super_arc.e(2,3)(pull)
  129.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  130.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  131.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  132. pos1(hair,180); pos0(flare,180);
  133. lft x0r=min(lft x2-eps,hround 1.2u);
  134. y0=vround min(.85h-.5flare,.8h+.5flare)+o;
  135. {{less_tense; bulb(2,1,0)}};  % arc and bulb
  136. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-u#);
  137. penlabels(0,1,2,3,4,5,6,7); endchar;
  138.