home *** CD-ROM | disk | FTP | other *** search
/ Softdisk G-S 148 / SGDS 148.2mg / SDGS.148 / B / CONCLUSION (.txt) < prev    next >
Encoding:
Applesoft BASIC Source Code  |  1993-11-28  |  5.2 KB  |  209 lines  |  [FC] Applesoft BASIC Program (0x0801)
  1. 10  HOME 
  2. 20  REM 
  3. 30  REM  ******************
  4. 40  REM  ***            *** 
  5. 50  REM  *** CONCLUSION ***
  6. 60  REM  ***            ***
  7. 70  REM  ******************
  8. 80  REM 
  9. 90  PRINT : PRINT  CHR$(4);"PR#3": HOME : PRINT 
  10. 100  REM 
  11. 110  REM   GETTING  PLAYER INFO
  12. 120  REM 
  13. 130  REM   NA$(0) = NAME OF PLAYER
  14. 140  REM 
  15. 150  REM     KK(0),LL(0),JJ(0)
  16. 160  REM     NN(0),CC(0),DD(0)
  17. 170  REM  --- PLAYER'S  SCORE ---
  18. 180  REM 
  19. 190  PRINT : PRINT  CHR$(4);"OPEN CARRIER"
  20. 200  PRINT  CHR$(4);"READ CARRIER"
  21. 210  INPUT NA$(0),KK(0),LL(0),JJ(0),NN(0),CC(0),DD(0),B7,B8,MI
  22. 220  PRINT  CHR$(4);"CLOSE CARRIER"
  23. 230 B3$ = NA$(0)
  24. 240  REM 
  25. 250  REM  -----
  26. 260  REM 
  27. 270  VTAB (2): HTAB (21): PRINT " ||==================================||"
  28. 280  VTAB (3): HTAB (21): PRINT " ||==================================||"
  29. 290  VTAB (4): HTAB (21): PRINT " ||                                  ||"
  30. 300  VTAB (5): HTAB (21): PRINT " ||     ";: INVERSE : PRINT " HONOR ROLL ";: NORMAL : PRINT "  QUALIFIERS     ||"
  31. 310  VTAB (6): HTAB (21): PRINT " ||                                  ||"
  32. 320  VTAB (7): HTAB (21): PRINT " || MUST PROVIDE EVIDENCE THAT SHOWS ||"
  33. 330  VTAB (8): HTAB (21): PRINT " ||                                  ||"
  34. 340  VTAB (9): HTAB (21): PRINT " ||==================================||"
  35. 350  VTAB (10): HTAB (21): PRINT " ||==================================||"
  36. 360  VTAB (11): HTAB (21): PRINT " ||                                  ||"
  37. 370  VTAB (12): HTAB (21): PRINT " || MINIMUM ";: INVERSE : PRINT " TEN ";: NORMAL : PRINT " SCREENS CHALLENGED ||"
  38. 380  VTAB (13): HTAB (21): PRINT " ||                                  ||"
  39. 390  VTAB (14): HTAB (21): PRINT " ||      SUCCESS RATIO OF ";: INVERSE : PRINT " ";: PRINT MI;: PRINT "% ";: NORMAL : VTAB (14): HTAB (58): PRINT "||"
  40. 400  VTAB (15): HTAB (21): PRINT " ||                                  ||"
  41. 410  VTAB (16): HTAB (21): PRINT " ||==================================||"
  42. 420  VTAB (17): HTAB (21): PRINT " ||==================================||"
  43. 430  VTAB (18): HTAB (21): PRINT " ||                                  ||"
  44. 440  VTAB (19): HTAB (21): PRINT " || -->  CHECKING  ==  UPDATING  <-- ||"
  45. 450  VTAB (20): HTAB (21): PRINT " ||                                  ||"
  46. 460  VTAB (21): HTAB (21): PRINT " ||==================================||"
  47. 470  VTAB (22): HTAB (21): PRINT " ||==================================||";
  48. 480  REM 
  49. 490  REM    = READING FROM =
  50. 500  REM     = HONOR ROLL =
  51. 510  REM 
  52. 520  PRINT  CHR$(13): PRINT  CHR$(4);"OPEN H.R.RECORD"
  53. 530  PRINT  CHR$(4);"READ H.R.RECORD"
  54. 540  FOR Q = 8 TO 1  STEP  -1: INPUT NA$(Q): INPUT KK(Q): INPUT LL(Q): INPUT JJ(Q): INPUT NN(Q): INPUT CC(Q): INPUT DD(Q): NEXT 
  55. 550  PRINT  CHR$(4);"CLOSE H.R.RECORD"
  56. 560  REM 
  57. 570  REM   =IS PLAYER ALREADY=
  58. 580  REM    =ON  HONOR ROLL?=
  59. 590  REM 
  60. 600  FOR Q = 1 TO 8
  61. 610  IF NA$(Q) = NA$(0)  THEN KK(Q) = KK(0):LL(Q) = LL(0):JJ(Q) = JJ(0):NN(Q) = NN(0):CC(Q) = CC(0):DD(Q) = DD(0): GOTO 750
  62. 620  NEXT 
  63. 630  REM 
  64. 640  REM   =AVOID  UNNECESSAY=
  65. 650  REM      =CALCULATING=
  66. 660  REM 
  67. 670  IF (KK(0) <10  OR (NN(0) <NN(1))) GOTO 1150
  68. 680  REM 
  69. 690  REM  *ENTER PLAYER'S STUFF*
  70. 700  REM 
  71. 710 NA$(9) = NA$(0):KK(9) = KK(0):LL(9) = LL(0):JJ(9) = JJ(0):NN(9) = NN(0):CC(9) = CC(0):DD(9) = DD(0)
  72. 720  REM 
  73. 730  REM    = SORTING =
  74. 740  REM 
  75. 750  FOR Q = 1 TO 9
  76. 760 K1(Q) = KK(Q)
  77. 770 L1(Q) = LL(Q)
  78. 780 J1(Q) = JJ(Q)
  79. 790 RB(Q) = NN(Q)
  80. 800 C1(Q) = CC(Q)
  81. 810 D1(Q) = DD(Q)
  82. 820  NEXT 
  83. 830  FOR I = 1 TO 9
  84. 840  FOR J = 1 TO 8
  85. 850 RB = RB(J):NA$ = NA$(J):K1 = K1(J):L1 = L1(J):J1 = J1(J):C1 = C1(J):D1 = D1(J)
  86. 860 BR = RB(J +1):A3$ = NA$(J +1):K2 = K1(J +1):L2 = L1(J +1):J2 = J1(J +1):C2 = C1(J +1):D2 = D1(J +1)
  87. 870  IF RB <BR  THEN 900
  88. 880 RB(J) = BR:NA$(J) = A3$:K1(J) = K2:L1(J) = L2:J1(J) = J2:C1(J) = C2:D1(J) = D2
  89. 890 RB(J +1) = RB:NA$(J +1) = NA$:K1(J +1) = K1:L1(J +1) = L1:J1(J +1) = J1:C1(J +1) = C1:D1(J +1) = D1
  90. 900  NEXT J
  91. 910  NEXT I
  92. 920  FOR Q = 1 TO 9
  93. 930 NN(Q) = RB(Q)
  94. 940 KK(Q) = K1(Q)
  95. 950 LL(Q) = L1(Q)
  96. 960 JJ(Q) = J1(Q)
  97. 970 CC(Q) = C1(Q)
  98. 980 DD(Q) = D1(Q)
  99. 990  NEXT 
  100. 1000  REM 
  101. 1010  REM  *DROP LOW SCORE*
  102. 1020  REM 
  103. 1030  FOR QQ = 1 TO 9
  104. 1040 NA$(QQ) = NA$(QQ +1)
  105. 1050 NN(QQ) = NN(QQ +1)
  106. 1060 KK(QQ) = KK(QQ +1)
  107. 1070 LL(QQ) = LL(QQ +1)
  108. 1080 JJ(QQ) = JJ(QQ +1)
  109. 1090 CC(QQ) = CC(QQ +1)
  110. 1100 DD(QQ) = DD(QQ +1)
  111. 1110  NEXT : GOTO 1240
  112. 1120  REM 
  113. 1130  REM  *PAUSE IF NECESSARY*
  114. 1140  REM 
  115. 1150  SPEED= 50: FOR X = 1 TO 50: VTAB (22): HTAB (2): PRINT "": NEXT : SPEED= 255
  116. 1160  REM 
  117. 1170  REM   RECORD  TO FILE
  118. 1180  REM        WITH
  119. 1190  REM    BIGGEST SCORE
  120. 1200  REM       ON  TOP
  121. 1210  REM 
  122. 1220  REM  *PRINT TO FILE*
  123. 1230  REM 
  124. 1240  PRINT  CHR$(4);"OPEN H.R.RECORD"
  125. 1250  PRINT  CHR$(4);"WRITE H.R.RECORD"
  126. 1260  FOR Q = 8 TO 0  STEP  -1
  127. 1270  PRINT NA$(Q): PRINT KK(Q): PRINT LL(Q): PRINT JJ(Q): PRINT NN(Q): PRINT CC(Q): PRINT DD(Q): NEXT 
  128. 1280  PRINT  CHR$(4);"CLOSE H.R.RECORD"
  129. 1290  REM 
  130. 1300  REM  *PRINT TO SCREEN*
  131. 1310  REM 
  132. 1320  HOME : PRINT : PRINT  CHR$(4);"PR#3": HOME : PRINT 
  133. 1330  FOR Q = 3 TO 77: VTAB (2): HTAB (Q): PRINT "X";: NEXT 
  134. 1340  FOR Q = 3 TO 22
  135. 1350  VTAB (Q): HTAB (3): PRINT "XX"
  136. 1360  VTAB (Q): HTAB (76): PRINT "XX"
  137. 1370  NEXT 
  138. 1380  FOR Q = 3 TO 77: VTAB (22): HTAB (Q): PRINT "X";: NEXT 
  139. 1390  VTAB (1): HTAB (28): PRINT "|=======================|
  140. 1400  VTAB (2): HTAB (28): PRINT "|  H O N O R   R O L L  |"
  141. 1410  VTAB (3): HTAB (28): PRINT "|=======================|"
  142. 1420  REM 
  143. 1430  REM  *INTERIOR*
  144. 1440  REM 
  145. 1450  FOR Q = 5 TO 21  STEP 2
  146. 1460  VTAB (Q): HTAB (5): PRINT "-----------|-----------|-----------------------|-----------|-----------"
  147. 1470  NEXT 
  148. 1480  VTAB (3): HTAB (8): PRINT "Total   |   Total"
  149. 1490  VTAB (3): HTAB (55): PRINT "Correct  |  Success"
  150. 1500  VTAB (4): HTAB (7): PRINT "Screens  |   Films   |  Player of Substance  |  Inserts  |  Percent"
  151. 1510  REM 
  152. 1520  REM  *PRINT INFO*
  153. 1530  REM 
  154. 1540 X9 = 6: FOR Q = 8 TO 1  STEP  -1
  155. 1550 L1 =  LEN(NA$(Q)):L2 = 41 -(L1/2): VTAB (X9): HTAB (L2): PRINT NA$(Q)
  156. 1560  IF NA$(Q) = B3$  THEN Z8 = X9:Z9 = L2
  157. 1570  IF KK(Q) <10  THEN L2 = 11: GOTO 1600
  158. 1580  IF KK(Q) <100  THEN L2 = 10: GOTO 1600
  159. 1590 L2 = 9
  160. 1600  VTAB (X9): HTAB (L2): PRINT KK(Q)
  161. 1610  IF LL(Q) <10  THEN L2 = 23: GOTO 1640
  162. 1620  IF LL(Q) <100  THEN L2 = 22: GOTO 1640
  163. 1630 L2 = 21
  164. 1640  VTAB (X9): HTAB (L2): PRINT LL(Q)
  165. 1650  IF JJ(Q) <10  THEN L2 = 59: GOTO 1680
  166. 1660  IF JJ(Q) <100  THEN L2 = 58: GOTO 1680
  167. 1670 L2 = 57
  168. 1680  VTAB (X9): HTAB (L2): PRINT JJ(Q)
  169. 1690  IF NN(Q) <10  THEN L2 = 70: GOTO 1720
  170. 1700  IF NN(Q) <100  THEN L2 = 69: GOTO 1720
  171. 1710 L2 = 68
  172. 1720  VTAB (X9): HTAB (L2): PRINT NN(Q);: PRINT "%"
  173. 1730 X9 = X9 +2
  174. 1740  NEXT 
  175. 1750  VTAB (22): HTAB (34): PRINT "=============";
  176. 1760  VTAB (23): HTAB (32): PRINT "XX-{ Any Key }-XX";
  177. 1770  POKE 49168,0: VTAB (22): HTAB (40)
  178. 1780  IF Z8 = 0  THEN  GET A$: GOTO 1860
  179. 1790  REM 
  180. 1800  REM  *FLASH NEW MEMBER*
  181. 1810  REM 
  182. 1820  VTAB (Z8): HTAB (30): PRINT "                     ";: FOR Q = 1 TO 500: NEXT 
  183. 1830  VTAB (Z8): HTAB (Z9): PRINT B3$: FOR Q = 1 TO 100: IF  PEEK(49152) >128 GOTO 1860
  184. 1840  NEXT 
  185. 1850  GOTO 1810
  186. 1860  FOR Q = 1 TO 500: NEXT : HOME 
  187. 1870  REM 
  188. 1880  REM  ------------------
  189. 1890  REM 
  190. 1900  PRINT : PRINT  CHR$(4);"BYE"
  191. 1910  REM 
  192. 1920  REM  ------------------
  193. 1930  REM  ------------------
  194. 1940  REM 
  195. 1950  REM  "TRIVIAL SHUFFLE"
  196. 1960  REM 
  197. 1970  REM  ------------------
  198. 1980  REM 
  199. 1990  REM   SAMUEL W. DAVIS
  200. 2000  REM  2341 McCOIG AVENUE
  201. 2010  REM  LAS VEGAS, NEVADA
  202. 2020  REM        89119
  203. 2030  REM 
  204. 2040  REM  ------------------
  205. 2050  REM 
  206. 2060  REM  (702) 736-0072
  207. 2070  REM 
  208. 2080  REM  ------------------
  209. 2090  REM