home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1988 February / 64er_Magazin_88-02_1988_Markt__Technik_de_Side_A.d64 / bild2 (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1988-01-01  |  1.7 KB  |  69 lines
  1. 10 rem ****************************
  2. 20 rem *   julia-mengen (x^3)     *
  3. 30 rem * 1987 by stefan vilsmeier *
  4. 40 rem ****************************
  5. 50 :
  6. 60 if peek(836)=0 then poke836,1:load "fractal.obj",8,1
  7. 70 open 1,8,15,"u9":close 1: rem diese zeile kann bei problemen mit dem
  8. 80 rem floppyspeeder weggelassen werden!
  9. 90 poke53280,0:poke53281,0
  10. 100 :
  11. 110 :
  12. 120 rem ******* eingaben ***********
  13. 130 :
  14. 140 x1=-2:x2=2:y1=-1.25:y2=1.25:z=13
  15. 190 :
  16. 200 :
  17. 210 rem ******* konstanten *********
  18. 220 :
  19. 230 ep=.0025:w=2/3
  20. 240 xa=1:ya=0:xb=-.5:yb=.8660254:xc=-.5:yc=-.8660254
  21. 250 sys 50176,14,0:sys 50179,1:sys 50194:rem grafik ein
  22. 260 :
  23. 270 :
  24. 280 rem ****************************
  25. 290 rem *       hauptschleife      *
  26. 300 rem ****************************
  27. 310 :
  28. 320 dx=(x2-x1)/320:dy=(y1-y2)/200
  29. 330 for yy=0 to 199
  30. 340 :for xx=0 to 319
  31. 350 : f=0:zz=0:za=0
  32. 360 : x  = x1 + xx*dx:y = y2 + yy*dy
  33. 370 : xq = x*x:yq = y*y
  34. 380 : n  = xq + yq:if n=0 then n=1e-5
  35. 390 : gosub 530:rem ******** check
  36. 400 : if zz<z and f=0 goto 390
  37. 410 : if not f then sys 50182,xx,yy,1
  38. 420 :next xx
  39. 430 next yy
  40. 450 sys 50179,0:gosub 700: rem 'grafik speichern'
  41. 460 goto 110: rem neustart
  42. 470 :
  43. 480 :
  44. 490 rem ****************************
  45. 500 rem *         'check'          *
  46. 510 rem ****************************
  47. 520 :
  48. 530 za = -2*((x-xa)*(x-xa)+(y-ya)*(y-ya)<=ep)
  49. 540 za = za-3*((x-xb)*(x-xb)+(y-yb)*(y-yb)<=ep)
  50. 550 za = za-4*((x-xc)*(x-xc)+(y-yc)*(y-yc)<=ep)
  51. 560 :
  52. 570 zz = zz+1
  53. 580 n  = n*n*3:xy  = x*y
  54. 590 x  = w*x+(xq-yq)/n:y  = w*y-(xy+xy)/n
  55. 600 xq = x*x:yq = y*y
  56. 610 n  = xq + yq
  57. 620 f  = -(n<1e-18)
  58. 630 if f=0 then f=-(n>1e+18)
  59. 640 if f=0 then f=za
  60. 650 return
  61. 660 :
  62. 670 rem ***************************
  63. 680 rem *   'grafik speichern'    *
  64. 690 rem ***************************
  65. 700 :
  66. 710 input "grafik-name ";n$
  67. 720 open 2,8,2,"pi."+n$+",p,w":sys 50191:close 2
  68. 730 return
  69.