Ahoy 1984 July to December/Ahoy_Magazine_84-Jul-Dec_1984_Double_L_unofficial.d64/biorhythm

Commodore BASIC | 1984-01-01 | 3.2 KB | 100 lines

2 print"[147]"
4 v=53280:fort=0to30step.25:a=int(16+15*sin(t)):printtab(a);:print"biorhythm"
6 c=int(16*rnd(1))+1:pokev,c:next
8 pokev,6:pokev+1,8
10 print"[147]"spc(14);" biorhythm "
12 print""spc(9);"a program for the c-64"
14 print""spc(13);"by b.w.behling"
16 fori=0to2000:next
18 dimm(12):m(1)=31:m(2)=28:m(3)=31:m(4)=30:m(5)=31:m(6)=30:m(7)=31:m(8)=31
20 m(9)=30:m(10)=31:m(11)=30:m(12)=31:m(0)=0
22 print"[147]     enter the birthdate in numbers."
24 print" example:"
26 print"        april 9, 1963 = 04/09/1963"
28 input" birthdate";bi$
30 rem empty line for frequent dates
32 rem empty line for frequent dates
34 rem empty line for frequent dates
36 rem empty line for frequent dates
38 rem empty line for frequent dates
40 print"[147]        enter date for biorhythm."
44 input" date";da$
45 iflen(bi$)<>10orlen(da$)<>10thengoto275
46 bm$=left$(bi$,2):bd$=mid$(bi$,4,2):by$=right$(bi$,4)
47 bm%=val(bm$)-1:bd%=val(bd$):by%=val(by$)
48 dm$=left$(da$,2):dd$=mid$(da$,4,2):dy$=right$(da$,4)
49 dm%=val(dm$)-1:dd%=val(dd$):dy%=val(dy$)
50 bl=by%/4:ifint(bl)=blthenbl=1:m(2)=29:goto54
52 bl=0:m(2)=28
54 bt%=bd%
56 fori=0tobm%:bt%=bt%+m(i):next
60 dl=dy%/4:ifint(dl)=dlthendl=1:m(2)=29:goto64
62 dl=0:m(2)=28
64 dt%=dd%
66 fori=0todm%:dt%=dt%+m(i):next
70 ifby%=dy%thentd%=dt%-bt%:goto90
72 ifbl=1thentd%=366-bt%:goto76
74 td%=365-bt%
76 yt%=(dy%-by%)-1
78 td%=td%+(int((yt%*365.25))+dt%)
90 ph=td%/23:ph=(ph-int(ph))*(2*(NULL)):ph=sin(ph)
92 em=td%/28:em=(em-int(em))*(2*(NULL)):em=sin(em):ifem<-.005orem>.005thengoto94
93 em=0
94 in=td%/33:in=(in-int(in))*(2*(NULL)):in=sin(in)
96 ph$=str$(ph):em$=str$(em):in$=str$(in):ph$=left$(ph$,4):em$=left$(em$,4)
98 in$=left$(in$,4)
100 print"[147] you have been alive"td%;"days!!"
102 print" your physical cycle value is  "ph$
104 print" your emotional cycle value is  "em$
106 print" your intellectual cycle value is  "in$
108 print" a value close to 1. is an 'up' value."
110 print" a value close to -1. is a 'down' value."
112 print" a value of 0 is considered critical!!"
114 print" hit [n] for another date."
118 print" hit space for 7 day forecast."
120 getk$:ifk$=""then120
122 ifk$="n"thenrun18
130 print"[147] day","physi.","emoti.","intel."
132 print" "td%,ph$,em$,in$
134 fori=1to7:td%=td%+1
136 ph=td%/23:ph=(ph-int(ph))*(2*(NULL)):ph=sin(ph)
138 em=td%/28:em=(em-int(em))*(2*(NULL)):em=sin(em):ifem<-.005orem>.005thengoto140
139 em=0
140 in=td%/33:in=(in-int(in))*(2*(NULL)):in=sin(in)
142 ph$=str$(ph):em$=str$(em):in$=str$(in):ph$=left$(ph$,4):em$=left$(em$,4)
144 in$=left$(in$,4)
146 print" "td%,ph$,em$,in$
148 next
150 printspc(14);"**commands**"
151 print" [n] = new date."
152 print" [e] = end program."
154 print" [c] = to convert day # to date."
155 print" space = continue to next 7 days."
162 getk$:ifk$=""then162
164 ifk$="n"thenrun18
166 ifk$="c"then200
168 ifk$="e"thenend
170 goto130
200 input"[147] enter day # to be converted";dc%
205 td%=td%-7:iftd%<=dc%thengoto220
210 print" invalid day # !!!"
215 print" day # must be greater than";td%;"!!":fori=0to3500:next:goto200
220 ct%=dc%-td%:cm%=dm%+1:cd%=dd%:cy%=dy%
225 ifct%>(m(cm%)-cd%)thenct%=ct%-(m(cm%)-cd%):cm%=cm%+1:cd%=0
230 ifcm%>12thencm%=0:cy%=cy%+1:m(2)=28:ifcy%/4=int(cy%/4)thenm(2)=29
235 ifct%<=(m(cm%)-cd%)thencd%=cd%+ct%:goto245
240 goto225
245 print" date:"cm%;"/";cd%;"/";cy%
250 print" hit space to return to 7 day forecast."
255 print" hit [c] to convert another day."
260 getk$:ifk$=""then260
265 ifk$="c"thentd%=td%+7:goto200
270 goto130
275 print""
280 fori=1to5:print" error!!";:next
285 print" you must enter the complete date!!!"
290 print" all zeros must be included!!!"
300 print" hit space to reset."
305 getk$:ifk$=""then305
310 run18