home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 26 / 64er_Magazin_Sonderheft_26_19xx_Markt__Technik_de_Side_A.d64 / miniterm (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1990-01-01  |  1.1 KB  |  48 lines
  1. 10 rem ********************************
  2. 20 rem *     miniterm                 *
  3. 30 rem *                              *
  4. 40 rem *     ein programm zum         *
  5. 50 rem *     ausprobieren von         *
  6. 60 rem *         mailboxen            *
  7. 70 rem *                              *
  8. 80 rem ********************************
  9. 85 :
  10. 90 rem eingabe der parameter
  11. 95 :
  12. 100 input"datenbits (8/7) 8[157][157][157][157] ";db
  13. 110 input"parity (n/e/o) n[157][157][157][157] ";pa$
  14. 120 input"stop-bits (1/2) 1[157][157][157][157] "; sb
  15. 125 :
  16. 130 rem parameter setzen
  17. 135 :
  18. 140 sr=6+(sb-1)*2^7+abs(db-8)*2^5
  19. 150 br=abs(pa$<>"n")*2^5+abs(pa$<>"o"andpa$<>"n")*2^6
  20. 155 :
  21. 160 rem kanal oeffnen
  22. 165 :
  23. 170 open 2,2,3,chr$(sr)+chr$(br)
  24. 175 gosub 1000
  25. 180 get#2,a$:print"[147]online ..."
  26. 485 :
  27. 490 rem senden und empfangen der daten
  28. 495 :
  29. 500 get b$:ifb$<>""then print#2,chr$(t%(asc(b$+chr$(0))));
  30. 510 get#2,c$
  31. 520 print chr$(f%(asc(c$+chr$(0))));
  32. 530 goto 500
  33. 985 :
  34. 990 : rem standard-ascii herstellen
  35. 995 :
  36. 1000 dim f%(255),t%(255)
  37. 1010 forj=32to64:t%(j)=j:next
  38. 1020 t%(13)=13:t%(20)=8
  39. 1030 forj=65to90:k=j+32:t%(j)=k:next
  40. 1040 forj=91to95:t%(j)=j:next
  41. 1050 forj=193to218:k=j-128:t%(j)=k:next
  42. 1055 t%(24)=24:t%(19)=19:t%(3)=3
  43. 1060 t%(17)=17:t%(146)=16:t%(133)=16
  44. 1070 forj=0to255:k=t%(j)
  45. 1080 ifk<>0then f%(k)=j:f%(k+128)=j
  46. 1090 next
  47. 1110 return
  48.