OpenStep 4.2J (Developer)/os42jdev.iso/NextDeveloper/OpenStepConversion/ConversionScripts/ArchiverConversion.tops

Text File | 1995-03-30 | 7.7 KB | 159 lines

/*********** ArchiverConversion: Constants ***********/

replace "TYPEDSTREAM_CALLER_ERROR"  with "NSArchiverCallerError"

replace "TYPEDSTREAM_FILE_INCONSISTENCY"  with "NSArchiverArchiveInconsistency"

replace "TYPEDSTREAM_CLASS_ERROR"  with "NSArchiverClassError"

replace "TYPEDSTREAM_TYPE_DESCRIPTOR_ERROR"  with "NSArchiverDescriptorError"

replace "TYPEDSTREAM_WRITE_REFERENCE_ERROR"  with "NSArchiverWriteReferenceError"

replace "TYPEDSTREAM_INTERNAL_ERROR"  with "NSArchiverInternalError"

/*********** ArchiverConversion: Archiver creation ***********/

replace "NXTypedStream" with "NSArchiver"

replace "NXOpenTypedStream(<stream>, NX_READONLY)" with "[[NSUnarchiver alloc] initForReadingWithData:<stream>]"
    error "ArchiverConversion: '[[NSUnarchiver alloc] init...]' used to be 'NXOpenTypedStream(...)'; <stream> should be converted to 'NSData *'."

replace "NXOpenTypedStream(<stream>, NX_WRITEONLY)" with "[[NSArchiver alloc] initForWritingWithMutableData:<stream>]"
    error "ArchiverConversion: '[[NSUnarchiver alloc] init...]' used to be 'NXOpenTypedStream(...)'; <stream> should be converted to 'NSMutableData *'."

replace "NXOpenTypedStream(<stream>, <mode>)" with same
    error "ArchiverConversion: 'NXOpenTypedStream(<stream>, <mode>)' should be '[[NSUnarchiver alloc] initForReadingWithData:<stream>]' for reading or '[[NSArchiver alloc] initForWritingWithMutableData:<stream>]' for writing. <stream> should be converted to 'NSMutableData *'."

replace "NXOpenTypedStreamForFile(<filename>, NX_READONLY)" with "[[NSUnarchiver alloc] initForReadingWithData:[NSData dataWithContentsOfFile:<filename>]]"

replace "NXOpenTypedStreamForFile(<filename>, NX_WRITEONLY)" with "[[NSArchiver alloc] initForWritingWithMutableData:[NSMutableData data]]"
    error "ArchiverConversion:  [<archiver> initForWritingWithMutableData:...] - used to be NXOpenTypedStreamForFile(<filename>, NX_WRITEONLY)) - NSArchiver contents must be explicitly writen to <filename> when archiving is completed"

replace "NXOpenTypedStreamForFile(<filename>, <mode>)" with same
    error "ArchiverConversion: 'NXOpenTypedStreamForFile(<filename>, <mode>)' should be '[[NSUnarchiver alloc] initForReadingWithData:[NSData dataWithContentsOfFile:<filename>]]' for reading or '[[NSArchiver alloc] initForWritingWithMutableData:[NSMutableData data]]' for writing. If writing, NSArchiver contents must be explicitly writen to <filename> when archiving is completed."

replace "NXCloseTypedStream(<stream>)" with "[<stream> release]"
    warning "ArchiverConvesion: [<stream> release] was NXCloseTypedStream(<stream>); <stream> has been converted to an NSArchiver instance (was NXTypedStream); if <stream> was opened with NXOpenTypedStreamForFile(<filename>, NX_WRITEONLY) contents of <stream> must be explicitly written to <filename>; a warning will have appeared if this is the case"

/*********** ArchiverConversion: Buffer functions ***********/

replace "NXWriteRootObjectToBuffer(<b args>)" with "NXWriteRootObjectToBuffer(<b args>)"
    error "ArchiverConversion: uses of typed streams should be converted to use NSArchiver and NSUnarchiver instead"

replace "NXReadObjectFromBuffer(<b args>)" with "NXReadObjectFromBuffer(<b args>)"
    error "ArchiverConversion: uses of typed streams should be converted to use NSArchiver and NSUnarchiver instead"

replace "NXReadObjectFromBufferWithZone(<b args>)" with "NXReadObjectFromBufferWithZone(<b args>)"
    error "ArchiverConversion: uses of typed streams should be converted to use NSArchiver and NSUnarchiver instead"

replace "NXFreeObjectBuffer(<b args>)" with "NXFreeObjectBuffer(<b args>)"
    error "ArchiverConversion: uses of typed streams should be converted to use NSArchiver and NSUnarchiver instead"

/*********** ArchiverConversion: awake, finishArchiving, startArchiving ***********/

