home *** CD-ROM | disk | FTP | other *** search
/ Ahoy: Best of 1985 / Ahoy_Best_of_1985_1986_Double_L.d64 / futurewar f'85 (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1985-01-01  |  11.3 KB  |  345 lines
  1. 2 v=53280:w=54272:sm=1024:cm=55296:pokev,11:pokev+1,0:print"[147]"
  2. 4 print"";tab(9);"*****[146] futurewar! *****"
  3. 6 printtab(13);"by b.w.behling"
  4. 8 printtab(11);"(c) copyright 1984"
  5. 10 gosub 12:gosub 22:goto 56
  6. 12 rem ** variables **
  7. 14 dimpn$(2,6),p(2,6),se(9,4,6),d%(12):tr=36
  8. 16 fori=1to6:readcl$:pn$(1,i)=cl$:readcl$:pn$(2,i)=cl$:nexti
  9. 18 fori=1to9:reada%(i):next:fori=2to9:readb%(i):next:fori=0to9:readc%(i):next
  10. 20 return
  11. 22 rem ** delay loop **
  12. 24 fordl=0to2000:nextdl:return
  13. 26 rem ** print message **
  14. 28 print"";msg$:gosub 22:return
  15. 30 rem ** erase message **
  16. 32 forer=1824to2023:pokeer,32:nexter:return
  17. 34 rem ** player info **
  18. 36 print"";pn$(0,pt);",";msg$:return
  19. 38 rem ** bomb sound **
  20. 40 fori=0to22:pokew+i,0:nexti:pokew+24,10:pokew+5,80:pokew+12,160
  21. 42 pokew+6,255:pokew+13,252:pokew+4,17:pokew+4,16
  22. 44 fori=255to200step-1:poke54273,i:nexti
  23. 46 fori=255to75step-1:poke54273,i
  24. 48 forj=1to5:next:next:pokew+1,10:pokew+8,1:pokew+5,112:pokew+6,252
  25. 50 pokew+4,129:pokew+11,129
  26. 52 fori=1to200:nexti
  27. 54 pokew+4,128:pokew+11,128:return
  28. 56 print"[147] number of players";:inputnp
  29. 58 ifnp<7then 62
  30. 60 print" sorry, no more than six can play!":gosub 22:goto 56
  31. 62 ifnp<1then 56
  32. 64 ifnp<3ornp>5then 68
  33. 66 print" can i play with you";:inputcp$:goto 70
  34. 68 cp=0:goto 74
  35. 70 ifleft$(cp$,1)="n"thencp=0:goto 74
  36. 72 cp=1
  37. 74 fori=1tonp
  38. 76 print" player #";i;:input"name";pn$(0,i)
  39. 78 iflen(pn$(0,i))<11then 84
  40. 80 print"[158] that name is too large!"
  41. 82 print" no more than 10 letters please.":goto 76
  42. 84 print" ";pn$(0,i);",your color is ";pn$(1,i);".":nexti
  43. 86 onnpgoto 90, 104
  44. 88 goto 112
  45. 90 print" player # 2 name? computer 2"
  46. 92 pn$(0,2)="computer 2":p(2,2)=1
  47. 94 print" ";pn$(0,2);",your color is ";pn$(1,2);".":i=3
  48. 96 print" player # 3 name? computer 3"
  49. 98 pn$(0,3)="computer 3":p(2,3)=1
  50. 100 print" ";pn$(0,3);",your color is ";pn$(1,3);"."
  51. 102 np=3:goto 120
  52. 104 print" player # 3 name? computer 3"
  53. 106 pn$(0,3)="computer 3":p(2,3)=1
  54. 108 print" ";pn$(0,3);",your color is ";pn$(1,3);"."
  55. 110 np=3:goto 120
  56. 112 ifcp<>1then 120
  57. 114 np=np+1:print" player #";np;"name? computer";np
  58. 116 pn$(0,np)="computer"+str$(np)
  59. 118 print" ";pn$(0,np);",your color is ";pn$(1,np);".":p(2,np)=1
  60. 120 gosub 22:gosub 22
  61. 122 ar=32-((np-3)*5):pt=int(np*rnd(0))+1
  62. 124 fori=1to6:p(1,i)=ar:nexti
  63. 126 rem ** draw screen **
  64. 128 print"[147]":fori=0to40:reads:pokesm+i,s+128:pokecm+i,7:nexti
  65. 130 fori=79to759step40:pokesm+i,160:pokecm+i,7
  66. 132 pokesm+i+1,160:pokecm+i+1,7:nexti
  67. 134 fori=761to799:reads:pokesm+i,s+128:pokecm+i,7:nexti
  68. 136 fori=1to4:printtab(1)" [206][163][163][205]    [206][163][163][205]    [206][163][163][205]    [206][163][163][205]    [206][163][163][205]"
  69. 138 printtab(1)"[206]    [205][164][164][206]    [205][164][164][206]    [205][164][164][206]    [205][164][164][206]    [205]"
  70. 140 printtab(1)"[205]    [206][163][163][205]    [206][163][163][205]    [206][163][163][205]    [206][163][163][205]    [206]"
  71. 142 printtab(1)" [205][164][164][206]    [205][164][164][206]    [205][164][164][206]    [205][164][164][206]    [205][164][164][206]":nexti
  72. 144 printtab(5)"[205]    [206]  [205]    [206]  [205]    [206]  [205]    [206]"
  73. 146 printtab(6)"[205][164][164][206]    [205][164][164][206]    [205][164][164][206]    [205][164][164][206]"
  74. 148 msg$="         now we choose sectors [146]":gosub 26:gosub 30
  75. 150 r1=int(9*rnd(0))+1:r2=4:r3=int(9*rnd(0))+1:r4=1
  76. 152 rem ** picking sectors **
  77. 154 msg$=" pick a sector.":gosub 34
  78. 156 ifp(2,pt)=1then 180
  79. 158 print"enter #";:inputpi$:iflen(pi$)<>2thengosub 30:goto 154
  80. 160 ifasc(left$(pi$,1))<49 or asc(left$(pi$,1))>57thengosub 30:goto 154
  81. 162 ifasc(right$(pi$,1))<49 or asc(right$(pi$,1))>52thengosub 30:goto 154
  82. 164 a=val(left$(pi$,1)):b=val(right$(pi$,1))
  83. 166 ifse(a,b,0)=0thense(a,b,pt)=1:se(a,b,0)=1:p(1,pt)=p(1,pt)-1:goto 172
  84. 168 msg$="             already picked [146]"
  85. 170 gosub 26:gosub 30:goto 154
  86. 172 gosub 246:tr=tr-1:pt=pt+1:ifpt>nptthenpt=1
  87. 174 iftr>0then 154
  88. 176 msg$="          all sectors occupied [146]":gosub 26:gosub 30
  89. 178 msg$="         now you must reinforce [146]":gosub 26:gosub 30:goto 208
  90. 180 rem ** comp. terr. pick **
  91. 182 print"enter #?";
  92. 184 ifpt=2then 196
  93. 186 ifse(r3,r4,0)=0then 194
  94. 188 r4=r4+1:ifr4>4thenr4=1:r3=r3+1
  95. 190 ifr3>9thenr3=1
  96. 192 goto 186
  97. 194 a=r3:b=r4:z=r3*10+r4:goto 206
  98. 196 ifse(r1,r2,0)=0then 204
  99. 198 r2=r2-1:ifr2<1thenr2=4:r1=r1-1
  100. 200 ifr1<1thenr1=9
  101. 202 goto 196
  102. 204 a=r1:b=r2:z=r1*10+r2
  103. 206 pi$=str$(z):printpi$:gosub 22:goto 166
  104. 208 rem ** initial reinforceing **
  105. 210 msg$="":gosub 34:print"you have";p(1,pt);"armies left"
  106. 212 ifp(2,pt)=1then 234
  107. 214 input"reinforce #";fo$:iflen(fo$)<>2thengosub 30:goto 210
  108. 216 ifasc(left$(fo$,1))<49 or asc(left$(fo$,1))>57thengosub 30:goto 210
  109. 218 ifasc(right$(fo$,1))<49 or asc(right$(fo$,1))>52thengosub 30:goto 210
  110. 220 a=val(left$(fo$,1)):b=val(right$(fo$,1))
  111. 222 ifse(a,b,pt)=1thense(a,b,0)=se(a,b,0)+1:p(1,pt)=p(1,pt)-1:goto 228
  112. 224 msg$="            not your sector! [146]"
  113. 226 gosub 26:gosub 30:goto 210
  114. 228 gosub 246:pt=pt+1:ifpt>nptthenpt=1
  115. 230 ifp(1,pt)>0then 210
  116. 232 msg$="          prepare for battle!! [146]":gosub 26:gosub 30:goto 274
  117. 234 rem ** computer reinforcing **
  118. 236 print"reinforce #?";
  119. 238 ra=int(9*rnd(0))+1:rb=int(4*rnd(0))+1
  120. 240 forpc=rbto4:ifse(ra,pc,pt)<>1thennextpc:goto 238
  121. 242 a=ra:b=pc:pc=ra*10+pc
  122. 244 pi$=str$(pc):printpi$:gosub 22:goto 222
  123. 246 rem ** update sectors **
  124. 248 ta=-2:fori=1toa:ta=ta+4:nexti
  125. 250 print"":ifa/2=int(a/2)then 262
  126. 252 onbgoto 254, 256, 258, 260
  127. 254 printtab(ta);"";pn$(2,pt):goto 272
  128. 256 printtab(ta);"";pn$(2,pt):goto 272
  129. 258 printtab(ta);"";pn$(2,pt):goto 272
  130. 260 printtab(ta);"";pn$(2,pt):goto 272
  131. 262 onbgoto 264, 266, 268, 270
  132. 264 printtab(ta);"";pn$(2,pt):goto 272
  133. 266 printtab(ta);"";pn$(2,pt):goto 272
  134. 268 printtab(ta);"";pn$(2,pt):goto 272
  135. 270 printtab(ta);"";pn$(2,pt)
  136. 272 printtab(ta);"    [145]":printtab(ta);se(a,b,0):gosub 30:return
  137. 274 rem ** main routine **
  138. 276 am=0:ea%=0:ea=0:forx=1to9:fory=1to4:ifse(x,y,pt)=1thenam=am+.75:ea=ea+2
  139. 278 nexty:ifea=8thenea%=ea%+ea
  140. 280 ea=0:nextx:ifam>0then 286
  141. 282 pt=pt+1:ifpt>npthenpt=1
  142. 284 goto 274
  143. 286 ifam<3thenam=3
  144. 288 p(1,pt)=int(am):ab=rnd(0)*.5:p(1,pt)=int(p(1,pt)+(ab*p(1,pt)))+ea%
  145. 290 msg$="":gosub 34:print"you have";p(1,pt);"armies to station"
  146. 292 ifp(2,pt)=1then 590
  147. 294 input"what sector #";ri$:iflen(ri$)<>2thengosub 30:goto 290
  148. 296 ifasc(left$(ri$,1))<49 or asc(left$(ri$,1))>57thengosub 30:goto 290
  149. 298 ifasc(right$(ri$,1))<49 or asc(right$(ri$,1))>52thengosub 30:goto 290
  150. 300 a=val(left$(ri$,1)):b=val(right$(ri$,1))
  151. 302 ifse(a,b,pt)=1then 308
  152. 304 msg$="            not your sector! [146]"
  153. 306 gosub 26:gosub 30:goto 290
  154. 308 print"[145]                    ":input"[145]how many";st%
  155. 310 ifst%<=p(1,pt)thense(a,b,0)=se(a,b,0)+st%:p(1,pt)=p(1,pt)-st%:goto 316
  156. 312 msg$="        you don't have that many! [146]"
  157. 314 gosub 26:gosub 30:goto 290
  158. 316 gosub 246:ifp(1,pt)<>0then 290
  159. 318 msg$="         all troops on station! [146]":gosub 26:gosub 30
  160. 320 msg$="do you want to attack? [y/n]":gosub 30:gosub 34
  161. 322 ifp(2,pt)=1then 510
  162. 324 getk$:ifk$=""then 324
  163. 326 ifk$="n"then 450
  164. 328 input"attack what sector";ds$
  165. 330 iflen(ds$)<>2thengosub 30:goto 320
  166. 332 ifasc(left$(ds$,1))<49 or asc(left$(ds$,1))>57thengosub 30:goto 320
  167. 334 ifasc(right$(ds$,1))<49 or asc(right$(ds$,1))>52thengosub 30:goto 320
  168. 336 ad=val(left$(ds$,1)):bd=val(right$(ds$,1))
  169. 338 ifse(ad,bd,pt)=0then 344
  170. 340 msg$="      that's one of your sectors! [146]"
  171. 342 gosub 26:gosub 30:goto 320
  172. 344 input"from";as$
  173. 346 iflen(as$)<>2thengosub 30:goto 320
  174. 348 ifasc(left$(as$,1))<49 or asc(left$(as$,1))>57thengosub 30:goto 320
  175. 350 ifasc(right$(as$,1))<49 or asc(right$(as$,1))>52thengosub 30:goto 320
  176. 352 aa=val(left$(as$,1)):ba=val(right$(as$,1))
  177. 354 ifse(aa,ba,pt)=1then 360
  178. 356 msg$="    that's not one of your sectors! [146]"
  179. 358 gosub 26:gosub 30:goto 320
  180. 360 ifse(aa,ba,0)>1then 366
  181. 362 msg$="   not enough armies for this attack [146]"
  182. 364 gosub 26:gosub 30:goto 320
  183. 366 ifaa=ad and ba=bd+1 or aa=ad and ba=bd-1then 382
  184. 368 ifaa<>ad-1 and aa<>ad+1then 378
  185. 370 ifad/2=int(ad/2)then 376
  186. 372 ifba=bd or ba=bd-1then 382
  187. 374 goto 378
  188. 376 ifba=bd or ba=bd+1then 382
  189. 378 msg$="         sectors do not connect [146]"
  190. 380 gosub 26:gosub 30:goto 320
  191. 382 ifse(aa,ba,0)-1=1thenas%=1:goto 388
  192. 384 msg$="":gosub 30:gosub 34:print"attacking strength [1 -";se(aa,ba,0)-1;
  193. 386 print"[157]]";:inputas%:ifas%<1then 382
  194. 388 ifas%>se(aa,ba,0)-1then 382
  195. 390 al=0:dl=0:forat=1toas%:a1=int(6*rnd(0))+1:d1=int(6*rnd(0))+1
  196. 392 al=al+1:ifa1>d1thenal=al-1:dl=dl+1
  197. 394 ifse(ad,bd,0)-dl<1then 400
  198. 396 ifse(aa,ba,0)-al<2then 402
  199. 398 nextat:goto 402
  200. 400 ifas%=>se(aa,ba,0)-althenas%=se(aa,ba,0)-(al+1)
  201. 402 a=aa:b=ba:gosub 30:gosub 38:se(a,b,0)=se(a,b,0)-al:gosub 246
  202. 404 a=ad:b=bd:se(a,b,0)=se(a,b,0)-dl:tp=pt
  203. 406 fors=1to6:ifse(a,b,s)=1thenpt=s:gosub 246
  204. 408 nexts:pt=tp:ifse(a,b,0)<1then 422
  205. 410 ifse(aa,ba,0)<2thenpokew+24,0:goto 320
  206. 412 msg$=" same attack again? [y/n]":pokew+24,0:gosub 30:gosub 34
  207. 414 ifp(2,pt)=1then 580
  208. 416 getk$:ifk$=""then 416
  209. 418 ifk$="y"thengosub 30:goto 382
  210. 420 goto 320
  211. 422 msg$="            sector conquered [146]":pokew+24,0:gosub 26:gosub 30
  212. 424 fors=1to6:se(a,b,s)=0:nexts:se(a,b,pt)=1
  213. 426 forx=1to9:fory=1to4:ifse(x,y,pt)=1thentt=tt+1
  214. 428 nexty:nextx:iftt<>36thentt=0
  215. 430 ifas%=se(aa,ba,0)-1thenoa%=as%:goto 442
  216. 432 msg$="":gosub 34:print"you must move in";as%;"armies minimum"
  217. 434 ifp(2,pt)=1then 584
  218. 436 input"how many";oa$:forc=1tolen(oa$):c$=mid$(oa$,c,1)
  219. 438 ifasc(c$)<49orasc(c$)>57then 432
  220. 440 nextc:oa%=val(oa$)
  221. 442 ifoa%<as% or oa%>se(aa,ba,0)-1then 432
  222. 444 se(a,b,0)=oa%:gosub 246:a=aa:b=ba:se(a,b,0)=se(a,b,0)-oa%:gosub 246
  223. 446 iftt=36then 650
  224. 448 goto 320
  225. 450 msg$=" move troops? [y/n]":gosub 30:gosub 34
  226. 452 ifp(2,pt)=1thenk$="n":printtab(31);"[145]n":gosub 22:goto 456
  227. 454 getk$:ifk$=""then 454
  228. 456 ifk$="n"thengosub 30:goto 506
  229. 458 input"move from";mf$
  230. 460 iflen(mf$)<>2then 450
  231. 462 ifasc(left$(mf$,1))<49 or asc(left$(mf$,1))>57then 450
  232. 464 ifasc(right$(mf$,1))<49 or asc(right$(mf$,1))>52then 450
  233. 466 af=val(left$(mf$,1)):bf=val(right$(mf$,1))
  234. 468 ifse(af,bf,pt)=1then 474
  235. 470 msg$="    that's not one of your sectors! [146]"
  236. 472 gosub 26:goto 450
  237. 474 input"move to";mt$
  238. 476 iflen(mt$)<>2then 450
  239. 478 ifasc(left$(mt$,1))<49 or asc(left$(mt$,1))>57then 450
  240. 480 ifasc(right$(mt$,1))<49 or asc(right$(mt$,1))>52then 450
  241. 482 at=val(left$(mt$,1)):bt=val(right$(mt$,1))
  242. 484 ifse(at,bt,pt)<>1then 470
  243. 486 ifaf=at and bf=bt+1 or bf=bt-1then 498
  244. 488 ifaf<>at-1 and af<>at+1then 496
  245. 490 ifat/2=int(at/2)then 494
  246. 492 ifbf=bt or bf=bt-1then 498
  247. 494 ifbf=bt or bf=bt+1then 498
  248. 496 msg$="         sectors do not connect [146]":gosub 26:goto 450
  249. 498 msg$="":gosub 30:gosub 34:input"how many";tm%
  250. 500 iftm%>se(af,bf,0)-1then 498
  251. 502 se(af,bf,0)=se(af,bf,0)-tm%:se(at,bt,0)=se(at,bt,0)+tm%
  252. 504 a=af:b=bf:gosub 246:a=at:b=bt:gosub 246
  253. 506 pt=pt+1:ifpt>npthenpt=1
  254. 508 goto 274
  255. 510 rem ** computer main routine **
  256. 512 z%=int(rnd(0)*100)+1:ifz%<90then 516
  257. 514 gosub 22:goto 450
  258. 516 ra%=int(9*rnd(0))+1
  259. 518 forra=1to9:ra%=ra%+1:ifra%>9thenra%=1
  260. 520 forrb=1to4:ifse(ra%,rb,pt)=1thennextrb:nextra:goto 514
  261. 522 ad=ra%:bd=rb:ds=ad*10+bd:ds$=str$(ds)
  262. 524 ifbd=1then 530
  263. 526 aa=ad:ba=bd-1:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  264. 528 ifbd=4then 532
  265. 530 aa=ad:ba=bd+1:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  266. 532 ifad=1then 538
  267. 534 aa=ad-1:ba=bd:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  268. 536 ifad=9then 540
  269. 538 aa=ad+1:ba=bd:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  270. 540 ifad/2<>int(ad/2)then 550
  271. 542 ifbd=4then 560
  272. 544 aa=ad-1:ba=bd+1:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  273. 546 aa=ad+1:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  274. 548 nextrb:nextra:goto 514
  275. 550 ifbd=1then 560
  276. 552 ifad=1then 558
  277. 554 aa=ad-1:ba=bd-1:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  278. 556 ifad=9then 560
  279. 558 aa=ad+1:ba=bd-1:ifse(aa,ba,pt)=1 and se(aa,ba,0)>2then 562
  280. 560 nextrb:nextra:goto 514
  281. 562 ifse(aa,ba,0)<se(ad,bd,0)/2thennextrb:nextra:goto 514
  282. 564 print"attack what sector?";
  283. 566 as=aa*10+ba:as$=str$(as)
  284. 568 printds$:gosub 22:print"from?";as$:gosub 22
  285. 570 as%=int(rnd(0)*(se(aa,ba,0)-1))+1
  286. 572 ifse(aa,ba,0)-1=1then 390
  287. 574 ifse(aa,ba,0)-1>se(ad,bd,0)andas%<int(se(ad,bd,0)/1.5)then 570
  288. 576 msg$="":gosub 30:gosub 34:print"attacking strength [1 -";se(aa,ba,0)-1;
  289. 578 print"[157]]?";as%:gosub 22:goto 390
  290. 580 ifse(aa,ba,0)>se(ad,bd,0)/2then 570
  291. 582 goto 320
  292. 584 oa%=int(rnd(0)*se(aa,ba,0))
  293. 586 ifoa%<as%then 584
  294. 588 print"how many?";oa%:gosub 22:goto 442
  295. 590 rem *** computer station ***
  296. 592 print"what sector #?";
  297. 594 ra=int(9*rnd(0))+1:rb=int(4*rnd(0))+1
  298. 596 ifse(ra,rb,pt)=1then 594
  299. 598 ad=ra:bd=rb
  300. 600 ifbd=1then 606
  301. 602 aa=ad:ba=bd-1:ifse(aa,ba,pt)=1then 638
  302. 604 ifbd=4then 608
  303. 606 aa=ad:ba=bd+1:ifse(aa,ba,pt)=1then 638
  304. 608 ifad=1then 614
  305. 610 aa=ad-1:ba=bd:ifse(aa,ba,pt)=1then 638
  306. 612 ifad=9then 616
  307. 614 aa=ad+1:ba=bd:ifse(aa,ba,pt)=1then 638
  308. 616 ifad/2<>int(ad/2)then 626
  309. 618 ifbd=4then 636
  310. 620 aa=ad-1:ba=bd+1:ifse(aa,ba,pt)=1then 638
  311. 622 aa=ad+1:ifse(aa,ba,pt)=1then 638
  312. 624 goto 594
  313. 626 ifbd=1then 636
  314. 628 ifad=1then 634
  315. 630 aa=ad-1:ba=bd-1:ifse(aa,ba,pt)=1then 638
  316. 632 ifad=9then 636
  317. 634 aa=ad+1:ba=bd-1:ifse(aa,ba,pt)=1then 638
  318. 636 goto 594
  319. 638 a=aa:b=ba:z=aa*10+ba
  320. 640 ri$=str$(z):printri$:gosub 22
  321. 642 print"[145]                    ":print"[145]how many?";
  322. 644 st%=int(rnd(0)*p(1,pt))+1:ifst%<10then 648
  323. 646 ifst%>p(1,pt)/5thenst%=int(p(1,pt)/5):ifst%<1thenst%=1
  324. 648 printst%:gosub 22:goto 310
  325. 650 rem ** game over **
  326. 652 ifp(2,pt)=1then 670
  327. 654 msg$="     ********** you won! **********[146]"
  328. 656 gosub 30:gosub 26
  329. 658 pokev,14:pokev+1,6:print"[147]* * * * * *               [146]"
  330. 660 fori=1to3:printtab(7);" * * * * *                [146]"
  331. 662 printtab(7);"* * * * * *               [146]":nexti
  332. 664 fori=1to3:printtab(7);"                          [146]"
  333. 666 printtab(7);"                          [146]":nexti
  334. 668 msg$=" you are a true champion!!":gosub 34:end
  335. 670 msg$="     you humans are so easy to beat! [146]"
  336. 672 gosub 30:gosub 26:end
  337. 674 rem ** data starts **
  338. 676 data"white[146]","pl#1[146]","red[146]","pl#2[146]","[154]blue[146]","[154]pl#3[146]","[158]yellow[146]"
  339. 678 data"[158]pl#4[146]","[156]purple[146]","[156]pl#5[146]","green[146]","pl#6[146]"
  340. 680 data1,2,3,4,5,6,7,8,9,15,13,4,14,6,7,8,9,10,11,12,13,4,14,6,7,8,9
  341. 682 data32,32,32,49,49,32,32,50,49,32,32,51,49,32,32,52,49,32,32,53,49,32,32
  342. 684 data54,49,32,32,55,49,32,32,56,49,32,32,57,49,32,32,32,32
  343. 686 data32,32,49,52,32,32,50,52,32,32,51,52,32,32,52,52,32,32,53,52,32,32
  344. 688 data54,52,32,32,55,52,32,32,56,52,32,32,57,52,32,32,32
  345.