home *** CD-ROM | disk | FTP | other *** search
/ Ahoy 1984 July to December / Ahoy_Magazine_84-Jul-Dec_1984_Double_L_unofficial.d64 / dos (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1984-01-01  |  4.5 KB  |  133 lines
  1. 10 print "[147]":poke 53280,0:poke 53281,1:dim ae$(200):print
  2. 20 print tab(10);"[169]  "
  3. 25 print tab(10);" [146]   [146][169]"
  4. 30 print tab(10);" [146]   [223][146]ommodore [192] 64"
  5. 35 print tab(10);"[223]  "
  6. 40 for a=1 to 3:print:next a
  7. 45 print tab(7);"d i s k"
  8. 50 print tab(11);"o p e r a t i n g"
  9. 55 print tab(21);" s y s t e m"
  10. 60 for a=1 to 4:print:next a
  11. 70 print tab(8);"designed by...bob lloret"
  12. 80 print tab(11)"[156]copyright [144](c) [156]1984"
  13. 90 for d=1 to 2500:next d
  14. 100 print "[147]":poke 53280,0:poke 53281,6
  15. 110 print " [213][192][192][192][192] disk operating system v3.0 [146][192][192][192][192][201] "
  16. 115 print "[145] [221]";spc(36)"[221]"
  17. 116 print " [221]";spc(36)"[221]"
  18. 120 print " [221] [1][146] format disk      [4][146] erase prg [221]"
  19. 125 print " [221]";tab(38)"[221]"
  20. 130 print " [221] [2][146] rename file      [5][146] write dos [221]"
  21. 135 print " [221]";tab(38)"[221]"
  22. 140 print " [221] [3][146] validate disk    [6][146] directory [221]"
  23. 141 print " [221]";tab(38)"[221]"
  24. 142 print " [221]           [7][146] help screen          [221]"
  25. 145 for a=1 to 1:print " [221]";tab(38)"[221]":next a
  26. 150 print " [202][192][192][192][192][192][192][192][192]>your choice ?[1-7][146]<[192][192][192][192][192][192][192][192][203]":print:print
  27. 160 get an$:if an$="" then 160
  28. 170 an=val(an$)
  29. 180 if an<1 or an>7 then 160
  30. 190 on an goto 200,300,400,500,600,700,1200
  31. 198 rem ****  format disk  ****
  32. 199 rem =======================
  33. 200 print tab(8);"enter disk name (16 chr)":input "";na$
  34. 210 print tab(10);"enter disk id (2 chr)":input "";id$
  35. 220 na$="new0:"+na$+","+id$
  36. 230 print tab(10);"[144] are you sure (y[206]n) ?"
  37. 240 get an$:if an$="" then 240
  38. 250 if an$="y" then 280
  39. 260 if an$="n" then 100
  40. 270 if an$<>"y" or an$<>"n" then 240
  41. 280 open 15,8,15,na$
  42. 290 close 15
  43. 295 goto 100
  44. 298 rem ****  rename utility  ****
  45. 299 rem ==========================
  46. 300 print tab(8);" enter new name (16 chr)":input "";nn$
  47. 310 print tab(8);" enter old name (16 chr)":input "";oln$
  48. 320 ch$="r0:"+nn$+"="+oln$
  49. 330 open 15,8,15,ch$:for d=1 to 1500:next d
  50. 340 print tab(17);" done ":for d=1 to 1000:next d
  51. 350 close 15:goto 100
  52. 398 rem ****  validate disk  ****
  53. 399 rem =========================
  54. 400 print tab(12);" validating disk "
  55. 410 open 15,8,15,"validate"
  56. 440 close 15:goto 100
  57. 498 rem **** scratch program ****
  58. 499 rem =========================
  59. 500 printtab(3);" name of program to erase (16 chr)":input "";pn$
  60. 510 er$="s0:"+pn$
  61. 520 open 15,8,15,er$
  62. 530 for d=1 to 500:next d:print tab(17);" done ":for d=1 to 1500:next d
  63. 540 close 15:goto 100
  64. 598 rem **** write dos ****
  65. 599 rem ===================
  66. 600 print tab(9);" writing d o s files "
  67. 610 save "dos",8
  68. 620 print tab(17);" done ":for d=1 to 1500:next d
  69. 630 close 15:goto 100
  70. 700 rem ****  disk directory  ****
  71. 705 rem ==========================
  72. 710 print "[147]":poke 53280,4:poke 53281,1
  73. 720 ae$="":an=0:a0=0:de=0:dr$="0"
  74. 730 er=0:f$="":fl=0:i=0:j=0:mm=0:mn=0
  75. 750 open 15,8,15:print#15,"i"+dr$
  76. 760 input#15,er:if er=21 then890
  77. 770 open 8,8,8,"$"+dr$+",seq"
  78. 780 for de=1 to 8:f$="":get #8,c$
  79. 790 if c$=chr$(199) thenclose 8:close 15:goto900
  80. 800 if c$="" thenj=29:goto860
  81. 810 if asc(c$)<>130 thenj=29:goto860
  82. 820 an=an+1:j=11:get #8,c$:get #8,c$
  83. 830 for i=1 to 16:get #8,c$:f$=f$+c$:next
  84. 840 if left$(f$,3)="dos" thenan=an-1:goto860
  85. 850 ae$(an)=dr$+":"+f$
  86. 860 for i=1 to j:get #8,c$:next
  87. 870 if de<>8 thenget #8,c$:get #8,c$
  88. 880 next:goto780
  89. 890 print"no diskette found in drive";dr$;"":ford=1to 2500:next:goto 100
  90. 900 if an=0 thenprint "[144]no programs found [146]":ford=1to2500:next:goto 100
  91. 910 print "[147]"tab(7)"[156][213][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][201]"
  92. 920 mm=9:print tab(7)"[221] * d i r e c t o r y * [221]"
  93. 930 print tab(7)"[156][202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203]":print ""
  94. 940 for i=1 to 9:if ae$(mn*9+1)="" thenmm=i-1:i=9:goto960
  95. 950 print tab(11);"[156][";right$(str$(i),1);"][146] ";mid$(ae$(mn*9+i),3,16)
  96. 960 next:print tab(11)"[156]your choice [1-9]"
  97. 965 print tab(11)"press f1 for dos"
  98. 970 print tab(11)"or return for more"
  99. 980 get c$:if c$="" then980
  100. 985 if c$="[133]" then 100
  101. 990 if c$<>chr$(13) then1020
  102. 1000 mn=mn+1:if mn*9+1>an thenmn=0
  103. 1010 goto910
  104. 1020 if val(c$)<1 or val(c$)>mm then980
  105. 1030 ae$=ae$(mn*9+val(c$))
  106. 1040 print:print "[147]menu item chosen: #";c$;" - ";mid$(ae$,3,16)
  107. 1050 for i=18 to 1 step -1:fl=i
  108. 1060 if asc(mid$(ae$,i,1))<>160 theni=1
  109. 1070 next:print "load";chr$(34);left$(ae$,fl);chr$(34);",8"
  110. 1080 print "run":print "[145][145][145][145][145][145][145][145][145]"
  111. 1090 poke 631,13:poke 632,13:poke 198,2:end
  112. 1200 print"[147]":poke 53280,0:poke 53281,0
  113. 1210 print tab(7)"[156] * h e l p  s c r e e n *"
  114. 1220 print"[1][146]  press #1[154] to format a new disk or      any disk you wish ";
  115. 1230 print "to totaly erase."
  116. 1240 print "[2][146]  press #2[154] to change the name of any    program on a disk.";
  117. 1250 print " you should always    list the disk directory first to make   sure";
  118. 1260 print " you spell the old name correctly   to insure no disk errors."
  119. 1270 print "[3][146]  press #3[154] after you have used a disk   for a while. this ";
  120. 1280 print "will compact your     programs and eliminate unused blocks ";
  121. 1290 print "   on a disk."
  122. 1300 print "[4][146]  press #4[154] when you wish to erase any   program on a disk.";
  123. 1310 print" always list the      disk directory to insure proper spell   ing";
  124. 1320 print " of the program."
  125. 1330 print "[5][146]  press #5[154] to make a copy of d o s on   all your disks.";
  126. 1340 print " this will make it       handy if you ever need it."
  127. 1350 print "[6][146]  press #6[154] to list the directory and    run any program";
  128. 1355 print " on the disk."
  129. 1360 print tab(10)"[158]<press f1 for d o s>";
  130. 1370 get an$:if an$="" then 1370
  131. 1380 if an$="[133]" then 100
  132. 1390 if an$<>"[133]" then 1370
  133.