home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 62 / 64er_Magazin_Sonderheft_62_19xx_Markt__Technik_de_Side_A.d64 / disk-utilities (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1990-01-01  |  3.7 KB  |  129 lines
  1. 1 rem ******************
  2. 2 rem * disk-utilities *
  3. 3 rem *      von       *
  4. 4 rem *  volker maahs  *
  5. 5 rem * (w) 01.02.1988 *
  6. 6 rem ******************
  7. 7 :
  8. 8 :
  9. 9 :
  10. 10 g=8
  11. 20 poke53280,0:poke53281,0:poke646,10:printchr$(8)chr$(142)chr$(147);
  12. 30 print"    (w) 01.02.1988 von volker maahs     [146]";
  13. 40 print"           * disk-utilities *           [146]";:poke646,7
  14. 50 print"========================================";
  15. 60 printspc(3)"geraetenummer:";g:printspc(2):gosub830:poke646,6:print
  16. 70 printspc(3)"f1  formatieren":print:poke646,14
  17. 80 printspc(3)"f3  diskname/id aendern":print:poke646,2:
  18. 90 printspc(3)"f5  file loeschen":print:poke646,1
  19. 100 printspc(3)"f7  directory":print:poke646,4
  20. 110 printspc(3)"f2  geraeteadresse aendern":print:poke646,5
  21. 120 printspc(3)"f4  initialisieren":print:poke646,13
  22. 130 printspc(3)"f6  filenamen aendern":print:poke646,12
  23. 140 printspc(3)"f8  validieren":print:poke646,15
  24. 150 printspc(3)"e   programm beenden":print:
  25. 160 getf$:iff$=chr$(133)then310
  26. 170 iff$=chr$(134)then880
  27. 180 iff$=chr$(135)then580
  28. 190 iff$=chr$(136)thenpoke646,10:goto750
  29. 200 iff$=chr$(137)then270
  30. 210 iff$=chr$(138)then560
  31. 220 iff$=chr$(139)then660
  32. 230 iff$=chr$(140)then480
  33. 240 iff$="e"thengosub1190:print"ende.":end
  34. 250 goto160
  35. 260 rem * geraetenummer aendern *
  36. 270 gosub1190:print"        * geraetenummer aendern *       [146]"
  37. 280 print:print:print:printspc(2)"wie lautet die neue geraetenummer";:inputg
  38. 290 goto20
  39. 300 rem * formatieren *
  40. 310 gosub1190:print"            * formatieren *             [146]":print
  41. 320 poke646,7:printspc(11)"diskette einlegen!":poke646,10
  42. 330 print:print:printspc(7)"diskname (max. 16 zeichen):"
  43. 340 print:print:printspc(12)"................"
  44. 350 print"[145][145]"spc(10);:inputd$:print:print:print
  45. 360 printspc(16)"id: "
  46. 370 printspc(22)"..":print"[145][145]"spc(20);:inputid$
  47. 380 print:print:print:printspc(6)"wirklich formatieren (j/n)?"
  48. 390 getz$:ifz$="j"then420
  49. 400 ifz$="n"then20
  50. 410 ifz$<>"j"orz$<>"n"then390
  51. 420 open7,g,15,"n:"+d$+","+id$:close7
  52. 430 print:printspc(7)"noch eine diskette (j/n)?"
  53. 440 getz$:ifz$="j"then310
  54. 450 ifz$="n"then20
  55. 460 ifz$<>"j"orz$<>"n"then440
  56. 470 rem * validieren *
  57. 480 gosub1190:print"             * validieren *             [146]";
  58. 490 print:print:printspc(12)"validieren (j/n)?"
  59. 500 getz$:ifz$="n"then20
  60. 510 ifz$="j"then530
  61. 520 ifz$<>"j"orz$<>"n"then500
  62. 530 fort=1to9:print:next:poke646,7:printspc(13)"validiere disk!"
  63. 540 open7,g,15,"v":close7:goto20
  64. 550 rem * initialisieren *
  65. 560 open7,g,15,"i":close7:goto20
  66. 570 rem * file loeschen *
  67. 580 gosub1190:print"           * file loeschen *            [146]"
  68. 590 print:print:printspc(3)"filename";:inputna$
  69. 600 open7,g,15,"s:"+na$:close7
  70. 610 print:printspc(3)"weitere files loeschen (j/n)?"
  71. 620 getz$:ifz$="j"then580
  72. 630 ifz$="n"then20
  73. 640 ifz$<>"j"orz$<>"n"then620
  74. 650 rem * filenamen aendern *
  75. 660 gosub1190:print"         * filenamen aendern *          [146]";
  76. 670 print:print:print:printspc(3)"alter filename";:inputaf$
  77. 680 print:printspc(3)"neuer filename";:inputnf$
  78. 690 open7,g,15,"r:"+nf$+"="+af$:close7
  79. 700 print:printspc(3)"weitere files aendern (j/n)?"
  80. 710 getz$:ifz$="j"then660
  81. 720 ifz$="n"then20
  82. 730 ifz$<>"j"orz$<>"n"then710
  83. 740 rem * directory *
  84. 750 print"[147] 0 ";:open1,g,0,"$":poke781,1:sys65478:geta$,a$,a$,a$:x$=chr$(0)
  85. 760 fori=1to7:geta$,b$,c$,d$:printa$b$c$d$;:next:print:geta$,a$,a$,b$
  86. 770 ifst then sys65484:close1:goto790
  87. 780 printasc(a$+x$)+256*asc(b$+x$);:goto760
  88. 790 poke646,7:print" return[146]"
  89. 800 getz$:ifz$<>chr$(13)then800
  90. 810 goto20
  91. 820 rem * fehlerkanal *
  92. 830 open1,g,15
  93. 840 input#1,a,b$,c,d
  94. 850 printa;"[157], ";b$","c;"[157],"d
  95. 860 close1:return
  96. 870 rem * diskname/id aendern *
  97. 880 gosub1190:print"          * disknamen aendern *         [146]";
  98. 890 dn$="":a$="":b$=""
  99. 900 open15,g,15
  100. 910 print#15,"i"+dv$:open1,g,3,"#":print#15,"u1:3"dv",18,0"
  101. 920 print#15,"b-p:3,144":dn$="":forl=1to16:get#1,a$:dn$=dn$+a$:next
  102. 930 print"    diskettenname:[158]"dn$"[146]"
  103. 940 poke646,10:print"    aendern (j/n)?"
  104. 950 getq$:ifq$=""then 950
  105. 960 ifq$="n"then1010
  106. 970 if q$<>"j"then950:goto980
  107. 980 print"    neuer name(max. 16 zeichen): ":input"    ";n$
  108. 990 n$=left$(n$+"              ",16)
  109. 1000 print#15,"b-p:3,144":print#1,n$:print#15,"u2:3"dv",18,0"
  110. 1010 printchr$(147);:print"          * disk-id  aendern *          [146]"
  111. 1020 print#15,"b-p:3,162":get#1,a$,b$,c$,d$,e$
  112. 1030 print"    disk id:      [158]"a$b$c$d$e$"[146]"
  113. 1040 poke646,10:print"    aendern (j/n)?"
  114. 1050 getz$:ifz$=""then1050
  115. 1060 ifz$="n"then1110
  116. 1070 ifz$<>"j"then1050:goto1080
  117. 1080 input"    neue id (max. 5 zeichen): ";id$
  118. 1090 iflen(id$)<>4thenid$=left$(id$+" ",5)
  119. 1100 print#15,"b-p:3,162":print#1,id$;:print#15,"u2:"3;0;18;0
  120. 1110 i$="i"+mid$(str$(dv),5):print#15,i$
  121. 1120 close1:close15
  122. 1130 print"       noch eine diskette (j/n)?"
  123. 1140 getz$:ifz$=""then1140
  124. 1150 ifz$="n"then1180
  125. 1160 ifz$<>"j"then1140
  126. 1170 goto 880
  127. 1180 goto20
  128. 1190 poke646,10:printchr$(147);:return
  129.