home *** CD-ROM | disk | FTP | other *** search
/ Ahoy 1985 April / Ahoy_Magazine_85-04_1985_Double_L.d64 / elecheck (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1985-01-01  |  12.0 KB  |  371 lines
  1. 0 print"[147]":poke53281,13:poke53280,7:dimdn(50):dimco(50)
  2. 1 dimpe$(200):dimcn(200):dimcd$(200):dimcp$(200):dimca(200):dimm$(14)
  3. 2 print"[144]":print:print"        please enter current date":print
  4. 3 print"              <mm-dd-yy>[146] ";da$
  5. 4 print:input"             ";da$:iflen(da$)<>8thenprint"watch format":goto3
  6. 6 bb$="****************************************"
  7. 7 vv$="========================================"
  8. 8 ff$="========================================"
  9. 9 yy$=vv$+ff$
  10. 10 poke53281,7:poke53280,7:print"[147]":forp=1to3:print:next
  11. 11 poke53282,16:poke53283,15:poke53284,2:poke53265,peek(53265)or64
  12. 20 printtab(8);"[144]1. add check information":print
  13. 30 printtab(8);"[144]2. examine check file   ":print
  14. 40 printtab(8);"[144]3. menu of print options":print
  15. 50 printtab(8);"[144]4. change information   ":print
  16. 60 printtab(8);"[144]5. initialize options   ":print
  17. 65 printtab(8);"[144]6. balance check book   ":print
  18. 70 printtab(8);"[144]7. graph comparsions    ":print
  19. 75 printtab(8);"[144]8. end program          ":print
  20. 80 printtab(8);"[144]please select one       "
  21. 85 getx$:ifx$=""then85
  22. 86 ifx$<"1"orx$>"8"thenprint"enter a number 1-7":goto85
  23. 90 x=val(x$):onxgoto30100,30100,31300,30100,20000,6000,30100,32000
  24. 100 s$="":k=0:c=0:h=0:q=0:t=0:x=0:a=0:gt=0:print"[147]":goto10
  25. 105 rem**********************************
  26. 110 rem**written by glenn lumpkins
  27. 140 rem**********************************
  28. 6000 rem*** routine to balance check book***
  29. 6001 poke53281,7:poke53280,9
  30. 6010 :print"[147]":print"      enter bank's ending balance"
  31. 6015 print:input"    $ ";be
  32. 6020 print:print"      how many deposits not listed":print
  33. 6025 input"    $ ";d$:print"[147]":d=val(d$)
  34. 6030 ifd$=""ord$="0"then6080
  35. 6040 fori=1tod
  36. 6050 print"       enter deposit not listed":print:input"     $ ";dn(i)
  37. 6055 print"[147]"
  38. 6060 dp=dp+dn(i):next
  39. 6080 print"      how many checks outstanding"
  40. 6085 print:input"   $ ";cn$:print"[147]":cn=val(cn$)
  41. 6090 ifcn$="0"orcn$=""then6130
  42. 6100 fori=1tocn
  43. 6110 print"   enter amount of outstanding check"
  44. 6115 print:input"$ ";co(i):print"[147]"
  45. 6120 ac=ac+co(i):next
  46. 6130 print"       any other charges such as:"
  47. 6135 print:print"          automatic deductions":print
  48. 6137 print"            service charges"
  49. 6140 print:print"                 <y/n>[146]"
  50. 6142 getas$:ifas$=""then6142
  51. 6145 ifas$="n"then6230
  52. 6150 ifas$="y"then6200
  53. 6155 ifas$<>"n"oras$<>"y"then6140
  54. 6200 print"[147]":print"   enter in total amount of charges"
  55. 6220 print:input"  $ ";oc
  56. 6230 ba=(be+dp)-(ac+oc)
  57. 6240 print"[147]":print:print"      enter your checkbook balance"
  58. 6250 print:input"     $ ";yb:print"[147]"
  59. 6255 ifyb=bathen6300
  60. 6260 ifba>0thenprint"          your balance should be":print
  61. 6262 bn$=str$(ba+.001):bn$=left$(bn$,len(bn$)-1)
  62. 6265 ifba<0thenprint"          your balance should be":print
  63. 6266 ifba>0thenprint"         $";bn$:print:goto6280
  64. 6270 b$=str$(ba-.001):b$=left$(b$,len(b$)-1):print"          $";b$:print
  65. 6280 ifba<ybthenbx=yb-ba:print:print"          you are over by"
  66. 6285 bc$=str$(bx+.001):bc$=left$(bc$,len(bc$)-1)
  67. 6288 ifba<ybthen:print:print"         [160]$";bc$:goto7000
  68. 6290 ifba>ybthenax=ba-yb:print:print"          you are under by"
  69. 6295 ay$=str$(ax+.001):ay$=left$(ay$,len(ay$)-1)
  70. 6297 ifba>ybthenprint:print"          $";ay$
  71. 6300 ifba=ybthenprint:print"[147]":print"you are in balance--no adjustment needed"
  72. 7000 print:print:print:print"       press any key to continue"
  73. 7010 getp$:ifp$=""then7010
  74. 7012 ba=0:yb=0:ac=0:dp=0
  75. 7020 goto100
  76. 10000 rem***routine for change***
  77. 10001 poke53281,1:poke53280,8
  78. 10010 print"[147]":open5,8,5,"0:"+z$+",r"
  79. 10015 print"    one moment reading ";z$
  80. 10020 fori=1to199:c=i
  81. 10030 input#5,cn(i),cd$(i),pe$(i),cp$(i),ca(i)
  82. 10040 ifcn(i)=9999thenclose5:goto10060
  83. 10050 next
  84. 10060 print"[147]":printtab(11);z$:print
  85. 10065 printbb$
  86. 10070 print"r#";"[146]  ";"ck no.";"[146]   ";"date";"[146]    ";"payee":print
  87. 10071 ifk=1then10100
  88. 10090 fori=1toc:k=k+1
  89. 10100 printi;tab(4)cn(i);tab(11)cd$(i);tab(21)pe$(i)
  90. 10101 v$=str$(ca(i)+.001):v$=left$(v$,len(v$)-1)
  91. 10102 print"purpose[218][146]";tab(11)cp$(i)
  92. 10106 print"amount [218][146]";tab(11)"$";v$:print
  93. 10120 ifk=4thenprint:print"         continue paging <y/n>[146]"
  94. 10121 ifk=4thengetss$:ifss$=""then10121
  95. 10125 ifk>4thenk=1:goto10060
  96. 10135 ifss$="n"thengoto10150
  97. 10140 next
  98. 10150 print:input"change which record no.";rn
  99. 10160 print"[147]":print"record number ";rn:print
  100. 10170 print"1. check number ";cn(rn):print
  101. 10171 print"2. check date[160][160]  ";cd$(rn):print
  102. 10172 print"3. check payee   ";pe$(rn):print
  103. 10174 print"4. check purpose ";cp$(rn):print
  104. 10176 print"5. check amount ";ca(rn):print
  105. 10177 print"6. return to menu ":print
  106. 10200 print:print"change which line"
  107. 10201 getci$:ifci$=""then10201
  108. 10202 ci=val(ci$):ifci<1orci>6thenprint"enter a number 1-6":goto10201
  109. 10205 print"[147]":forg=1to10:print:nextg:printtab(7);z$;" check"
  110. 10210 ifci=1thenprint"old check number ";cn(rn):input"new check number";cn(rn)
  111. 10219 ifci=6thenprint"[147]":goto100
  112. 10220 ifci=2thenprint"old check date  ";cd$(rn):input"new check date";cd$(rn)
  113. 10225 iflen(cd$(rn))>8thenprint"watch format":print:goto10220
  114. 10230 ifci=3thenprint"old check payee  ";pe$(rn):input"new check payee";pe$(rn)
  115. 10235 iflen(pe$(rn))>17thenprint"17 characters max. please":print:goto10230
  116. 10240 ifci=4thenprint"old check purpose  ";cp$(rn)
  117. 10241 ifci=4theninput"new check purpose ";cp$(rn)
  118. 10245 iflen(cp$(rn))>30thenprint"30 characters max. please":print:goto10240
  119. 10250 ifci=5thenprint"old check amount "ca(rn):input"new check amount";ca(rn)
  120. 10252 print:print"change another line <y/n>[146]"
  121. 10253 getac$:ifac$=""then10253
  122. 10255 ifac$="n"thengoto10260
  123. 10256 ifac$="y"thengoto10160
  124. 10260 ifx=4thenopen5,8,5,"@0:"+z$+",w"
  125. 10270 fori=1toc
  126. 10280 print#5,cn(i):print#5,cd$(i):print#5,pe$(i):print#5,cp$(i):print#5,ca(i)
  127. 10290 next:i=c+1:cn(i)=999:cd$(i)="date":pe$(i)="eof":cp$(i)="xxxx":ca(i)=9999
  128. 10300 print#5,cn(i):print#5,cd$(i):print#5,pe$(i):print#5,cp$(i):print#5,ca(i)
  129. 10310 close5:goto100
  130. 19999 rem***routine for initializing**
  131. 20000 print"[147]":forg=1to8:print:next
  132. 20001 printtab(6);"1. initialize with information":print
  133. 20002 printtab(6);"2. initialize one file only   ":print
  134. 20003 printtab(6);"3. auto initialize all files  ":print
  135. 20004 printtab(6);"4. return to menu             ":print
  136. 20005 printtab(6);"please select one             "
  137. 20006 getq$:ifq$=""then20006
  138. 20007 q=val(q$):ifq<1orq>4then20006
  139. 20010 ifq=1thenh=0:c=0:goto30100
  140. 20025 ifq=4thengoto100
  141. 20030 ifq=2thengoto30100
  142. 20040 print"[147]":forg=1to12:print:next:printtab(7);"initializing ";z$
  143. 20042 open5,8,5,"0:"+z$+",w"
  144. 20050 pe$(1)="eof":cn(1)=9999:cd$(1)="date":cp$(1)="xxxx":ca(1)=9999
  145. 20060 print#5,cn(1):print#5,cd$(1):print#5,pe$(1):print#5,cp$(1):print#5,ca(1)
  146. 20070 close5:ifq=2thenq=0:a=0:goto100
  147. 20080 ifq=3thena=a+1:goto30115
  148. 29999 rem***data for sub menu***
  149. 30000 dataselection menu,1.  charge cards,2.  contributions
  150. 30010 data3.  entertainment,4.  household,5.  loan payments,6.  medical/dental
  151. 30020 data7.  mortgage payments,8.  taxes,9.  tuition,10. utilities
  152. 30030 data11. insurance,12. miscellaneous,13. return main menu
  153. 30100 print"[147]":fors=1to4:print:next
  154. 30105 rem**routine to select  routines**
  155. 30110 fors=1to14:readm$(s):printtab(9);m$(s):next:restore
  156. 30112 print:input"       please select one";a
  157. 30113 ifa<1ora>13then30112
  158. 30115 ifa=1thenz$="charge cards"
  159. 30117 ifa=2thenz$="contributions"
  160. 30119 ifa=3thenz$="entertainment"
  161. 30120 ifa=4thenz$="household"
  162. 30122 ifa=5thenz$="loan payments"
  163. 30124 ifa=6thenz$="medical/dental"
  164. 30126 ifa=7thenz$="mortgage payments"
  165. 30128 ifa=8thenz$="taxes"
  166. 30130 ifa=9thenz$="tuition"
  167. 30132 ifa=10thenz$="utilities"
  168. 30134 ifa=11thenz$="insurance"
  169. 30136 ifa=12thenz$="miscellaneous"
  170. 30137 ifa=13thenopen3,4:goto31393
  171. 30138 ifq=2thengoto20040
  172. 30139 ifq=3thengoto20040
  173. 30140 ifx=1thengoto31000
  174. 30145 ifx=2thengoto31200
  175. 30150 ifx=4thengoto10000
  176. 30155 ifx=3thengoto31305
  177. 30158 ifx=7thengoto35000
  178. 30160 ifh=2thengoto31335
  179. 30170 ifh=1then31450
  180. 30180 goto31070
  181. 31000 rem**routine to read--load array--add info***
  182. 31001 poke53281,12:poke53280,10:print"[147]":print"    one moment reading "z$
  183. 31010 open5,8,5,"0:"+z$+",r"
  184. 31020 fori=1to199:c=i
  185. 31030 input#5,cn(i),cd$(i),pe$(i),cp$(i),ca(i)
  186. 31040 ifcn(i)=9999thenclose5:goto31055
  187. 31050 next
  188. 31055 c=c-1
  189. 31070 print"[147]":c=c+1:ifx=5thenprint"initializing ";z$
  190. 31071 print:print:ifx=1then print"information for ";z$:print
  191. 31075 input"enter check number   ";cn(c):print
  192. 31080 input"enter date <mm-dd-yy>";cd$(c):print
  193. 31085 iflen(cd$(c))<>8thenprint"watch format":goto31080
  194. 31090 input"enter payee          ";pe$(c):print
  195. 31095 iflen(pe$(c))>17thenprint"17 characters max. please":goto31090
  196. 31100 input"enter purpose        ";cp$(c):print
  197. 31105 iflen(cp$(c))>30thenprint"30 characters max. please":goto31100
  198. 31110 input"enter check amount   ";ca(c):print
  199. 31115 print"is this correct <y/n/r>[146]":print
  200. 31116 getr$:ifr$=""then31116
  201. 31117 ifr$="n"then31075
  202. 31118 ifr$="r"thengoto100
  203. 31120 print"another ";z$;" check <y/n>[146] "
  204. 31130 getan$:ifan$=""then31130
  205. 31140 ifan$="y"then31070
  206. 31142 ifx=5thenopen5,8,5,"0:"+z$+",w":goto31150
  207. 31145 open5,8,5,"@0:"+z$+",w"
  208. 31150 fori=1toc
  209. 31160 print#5,cn(i):print#5,cd$(i):print#5,pe$(i):print#5,cp$(i):print#5,ca(i)
  210. 31170 next:i=c+1:pe$(i)="eof":cn(i)=9999:cd$(i)="date":cp$(i)="xxxx":ca(i)=9999
  211. 31180 print#5,cn(i):print#5,cd$(i):print#5,pe$(i):print#5,cp$(i):print#5,ca(i)
  212. 31182 close5:goto100
  213. 31200 rem***routine to examine files***
  214. 31201 poke53281,7:poke53280,14
  215. 31210 open5,8,5,"0:"+z$+",r":print"[147]":print"    one moment reading ";z$
  216. 31215 fori=1to199:c=i
  217. 31220 input#5,cn(i),cd$(i),pe$(i),cp$(i),ca(i)
  218. 31225 ifcn(i)=9999thenclose5:goto31232
  219. 31230 next
  220. 31232 print"[147]":printtab(11);z$:print
  221. 31233 printbb$
  222. 31235 print"ck no.";"[146]     ";" date ";"[146]     ";" payee ":print
  223. 31237 ifk=1thengoto31242
  224. 31240 fori=1toc-1:k=k+1
  225. 31242 v$=str$(ca(i)+.001):v$=left$(v$,len(v$)-1)
  226. 31245 printcn(i),cd$(i),"  ";pe$(i)
  227. 31246 print"purpose[218][146]",cp$(i)
  228. 31247 print"amount [218][146]","$";v$:print
  229. 31250 ifk=4thenprint:print"         continue paging <y/n>[146]"
  230. 31251 ifk=4thengets$:ifs$=""then31251
  231. 31253 ifk>4thenk=1:goto31232
  232. 31255 ifs$="n"thengoto100
  233. 31260 next
  234. 31269 print:print"       press any key to continue"
  235. 31270 getct$:ifct$=""then31270
  236. 31271 goto100
  237. 31300 print"[147]":forp=1to8:print:nextp:poke53281,3:poke53280,10
  238. 31305 printtab(9);"print options     ":print:printtab(9);"1. one check file "
  239. 31307 print:printtab(9)"2. all check files"
  240. 31308 print:printtab(9);"3. return to menu ":print
  241. 31310 printtab(9);"please select one "
  242. 31312 geth$:ifh$=""then31312
  243. 31313 ifh$<"1"orh$>"3"thenh$="":goto31310
  244. 31314 ifh$="2"thenprint"[147]":print"     are you sure you want all files":print
  245. 31315 ifh$="2"theninput"                 <y/n/r>[146]";ic$
  246. 31316 ific$="n"then31300
  247. 31317 ific$="r"then100
  248. 31320 h=val(h$):ifh<1orh>3then31315
  249. 31331 a=0:t=0:x=0:c=0:q=0:gt=0:print"[147]"
  250. 31332 ifh=2thena=a+1:goto30115
  251. 31333 ifh=1thengoto30100
  252. 31334 ifh=3thenprint"[147]":goto100
  253. 31335 rem**start of print all files**
  254. 31336 open5,8,5,"0:"+z$+",r"
  255. 31338 ifh=2thenprinttab(7);"printing ";z$;" file":print
  256. 31340 fori=1to199:c=i
  257. 31345 input#5,cn(i),cd$(i),pe$(i),cp$(i),ca(i)
  258. 31350 ifcn(i)=9999thenclose5:goto31368
  259. 31360 t=t+ca(i)
  260. 31365 next
  261. 31366 rem**routine to print all files**
  262. 31368 c=c-1:gt=gt+t:gt$=str$(gt+.001):gt$=left$(gt$,len(gt$)-1)
  263. 31369 ifcn(1)=9999thenprinttab(7);"no entries for ";z$:close5:print:goto31332
  264. 31370 open3,4:print#3,chr$(16)chr$(51)chr$(51);z$
  265. 31373 cc=len(z$):uu$=left$(bb$,cc):print#3,chr$(16)chr$(51)chr$(51);uu$
  266. 31374 print#3,chr$(10):print#3,yy$:print#3,chr$(16)chr$(48)chr$(49)"check #";
  267. 31375 print#3,chr$(16)chr$(49)chr$(50)"date";chr$(16)chr$(50)chr$(49)"[199]";
  268. 31376 print#3,chr$(16)chr$(50)chr$(56)"payee";chr$(16)chr$(51)chr$(56)"[200]";
  269. 31377 print#3,chr$(16)chr$(52)chr$(49)"[199]";chr$(16)chr$(53)chr$(50)"purpose";
  270. 31378 print#3,chr$(16)chr$(55)chr$(48)"[200]";chr$(16)chr$(55)chr$(52)"amount"
  271. 31379 print#3,yy$
  272. 31380 fori=1toc
  273. 31382 print#3,chr$(16)chr$(48)chr$(50);cn(i);chr$(16)chr$(49)chr$(48);cd$(i);
  274. 31384 print#3,chr$(16)chr$(50)chr$(49);pe$(i);chr$(16)chr$(52)chr$(49);cp$(i);
  275. 31385 i$=str$(int(ca(i)))+"."+right$(str$(ca(i)*100),2)
  276. 31386 print#3,chr$(16)chr$(55)chr$(49)"$";""tab(8-len(i$));i$
  277. 31387 t$=str$(t+.001):t$=left$(t$,len(t$)-1)
  278. 31392 ifi=cthenprint#3:print#3,"total for ";z$;" $";t$:t=0:print#3:print#3
  279. 31393 ifa=13thenprint#3,"year to date ";da$;" total";" $";gt$:print#3:print#3
  280. 31394 ifa=13thenclose3:goto100
  281. 31395 ifi=cthenclose3:goto31332
  282. 31396 next
  283. 31450 rem**routine to print one file**
  284. 31460 open5,8,5,"0:"+z$+",r"
  285. 31461 ifh=1thenprint"[147]":forg=1to10:print:next:printtab(7);"printing ";z$;" file"
  286. 31470 fori=1to199:c=i
  287. 31480 input#5,cn(i),cd$(i),pe$(i),cp$(i),ca(i)
  288. 31490 ifcn(i)=9999thenclose5:goto31510
  289. 31495 t=t+ca(i)
  290. 31500 next
  291. 31510 c=c-1:t$=str$(t +.001):t$=left$(t$,len(t$)-1)
  292. 31520 open3,4:print#3,chr$(16)chr$(51)chr$(51);z$
  293. 31522 cc=len(z$):uu$=left$(bb$,cc):print#3,chr$(16)chr$(51)chr$(51);uu$
  294. 31523 print#3,chr$(10):print#3,yy$:print#3,chr$(16)chr$(48)chr$(49)"check #";
  295. 31524 print#3,chr$(16)chr$(49)chr$(50)"date";chr$(16)chr$(50)chr$(49)"[199]";
  296. 31525 print#3,chr$(16)chr$(50)chr$(56)"payee";chr$(16)chr$(51)chr$(56)"[200]";
  297. 31526 print#3,chr$(16)chr$(52)chr$(49)"[199]";chr$(16)chr$(53)chr$(50)"purpose";
  298. 31527 print#3,chr$(16)chr$(55)chr$(48)"[200]";chr$(16)chr$(55)chr$(52)"amount"
  299. 31545 print#3,yy$
  300. 31550 fori=1toc
  301. 31560 print#3,chr$(16)chr$(48)chr$(50);cn(i);chr$(16)chr$(49)chr$(48);cd$(i);
  302. 31561 print#3,chr$(16)chr$(50)chr$(49);pe$(i);chr$(16)chr$(52)chr$(49);cp$(i);
  303. 31562 i$=str$(int(ca(i)))+"."+right$(str$(ca(i)*100),2)
  304. 31563 print#3,chr$(16)chr$(55)chr$(49)"$";""tab(8-len(i$));i$
  305. 31572 ifi=cthengoto31590
  306. 31580 next
  307. 31590 print#3:print#3,"total for ";z$;" $";t$:forl=1to5:print#3:next:close3
  308. 31595 goto100
  309. 32000 print"[147]":forl=1to10:print:next
  310. 32005 printtab(9);"it's been a pleasure":forl=1to4000:next:print"[147]":end
  311. 35000 rem**routine for graphs**
  312. 35001 print"[147]": print" do you wish a copy of the graph <y/n>[146]"
  313. 35002 getha$:ifha$=""then35002
  314. 35010 print"[147]":poke53280,7:poke53281,7:print"    one moment reading "z$
  315. 35020 open5,8,5,"0:"+z$+",r"
  316. 35030 fori=1to199
  317. 35040 input#5,cn(i),cd$(i),pe$(i),cp$(i),ca(i)
  318. 35050 ifcn(i)=9999thenclose5:goto40005
  319. 35060 j$=left$(cd$(i),2):ifj$="01"thenj=j+ca(i)
  320. 35070 ifj$="02"thenf=f+ca(i)
  321. 35080 ifj$="03"thenm=m+ca(i)
  322. 35090 ifj$="04"thenap=ap+ca(i)
  323. 35100 ifj$="05"thenma=ma+ca(i)
  324. 35110 ifj$="06"thenju=ju+ca(i)
  325. 35120 ifj$="07"thenjl=jl+ca(i)
  326. 35130 ifj$="08"thenau=au+ca(i)
  327. 35140 ifj$="09"thensp=sp+ca(i)
  328. 35150 ifj$="10"thenoc=oc+ca(i)
  329. 35160 ifj$="11"thenno=no+ca(i)
  330. 35170 ifj$="12"thende=de+ca(i)
  331. 35180 next
  332. 40005 print"[147]"
  333. 40010 print"   [194]":n=25:ifj>660thenn=50
  334. 40020 print"jan[171][192]";:fori=1toj/n:print" [144][146]";:next:printj;:print:n=25
  335. 40025 print"   [194]":iff>660thenn=50
  336. 40030 print"feb[171][192]";:fori=1tof/n:print" [144][146]";:next:printf;:print:n=25
  337. 40040 print"   [194]":ifm>660thenn=50
  338. 40050 print"mar[171][192]";:fori=1tom/n:print" [144][146]";:next:printm;:print:n=25
  339. 40060 print"   [194]":ifap>660thenn=50
  340. 40070 print"apr[171][192]";:fori=1toap/n:print"[158] [144][146]";:next:printap;:print:n=25
  341. 40080 print"   [194]":ifma>660thenn=50
  342. 40090 print"may[171][192]";:fori=1toma/n:print"[156] [144][146]";:next:printma;:print:n=25
  343. 40100 print"   [194]":ifju>660thenn=50
  344. 40110 print"jun[171][192]";:fori=1toju/n:print"[144] [144][146]";:next:printju;:print:n=25
  345. 40120 print"   [194]":ifjl>660thenn=50
  346. 40130 print"jul[171][192]";:fori=1tojl/n:print" [144][146]";:next:printjl;:print:n=25
  347. 40140 print"   [194]":ifau>660thenn=50
  348. 40150 print"aug[171][192]";:fori=1toau/n:print" [144][146]";:next:printau;:print:n=25
  349. 40160 print"   [194]":ifsp>660thenn=50
  350. 40170 print"sep[171][192]";:fori=1tosp/n:print" [144][146]";:next:printsp;:print:n=25
  351. 40180 print"   [194]":ifoc>660thenn=50
  352. 40190 print"oct[171][192]";:fori=1tooc/n:print"[158] [144][146]";:next:printoc;:print:n=25
  353. 40200 print"   [194]":ifno>660thenn=50
  354. 40210 print"nov[171][192]";:fori=1tono/n:print"[156] [144][146]";:next:printno;:print:n=25
  355. 40220 print"   [194]":ifde>660thenn=50
  356. 40230 print"dec[171][192]";:fori=1tode/n:print"[144] [144][146]";:next:printde;:print:n=25
  357. 40235 ifha$="y"thenprint"   [173][195][177][195][177][195][177][195][177][195][177][195]";z$;"[177][195][177][195][177][195][177][195][177][195][189]":goto40260
  358. 40240 print".......press any key to continue......"
  359. 40250 geta$:ifa$=""then40250
  360. 40260 j=0:f=0:m=0:ap=0:ma=0:ju=0:jl=0:au=0:sp=o:oc=0:no=0:de=0
  361. 40270 ifha$="y"then41001
  362. 41000 ifha$="n"thengoto100
  363. 41001 print"";:ss=(peek(210))*256:open3,3:open4,4
  364. 41002 forr=0to24:b$=""
  365. 41003 forc=0to39:a$=""
  366. 41004 ifpeek(ss+((r*40)+c))>127then:get#3,a$:b$=b$+chr$(18)+a$+chr$(146)
  367. 41005 ifpeek(ss+((r*40)+c))>127thengoto41100
  368. 41006 get#3,a$:ifa$=chr$(13)then:a$=" "
  369. 41007 b$=b$+a$
  370. 41100 nextc:print#4,b$:nextr:close4:close3:goto100
  371.