home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 493.lha / OnTrap / c.a next >
Encoding:
Text File  |  1991-04-06  |  11.7 KB  |  474 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Use the following command line to make c.o
  5. * asm -u -iINCLUDE: c.a
  6. *
  7. * Use the following command line to make cres.o
  8. * asm -u -dRESIDENT -iINCLUDE: -ocres.o c.a
  9. *
  10.     INCLUDE    "exec/types.i"
  11.     INCLUDE    "exec/alerts.i"
  12.     INCLUDE    "exec/nodes.i"
  13.     INCLUDE    "exec/lists.i"
  14.     INCLUDE    "exec/ports.i"
  15.     INCLUDE    "exec/libraries.i"
  16.     INCLUDE    "exec/tasks.i"
  17.     INCLUDE    "exec/memory.i"
  18.     INCLUDE    "exec/execbase.i"
  19.     INCLUDE    "libraries/dos.i"
  20.     INCLUDE    "libraries/dosextens.i"
  21.     INCLUDE    "workbench/startup.i"
  22. FUNCDEF         MACRO   * function
  23. _LVO\1          EQU     FUNC_CNT
  24. FUNC_CNT        SET     FUNC_CNT-6
  25.                 ENDM
  26.  
  27. FUNC_CNT        SET     LIB_NONSTD
  28.  
  29.     INCLUDE    "exec/exec_lib.i"
  30.     INCLUDE    "libraries/dos_lib.i"
  31.  
  32. MEMFLAGS    EQU    MEMF_CLEAR+MEMF_PUBLIC
  33. AbsExecBase    EQU    4
  34.  
  35. ;;;
  36. ;;;   Stack map.
  37. ;;;
  38.       OFFSET  0
  39.            ds.b    4
  40. savereg    ds.b    13*4
  41. stackbtm   ds.b    4
  42.  
  43.  
  44.  
  45. ; some usefull macros:
  46.  
  47. callsys macro
  48.     CALLLIB _LVO\1
  49.     endm
  50.     
  51.     xdef    XCEXIT        * exit(code) is standard way to leave C.
  52.     xdef    @XCEXIT
  53.     
  54.     xref    LinkerDB    * linker defined base value
  55.     xref    _BSSBAS        * linker defined base of BSS
  56.     xref    _BSSLEN        * linker defined length of BSS
  57.     IFD    RESIDENT
  58.     xref    RESLEN
  59.     xref    RESBASE
  60.     xref    NEWDATAL
  61.     xref    _stack
  62.     ENDC
  63.     
  64. *       library references
  65.  
  66.     section text,code
  67.  
  68.     xref    _main            * Name of C program to start with.
  69.     xref    MemCleanup        * Free all allocated memory
  70.     xref    __fpinit        * initialize floating point
  71.     xref    __fpterm        * terminate floating point
  72.  
  73. start:
  74.     movem.l d1-d6/a0-a6,-(a7)       * save registers
  75.  
  76.     move.l  a0,a2            * save command pointer
  77.     move.l  d0,d2            * and command length
  78.     lea     LinkerDB,a4        * load base register
  79.     move.l  AbsExecBase.W,a6
  80.  
  81.     IFND    RESIDENT
  82.     lea     _BSSBAS,a3        * get base of BSS
  83.     moveq   #0,d1
  84.     move.l  #_BSSLEN,d0        * get length of BSS in longwords
  85.     bra.s   clr_lp            * and clear for length given
  86. clr_bss move.l  d1,(a3)+
  87. clr_lp  dbf     d0,clr_bss
  88.     move.l  a7,_StackPtr(A4)       * Save stack ptr
  89.     move.l  a6,SysBase(A4)
  90.     ENDC
  91.     
  92.  
  93.     IFD    RESIDENT
  94.     move.l    d2,-(a7)
  95.     movem.l    a0-a2,-(a7)
  96.  
  97. *------ get the size of the stack, if CLI use cli_DefaultStack
  98. *------                       if WB use a7 - TC_SPLOWER
  99.     move.l    ThisTask(a6),A3
  100.     move.l  pr_CLI(A3),d1
  101.     beq.s   fromwb
  102.     lsl.l    #2,d1
  103.     move.l    d1,a0
  104.     move.l    cli_DefaultStack(a0),d1
  105.     lsl.l    #2,d1            * # longwords -> # bytes
  106.     bra.s    dostack
  107.  
  108. fromwb:
  109.     move.l    a7,d1             
  110.     sub.l    TC_SPLOWER(a3),d1
  111. dostack:
  112.     moveq    #0,d2            * use d2 as flag for newstack or not
  113.     move.l    #RESLEN,d0
  114.     cmp.l    _stack(a4),d1        * This a4 is in the original 
  115.                     * set of data
  116.     bcc.s    nochange    
  117.     move.l    _stack(a4),d1
  118.     add.l    d1,d0            * increase size of mem for new stack
  119.     moveq    #1,d2            * set flag
  120.         
  121. nochange:
  122.     move.l    d1,a3            * save stacksize to set up stack checking
  123.     move.l    #MEMFLAGS,d1
  124.     callsys AllocMem
  125.     tst.l    d0
  126.     bne.s    ok1
  127.     movem.l    (a7)+,d2/a0-a2
  128.     bra.w   return
  129.  
  130. ok1:    move.l    d0,a0
  131.     move.l    d0,a2
  132.  
  133. ;a2 now has difference
  134.     move.l    d0,a1
  135.     move.l    #NEWDATAL,d0
  136.     sub.l    #RESBASE,a4
  137. ;copy data over
  138. cpy:    move.l    (a4)+,(a0)+
  139.     subq.l    #1,d0
  140.     bne.s    cpy
  141. ;a4 now points at number of relocs
  142.     move.l    (a4)+,d0
  143. reloc:  beq.s    nreloc
  144.     move.l    a1,a0
  145.     add.l    (a4)+,a0        * a0 now has add of reloc
  146.     add.l    (a0),a2
  147.     move.l    a2,(a0) 
  148.     move.l    a1,a2            * restore offset
  149.     subq.l    #1,d0
  150.     bra.s    reloc
  151.     
  152. nreloc: move.l    a1,a4            * set up new base register
  153.     add.l    #RESBASE,a4
  154.  
  155.     move.l    #RESLEN,realdatasize(a4)
  156.     movem.l (a7)+,a0-a2
  157.  
  158.     move.l  a6,SysBase(A4)
  159.     tst.b    d2
  160.     movem.l    (a7)+,d2        * restore d2 
  161.     movem.l a7,_StackPtr(A4)    * Save stack ptr (movem doesn't
  162.                     * change flags
  163.     beq.s    nochg2
  164.  
  165. *------ set up new stack
  166.     move.l    a4,d0
  167.     sub.l    #RESBASE,d0
  168.     add.l    #RESLEN,d0
  169.     add.l    _stack(a4),d0        * here a4 will be pointing at the
  170.                     * new data, but _stack will be the
  171.                     * same if all goes well
  172.     sub.l    #128,d0            * 128 down for good measure
  173.     move.l    d0,a7
  174.     move.l    _stack(a4),d0
  175.     move.l    d0,4(a7)        * fill in size of new stack    
  176.     add.l    d0,realdatasize(a4)     * need to know how much to free later
  177.  
  178. nochg2:
  179. *------ Set _base for stack checking
  180.     move.l    a7,d1
  181.     sub.l    a3,d1            * get top of stack
  182.     add.l   #128,D1            * allow for parms overflow
  183.     move.l  D1,_base(A4)        * save for stack checking
  184.  
  185.     ENDC
  186.  
  187. clrwb:
  188.     clr.l   WBenchMsg(A4)
  189.  
  190. *JVP--- get the address of our task
  191.     move.l    ThisTask(a6),A3
  192.  
  193. *JVP--- set up for my very own trap handler
  194.     move.l    TC_TRAPCODE(a3),oldTrapCode(a4)    * save the old trap code
  195.     lea    trapcode,a0        * do something a little less
  196.     move.l    a0,TC_TRAPCODE(a3)    * drastic.
  197.  
  198. *-----  clear any pending signals
  199.     moveq    #0,d0
  200.     move.l    #$00003000,d1
  201.     callsys    SetSignal
  202.     
  203.  
  204. *------ attempt to open DOS library:
  205.     lea     DOSName(PC),A1
  206.     moveq.l #0,D0
  207.     callsys OpenLibrary
  208.     move.l  D0,DOSBase(A4)
  209.     bne.s    ok2
  210.     moveq.l #100,d0
  211.     bra.w   exit2
  212.  
  213. ok2:
  214. *------ are we running as a son of Workbench?
  215.     move.l    ThisTask(a6),A3
  216.     move.l  pr_CurrentDir(A3),curdir(A4)
  217.     tst.l   pr_CLI(A3)
  218.     beq.w  fromWorkbench
  219.     
  220. *=======================================================================
  221. *====== CLI Startup Code ===============================================
  222. *=======================================================================
  223. *
  224. * Entry: D2 = command length
  225. *    A2 = Command pointer
  226. fromCLI:
  227.     ifnd    RESIDENT    * we need to set _base if not resident
  228.         move.l  a7,D0           * get top of stack
  229.         sub.l   stackbtm(a7),D0 * compute bottom
  230.         add.l   #128,D0         * allow for parms overflow
  231.         move.l  D0,_base(A4)    * save for stack checking
  232.     endc
  233.     
  234. *------ find command name:
  235.     move.l  pr_CLI(a3),a0
  236.     add.l   a0,a0       * bcpl pointer conversion
  237.     add.l   a0,a0
  238.     move.l  cli_CommandName(a0),a1
  239.     add.l   a1,a1       * bcpl pointer conversion
  240.     add.l   a1,a1
  241.  
  242. *------ collect parameters:
  243.     move.l  d2,d0           * get command line length
  244.     moveq.l #0,d1
  245.     move.b  (a1)+,d1
  246.     move.l  a1,_ProgramName(A4)
  247.     add.l   d1,d0           * add length of command name
  248.     addq.l  #7,d0           * allow for space after command, quotes
  249.                        * and null terminator, as well as 
  250.     andi.w  #$fffc,D0       * force to long word boundary
  251.         move.l   d0,Commandlen(a4)
  252.    
  253.    movem.l  d1/a1,-(a7)
  254.     move.l    #MEMFLAGS,d1
  255.     callsys AllocMem
  256.     movem.l  (a7)+,d1/a1
  257.     tst.l   d0
  258.     bne.s   ok_copy
  259.    
  260.     move.l  #1000,d0        * what should the return code be for out of mem?
  261.     move.l  d0,-(a7)        * put a return code on the stack
  262.     beq.w   nodofree        * Was exitToDOS
  263.    
  264. ok_copy:
  265.     move.l   d0,a0
  266.     move.l   d0,Commandbuf(a4)
  267.          
  268. *------ copy command line into memory
  269.     move.l  d2,d0           * get command line length
  270.     subq.l  #1,d0
  271.     add.l   d1,d2
  272.    
  273. copy_line:
  274.     move.b  0(A2,D0.W),2(A0,D2.W)   * copy command line to stack
  275.     subq.l  #1,d2
  276.     dbf     d0,copy_line
  277.     move.b  #' ',2(a0,d2.w)     * add space between command and parms
  278.     subq.l  #1,d2
  279.     move.b  #'"',2(a0,d2.w)     * add end quote
  280.    
  281. copy_cmd:
  282.     move.b  0(a1,d2.w),1(a0,d2.w)   * copy command name to stack
  283.     dbf     d2,copy_cmd
  284.         move.b  #'"',(a0)
  285.     move.l  A0,-(A7)        * push command line address
  286.     bra.s   main            * call C entrypoint
  287.  
  288. *=======================================================================
  289. *====== Workbench Startup Code =========================================
  290. *=======================================================================
  291.  
  292. fromWorkbench:
  293.  
  294.     ifnd    RESIDENT    * we need to set _base if not resident
  295.         move.l  TC_SPLOWER(a3),_base(A4) * set base of stack
  296.     moveq   #127,d0
  297.     addq.l    #1,d0                    * Efficient way of getting in 128
  298.         add.l   d0,_base(A4)             * allow for parms overflow
  299.     endc
  300.  
  301. *------ we are now set up.  wait for a message from our starter
  302.     lea     pr_MsgPort(A3),a0       * our process base
  303.     callsys WaitPort
  304.     lea     pr_MsgPort(A3),a0       * our process base
  305.     callsys GetMsg
  306.     move.l  d0,WBenchMsg(a4)
  307.     move.l  d0,-(SP)
  308. *
  309.     move.l  d0,a2           * get first argument
  310.     move.l  sm_ArgList(a2),d0
  311.     beq.s   do_cons
  312.     move.l  DOSBase(a4),a6
  313.     move.l  d0,a0
  314.     move.l  wa_Lock(a0),d1
  315.         callsys DupLock
  316.     move.l  d0,curdir(A4)
  317.     move.l  d0,d1
  318.     callsys CurrentDir
  319. do_cons:
  320.     move.l  sm_ToolWindow(a2),d1    * get the window argument
  321.     beq.s   do_main
  322.     move.l  #MODE_OLDFILE,d2
  323.     callsys Open
  324.     move.l  d0,stdin(a4)
  325.     beq.s   do_main
  326.     lsl.l   #2,d0
  327.     move.l  d0,a0
  328.     move.l  fh_Type(a0),pr_ConsoleTask(A3)
  329. do_main:
  330.     move.l  WBenchMsg(A4),a0    * get address of workbench message
  331.     move.l  a0,-(a7)        * push argv
  332.     pea     NULL(a4)        * push argc
  333.     move.l  sm_ArgList(a0),a0       * get address of arguments
  334.     move.l  wa_Name(a0),_ProgramName(A4)       * get name of program
  335.  
  336. *=============================================
  337. *------ common code --------
  338. *=============================================
  339.  
  340. main    jsr     __fpinit(PC)        * Initialize floating point
  341.     jsr     _main(PC)           * call C entrypoint
  342.     moveq.l #0,d0           * set successful status
  343.     bra.s   exit2
  344. *
  345.  
  346. XCEXIT:
  347.     move.l  4(SP),d0        * extract return code
  348. @XCEXIT:
  349. exit2:
  350.         movea.l _StackPtr(a4),a7         * restore stack ptr
  351.     move.l  d0,-(a7)
  352.     move.l  _ONEXIT(A4),d0      * exit trap function?
  353.     beq.s   exit3
  354.     move.l  d0,a0
  355.     jsr     (a0)
  356. exit3:
  357.     jsr     MemCleanup(PC)      * cleanup leftover memory alloc.
  358.     jsr     __fpterm(PC)        * clean up any floating point
  359.  
  360. *------ if we ran from CLI, skip workbench cleanup:
  361.     tst.l   WBenchMsg(A4)
  362.     beq.s   exitToDOS
  363.         move.l  DOSBase(A4),a6
  364.     move.l  stdin(a4),d1
  365.     beq.s   done_4
  366.     callsys Close
  367. done_4:
  368.  
  369. *------ return the startup message to our parent
  370. *       we forbid so workbench can't UnLoadSeg() us
  371. *       before we are done:
  372.         move.l  curdir(a4),d1
  373.         beq.s   done_5
  374.         callsys UnLock
  375. done_5:
  376.     move.l  AbsExecBase.W,A6
  377.     callsys Forbid
  378.     move.l  WBenchMsg(a4),a1
  379.     callsys ReplyMsg
  380.     bra.s   nodofree
  381.  
  382. exitToDOS:
  383. *JVP--- restore original TC_TRAPCODE leaving the shell as it was.
  384.     move.l    ThisTask(a6),a1
  385.     move.l    oldTrapCode(a4),TC_TRAPCODE(a1)    * politely restore this guy.
  386. *------ free the command line buffer
  387.     move.l   Commandlen(a4),d0
  388.     beq.s    nodofree
  389.     move.l   Commandbuf(a4),a1
  390.     move.l  AbsExecBase.W,a6
  391.     callsys FreeMem
  392.    
  393. *------ this rts sends us back to DOS:
  394. nodofree:
  395.     move.l  DOSBase(A4),a1
  396.     callsys CloseLibrary        * close Dos library
  397.  
  398.     IFD    RESIDENT
  399.     move.l    realdatasize(a4),d0
  400.     move.l  a4,a1
  401.     sub.l   #RESBASE,a1
  402.     callsys FreeMem
  403.     ENDC
  404.     move.l  (a7)+,d0
  405.  
  406. return:    
  407.     movem.l (a7)+,d1-d6/a0-a6
  408.     rts
  409.  
  410. *JVP---------------------------------------------------------------------
  411. *  Trap handler. Helps avoid the GURU.
  412.  
  413. trapcode:
  414.         move.l    (sp)+,d0    ; get the trap code off the supervisor stack
  415.                 andi    #$DFFF,SR    ; switch back to Usermode
  416.                 lea     LinkerDB,A4    ; load linker defined base register
  417.                 move.l    d0,_TRAPCODE(A4) ; Make the trap code available to C functions
  418.         move.l    _ONTRAP(A4),d0    ; get the new trap vector
  419.         beq    1$        ; skip C routine call if not supplied
  420.         move.l    d0,a0        ; make it a funtion address
  421.                 jsr     (a0)        ; Let C code clean up.
  422. 1$:        move.l    _TRAPCODE(A4),d0    ; use the trap code as the return code
  423.         add.l    #1000,d0    ; give it an offset to force exit message
  424.                 jmp     exit2        ; exit this error prone program.
  425.  
  426.  
  427. DOSName     dc.b    'dos.library',0
  428.  
  429.     section __MERGED,BSS
  430. *
  431.     xref    DOSBase
  432.  
  433.     xdef    NULL,SysBase,WBenchMsg
  434.     xdef    curdir,_mbase,_mnext,_msize,_tsize
  435.     xdef    _oserr,_OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  436.     xdef    _SIGINT
  437.     xdef    _ProgramName,_StackPtr,_base
  438.  
  439. *JVP--- ontrap externals
  440.     xdef    _ONTRAP,_TRAPCODE
  441. *
  442.     ifd    RESIDENT
  443. realdatasize    ds.b    4    * size of memory allocated for data +
  444.                 * possible stack
  445.     endc
  446.     
  447. NULL        ds.b    4    *
  448. _base        ds.b    4    * base of stack
  449. _mbase        ds.b    4    * base of memory pool
  450. _mnext        ds.b    4    * next available memory location
  451. _msize        ds.b    4    * size of memory pool
  452. _tsize        ds.b    4    * total size?
  453. _oserr        equ     *
  454. _OSERR        ds.b    4
  455. _FPERR        ds.b    4
  456. _SIGFPE        ds.b    4
  457. _SIGINT        ds.b    4
  458. _ONERR        ds.b    4
  459. _ONEXIT        ds.b    4
  460. _ONBREAK    ds.b    4
  461. curdir         ds.b    4
  462. SysBase        ds.b    4
  463. WBenchMsg    ds.b    4
  464. _StackPtr    ds.b    4
  465. stdin        ds.b    4
  466. _ProgramName    ds.b    4
  467. Commandbuf    ds.b    4
  468. Commandlen    ds.b    4
  469. *JVP--- ontrap storage
  470. _ONTRAP         ds.b    4        * my trap handler vector
  471. _TRAPCODE    ds.b    4
  472. oldTrapCode     ds.b    4
  473.         END
  474.