Softdisk G-S 140/SGDS 140.2mg/SDGS.140/B/MMXXIII

Applesoft BASIC Source Code | 1993-04-12 | 23.6 KB | 550 lines | [FC] Applesoft BASIC Program (0x0801)

10  HOME
20  REM  *------------------------*
30  REM  *---                  ---*
40  REM  *--- CROSSROADS MANOR ---*
50  REM  *---                  ---*
60  REM  *------------------------*
70  REM
80  REM
90  REM  *SOME VARIABLES*
100  REM
110  FOR Q = 1 TO 8: READ AA$(Q): NEXT
120  REM
130  DIM HT$(23),LT(23)
140  REM
150  REM  *ACCESS 80-COLUMN*
160  REM
169  ONERR  GOTO 175
170  PRINT  CHR$(4);"PR#3": GOTO 180
175  TEXT : HOME : VTAB 10: PRINT "You need 80 columns to run this program.": PRINT : POKE 1403,10: PRINT "Press a key to exit.": GET A$: PRINT  CHR$(4)"BYE"
180  POKE 216,0
190  GOSUB 4760: REM  *NULL STUFF*
200  GOSUB 910: REM   *GET MATERIAL*
210  GOSUB 4850: REM  *DO PRINTING*
220  GOSUB 4600: REM  *FLIP*
230  GOSUB 4700: REM  *KEY INPUT*
240  REM
250  REM  *STATEMENT CHOICE*
260  REM
270 G2 = 0: GOSUB 4760
280  GOSUB 1050
290  GOSUB 4850
300  GOSUB 4700
310  REM
320  REM  *WANT TO QUIT?*
330  REM
340  IF GG = 27  THEN G2 = 1: GOSUB 4760: GOSUB 4170: GOSUB 4850
350  IF G2 = 1  THEN  GOSUB 4700
360  IF G2 = 1  AND GG = 49  THEN  HOME : PRINT : PRINT  CHR$(4);"BYE"
370  IF G2 = 1  AND GG = 50  THEN  HOME : PRINT : PRINT  CHR$(4);"RUN MANOR.2"
380  IF G2 = 1  AND GG = 51  THEN  GOTO 270
390  IF G2 = 1  THEN  GOTO 350
400  REM
410  REM  *WANT TO MAKE AN ARREST?*
420  REM
430  IF GG = 32  THEN G2 = 2: GOSUB 4760: GOSUB 4260: GOSUB 4850
440  IF G2 = 2  THEN  GOSUB 4700
450  IF G2 = 2  AND GG = 27  THEN  GOTO 270
460  IF G2 = 2  AND (GG <49  OR GG >57)  THEN  GOTO 440
470  IF G2 = 2  THEN  GOSUB 4760: GOSUB 4400: GOSUB 4850
480  IF G2 = 2  THEN  GOSUB 4700
490  IF G2 = 2  AND GG = 32  THEN  HOME : PRINT : PRINT  CHR$(4);"RUN MANOR.2"
500  IF G2 = 2  AND GG = 27  THEN GG = 32: GOTO 430
510  IF G2 = 2  THEN  GOTO 480
520  REM
530  REM  *ACCESSING STATEMENTS*
540  REM
545  IF GG <49  OR GG >57  THEN 300
550  GOSUB 4760
560 G1 = GG -48
570  REM
580  REM  *PAGE #1*
590  REM
600  ON G1 GOSUB 1200,2090,2490,2720,2890,3100,3480,3720,3950
610  REM
620  REM  *PRINT FIRST PAGE*
630  REM
640  GOSUB 4850
650  REM
660  REM  *PAGE #2*
670  REM
680  IF G1 = 1  THEN  GOSUB 4600: GOSUB 4700: GOSUB 4760: GOSUB 1440: GOSUB 4850
690  REM
700  REM  *JUST TWO PAGES*
710  REM
720  IF G1 = 2  THEN  GOSUB 4600: GOSUB 4700: GOSUB 4760: GOSUB 2320: GOSUB 4850: GOSUB 4650: GOSUB 4700: GOTO 270
730  IF G1 = 6  THEN  GOSUB 4600: GOSUB 4700: GOSUB 4760: GOSUB 3300: GOSUB 4850: GOSUB 4650: GOSUB 4700: GOTO 270
740  REM
750  REM  *PAGE #3*
760  REM
770  IF G1 = 1  THEN  GOSUB 4600: GOSUB 4700: GOSUB 4760: GOSUB 1680: GOSUB 4850
780  REM
790  REM  *PAGE #4*
800  REM
810  IF G1 = 1  THEN  GOSUB 4600: GOSUB 4700: GOSUB 4760: GOSUB 1870: GOSUB 4850: GOSUB 4650: GOSUB 4700: GOTO 270
820  REM
830  REM  *JUST ONE PAGE*
840  REM
850  GOSUB 4650: GOSUB 4700: GOTO 270
860  REM
870  END
880  REM
890  REM  *INTRO*
900  REM
910 HT = 9
920  REM
930 HT$(1) = "                   THE INCIDENT AT CROSSROADS MANOR"
940 HT$(3) = "Consider yourself a student in the Criminology Department of the famous"
950 HT$(4) = "Acme Detective and Dry Cleaning School of Lincoln, Nebraska.  As a term"
960 HT$(5) = "final you are being presented with pertinent information concerning a"
970 HT$(6) = "classic murder case that occurred in New York's Catskill Mountains."
980 HT$(7) = "Your challenge is to take these preliminary findings and determine, in"
990 HT$(8) = "fact, the identity of the Killer and, in your own mind, the manner in"
1000 HT$(9) = "which the crime was committed."
1010  RETURN
1020  REM
1030  REM  *MAIN MENU*
1040  REM
1050 HT = 17
1060  REM
1070 HT$(1) = "                    >> REPORTS AND/OR STATEMENTS <<"
1080 HT$(3) = "                    1- Frank W. Pennington, Sheriff"
1090 HT$(5) = "2- Max Faraday, Security Officer    3- James Simpson, Athletic Director"
1100 HT$(7) = "4- Clyde Augger, Cook's Helper      5- Joe MacDougall, Asst. Maintenance"
1110 HT$(9) = "6- Kenneth Mason, Doctor            7- Steven Monroe, Cook"
1120 HT$(11) = "8- Ted Dunbar, Ent. Director        9- Felix Flange, Chief Maintenance"
1130 HT$(13) = "------------------------------------------------------------------------"
1140 HT$(15) = "          { 1-2-3-4-5-6-7-8-9 } For Reports and/or Statements"
1150 HT$(17) = "          <SPACE>  =  Make Arrest           <ESCAPE>  =  Quit"
1160  RETURN
1170  REM
1180  REM  **FRANK PENNINGTON*
1190  REM
1200 HT = 20
1210  REM
1220 HT$(1) = "Preliminary Report: Page 1 of 4.............Frank W. Pennington, Sheriff"
1230 HT$(3) = "This office received a telephone call at approximately 7:15 AM on"
1240 HT$(4) = "Friday, September 17, 1982 from Mr. Max Faraday, Chief Security Officer"
1250 HT$(5) = "of the Crossroads Manor Hotel and Resort.  He reported having heard a"
1260 HT$(6) = "single gunshot within the hotel at 7:00 AM; then the discovery of a"
1270 HT$(7) = "deceased human being on the premises at 7:05 AM.  This office proceeded"
1280 HT$(8) = "on the basis of a probable homicide."
1290 HT$(10) = "In the company of my deputy, Harry Stone, I responded to this call and"
1300 HT$(11) = "arrived at Crossroads Manor at approximately 7:30 AM.  Crossroads Manor"
1310 HT$(12) = "is an expensive resort complex located on two hundred acres of land in"
1320 HT$(13) = "the Catskill Mountains of New York State, approximately six miles from"
1330 HT$(14) = "Pleasantville and within the geographic jurisdiction of this agency."
1340 HT$(15) = "Apart from a few small maintenance buildings, the resort consists of a"
1350 HT$(16) = "single large hotel which houses both guests and staff.  It is a four"
1360 HT$(17) = "story structure with a single story wing which comprises a large ball-"
1370 HT$(18) = "room.  The grounds contain a swimming pool, tennis courts, a skeet"
1380 HT$(19) = "shooting range, a nine-hole golf course, and other features that would"
1390 HT$(20) = "be appropriate to a vacation resort of this kind."
1400  RETURN
1410  REM
1420  REM  *PENNINGTON - PAGE #2*
1430  REM
1440 HT = 20
1450  REM
1460 HT$(1) = "Preliminary Report: Page 2 of 4.............Frank W. Pennington, Sheriff"
1470 HT$(3) = "Deputy Stone and I were met at the front entrance by Max Faraday, who"
1480 HT$(4) = "led us inside and escorted us to the ballroom.  I then observed the body"
1490 HT$(5) = "of Jonathan Sumner, owner and operator of Crossroads Manor, lying on"
1500 HT$(6) = "its back near the center of the room.  A pattern of buckshot from a"
1510 HT$(7) = "shotgun covered the front of the body, extending from the forehead to"
1520 HT$(8) = "the hips.  Although the bleeding was not profuse, spatterings of blood"
1530 HT$(9) = "were observed on the body in the area of the multiple wounds and on the"
1540 HT$(10) = "immediately surrounding floor."
1550 HT$(12) = "The ballroom itself measured forty feet by sixty feet.  Its only en-"
1560 HT$(13) = "trance was a double door leading into the room from the adjacent hall-"
1570 HT$(14) = "way.  A skylight, measuring five feet by five feet, was located in the"
1580 HT$(15) = "center of the fifteen foot ceiling.  At this time the skylight stood"
1590 HT$(16) = "totally open; the hinged glass and window frame had been folded back"
1600 HT$(17) = "and was resting out-of-sight on the rooftop.  There were no furnishings"
1610 HT$(18) = "of any kind in the room since the few things it normally contained had"
1620 HT$(19) = "been packed away several days earlier in anticipation of the resort's"
1630 HT$(20) = "closing for the winter."
1640  RETURN
1650  REM
1660  REM  *PENNINGTON PAGE #3*
1670  REM
1680 HT = 15
1690  REM
1700 HT$(1) = "Preliminary Report: Page 3 of 4.............Frank W. Pennington, Sheriff"
1710 HT$(3) = "Our examination of this room revealed no signs of a struggle, no scuffs"
1720 HT$(4) = "or marks of any kind on the floor or the walls, or in the hallway out-"
1730 HT$(5) = "side the room.  A double-barreled 12-gauge shotgun, identified as being"
1740 HT$(6) = "the property of Jonathan Sumner, was found lying on the floor about"
1750 HT$(7) = "twenty-five feet from the body.  One of the chambers was empty and the"
1760 HT$(8) = "other contained a spent shell.  There was a definite smell of burned"
1770 HT$(9) = "gunpowder in the room."
1780 HT$(11) = "Two men from the County Coroner's Office arrived and the body of Jona-"
1790 HT$(12) = "than Sumner was removed from the scene at approximately 8:20 AM.  It"
1800 HT$(13) = "was noted that it was unnecessary to mark the body's location on the"
1810 HT$(14) = "floor since the spatterings of blood formed a clear outline of the"
1820 HT$(15) = "body's position."
1830  RETURN
1840  REM
1850  REM  *PENNINGTON PAGE #4*
1860  REM
1870 HT = 19
1880  REM
1890 HT$(1) = "Preliminary Report: Page 4 of 4.............Frank W. Pennington, Sheriff"
1900 HT$(3) = "We were informed that the last guests had checked out of the hotel"
1910 HT$(4) = "shortly after Labor Day, and since that time the staff's activities had"
1920 HT$(5) = "been concerned with preparing the complex for its seasonal shutdown."
1930 HT$(6) = "The staff had been reduced to a skeleton crew, and since 4:00 PM the"
1940 HT$(7) = "previous day only nine people, including Jonathan Sumner, had been pre-"
1950 HT$(8) = "sent on the grounds."
1960 HT$(10) = "We were able to immediately rule out suicide.  To commit suicide with a"
1970 HT$(11) = "shotgun would require the weapon to be discharged at very close range"
1980 HT$(12) = "and the body would have been torn apart.  It was obvious that the"
1990 HT$(13) = "Killer of Jonathan Sumner had to be one of the remaining staff members."
2000 HT$(15) = "We immediately interrogated each of the eight suspects as to their act-"
2010 HT$(16) = "ivities and whereabouts during the preceding day and up to the time of"
2020 HT$(17) = "the body's discovery this morning.  We were subsequently able to inde-"
2030 HT$(18) = "pendently verify as true all details of the suspects' statements that"
2040 HT$(19) = "were capable of being independently verified."
2050  RETURN
2060  REM
2070  REM  *MAX FARADAY*
2080  REM
2090 HT = 18
2100  REM
2110 HT$(1) = "Statement: Page 1 of 2.....................Max Faraday, Security Officer"
2120 HT$(3) = "I spent yesterday checking the various security devices on the grounds."
2130 HT$(4) = "The gates and fence were in good repair.  All locks seemed to be in good"
2140 HT$(5) = "shape.  On Sumner's specific instructions, I left the skylight in the"
2150 HT$(6) = "ballroom completely open so that the area could air out before it was"
2160 HT$(7) = "closed and locked today.  The last time I actually saw Sumner was about"
2170 HT$(8) = "3:00 PM when I told him I would be leaving the grounds.  At 3:30 PM I"
2180 HT$(9) = "left and drove six miles to the Pleasantville Sheriff's Office to make"
2190 HT$(10) = "arrangements for them to keep an eye on the place during the off season."
2200 HT$(11) = "When I started to head back I found the battery dead in the truck, so I"
2210 HT$(12) = "called the resort and got Ted Dunbar on the phone.  He met me in town"
2220 HT$(13) = "at about five o'clock and we had a few drinks at Morry's Bar.  We"
2230 HT$(14) = "headed back to the Manor and got there about 6:15 PM.  After dinner I"
2240 HT$(15) = "went to my room and watched some TV.  I made one final security check"
2250 HT$(16) = "through the hotel between ten- and eleven-o'clock.  I was in the ball-"
2260 HT$(17) = "room at about 10:45 PM and everything seemed to be in order at that"
2270 HT$(18) = "time."
2280  RETURN
2290  REM
2300  REM  *FARADAY - PAGE #2*
2310  REM
2320 HT = 13
2330  REM
2340 HT$(1) = "Statement: Page 2 of 2.....................Max Faraday, Security Officer"
2350 HT$(3) = "As usual, when I got back to my room I gave Sumner a call in his room"
2360 HT$(4) = "and informed him that I had completed the check.  We didn't talk very"
2370 HT$(5) = "long because I caught him right in the middle of brushing his teeth."
2380 HT$(6) = "He just said, 'Okay.  See you tomorrow,' or something like that.  I then"
2390 HT$(7) = "went to bed and fell asleep about 11:30 PM.  I woke up about 6:45 AM and"
2400 HT$(8) = "was taking my time getting dressed when I heard the gunshot.  It was ex-"
2410 HT$(9) = "actly seven o'clock.  I grabbed my pants and headed out through the"
2420 HT$(10) = "hotel to investigate.  It took about five minutes to get to the ballroom"
2430 HT$(11) = "area.  As I was approaching the ballroom I saw Ken Mason approaching"
2440 HT$(12) = "from the opposite direction.  We discovered the body together."
2450  RETURN
2460  REM
2470  REM  *JAMES SIMPSON - PAGE #1*
2480  REM
2490 HT = 19
2500  REM
2510 HT$(1) = "Statement: Page 1 of 1..................James Simpson, Athletic Director"
2520 HT$(3) = "I spent most of yesterday working on the tennis courts, getting them in"
2530 HT$(4) = "shape for the winter, and packing things away in the pro shop.  I fin-"
2540 HT$(5) = "ished up about 4:15 PM and went to my room to clean up.  While I was"
2550 HT$(6) = "doing that, I broke a glass in the sink and gashed my left wrist pretty"
2560 HT$(7) = "good.  I couldn't get the bleeding stopped and had to go see Ken Mason."
2570 HT$(8) = "He got it stopped, put a bandage on me and gave me a couple of extra"
2580 HT$(9) = "ones in case it started up again.  I was feeling a little woozy and went"
2590 HT$(10) = "back to my room in hopes of lying down and dozing a little.  Sleeping"
2600 HT$(11) = "was pretty much impossible, however, because Sumner started practicing"
2610 HT$(12) = "with his shotgun at five o'clock.  I went to dinner at 6:30 PM, but de-"
2620 HT$(13) = "cided to skip dessert and went back to my room.  I called Sumner in his"
2630 HT$(14) = "room at about 8:00 PM to see if he had any additional athletic equipment"
2640 HT$(15) = "he wanted me to pack away.  He said that anything he still had he would"
2650 HT$(16) = "be taking back to the city.  I then watched a little TV and went to"
2660 HT$(17) = "sleep about 10:00 PM.  I probably heard the gunshot in the morning, but"
2670 HT$(18) = "it was really shouting voices in the hall that woke me up."
2680  RETURN
2690  REM
2700  REM  *CLYDE AUGGER - PAGE #1*
2710  REM
2720 HT = 12
2730  REM
2740 HT$(1) = "Statement: Page 1 of 1.......................Clyde Augger, Cook's Helper"
2750 HT$(3) = "I'm sure my story is the same as Steve Monroe's.  We laid around in the"
2760 HT$(4) = "sun most of yesterday, then started preparing dinner at about five"
2770 HT$(5) = "o'clock.  Dinner was at six-thirty in the dining room.  Everybody was"
2780 HT$(6) = "there.  I didn't much care for the taste of the strawberry shortcake, so"
2790 HT$(7) = "while everybody else was eating their's, I went and picked up the empty"
2800 HT$(8) = "tray from outside Sumner's door.  Monroe and I then cleaned up the"
2810 HT$(9) = "dining room and kitchen.  I went to bed about 9:00 PM.  A loud boom, the"
2820 HT$(10) = "gunshot I guess, woke me this morning.  That was at seven o'clock.  When"
2830 HT$(11) = "I didn't see Monroe after a while I figured he was still sleeping in his"
2840 HT$(12) = "room.  I woke him at 7:30 AM."
2850  RETURN
2860  REM
2870  REM  *JOE MACDOUGALL - PAGE #1*
2880  REM
2890 HT = 16
2900  REM
2910 HT$(1) = "Statement: Page 1 of 1.............Joe MacDougall, Assistant Maintenance"
2920 HT$(3) = "Felix and I worked together all day yesterday.  Sumner came by about"
2930 HT$(4) = "12:30 PM and talked with Felix; I don't know what about.  I guess that"
2940 HT$(5) = "was the last time I saw Sumner -- alive, that is.  We bent a blade on"
2950 HT$(6) = "the mower while we were cutting the south lawn and I was over in the"
2960 HT$(7) = "machine shop from 5:15 PM to 5:45 PM trying to find a new one.  When I"
2970 HT$(8) = "got back, Felix and I were still able to get the mowing done in time to"
2980 HT$(9) = "get to dinner at 6:30 PM.  I was plenty hungry and could have eaten"
2990 HT$(10) = "seconds on dessert, but Augger ran me out of the room saying he had to"
3000 HT$(11) = "get the area cleaned up.  Felix and I then went to our room.  He watched"
3010 HT$(12) = "some TV; I read a newspaper.  We went to sleep right after the eleven"
3020 HT$(13) = "o'clock news.  I think the sound of the gunshot woke me up this morning."
3030 HT$(14) = "I was just trying to shake myself awake when Felix came into the room"
3040 HT$(15) = "from the hallway and said he thought something had happened.  This was"
3050 HT$(16) = "a few minutes after seven."
3060  RETURN
3070  REM
3080  REM  *KENNETH MASON - PAGE #1*
3090  REM
3100 HT = 18
3110  REM
3120 HT$(1) = "Statement: Page 1 of 2.............................Kenneth Mason, Doctor"
3130 HT$(3) = "I was busy most of yesterday packing up equipment for transport back to"
3140 HT$(4) = "the city.  Flange and MacDougall started cutting the grass outside my"
3150 HT$(5) = "window about 4:00 PM.  Shortly after four-thirty Jim Simpson showed up"
3160 HT$(6) = "and needed some medical attention.  He had accidentally cut his wrist"
3170 HT$(7) = "and was having some trouble getting the bleeding stopped.  I fixed him"
3180 HT$(8) = "up and he was on his way before 5:00 PM.  Flange knocked on my window"
3190 HT$(9) = "about five-fifteen.  I gave him some lemonade out of my refrigerator and"
3200 HT$(10) = "we shot the breeze for about half-an-hour."
3210 HT$(12) = "Oh, yes, I heard Sumner practicing his shotgun-shooting while we were"
3220 HT$(13) = "drinking the lemonade.  He does that at the skeet range right outside"
3230 HT$(14) = "the private entrance to his room; makes it very handy."
3240 HT$(16) = "I went to dinner at 6:30 PM; everybody was there, although Simpson did"
3250 HT$(17) = "leave the table a little early because he still wasn't feeling well."
3260  RETURN
3270  REM
3280  REM  *MASON - PAGE #2*
3290  REM
3300 HT = 14
3310  REM
3320 HT$(1) = "Statement: Page 2 of 2.............................Kenneth Mason, Doctor"
3330 HT$(3) = "After dinner I went back to my office briefly, then went back to my room"
3340 HT$(4) = "and fell asleep shortly after 10:00 PM.  The route from the dining room"
3350 HT$(5) = "to my office takes you right past Sumner's door.  I could hear a TV or"
3360 HT$(6) = "radio playing in there as I went by."
3370 HT$(8) = "I had awoke a few minutes before 7:00 AM and was still lying in bed when"
3380 HT$(9) = "I heard the gunshot.  As I said before, I had often heard Sumner -- and"
3390 HT$(10) = "other people -- shooting outside on the skeet range.  This gunshot ob-"
3400 HT$(11) = "viously came from inside the building.  I got up and immediately left my"
3410 HT$(12) = "room to look around.  In just a few minutes I saw Max Faraday coming"
3420 HT$(13) = "along the hall near the ballroom.  We both discovered the body at the"
3430 HT$(14) = "same time."
3440  RETURN
3450  REM
3460  REM  *STEVEN MONROE - PAGE #1*
3470  REM
3480 HT = 20
3490  REM
3500 HT$(1) = "Statement: Page 1 of 1...............................Steven Monroe, Cook"
3510 HT$(3) = "Clyde Augger and I didn't have much to do yesterday.  We prepared a noon"
3520 HT$(4) = "meal -- just a sort of pickup affair where people can stop by and grab"
3530 HT$(5) = "something if they want it.  Sumner stopped by just a few minutes before"
3540 HT$(6) = "noon and took a sandwich.  Augger and I then sat in the sun reading mag-"
3550 HT$(7) = "azines until 5:00 PM.  I knew the time -- although I checked my watch to"
3560 HT$(8) = "be sure -- because I could hear Sumner start up with his shotgun.  Aug-"
3570 HT$(9) = "ger and I used that as a signal to start preparing the evening meal."
3580 HT$(10) = "After serving everybody in the dining room, I left a tray right outside"
3590 HT$(11) = "Sumner's door at about 6:45 PM -- as was my custom since he always ate"
3600 HT$(12) = "this meal in his room.  The meal was pleasant enough and everybody was"
3610 HT$(13) = "there about an hour.  Oh, Simpson did leave the table a little sooner"
3620 HT$(14) = "than usual.  He had cut his arm earlier in the day and said he was feel-"
3630 HT$(15) = "ing a little weak and wanted to lie down.  We cleaned up after the meal;"
3640 HT$(16) = "then, about 9:00 PM, Augger went to bed.  I went to sleep about"
3650 HT$(17) = "11:00 PM.  I don't remember hearing the gunshot this morning.  But since"
3660 HT$(18) = "I'm a sound sleeper and my room is the furthest one from the ballroom,"
3670 HT$(19) = "that's probably the reason.  Augger woke me at 7:30 AM."
3680  RETURN
3690  REM
3700  REM  *TED DUNBAR - PAGE #1*
3710  REM
3720 HT = 19
3730  REM
3740 HT$(1) = "Statement: Page 1 of 1................Ted Dunbar, Entertainment Director"
3750 HT$(3) = "My stage manager and three stage hands were still on the grounds yester-"
3760 HT$(4) = "day helping me.  We spent most of the day cleaning up the amphitheatre."
3770 HT$(5) = "From 2:00 PM to 4:00 PM we were loading scenery into a large truck that"
3780 HT$(6) = "had been rented for that purpose.  At 4:00 PM the stage manager and crew"
3790 HT$(7) = "left in the truck for the city.  I then got a call from Max Faraday that"
3800 HT$(8) = "he was stuck in Pleasantville.  I stopped by Sumner's office and told"
3810 HT$(9) = "him I'd be gone for a while, then left the grounds about 4:45 PM and met"
3820 HT$(10) = "Faraday in town about five o'clock.  We had a few drinks in a bar, then"
3830 HT$(11) = "got back to the resort about 6:15 PM.  I had dinner in the dining room"
3840 HT$(12) = "with the rest of the staff, except for Sumner who never had an evening"
3850 HT$(13) = "meal with us and preferred to eat in his room.  As was his habit, once"
3860 HT$(14) = "he retired to his room in the early evening, he was seldom seen again"
3870 HT$(15) = "until the next morning.  I don't remember anything unusual at dinner."
3880 HT$(16) = "Simpson did indicate he was feeling poorly.  After dinner I went to my"
3890 HT$(17) = "room and went to sleep about 10:30 PM.  I was woke up by the sound of"
3900 HT$(18) = "the gunshot at seven this morning, same as the rest of the staff."
3910  RETURN
3920  REM
3930  REM  *FELIX FLANGE - PAGE #1*
3940  REM
3950 HT = 18
3960  REM
3970 HT$(1) = "Statement: Page 1 of 1...................Felix Flange, Chief Maintenance"
3980 HT$(3) = "MacDougall and I spent most of yesterday storing away grounds-keeping"
3990 HT$(4) = "equipment.  I talked briefly with Sumner just after the noon hour.  He"
4000 HT$(5) = "wanted to know if we intended to do any more grass-cutting.  In the late"
4010 HT$(6) = "afternoon we spent a couple of hours mowing the large south lawn, just"
4020 HT$(7) = "outside Doc Mason's office.  At maybe ten minutes after five the machine"
4030 HT$(8) = "hit a rock and bent its blade.  MacDougall headed off to the machine"
4040 HT$(9) = "shop behind the amphitheatre to see if he could find a replacement.  I"
4050 HT$(10) = "took the opportunity to have a break and had some lemonade with Doc"
4060 HT$(11) = "Mason.  MacDougall got back with a new blade about 5:45 PM; he'd had to"
4070 HT$(12) = "scrounge through a lot of boxes to find it.  Yeah, I heard Sumner"
4080 HT$(13) = "practicing his skeet shooting at the range, which is just outside his"
4090 HT$(14) = "room on the north side of the hotel.  He does that everyday for about a"
4100 HT$(15) = "half-hour, starting at 5:00 PM.  I had dinner at 6:30 PM; everybody was"
4110 HT$(16) = "there except Sumner.  Then MacDougall and I watched some TV in our room"
4120 HT$(17) = "and went to sleep about 11:30 PM.  The gunshot woke us in the morning."
4130  RETURN
4140  REM
4150  REM  *QUIT ROUTINE*
4160  REM
4170 HT = 6
4180  REM
4190 HT$(2) = "1- Retire in Ignorance"
4200 HT$(4) = "2- Receive Solution"
4210 HT$(6) = "3- Keep Playing"
4220  RETURN
4230  REM
4240  REM  *MAKE ARREST*
4250  REM
4260 HT = 15
4270  REM
4280 HT$(1) = "                         --- MAKE AN ARREST ---"
4290 HT$(3) = "1- Max Faraday, Security Officer    2- James Simpson, Athletic Director"
4300 HT$(5) = "3- Clyde Augger, Cook's Helper      4- Joe MacDougall, Asst. Maintenance"
4310 HT$(7) = "5- Kenneth Mason, Doctor            6- Steven Monroe, Cook"
4320 HT$(9) = "7- Ted Dunbar, Ent. Director        8- Felix Flange, Chief Maintenance"
4330 HT$(11) = "-----------------------------------------------------------------------"
4340 HT$(13) = "                  { 1-2-3-4-5-6-7-8 }  To Make Arrest"
4350 HT$(15) = "                  { ESCAPE } = Continue Investigation"
4360  RETURN
4370  REM
4380  REM  *EVALUATE ARREST*
4390  REM
4400  IF GG = 50  THEN HT = 8: GOTO 4420
4410 HT = 10
4420 GG = GG -48
4430  REM
4440 HT$(2) = "        -- Making An Arrest! --"
4450 HT$(4) = "      -- >>  " +AA$(GG) +"  << --       "
4460  IF GG = 2  THEN  GOTO 4480
4470 HT$(6) = "        Sorry!  You're Wrong!!": GOTO 4490
4480 HT$(6) = "  You Got Him.  Put The Cuffs On Him."
4490 HT$(8) = "   { SPACE } = Detailed Explanation"
4500  IF GG = 2  THEN  GOTO 4520
4510 HT$(10) = "       { ESCAPE } = Keep Playing"
4520  RETURN
4530  REM
4540  REM  *MAKE CLICK*
4550  REM
4560  FOR AB = 1 TO 4:BU =  PEEK(49200): NEXT : RETURN
4570  REM
4580  REM  *FLIP INSTRUCTION*
4590  REM
4600  VTAB (VV): POKE 36,H +ZZ -26: PRINT "{ Press <SPACE> For More }"
4610  RETURN
4620  REM
4630  REM  *CHOICE INSTRUCTION*
4640  REM
4650  VTAB (VV): POKE 36,H +ZZ -23: PRINT "{ END - Press <SPACE> }"
4660  RETURN
4670  REM
4680  REM  *KEY INPUT*
4690  REM
4700  POKE 49168,0: VTAB (VV): POKE 36,H +ZZ +1: GET A$
4710 GG =  PEEK(49152)
4720  RETURN
4730  REM
4740  REM  *NULL STUFF*
4750  REM
4760  FOR Q = 1 TO 23
4770 HT$(Q) = ""
4780 LT(Q) = 0
4790  NEXT
4800 ZZ = 0
4810  RETURN
4820  REM
4830  REM  *BOX PRINTING ROUTINE*
4840  REM
4850  HOME : PRINT :HT = HT +3
4860  REM
4870  REM  *MEASURE LENGTH OF
4880  REM        LONGEST LINE*
4890  REM
4900  FOR Q = 1 TO HT
4910 LT(Q) =  LEN(HT$(Q))
4920  IF LT(Q) >ZZ  THEN ZZ = LT(Q)
4930  NEXT
4940  REM  *FIND UPPER LEFT
4950  REM   80-COLUMN START*
4960  REM
4970 V =  INT(13 -(HT/2))
4980 H =  INT(39 -(ZZ/2))
4990  REM
5000  REM  *MEASURE FOR INSTRUCTION*
5010  REM
5020 VV = V +(HT -2)
5030 HH = ZZ -20
5040  REM
5050  REM  *DRAW HORIZONTAL
5060  REM      TOP & BOTTOM*
5070  REM
5080  FOR Q = V TO (V +HT)  STEP HT -1
5090  FOR Z = (H -1) TO (H +ZZ +4)
5100  VTAB (Q): POKE 1403,(Z -1): PRINT "";
5110  NEXT Z: NEXT Q
5120  REM
5130  REM  *DRAW VERTICAL SIDES*
5140  REM
5150  FOR Q = V +1 TO (V +HT -2)
5160  VTAB (Q): POKE 1403,(H -2): PRINT "|";: POKE 1403,(H +ZZ +2): PRINT "|";
5170  NEXT
5180  REM
5190  REM  *PRINT CONTENTS
5200  REM           OF BOX*
5210  REM
5220 Z = 1
5230  GOSUB 4560: REM  - CLICK
5240  FOR Q = (V +1) TO (V +HT -1)
5250  VTAB (Q): POKE 1403,(H +1): PRINT HT$(Z);
5260 Z = Z +1
5270  NEXT
5280  GOSUB 4560: REM  - CLICK
5290  RETURN
5300  REM
5310  REM  *END OF PRINTING ROUTINE*
5320  REM
5330  REM  *DATA ON NAMES*
5340  REM
5350  DATA  "Max Faraday","James Simpson","Clyde Augger","Joe MacDougall","Kenneth Mason","Steven Monroe","Ted Dunbar","Felix Flange"
5360  REM
5370  REM  --------------------
5380  REM
5390  REM   SAMUEL W. DAVIS
5400  REM   2341 MCCOIG AVENUE
5410  REM   LAS VEGAS, NEVADA
5420  REM   89119
5430  REM
5440  REM   1-702-736-0072
5450  REM
5460  REM  --------------------
5470  REM