home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 5 / 64er_Magazin_Sonderheft_05_86-05_1986_Markt__Technik_de.d64 / schallplattenv. (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1986-01-01  |  2.4 KB  |  93 lines
  1. 10 rem --- schallplattenverwaltung ---
  2. 20 rem ----- (s.baloui/feb 1986) -----
  3. 30 :
  4. 40 rem --- dimensionierung ---
  5. 50 dimt$(500),i$(500),p$(500),m$(500)
  6. 60 :
  7. 70 rem --- vorbereitung ---
  8. 80 g$="d":rem bei floppybetrieb in 'f' aendern
  9. 90 print"'e' druecken, wenn erstbenutzung des programms"
  10. 100 geta$:ifa$=""then100
  11. 110 ifa$<>"e"thengosub780:rem datei einlesen
  12. 120 :
  13. 130 rem --- menue ---
  14. 140 printchr$(147):rem screen loeschen
  15. 150 print"(e)intragen von datensaetzen"
  16. 160 print"(s)uchen von datensaetzen"
  17. 170 print"(b)eenden des programms"
  18. 180 print:print"kommando ?"
  19. 190 geta$:ifa$=""then190
  20. 200 ifa$="e"thengosub260
  21. 210 ifa$="s"thengosub340
  22. 220 ifa$="b"thengosub600:end
  23. 230 goto140
  24. 240 :
  25. 250 rem --- eintragen ---
  26. 260 ad=ad+1:rem anzahl datensaetze um eins erhoehen
  27. 270 input"titel";t$(ad)
  28. 280 input"interpret";i$(ad)
  29. 290 input"platte";p$(ad)
  30. 300 input"musikrichtung";m$(ad)
  31. 310 return
  32. 320 :
  33. 330 rem --- suchen ---
  34. 340 input"suchkriterium";s$
  35. 350 fori=1toad
  36. 360 ifs$<>t$(i)ands$<>i$(i)ands$<>p$(i)ands$<>m$(i)then460
  37. 370 printt$(i):printi$(i):printp$(i):printm$(i)
  38. 380 print"weitersuchen (j/n) ?"
  39. 390 geta$:ifa$=""then390
  40. 400 ifa$="j"then460
  41. 410 print"(l)oeschen/(a)endern ?"
  42. 420 geta$:ifa$=""then420
  43. 430 ifa$="l"ora$="a"thenn=i:gosub500:rem loeschen
  44. 440 ifa$="a"thengosub260:rem eintragen
  45. 450 goto470:rem ende
  46. 460 next
  47. 470 return
  48. 480 :
  49. 490 rem --- loeschen ---
  50. 500 fori=ntoad-1
  51. 510 t$(i)=t$(i+1)
  52. 520 i$(i)=i$(i+1)
  53. 530 p$(i)=p$(i+1)
  54. 540 m$(i)=m$(i+1)
  55. 550 next
  56. 560 ad=ad-1:rem anzahl datensaetze um eins erniedrigen
  57. 570 return
  58. 580 :
  59. 590 rem --- datei speichern ---
  60. 600 ifg$="d"thenopen1,1,1,"schallplatten":goto630:rem datasette
  61. 610 open15,8,15,"s:schallplatten":close15:rem loeschen der alten datei
  62. 620 open1,8,2,"schallplatten,s,w":rem floppy
  63. 630 print#1,ad:rem anzahl datensaetze speichern
  64. 640 fori=1toad
  65. 650 ift$(i)=""thent$(i)="*":rem leerer string?
  66. 660 print#1,t$(i):rem t$(1)-t$(ad) speichern
  67. 670 ifi$(i)=""theni$(i)="*":rem leerer string?
  68. 680 print#1,i$(i):rem i$(1)-i$(ad) speichern
  69. 690 ifp$(i)=""thenp$(i)="*":rem leerer string?
  70. 700 print#1,p$(i):rem p$(1)-p$(ad) speichern
  71. 710 ifm$(i)=""thenm$(i)="*":rem leerer string?
  72. 720 print#1,m$(i):rem m$(1)-m$(ad) speichern
  73. 730 next
  74. 740 close1:rem datei schliessen
  75. 750 return
  76. 760 :
  77. 770 rem --- datei einlesen ---
  78. 780 ifg$="d"thenopen1,1,0,"schallplatten":goto800:rem datasette
  79. 790 open1,8,2,"schallplatten,s,r":rem floppy
  80. 800 input#1,ad:rem anzahl datensaetze einlesen
  81. 810 fori=1toad
  82. 820 input#1,t$(i):rem titel einlesen
  83. 830 ift$(i)="*"thent$(i)="":rem leerer string?
  84. 840 input#1,i$(i):rem interpret einlesen
  85. 850 ifi$(i)="*"theni$(i)="":rem leerer string?
  86. 860 input#1,p$(i):rem platte einlesen
  87. 870 ifp$(i)="*"thenp$(i)="":rem leerer string?
  88. 880 input#1,m$(i):rem musikrichtung einlesen
  89. 890 ifm$(i)="*"thenm$(i)="":rem leerer string?
  90. 900 next
  91. 910 close1:rem datei schliessen
  92. 920 return
  93.