replacemethod "awake" with same
    error "ArchiverConversion: put the contents of your 'awake' method at the end of your 'initWithCoder:' method instead"

replacemethod "finishUnarchiving" with "awakeAfterUsingCoder:<coder>" {
    replace "<coder_type>" with "(NSCoder *)"
    replace "<coder_param>" with "aDecoder"
    replace "<coder_arg>" with "nil"
    }
    within ("<implementation>") {
        replace "return nil" with "return self"
    }

replacemethod "startArchiving:" with same
    error "ArchiverConversion: 'startArchiving:' is obsolete; 'replacementObjectForCoder:' is a possible replacement"

/*********** ArchiverConversion: writing ***********/

replace "NXWriteArray(<coder>, <type>, <count>, <val>)" with "[<coder> encodeArrayOfObjCType:<type> count:<count> at:<val>]"

replace "NXWriteObject(<coder>, <obj>)" with "[<coder> encodeObject:<obj>]"

replace "NXWriteObjectReference(<coder>, <obj>)" with "[<coder> encodeConditionalObject:<obj>]"

replace "NXWritePoint(<coder>, <point>)" with "[<coder> encodePoint:*<point>]"

replace "NXWriteRect(<coder>, <rect>)" with "[<coder> encodeRect:*<rect>]"

replace "NXWriteRootObject(<stream>, <obj>)" with "[<stream> encodeRootObject:<obj>]"

replace "NXWriteSize(<coder>, <size>)" with "[<coder> encodeSize:*<size>]"

replace "NXWriteType(<coder>, <type>, <val>)" with "[<coder> encodeValueOfObjCType:<type> at:<val>]"

replace "NXWriteTypes(<coder>, <b args>)"  with "[<coder> encodeValuesOfObjCTypes:<b args>]"

/*********** ArchiverConversion: reading ***********/

replace "NXReadArray(<coder>, <type>, <count>, <val>)" with "[<coder> decodeArrayOfObjCType:<type> count:<count> at:<val>]"

replace "NXReadObject(<coder>)" with "[[<coder> decodeObject] retain]"

replace "NXReadPoint(<coder>, <point>)" with "*<point> = [<coder> decodePoint]"

replace "NXReadRect(<coder>, <rect>)" with "*<rect> = [<coder> decodeRect]"

replace "NXReadSize(<coder>, <size>)" with "*<size> = [<coder> decodeSize]"

replace "NXReadType(<coder>, <type>, <val>)" with "[<coder> decodeValueOfObjCType:<type> at:<val>]"

replace "NXReadTypes(<coder>, <b args>)" with "[<coder> decodeValuesOfObjCTypes:<b args>]"

/*********** ArchiverConversion: zones ***********/

replace "NXSetTypedStreamZone(<coder>, <zone>)" with"[<coder> setObjectZone:<zone>]"

replace "NXGetTypedStreamZone(<coder>)" with "[<coder> objectZone]"

/*********** ArchiverConversion: versions ***********/

replace "NXSystemVersion(<coder>)" with "[<coder> systemVersion]"

replace "NXTypedStreamClassVersion(<coder>, <class>)" with "[<coder> versionForClassName:[NSString stringWithCString:<class>]]"

/*********** ArchiverConversion: other functions ***********/

replace "NXFlushTypedStream(<coder>)" with same
    error "ArchiverConversion:  NXFlushTypedStream is no longer applicable"

replace "NXEndOfTypedStream(<coder>)" with "[<coder> isAtEnd]"

/*********** ArchiverConversion: super ***********/

/*********** ArchiverConversion: cleanup ***********/

replacemethod "write:<stream>" with "encodeWithCoder:<stream>" {
    replace "<rettype>" with "(void)"
    replace "<stream_type>" with "(NSCoder *)"
    replace "<stream_param>" with "aCoder"
    }
    within ("<implementation>") {
        replace "<stream_param>" with "aCoder"
    }

replacemethod "read:<stream>" with "initWithCoder:<stream>" {
    replace "<rettype>" with "(id)"
    replace "<stream_type>" with "(NSCoder *)"
    replace "<stream_param>" with "aDecoder"
    }
    within ("<implementation>") {
        replace "<stream_param>" with "aDecoder"
    }

replace "[[NSString stringWithCString:<aString>] cString]" with "<aString>"

replace "[[<aString> cString] cString]" with "[<aString> cString]"

replace "[NSString stringWithCString:[<aString> cString]]" with "<aString>"

replace "[NSString stringWithCString:@<string stringconst>]" with "@<string stringconst>"

replace "[NSString stringWithCString:<string stringconst>]" with "@<string stringconst>"

replace "[@<string stringconst> cString]" with "<string stringconst>"