home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 568a.lha / MemMan / MemMan.asm < prev    next >
Encoding:
Assembly Source File  |  1991-11-08  |  6.9 KB  |  287 lines
  1. ********************************************************************
  2. *
  3. *                                  MemMan
  4. *                            Low-Memory manager
  5. *                       Copyright (C) 1991 Bryan Ford
  6. *
  7. *
  8. * This source code may be freely distributed as long as it is complete (see
  9. * MemMan.doc for the required files), all of the files are unmodified, and no
  10. * charge is made for such distribution other than a small fee to cover the
  11. * cost of copying (no profit may be made through distribution of this
  12. * program).  You may modify this code for your own personal use, but you may
  13. * not distribute modified versions.  (Just send your improvements back to me
  14. * - I'll incorporate them in the master, of course giving credit to you, and
  15. * that way we won't have hundreds of different versions floating around.)
  16. * 
  17. * You may use the object code derived from this (or your own modified version
  18. * of this) source code in your own public domain, freeware, or shareware
  19. * programs (programs that are distributed on similar terms to this source
  20. * code), as long as you mention the use of MemMan and its author (me)
  21. * somewhere in your documentation.  You do not need to obtain any kind of
  22. * license in this case.
  23. * 
  24. * If you wish to distribute MemMan (or any modified variation of it), in
  25. * either source or object form, with a commercial package, you must obtain my
  26. * written permission.  (Don't worry, I'm not starving at this point - a
  27. * license will be very cheap, most likely consisting simply of a copy of the
  28. * program you're using it in.)
  29. *
  30. ********************************************************************
  31. *
  32. * Assemble with A68k version >2.71.
  33. *
  34.  
  35.     include "exec/types.i"
  36.     include "exec/lists.i"
  37.     include "exec/ables.i"
  38.     include "exec/memory.i"
  39.     include "exec/libraries.i"
  40.     include "exec/semaphores.i"
  41.     include "exec/funcdef.i"
  42.     include "exec/exec_lib.i"
  43.     include "bry/macros.i"
  44.     include "bry/memman.i"
  45.  
  46.  STRUCTURE    MemManSem,SS_SIZE    ; SignalSemaphore
  47.     UWORD    mms_AppCount        ; Number of apps using MemMan now
  48.     STRUCT    mms_MMList,MLH_SIZE    ; List we link MMNodes onto
  49.     LABEL    mms_Code        ; Copied MemMan library code
  50.     ; Structure is continued farther down...
  51.  
  52.     code    text
  53.  
  54.     xdef    MMInit,MMFinish,MMAddNode,MMRemNode
  55.     xdef    _MMInit,_MMFinish,_MMAddNode,_MMRemNode
  56.  
  57. * This code is copied into the global MemManSem structure.
  58. * The first six bytes are overwritten with a JMP instruction
  59. * whenever MemMan is not in use.
  60. * Immediately after that is the old AllocMem vector
  61. * (last part of the JSR instruction).
  62. * Yup, self-modifying code - isn't it wonderful? :-)
  63. * This makes each AllocMem() call slightly faster and should be OK if we
  64. * are careful of the caches.
  65. codest:
  66.     push.l    d0/d1            ; Save registers (4 bytes of code)
  67.     
  68. jsrinst:
  69.     jsr    $12345678        ; Call regular AllocMem() (2 + 4 bytes)
  70.     tst.l    d0
  71.     bz.s    \failed
  72.     
  73.     addq.l    #8,sp            ; Succeeded on the first try
  74.     rts
  75.     
  76. \failed:
  77.     push.l    a2-a3
  78.     move.l    codest-mms_Code+mms_MMList+LH_HEAD(pc),a2
  79.     move.l    jsrinst+2(pc),a3
  80.     
  81.     FORBID
  82.     
  83. \retry:
  84.     move.l    LN_SUCC(a2),d1        ; Traverse the list forwards
  85.     bz.s    \fin            ; (kill HIGHEST priority nodes first)
  86.     
  87.     move.l    mmn_GetRidFunc(a2),a1    ; Call the GetRidFunc
  88.     move.l    mmn_GetRidData(a2),a0
  89.     move.l    d1,a2            ; Find next node BEFORE call
  90.     movem.l    8(sp),d0/d1
  91.     jsr    (a1)
  92.     
  93.     movem.l    8(sp),d0/d1        ; Try allocating again
  94.     jsr.l    (a3)
  95.     tst.l    d0
  96.     bz.s    \retry
  97.     
  98. \fin:
  99.     push.l    d0-d1/a0-a1        ; Some nasty apps rely on d1/a0/a1...
  100.     PERMIT
  101.     pop.l    d0-d1/a0-a1/a2-a3
  102.     addq.l    #8,sp            ; Pop AllocMem args off stack
  103.     rts
  104.  
  105. semname:
  106.     dc.b    "MemMan",0
  107.     ds.w    0
  108.  
  109. codefin:
  110.  
  111.     ; Continuation of MemManSem structure
  112.     STRUCT    mms_Code_def2,(codefin-codest)
  113.     LABEL    mms_SIZEOF
  114.  
  115. *** Initialize MemMan - patches AllocMem()
  116. * Returns:
  117. * d0 = Nonzero if successful, zero if failed
  118. MMInit:
  119. _MMInit:
  120.     push.l    a5/a6
  121.     move.l    4,a6
  122.     
  123.     lea    semname(pc),a1        ; See if the semaphore already exists
  124.     jsr    _LVOFindSemaphore(a6)
  125.     move.l    d0,semaphore
  126.     bnz    \oldsem
  127.     
  128.     ; There is the very slight chance we could get two MemMan semaphores
  129.     ; at once.  Who cares?  Nothing terrible would happen anyway.
  130. \newsem:
  131.     move.l    #mms_SIZEOF,d0        ; Allocate the public memory block
  132.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1
  133.     jsr    _LVOAllocMem(a6)
  134.     move.l    d0,semaphore
  135.     bz    \out
  136.     move.l    d0,a5
  137.     
  138.     lea    mms_MMList(a5),a0    ; Initialize the data area
  139.     NEWLIST    a0
  140.     move.w    #1,mms_AppCount(a5)
  141.     lea    mms_Code+(semname-codest)(a5),a0
  142.     move.l    a0,LN_NAME(a5)
  143.     
  144.     lea    codest(pc),a0        ; Copy the public code
  145.     lea    mms_Code(a5),a1
  146.     move.l    #codefin-codest,d0
  147.     jsr    _LVOCopyMem(a6)
  148.     
  149.     FORBID                ; No AllocMem()s in here please
  150.     
  151.     move.l    a6,a1            ; SetFunction AllocMem()
  152.     lea    mms_Code(a5),a0
  153.     move.l    a0,d0
  154.     movea.w    #_LVOAllocMem,a0
  155.     jsr    _LVOSetFunction(a6)
  156.     
  157.     move.l    d0,mms_Code+(jsrinst-codest)+2(a5)    ; Set JSR vector
  158.     
  159.     cmpi.w    #36,LIB_VERSION(a6)    ; Clear the cache after setting vector
  160.     blo.s    \newsemcc
  161.     jsr    _LVOCacheClearU(a6)
  162. \newsemcc:
  163.     PERMIT
  164.     
  165.     move.l    a5,a1            ; Add to system semaphore list
  166.     jsr    _LVOAddSemaphore(a6)
  167.     
  168.     bra    \outok
  169.     
  170. \oldsem:                ; Semaphore was already in memory
  171.     move.l    d0,a5
  172.     
  173.     move.l    d0,a0
  174.     jsr    _LVOObtainSemaphore(a6)
  175.     
  176.     addq.w    #1,mms_AppCount(a5)
  177.     
  178.     cmp.w    #$4ef9,mms_Code(a5)    ; See if we have to reactive the code
  179.     bne.s    \codefine
  180.     
  181.     FORBID                ; No AllocMem()s while we change code
  182.     
  183.     move.l    codest(pc),mms_Code(a5)    ; Restore first six bytes
  184.     move.w    codest+4(pc),mms_Code+4(a5) ; No more or we'll trash the vector
  185.     
  186.     cmpi.w    #36,LIB_VERSION(a6)    ; Clear the cache after changing code
  187.     blo.s    \oldsemcc
  188.     jsr    _LVOCacheClearU(a6)
  189. \oldsemcc:
  190.     
  191.     PERMIT
  192. \codefine:
  193.     
  194.     move.l    a5,a0
  195.     jsr    _LVOReleaseSemaphore(a6)
  196. \outok:
  197.     lea    mms_MMList(a5),a0
  198.     move.l    a0,mmlist
  199.     
  200.     moveq    #1,d0
  201. \out:
  202.     pop.l    a5/a6
  203.     rts
  204.  
  205.  
  206. *** Uninstall our application from the memory manager
  207. MMFinish:
  208. _MMFinish:
  209.     push.l    a5/a6
  210.     move.l    4,a6
  211.     
  212.     move.l    semaphore,d0        ; Never successfully initialized?
  213.     bz    \out
  214.     move.l    d0,a5
  215.     
  216.     move.l    a5,a0
  217.     jsr    _LVOObtainSemaphore(a6)
  218.     
  219.     subq.w    #1,mms_AppCount(a5)
  220.     bnz.s    \otherapps
  221.     
  222.     FORBID                ; No AllocMem()s while we change the code
  223.     
  224.     move.w    #$4ef9,mms_Code(a5)    ; Quick bounce with a JMP instruction
  225.     move.l    mms_Code+(jsrinst-codest)+2(a5),mms_Code+2(a5)
  226.     
  227.     cmpi.w    #36,LIB_VERSION(a6)    ; Clear the cache after changing code
  228.     blo.s    \cc
  229.     jsr    _LVOCacheClearU(a6)
  230. \cc:
  231.     
  232.     PERMIT
  233. \otherapps:
  234.     
  235.     move.l    a5,a0
  236.     jsr    _LVOReleaseSemaphore(a6)
  237.     
  238.     clr.l    semaphore        ; Safety
  239.     
  240. \out:
  241.     pop.l    a5/a6
  242.     rts
  243.  
  244.  
  245. *** Add an MMNode (if it wasn't already on the MMList)
  246. * a1 = Pointer to MMNode
  247. MMAddNode:
  248. _MMAddNode:
  249.     tst.b    mmn_Linked(a1)    ; Don't add a node twice
  250.     bnz.s    9$
  251.     
  252.     st.b    mmn_Linked(a1)    ; Mark it as added
  253.     
  254.     push.l    a6        ; Add it to the global list in prioritized order
  255.     move.l    4,a6
  256.     FORBID
  257.     move.l    mmlist(pc),a0
  258.     jsr    _LVOEnqueue(a6)
  259.     PERMIT
  260.     pop.l    a6
  261.     
  262. 9$    rts
  263.  
  264.  
  265. *** Remove an MMNode (only if it was on the MMList)
  266. * a1 = Pointer to MMNode
  267. MMRemNode:
  268. _MMRemNode:
  269.     tst.b    mmn_Linked(a1)    ; Don't remove unless it was added
  270.     bz.s    9$
  271.     
  272.     clr.b    mmn_Linked(a1)    ; Mark it as not added
  273.     
  274.     push.l    a6        ; Remove it from the public MMList
  275.     move.l    4,a6
  276.     FORBID
  277.     REMOVE
  278.     PERMIT
  279.     pop.l    a6
  280.     
  281. 9$    rts
  282.  
  283. semaphore    ds.l    1        ; Pointer to public semaphore
  284. mmlist        ds.l    1        ; Points to mms_MMList in MemManSem
  285.  
  286.     end
  287.