home *** CD-ROM | disk | FTP | other *** search
/ Softdisk G-S 103 / SGDS 103.2mg / SDGS.103 / SDA103 / A / WORDCASTLE.EDIT (.txt) < prev    next >
Encoding:
Applesoft BASIC Source Code  |  1990-03-16  |  7.7 KB  |  247 lines  |  [FC] Applesoft BASIC Program (0x0801)
  1. 0  POKE 32,0: POKE 33,40
  2. 1  LOMEM: 26112
  3. 2  PRINT  CHR$(21)
  4. 3 LD% = 0:NF = 0
  5. 4 CU$ = "2343":ES$ = "$ !" + CHR$(34) +"! "
  6. 5  DIM WD$(32),WA$(40),AL$(26),NU%(10),CA$(80),NW%(80),WF%(40),BA%(16,5),TUNE%(24,1),IW$(32),NO%(12)
  7. 11  FOR I = 1 TO 40:U$ = U$ + CHR$(24 +32): NEXT I
  8. 12  HCOLOR= 7: HPLOT 0,184 TO 279,184: HCOLOR= 6: FOR I = 185 TO 191: HPLOT 0,I TO 279,I: NEXT I
  9. 13  HCOLOR= 0: COLOR= 0
  10. 14  GOSUB 1300
  11. 15  GOSUB 7000
  12. 20  ONERR  GOTO 20000
  13. 60 A$ = "Word Castle Editor": VTAB 1: HTAB 1: FOR I = 1 TO  LEN(A$): PRINT  MID$ (A$,I,1);: POKE 768,8: POKE 769,4: CALL 770: NEXT 
  14. 62  VTAB 2: HTAB 1: PRINT "   (c) 1990 by Softdisk, Incorporated.  "
  15. 75  POKE 34,3: POKE 35,24: POKE 32,0: POKE 33,40: VTAB 1: HTAB 20: PRINT "            Main Menu"
  16. 76  HCOLOR= 6: HPLOT 0,18 TO 279,18
  17. 77  FOR I = 4 TO 23: VTAB I: HTAB 1: PRINT  SPC( 40);: NEXT I
  18. 80 V = 5:H = 5:WW = 30:WH = 14: GOSUB 1000
  19. 90  POKE 49168,0
  20. 95  PRINT "You may do the following:"
  21. 96  PRINT : PRINT "Edit List": PRINT : PRINT "Change current list name"
  22. 97  PRINT : PRINT "Play Word Castle"
  23. 98  VTAB 15: HTAB 1: PRINT "Use arrow keys to choose": PRINT "and hit RETURN when choice": PRINT "is underlined."
  24. 99 A = 1
  25. 100  VTAB 7 +A *2: HTAB 1: COLOR= 3: PRINT  LEFT$(U$,9 +(A = 3) *7 +(A = 2) *15): COLOR= 0
  26. 105  WAIT  -16384,128:A$ =  CHR$( PEEK( -16384) -128): POKE  -16368,0
  27. 107  IF A$ =  CHR$(27)  THEN 8000
  28. 110  IF A$ =  CHR$(8)  OR A$ =  CHR$(11)  THEN  VTAB 7 +A *2: PRINT  SPC( 27):A = A -1: IF A <1  THEN A = 3
  29. 115  IF A$ =  CHR$(21)  OR A$ =  CHR$(10)  THEN  VTAB 7 +A *2: PRINT  SPC( 27):A = A +1: IF A >3  THEN A = 1
  30. 120  IF A$ =  CHR$(13)  THEN 140
  31. 125  IF A$ < > CHR$(21)  AND A$ < > CHR$(8)  AND A$ < > CHR$(11)  AND A$ < > CHR$(10)  THEN  FOR I = 0 TO 10:SO =  PEEK( -16336): NEXT 
  32. 130  GOTO 100
  33. 140  ON A GOTO 4150,2000,8000
  34. 557  REM  ==================
  35. 558  REM  GOOD INPUT ROUTINE
  36. 559  REM  ==================
  37. 560  COLOR= 3: PRINT  CHR$(34);: COLOR= 0:CM$ = ""
  38. 565 PV =  PEEK(37) +1:PH =  PEEK(36) +1
  39. 567  PRINT  SPC( 32)
  40. 570  VTAB PV: HTAB PH + LEN(CM$)
  41. 571  FOR BV = 1 TO  LEN(CU$): COLOR= 3: PRINT  MID$ (CU$,BV,1) CHR$(8);: COLOR= 0: FOR ZZ = 1 TO 10: IF  PEEK(49152) <128  THEN  NEXT : NEXT : GOTO 571
  42. 574 G$ =  CHR$( PEEK( -16384) -128): POKE  -16368,0: IF  ASC(G$) = 13  THEN 690
  43. 575 XX =  RND(1)
  44. 580  IF  ASC(G$) < >8  AND G$ < >""  THEN 625
  45. 590  IF  LEN(CM$) <1  THEN CM$ = "": GOTO 570
  46. 600  IF  LEN(CM$) = 1  THEN CM$ = "": GOTO 620
  47. 610 CM$ =  LEFT$(CM$, LEN(CM$) -1)
  48. 620  HTAB PH + LEN(CM$): PRINT "  ";: GOTO 570
  49. 625  IF G$ =  CHR$(27)  THEN CM$ = "": GOTO 690
  50. 630  IF  ASC(G$) <65  THEN  GOSUB 700: GOTO 570
  51. 633  IF G$ >"Z"  THEN G$ =  CHR$( ASC(G$) -32)
  52. 635  IF G$ <"A"  OR G$ >"Z"  THEN  GOSUB 700: GOTO 570
  53. 650 CM$ = CM$ +G$
  54. 660  PRINT G$;
  55. 670  IF  LEN(CM$) >15  THEN CM$ =  LEFT$(CM$,15)
  56. 680  GOTO 570
  57. 690  PRINT : RETURN 
  58. 699  REM <CTRL-0x0a>beep at 'em
  59. 700  POKE 768,96: POKE 769,3: CALL 770: RETURN 
  60. 998  PRINT 
  61. 999  GOTO 999
  62. 1000  COLOR= 3: VTAB V: HTAB H: PRINT  CHR$(28 +32);: VTAB V +WH -1: HTAB H: PRINT  CHR$(29 +32);: VTAB V: HTAB H +WW -1: PRINT  CHR$(30 +32);: VTAB V +WH -1: HTAB H +WW -1: PRINT  CHR$(31 +32);: COLOR= 0
  63. 1010  IF WW >2  THEN  COLOR= 3: FOR I = 1 TO WW -2: VTAB V: HTAB H +I: PRINT  CHR$(32 +24);: VTAB V +WH -1: HTAB H +I: PRINT  CHR$(25 +32);: POKE 768,I *2: POKE 769,2: CALL 770: NEXT I: COLOR= 0
  64. 1020  IF WH >2  THEN  COLOR= 3: FOR I = 1 TO WH -2: VTAB V +I: HTAB H: PRINT  CHR$(26 +32);: VTAB V +I: HTAB H +WW -1: PRINT  CHR$(27 +32);: NEXT I: COLOR= 0
  65. 1025  POKE 34,V: POKE 32,H: POKE 35,V +WH -2: POKE 33,WW -2: VTAB V +1: HTAB 1: FOR I = 1 TO WH -2: PRINT  SPC( WW -2);: NEXT I: VTAB V +1: HTAB 1
  66. 1030  RETURN 
  67. 1300  FOR I = 810 TO 815: READ PP: POKE I,PP: NEXT I
  68. 1310  RETURN 
  69. 1320  DATA   169,32,32,0,112,96 
  70. 1400 NN = 24
  71. 1405  FOR I = 1 TO NN: IF TU%(I,0) = 0  THEN  FOR WA = 1 TO 200: NEXT I: GOTO 1420
  72. 1410  POKE 768,TU%(I,0): POKE 769,TU%(I,1): CALL 770
  73. 1420  NEXT I: RETURN 
  74. 2000  POKE 34,3: POKE 35,24: POKE 32,0: POKE 33,40
  75. 2002  VTAB 1: HTAB 20: PRINT "     Change List Name"
  76. 2005  PRINT  CHR$(4)"opencurrentlistname"
  77. 2006  PRINT  CHR$(4)"readcurrentlistname"
  78. 2007  INPUT CN$
  79. 2008  PRINT  CHR$(4)"close"
  80. 2010  FOR I = 5 TO 18: VTAB I: HTAB 1: PRINT  SPC( 34);: NEXT I
  81. 2022  VTAB 4: HTAB 2: PRINT "Current name: "CN$
  82. 2030  IF NF = 0  THEN  GOSUB 4600
  83. 2033  GOSUB 4675
  84. 2035 MS$ = "Which file to get words from?": GOSUB 5000
  85. 2036  IF G$ =  CHR$(27)  THEN 75
  86. 2039 CM$ = CA$(A)
  87. 2040  PRINT  CHR$(4)"OPEN CURRENTLISTNAME"
  88. 2050  PRINT  CHR$(4)"WRITE CURRENTLISTNAME"
  89. 2060  PRINT CM$
  90. 2070  PRINT  CHR$(4)"CLOSE CURRENTLISTNAME"
  91. 2080  GOTO 75
  92. 4000  REM 
  93. 4150  POKE 34,3: POKE 35,24: POKE 32,0: POKE 33,40
  94. 4160  FOR I = 5 TO 18: VTAB I: HTAB 1: PRINT  SPC( 34);: NEXT I
  95. 4163  IF NF = 0  THEN  GOSUB 4600
  96. 4165  GOSUB 4660
  97. 4170  VTAB 5: HTAB 5: PRINT "Enter name of file to load,": VTAB 6: HTAB 5: PRINT "Type 'DELETE' to delete a file,": VTAB 7: HTAB 5: PRINT "or RETURN to make a new file.": VTAB 8: HTAB 4: GOSUB 560
  98. 4180  VTAB 5: HTAB 4: PRINT  SPC( 145);
  99. 4182  FOR I = 0 TO NW:WA$(I) = "": NEXT :NW = 0
  100. 4185  IF CM$ = "DELETE"  THEN 5500
  101. 4190  IF CM$ < >""  THEN 4230
  102. 4192  IF G$ =  CHR$(27)  THEN 75
  103. 4195  IF NF >9  THEN  VTAB 6: HTAB 4: PRINT "There are already ten files.": GOTO 4150
  104. 4200  VTAB 6: HTAB 4: PRINT "Enter name for new file.": HTAB 4: PRINT "RETURN alone aborts.": HTAB 4: GOSUB 560
  105. 4210  VTAB 6: HTAB 1: PRINT  SPC( 119);: IF CM$ = ""  THEN  VTAB 6: HTAB 3: PRINT "No file selected--return to Menu.": FOR I = 160 TO 20  STEP  -4: POKE 768,I: POKE 769,4: CALL 770: NEXT I: VTAB 6: HTAB 3: PRINT  SPC( 36);: GOTO 75
  106. 4220  GOTO 4300
  107. 4230  FOR I = 1 TO NF: IF CM$ = CA$(I)  THEN 4250
  108. 4240  NEXT I:CM$ = "": GOTO 4210
  109. 4250  VTAB 3: HTAB 1: PRINT : PRINT  CHR$(4)"OPEN "CM$
  110. 4260  PRINT  CHR$(4)"READ "CM$
  111. 4270  INPUT NW
  112. 4280  FOR I = 1 TO NW: INPUT WA$(I): NEXT I
  113. 4290  PRINT  CHR$(4)"CLOSE "CM$
  114. 4300  POKE 34,3: POKE 35,24: POKE 32,0: POKE 33,40
  115. 4303 FI$ = CM$
  116. 4305  VTAB 1: HTAB 20: PRINT "       Word List Edit"
  117. 4307  FOR I = 4 TO 23: VTAB I: HTAB 1: PRINT  SPC( 40);: NEXT I
  118. 4310 V = 6:H = 2:WW = 38:WH = 12: GOSUB 1000
  119. 4314  POKE 32,0: POKE 33,40
  120. 4315 V = 20:H = 1:WW = 40:WH = 4: GOSUB 1000
  121. 4320 TL = 1:BL = 10:ED = 0:CP = 1
  122. 4340  PRINT "C)hange word, Arrow keys move cursor, D)elete word, Q)uit & save, ESC Exits."
  123. 4345  POKE 34,6: POKE 32,2: POKE 35,16: POKE 33,38
  124. 4350  FOR I = 0 TO 9: VTAB I +7: HTAB 1
  125. 4355 S$ = " ": IF TL +I >9  THEN S$ = ""
  126. 4360  PRINT S$;TL +I;" ";WA$(TL +I); SPC( 32 - LEN(WA$(TL +I)));: NEXT I
  127. 4365  VTAB 6 +CP: HTAB 3
  128. 4370  FOR BV = 1 TO  LEN(ES$): COLOR= 3: PRINT  MID$ (ES$,BV,1) CHR$(8);: COLOR= 0: FOR ZZ = 1 TO 10: IF  PEEK(49152) <128  THEN  NEXT : NEXT : GOTO 4370
  129. 4380 A$ =  CHR$( PEEK( -16384) -128)
  130. 4385  IF A$ > = "A"  AND WA$(TL +CP -1) = ""  THEN A$ = "C": GOTO 4450
  131. 4389  POKE 49168,0
  132. 4390  IF (A$ =  CHR$(8)  OR A$ =  CHR$(11))  AND CP >1  THEN  VTAB CP +6: HTAB 3: PRINT " ";:CP = CP -1: GOTO 4365
  133. 4395  IF (A$ =  CHR$(8)  OR A$ =  CHR$(11))  AND TL >1  THEN TL = TL -1:BL = BL -1: GOTO 4350
  134. 4400  IF (A$ =  CHR$(21)  OR A$ =  CHR$(10))  AND (TL +CP -1) < = NW  AND CP <10  THEN  VTAB CP +6: HTAB 3: PRINT " ";:CP = CP +1: GOTO 4365
  135. 4410  IF (A$ =  CHR$(21)  OR A$ =  CHR$(10))  AND (TL +CP -1) < = NW  AND BL <40  THEN TL = TL +1:BL = BL +1: GOTO 4350
  136. 4420  IF (A$ = "D"  OR A$ = "d")  AND WA$(TL +CP -1) < >""  THEN  FOR I = TL +CP TO NW:WA$(I -1) = WA$(I): NEXT I:WA$(NW) = "":NW = NW -1:ED = 1: GOTO 4350
  137. 4430  IF (A$ = "Q"  OR A$ = "q")  THEN 4470
  138. 4440  IF A$ =  CHR$(27)  THEN 75
  139. 4450  IF (A$ = "C"  OR A$ = "c")  THEN  VTAB 6 +CP: HTAB 3: GOSUB 560: IF CM$ < >""  THEN WA$(CP +TL -1) = CM$:ED = 1: IF NW <TL +CP -1  THEN NW = NW +1
  140. 4455  GOSUB 700
  141. 4460  GOTO 4350
  142. 4470  POKE 34,3: POKE 35,23: POKE 32,0: POKE 33,40: FOR I = 4 TO 23: VTAB I: HTAB 1: PRINT  SPC( 40);: NEXT I
  143. 4475  IF ED = 0  THEN  VTAB 6: HTAB 1: PRINT "No changes to file.": FOR I = 1 TO 20: POKE 768,96: POKE 769,8: CALL 770: POKE 768,72: POKE 769,8: CALL 770: NEXT I: GOTO 75
  144. 4480  VTAB 6: HTAB 1: PRINT "Save as "FI$" (y/n)? ";
  145. 4490  WAIT  -16384,128:A$ =  CHR$( PEEK( -16384) -128): POKE  -16368,0
  146. 4495  VTAB 6: HTAB 1: PRINT  SPC( 75);
  147. 4500  IF A$ = "Y"  OR A$ = "y"  THEN 4520
  148. 4510  IF A$ < >"N"  AND A$ < >"n"  THEN 4480
  149. 4513  VTAB 6: HTAB 1: PRINT  SPC( 75);
  150. 4515  VTAB 6: HTAB 4: PRINT "Enter name of file.": HTAB 4: PRINT "RETURN alone aborts.": HTAB 4: GOSUB 560: IF CM$ = ""  THEN 4210
  151. 4517  FOR A = 1 TO NF: IF FI$ = CA$(A)  THEN  GOSUB 5700: GOTO 4519
  152. 4518  NEXT 
  153. 4519 FI$ = CM$
  154. 4520  VTAB 6: HTAB 1: PRINT  SPC( 100)
  155. 4525  VTAB 6: HTAB 1: PRINT "Saving "FI$"..."
  156. 4527  IF NF = 10  THEN  VTAB 8: HTAB 2: PRINT "ERROR--Already ten spelling files!": FOR I = 160 TO 20  STEP  -4: POKE 768,I: POKE 769,4: CALL 770: NEXT I: GOTO 4690
  157. 4530  PRINT : PRINT  CHR$(4)"OPEN "FI$
  158. 4540  PRINT  CHR$(4)"WRITE "FI$
  159. 4550  PRINT NW
  160. 4560  FOR I = 1 TO NW: PRINT WA$(I): NEXT I
  161. 4570  PRINT  CHR$(4)"CLOSE "FI$
  162. 4575  FOR I = 1 TO NF: IF FI$ = CA$(I)  THEN  GOTO 4000
  163. 4578  NEXT I: GOSUB 4700
  164. 4580  GOTO 75
  165. 4600  PRINT  CHR$(4)"OPEN WORDCASTLE.VTOC"
  166. 4610  PRINT  CHR$(4)"READ WORDCASTLE.VTOC"
  167. 4620  INPUT NF: IF NF = 0  THEN 4640
  168. 4630  FOR I = 1 TO NF: INPUT NO%(I): INPUT CA$(I): NEXT I
  169. 4640  PRINT  CHR$(4)"CLOSE WORDCASTLE.VTOC"
  170. 4650  RETURN 
  171. 4660  COLOR= 3: VTAB 9: HTAB 1: PRINT U$: VTAB 10: HTAB 1: COLOR= 0
  172. 4665  PRINT "Spelling File Catalog"
  173. 4670  VTAB 12: HTAB 1: IF NF = 0  THEN  HTAB 16: PRINT "No files.": RETURN 
  174. 4675  FOR I = 1 TO NF: VTAB 12 +I: HTAB 1: PRINT " "CA$(I)" ": NEXT 
  175. 4676  VTAB 12 +I: HTAB 1: PRINT  SPC( 16)
  176. 4680  RETURN 
  177. 4689  REM  GROSS EXIT BACK TO<CTRL-0x0a>            SPELLING MENU
  178. 4690  FOR I = 4 TO 23: VTAB I: HTAB 1: PRINT  SPC( 40);: NEXT I: GOTO 4000
  179. 4700 NF = NF +1:CA$(NF) = FI$:NO%(NF) = NW
  180. 4705  PRINT 
  181. 4710  PRINT  CHR$(4)"OPEN WORDCASTLE.VTOC"
  182. 4720  PRINT  CHR$(4)"WRITE WORDCASTLE.VTOC"
  183. 4730  PRINT NF
  184. 4740  FOR I = 1 TO NF: PRINT NO%(I): PRINT CA$(I): NEXT I
  185. 4750  PRINT  CHR$(4)"CLOSE WORDCASTLE.VTOC"
  186. 4760  RETURN 
  187. 5000 A = 1
  188. 5003  IF NF = 0  THEN G$ =  CHR$(27): VTAB 12: HTAB 16: PRINT "No files.": FOR I = 0 TO 750: NEXT : RETURN 
  189. 5005  VTAB 6: HTAB 5: PRINT MS$
  190. 5010  VTAB 7: HTAB 4: COLOR= 3: PRINT  CHR$(34): COLOR= 0
  191. 5012  VTAB 9: HTAB 1: COLOR= 3: PRINT "8888888888888888888888888888888888888888";: COLOR= 0
  192. 5015  VTAB 10: HTAB 1: PRINT "Use ";: COLOR= 3: PRINT "(";: COLOR= 0: PRINT "Arrows";: COLOR= 3: PRINT ")";: COLOR= 0: PRINT " to move highlight,"
  193. 5017  VTAB 11: PRINT "RETURN selects, ESC aborts."
  194. 5020  VTAB 12 +A: INVERSE : PRINT " "CA$(A)" ": NORMAL 
  195. 5030  VTAB 7: HTAB 5: PRINT CA$(A); SPC( 16)
  196. 5040  GET G$: VTAB 12 +A: HTAB 1: PRINT " "CA$(A)" "
  197. 5050  IF G$ =  CHR$(8)  OR G$ =  CHR$(11)  THEN A = A -1: IF A <1  THEN A = NF
  198. 5060  IF G$ =  CHR$(10)  OR G$ =  CHR$(21)  THEN A = A +1: IF A >NF  THEN A = 1
  199. 5070  IF G$ =  CHR$(13)  OR G$ =  CHR$(27)  THEN  RETURN 
  200. 5090  GOTO 5020
  201. 5500 MS$ = "Which file to delete?": GOSUB 5000
  202. 5510  IF G$ =  CHR$(27)  THEN 4000
  203. 5610  PRINT  CHR$(4)"delete"CA$(A)
  204. 5630  GOSUB 5700
  205. 5635  GOSUB 4710
  206. 5640  GOTO 75
  207. 5700  FOR I = A TO NF
  208. 5710 CA$(I) = CA$(I +1):NO%(I) = NO%(I +1)
  209. 5720  NEXT :CA$(NF) = "":NO%(NF) = 0
  210. 5730 NF = NF -1
  211. 5740  RETURN 
  212. 6000  POKE  -16368,0
  213. 6004 CH = 18:AD = 1
  214. 6005  COLOR= 3: VTAB V: HTAB H: PRINT  CHR$(CH +32): COLOR= 0
  215. 6007  IF LW <2  THEN  VTAB 18: HTAB 13: PRINT "            "
  216. 6010  IF CH = 18  THEN AD = 1
  217. 6015  IF CH = 20  THEN AD =  -1
  218. 6020 CH = CH +AD
  219. 6030  FOR I = 1 TO 10: IF  PEEK( -16384) >127  THEN 6035
  220. 6032  NEXT I: GOTO 6005
  221. 6035 CH =  PEEK( -16384) -128: POKE  -16368,0
  222. 6040  IF (CH <91  AND CH >64)  THEN  VTAB V: HTAB H: PRINT  CHR$(CH):H = H +1:LW = LW +1: RETURN 
  223. 6045  IF CH = 8  AND LW <2  THEN GW$ = ""
  224. 6046  IF CH = 8  AND LW >1  THEN GW$ =  LEFT$(GW$, LEN(GW$) -1)
  225. 6047  IF CH = 8  AND LW >0  THEN  VTAB V: HTAB H: PRINT " ":H = H -1:LW = LW -1
  226. 6050  IF CH = 13  OR CH = 27  THEN  RETURN 
  227. 6060  GOTO 6004
  228. 7000  FOR I = 1 TO 24: READ TU%(I,0): READ TU%(I,1): NEXT I
  229. 7005  FOR I = 0 TO 16: FOR J = 0 TO 5: READ BA%(I,J): NEXT J,I: RETURN 
  230. 7007  DATA 171,60,144,90,171,30,161,60,144,120,0,0,171,60,144,90,171,30,161,60,144,120,0,0,85,90,85,60,108,60,96,60,108,60,96,60,108,60,85,60,108,60,108,60,96,60,108,255
  231. 7010  DATA 32,32,21,22,32,32,23,32,23,23,32,23,23,23,23,23,23,23,23,23,23,23,23,23
  232. 7020  DATA 32,23,23,23,23,32,32,23,23,23,23,32,32,23,23,23,23,32,32,23,23,23,23,32,32,23,23,23,23,32,32,23,23,23,23,32
  233. 7030  DATA 23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,23,28,30,23,23,23,23,26,27,23,23
  234. 8000  GOSUB 9000: PRINT  CHR$(4)"-WORDCASTLE.PROG"
  235. 8999  REM <CTRL-0x0a>say one moment
  236. 9000  POKE 32,0: POKE 33,40: POKE 34,2: POKE 35,24:V = 11:H = 14:WW = 12:WH = 3: GOSUB 1000: POKE 34,2: POKE 35,23: POKE 32,0: POKE 33,40: VTAB 12: HTAB 15: PRINT "One moment";: RETURN 
  237. 9998  REM   DRAWS WHOLE CASTLE (TEST)
  238. 9999  FOR I = 0 TO 16: FOR J = 0 TO 5: VTAB I +7: HTAB J +31: PRINT  CHR$(BA%(I,J));: NEXT J,I
  239. 20000  REM  error
  240. 20010  POKE 216,0
  241. 20020  TEXT : HOME : PRINT "THERE WAS AN ERROR."
  242. 20030  PRINT : PRINT "PRESS A KEY TO GO TO SOFTDISK MENU."
  243. 20040  GET A$: PRINT  CHR$(4)"bye"
  244. 60000  HGR2 : HCOLOR= 6: HPLOT 140,80: CALL 62454: VTAB 12: HTAB 10: PRINT "Hit any key to boot"
  245. 60005  POKE  -16368,0
  246. 60010  REM  GETA$:PR#6
  247. 60020  GOTO 60020