home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 303.lha / AssemTools / Asm65 / Asm65.asm < prev    next >
Encoding:
Assembly Source File  |  1980-12-03  |  93.1 KB  |  4,324 lines
  1. ;
  2. ; ### 65c02 Cross Assembler by JM,TM v 2.352 ###
  3. ;
  4. ; - Created 880425 by JM -
  5. ;
  6. ;
  7. ; Quack!
  8. ;
  9. ; Bugs: Who knows...  Many, many fixed.
  10. ; 
  11. ; * lda #-1-8 causes en ermsg: 8-bit value required
  12. ;
  13. ;
  14. ; Edited:    (Times and dates are UTC)
  15. ;=========
  16. ;
  17. ; - 880425 by JM    -> v0.00    - does not work
  18. ; - 880602 by JM    -> v0.01    - mnemonic table etc.
  19. ; - 880603 by JM,TM -> v0.02    - calc finished, seek_op, amode, slabel
  20. ;                  RELATIVE ADDRESSING???
  21. ; - 880604 by JM,TM -> v0.03    - seek_op finished   ### CPU CARD RUNS! ###
  22. ; - 880605 by JM,TM -> v0.04    - glabel&pass1 written, many Bugs fixed
  23. ; - 880606 by JM    -> v0.05    - pass2 written, many Bugs fixed
  24. ;                - IT COMPILES!!!
  25. ;                - DB, DW, DL
  26. ;                - z also accepted in symbol names
  27. ; - 880607 by JM,TM -> v1.00    - ';' works
  28. ; - 880608 by JM    -> v1.10    - listing file, conv_10
  29. ; - 880609 by JM    -> v1.11    - listing file improved, conv_16, dumplabels
  30. ; - 880610 by JM    -> v1.20    - dumplabels writes to listfile, too
  31. ;                - options allowed on cmd line
  32. ;                - MODE mnemonic added
  33. ;                - usage added
  34. ; - 880610 by JM    -> v1.30    - include added (well, that was a hard one...)
  35. ; - 880611 by JM    -> v1.34    - include edited (that took about one day)
  36. ; - 880611 by JM    -> v1.40    - conditional assembly added
  37. ; - 880611 by JM    -> v1.42    - conditional assembly improved (nesting allowed)
  38. ; - 880615 by JM    -> v1.46    - include nesting file names buffered
  39. ;                - maximum nesting level set to #INCNESTING
  40. ;                - label not found in abs or rel now only
  41. ;                  generates one error message
  42. ;                - started writing macro routines
  43. ; - 880616 by JM    -> v1.47    - FF added to the end of listfile
  44. ; - 880618 by JM    -> v1.48    - getlb written
  45. ;            -> v1.49    - macro routines continued
  46. ;            -> v1.50    - macro routines continued
  47. ;            -> v1.51    - macros work without parameters and nesting
  48. ;            -> v1.52    - macros improved
  49. ; - 880619 by JM    -> v1.57    - macros improved
  50. ;            -> v1.60    - macros: parameters
  51. ;            -> v1.62    - problems...
  52. ; - 880624 by JM,TM -> v1.65    - ifc/ifnc written
  53. ;                - ermsgs added
  54. ;                - ifi/ifni written (TM)
  55. ; - 880624 by JM    -> v1.67    - macros nesting without parameter nesting
  56. ; - 880625 by JM    -> v1.68    - macros nesting with parameter nesting
  57. ;            -> v1.74    - parameter nesting finished; errhandler
  58. ;                  edited
  59. ;            -> v1.75    - @MODE written; glabel now gives an ermsg if
  60. ;                  no symbol name is given
  61. ; - 880626 by JM    -> v1.77    - Big Params allowed in macros
  62. ;            -> v1.90    - It seems to work well.
  63. ;            -> v1.91    - Macros now accept four parameters
  64. ;                - Addresses > $ffff now generate an ermsg
  65. ;            -> v1.92    - Labels also processed on macro usage lines
  66. ; - 880814 by JM    -> v1.93    - Hex mode can now be set in source file
  67. ;                  using MODE directive - NOTE: No .hex extension
  68. ;                  will be added to output file in this case!
  69. ;                - CTRL+Z is added to end of hex output file
  70. ; - 880816 by JM    -> v1.95    - Fixed a bug in conditional assembly:
  71. ;                  Nested conditions should now work properly.
  72. ;                  A 'stack' for all condition levels added.
  73. ; - 880816 by JM    -> v1.97    - Stack now consists of bytes (no need to
  74. ;                  multiply index by two -> no guru3's on 68000)
  75. ;                - CTRL_C signals now checked in pass1, pass2
  76. ;                  and MainLoad.
  77. ; - 880816 by JM    -> v2.00    - CTRL_C checked also in dumplabels
  78. ;                - endc statements now allow for labels BUT:
  79. ;                  endm's DON'T!!!
  80. ; - 880817 by JM    -> v2.02    - SET and EQU should now work properly.
  81. ;                  There was a problem when SETting a label to
  82. ;                  value label+n because slabel corrupted
  83. ;                  the LINFO value before GLABEL read it.
  84. ; - 880817 by JM    -> v2.06    - Fixed a bug: MODE L produced 1006 bytes
  85. ;                  of object code when listfile was opened.
  86. ;                  Now none of pseudos should produce object
  87. ;                  code (=increment prgc) unintentionally.
  88. ;                - Listmode is now read from userlmode, whose
  89. ;                  value is derived from cmd line option -l.
  90. ;                  Now the default listmode at start of each
  91. ;                  pass is userlmode instead of the value of
  92. ;                  listmode inherited from previous pass.
  93. ;                - Mode l/L commands no longer written to
  94. ;                  listfile.
  95. ;                - <<>> now produces an ermsg in macro exps.
  96. ;                - Macro parameters no longer contain following
  97. ;                  blanks.
  98. ;                - Macro, include and conditional nesting levels
  99. ;                  raised.
  100. ;                - Symbol definitions using EQU or SET now
  101. ;                  generate listing according to the value
  102. ;                  assigned. '=' = EQU, '>' = SET.
  103. ;                  DOESN'T WORK YET!!!
  104. ; - 880818 by JM    -> v2.10    - Fixed a new bug: listfile now opened correctly
  105. ;                - dumplabels no longer crashes is odd number of
  106. ;                  labels is printed (a bug in nextlab fixed)
  107. ;                - '=' and '>' now work in listmode.
  108. ;                - MainLoad now tells us what it is doing.
  109. ; - 880818 by JM    -> v2.15    - Fixed an old bug which caused wrong filenames
  110. ;                  and lines to be printed if any of the files
  111. ;                  was not found.
  112. ; - 880818 by JM    -> v2.2    - Macro parameters containing blanks in ''
  113. ;                  now allowed.
  114. ;                - Quote error messages added.
  115. ; - 880819 by JM    -> v2.23    - Macro parameter errors now should only
  116. ;                  print one errormsg.
  117. ;                - Macro ermsgs contain error line instead of
  118. ;                  a null.
  119. ;                - SET symbols not show their correct values
  120. ;                  in listfile.
  121. ;                - MODulo operation added (\).  Only handles
  122. ;                  signed 16-bit values for now.
  123. ; - 880819 by JM    -> v2.24    - Still a bug fixed.  Now SET symbols really
  124. ;                  work fine (with abs values, too).
  125. ; - 880819 by JM    -> v2.25    - Nested conditional assembly with FALSE
  126. ;                  block now should work properly.  This one
  127. ;                  was hard to find but easy to fix (just one
  128. ;                  clr.b pat_pend needed)
  129. ; - 880907 by JM    -> v2.26    - BBR and BBS now don't check offset value
  130. ;                  during pass 1.  So forward jumps work.
  131. ; - 880907 by JM    -> v2.30    - Macros listed properly during false condition.
  132. ; - 880907 by JM    -> v2.32    - BBR and BBS now get right mem address
  133. ;                - Abs_Sym_Mism error printed only once
  134. ; - 881201 by JM    -> v2.33    - Now an error during seek_op() should not
  135. ;                  produce an extra long destination line.
  136. ;                  So the relative branches should no longer
  137. ;                  cause extra ermsgs after an unknown label.
  138. ; - 890125 by JM    -> v2.34    - Now flushes the output buffer ALWAYS at the
  139. ;                  end of assembly
  140. ;                - Several relative branches converted to short.
  141. ; - 890131 by JM    -> v2.35    - PAGE directive added.
  142. ; - 890310 by JM    -> v2.351    - All b???.l and b???.b instructions converted
  143. ;                  to b??? to allow compiling with A68k.
  144. ; - 890310 by JM    -> v2.352    - All PULL <onereg> checked because A68k
  145. ;                  changes these into MOVE.L -> flags change.
  146. ;                  -> seems to work even if compiled with
  147. ;                  A68k.
  148. ;
  149. ;
  150. ;------------------------------------------------------------------------
  151. ;
  152.  
  153. LABELLEN    equ    16            maximum length of label name
  154. LABELSPC    equ    LABELLEN+1+1+4+4    name,null,info,usage,value
  155. LINFO        equ    LABELLEN+1
  156. LUSAGE        equ    LABELLEN+1+1
  157. LVALUE        equ    LABELLEN+1+1+4
  158. NUMLAB        equ    5000            maximum number of label names
  159.  
  160. MAXLINE        equ    60            default value
  161. HUGELINE    equ    MAXLINE+10        higher than maxline
  162.  
  163. INCNESTING    equ    8            maximum level of nested includes
  164. MCNESTING    equ    8            maximum level of nested macros
  165. CONDNESTING    equ    16            maximum level of nested conditions
  166.  
  167.  
  168. NAME1BUF    equ    256            buffer sizes
  169. NAME2BUF    equ    256
  170. AUXBUF        equ    256
  171. LISTBUF        equ    512
  172. MULTIBUF    equ    NAME1BUF+NAME2BUF+AUXBUF+LISTBUF
  173. OBUF        equ    2048            output buffer size
  174. LABELBUF    equ    LABELSPC*NUMLAB        name,null,pad,info,value
  175. MINSOURCE    equ    10000            minimum buffer for source
  176.  
  177.  
  178. ;------------------------------------------------------------------------
  179.  
  180.  
  181. TAB        equ    9            some ASCII characters
  182. LF        equ    10
  183. FF        equ    12
  184. CR        equ    13
  185. CTRL_C        equ    12
  186. CTRL_Z        equ    26
  187. ESC        equ    27
  188. CSI        equ    128+ESC
  189. ID        equ    160            id byte for internal mnemonics
  190.  
  191.  
  192. ;------------------------------------------------------------------------
  193.  
  194.  
  195. IMM        equ    0            identifiers for addressing
  196. ABS        equ    1            modes
  197. ZP        equ    2
  198. ACC        equ    3
  199. IMP        equ    4
  200. INDX        equ    5
  201. INDY        equ    6
  202. ZPX        equ    7
  203. ABSX        equ    8
  204. ABSY        equ    9
  205. REL        equ    10
  206. IND        equ    11
  207. ZPY        equ    12
  208.  
  209.  
  210. ;------------------------------------------------------------------------
  211.  
  212.  
  213.         include    "exec.xref"
  214.         include    "dos.xref"
  215.         include "JMPLibs.i"
  216.  
  217. MEMF_PUBLIC    equ    1        no need of intuition.i
  218. MEMF_CHIP    equ    2
  219. MEMF_FAST    equ    4
  220. MEMF_CLEAR    equ    65536
  221.  
  222.  
  223. ;------------------------------------------------------------------------
  224.  
  225.  
  226. VERSION        macro
  227.         dc.b    'v2.352'
  228.         endm
  229.  
  230. otxt        macro
  231.         push    a0/d7
  232.         lea    otxtdat\@,a0
  233. otxtl\@        move.b    (a0)+,d7
  234.         beq    otxte\@
  235.         bsr    ochr
  236.         bra    otxtl\@
  237. otxtdat\@    dc.b    \1
  238.         dc.b    0
  239.         cnop    0,4
  240. otxte\@        pull    a0/d7
  241.         endm
  242.  
  243.  
  244. error        macro                calls error handler
  245.         push    all
  246.         ifnc    '\1',''
  247.         move.w    \1,d0
  248.         endc
  249.         bsr    errhandler
  250.         pull    all
  251.         endm
  252.  
  253.  
  254. ;------------------------------------------------------------------------
  255.  
  256.  
  257. Start        push    d2-d7/a2-a6        save regs
  258.         move.l    d0,_CMDLen        len of cmd line
  259.         move.l    a0,_CMDBuf        start addr of cmd line
  260.         clr.b    -1(a0,d0.l)        add null
  261.         openlib Dos,cleanup        open Dos library
  262.  
  263.         printa    #PAGEMSG        print starting msg
  264.         move.b    #' ',PAGENULL
  265.         printa    #LFLF
  266.  
  267.         lib    Dos,Output        get output file handle
  268.         move.l    d0,clifile
  269.  
  270.         move.l    #OBUF,d0        reserve output buffer
  271.         move.l    #MEMF_CLEAR,d1
  272.         lib    Exec,AllocMem
  273.         move.l    d0,obuf            save start addr
  274.         move.l    d0,opoi            set output buffer pointer
  275.         beq    mem_cleanup        no mem, exit
  276.  
  277.         move.l    #MULTIBUF,d0        several buffers
  278.         move.l    #MEMF_CLEAR,d1
  279.         lib    Exec,AllocMem        ask for mem
  280.         move.l    d0,multibuf        save start addr for FreeMem
  281.         beq    mem_cleanup        no mem, exit
  282.         add.l    #NAME1BUF+NAME2BUF,d0
  283.         move.l    d0,auxbuf        another buffer
  284.         add.l    #AUXBUF,d0
  285.         move.l    d0,libuf        buffer for listing
  286.  
  287.         move.l    #LABELBUF,d0        allocate mem for symbols
  288.         move.l    #MEMF_CLEAR,d1
  289.         lib    Exec,AllocMem
  290.         move.l    d0,labelbuf        save start addr
  291.         beq    mem_cleanup        no mem, exit
  292.  
  293.         bsr    OpenFiles        open files, read prg
  294.         bcs    cleanup
  295.  
  296.         move.l    errcnt(pc),d0        errors during macro/include pass?
  297.         bne    cleanup
  298.         bsr    pass1
  299.         bcs    cleanup
  300.         bsr    pass2
  301.  
  302.         move.w    hexmode(pc),d0
  303.         beq.s    noCTRLz
  304.         moveq.l    #CTRL_Z,d7        end-of-file mark
  305.         bsr    ochr
  306.  
  307. noCTRLz        moveq.l    #-1,d7            flush output buffer
  308.         bsr    ochr
  309.  
  310.         move.l    errcnt(pc),d0        no msg below if errors
  311.         bne.s    not_complete
  312.  
  313.         print    <'Object file complete.',LF>
  314. not_complete    bsr    dumplabels
  315.         bra.s    cleanup
  316.  
  317.  
  318. ;------------------------------------------------------------------------
  319.  
  320.  
  321. mem_cleanup    error    #41
  322. cleanup        move.w    broken(pc),d0
  323.         beq.s    nobreak
  324.         print    <'*** User break request ***',LF>
  325. nobreak        move.l    outfile(pc),d1
  326.         beq.s    cleanf1
  327.         lib    Dos,Close
  328.  
  329. cleanf1        move.l    listfile(pc),d1
  330.         beq.s    clean01
  331.         print    <FF>,d1            add final form feed
  332.         lib    Dos,Close
  333.  
  334. clean01        move.l    sourcebuf(pc),d0    if mem reserved release it
  335.         beq.s    clean02
  336.         move.l    d0,a1
  337.         move.l    SOURCEBUF(pc),d0
  338.         lib    Exec,FreeMem
  339.  
  340. clean02        move.l    obuf(pc),d0        if mem reserved release it
  341.         beq.s    clean03
  342.         move.l    d0,a1
  343.         move.l    #OBUF,d0
  344.         lib    Exec,FreeMem
  345.  
  346. clean03        move.l    multibuf(pc),d0        if mem reserved release it
  347.         beq.s    clean04
  348.         move.l    d0,a1
  349.         move.l    #MULTIBUF,d0
  350.         lib    Exec,FreeMem
  351.  
  352. clean04        move.l    labelbuf(pc),d0        if mem reserved release it
  353.         beq.s    clean90
  354.         move.l    d0,a1
  355.         move.l    #LABELBUF,d0
  356.         lib    Exec,FreeMem
  357.  
  358. clean90        closlib    Dos
  359.         pull    d2-d7/a2-a6
  360.         moveq.l    #0,d0
  361.         rts
  362.  
  363.  
  364.  
  365. ;========================================================================
  366.  
  367.  
  368. output        cmp.b    #2,pass            if pass#2, write to dest.
  369.         beq.s    output_y
  370.         rts
  371. output_y    push    d0-d1/a0-a1
  372.         move.w    listmode(pc),d0        if listmode
  373.         beq.s    output_no_b
  374.         move.w    hexbytcnt(pc),d0    if still bytes to buffer
  375.         beq.s    output_no_b        (writes only first 3 bytes)
  376.         subq.w    #1,d0            Outputs assembled bytes to libuf
  377.         move.w    d0,hexbytcnt        2.1.0
  378.         eor.w    #3,d0            1.2.3
  379.         mulu.w    #3,d0            3.6.9
  380.         lea    hextable(pc),a0
  381.         move.l    libuf(pc),a1
  382.         moveq.l    #0,d1
  383.         move.b    d7,d1
  384.         lsr.b    #4,d1
  385.         move.b    0(a0,d1.w),9(a1,d0.w)    high nybble
  386.         move.b    d7,d1
  387.         and.b    #15,d1
  388.         move.b    0(a0,d1.w),10(a1,d0.w)    low nybble
  389.  
  390. output_no_b    move.w    hexmode(pc),d0
  391.         bne.s    output_hex
  392.         bsr    ochr
  393.         bra.s    no_output
  394. output_hex    bsr    ohex
  395. no_output    pull    d0-d1/a0-a1
  396.         rts
  397.  
  398.  
  399. ;------------------------------------------------------------------------
  400.  
  401.  
  402. listout        push    d0-d3/a0-a1        write pc, line# & line in libuf
  403.         move.w    listmode(pc),d0
  404.         beq    listout_ex
  405.         move.w    no_list(pc),d0        if a special mnemonic, no listing
  406.         bne    listout_ex
  407.         cmp.b    #2,pass            if not pass#2, no listing
  408.         bne    listout_ex
  409.         move.l    libuf(pc),a1        listing linebuffer
  410.         lea    hextable(pc),a0        table of ASCII hex chars
  411.         move.w    hexbytcnt(pc),d0
  412.         subq.w    #3,d0
  413.         bne.s    listout_pc
  414.  
  415.         move.l    equset(pc),d1        label set/equted on this line?
  416.         beq.s    listout_noadr        no, output nothing
  417.         addq.l    #1,a1            tab one col right
  418.         btst    #31,d1
  419.         beq.s    listo1
  420.         move.b    #'=',6(a1)        flag user: symbol was EQUted
  421.         bra.s    listo2
  422. listo1        move.b    #'>',6(a1)        flag user: symbol was SET
  423. listo2        bsr    listout_prgc
  424.         subq.l    #1,a1            tab back to orig positing
  425.         clr.l    equset            operation performed -> clear
  426.         bra.s    listout_noadr
  427.  
  428. listout_pc    move.l    prgc(pc),d1        write pc value into buffer
  429.         bsr    listout_prgc
  430.  
  431. listout_noadr    move.w    idepth(pc),d0
  432.         beq.s    listout_noinc
  433.         move.b    #'I',5(a1)        code from include file
  434.  
  435. listout_noinc    cmp.w    #-2,incstrt        code from macro expansion?
  436.         bne.s    listout_nomac
  437.         move.b    #'M',5(a1)
  438.  
  439. listout_nomac    move.w    condstrt(pc),d0        check if TRUE or FALSE needed
  440.         beq.s    listout_nocond
  441.         lea    7(a1),a1        column
  442.         bmi.s    listout_false
  443.         lea    LO_TRUE(pc),a0
  444.         bra.s    listout_r_cond
  445. listout_false    lea    LO_FALSE(pc),a0
  446. listout_r_cond    bsr    copy_10            write string
  447.         clr.w    condstrt
  448.         move.l    libuf(pc),a1        get pointer back
  449.  
  450. listout_nocond    move.l    linnum(pc),d0
  451.         setc                no zero suppression
  452.         bsr    conv_10
  453.         lea    buf_10+7(pc),a0
  454.         moveq.l    #4,d1
  455. listout_line    move.b    (a0)+,(a1)+        copy line number
  456.         dbf    d1,listout_line
  457.  
  458.         move.l    linstrt(pc),a0        copy the line itself
  459.         move.l    libuf(pc),a1
  460.         add.l    #22,a1            tab to col 22
  461.         moveq.l    #0,d1            column counter
  462. listout_cpy    move.b    (a0)+,d0        copyloop
  463.         cmp.b    #TAB,d0
  464.         bne.s    listout_cpynt
  465. listout_tab    move.b    #' ',(a1)+        replace tabs with 1...8 spaces
  466.         addq.l    #1,d1
  467.         move.b    d1,d2
  468.         and.b    #7,d2
  469.         bne.s    listout_tab
  470.         bra.s    listout_cpy        continue with next char
  471. listout_cpynt    move.b    d0,(a1)+
  472.         addq.l    #1,d1            next column
  473.         cmp.b    #LF,d0
  474.         beq.s    listout_eol
  475.         cmp.b    #CR,d0
  476.         bne.s    listout_cpy
  477.  
  478. listout_eol    bsr    header            print page header if needed
  479.         move.l    listfile(pc),d1        write it out
  480.         move.l    libuf(pc),d2
  481.         move.l    a1,d3
  482.         sub.l    d2,d3
  483.         lib    Dos,Write
  484.         cmp.l    d3,d0            requested length written?
  485.         beq.s    listout_wrok
  486.         error    #62
  487.         bra.s    listout_err
  488. listout_wrok    addq.l    #5,d2            buffer start+5
  489.         move.l    d2,a1
  490.         moveq.l    #16,d0
  491.         moveq.l    #' ',d1
  492. listout_clr    move.b    d1,(a1)+        clear numeric bytes
  493.         dbf    d0,listout_clr
  494.         move.w    #3,hexbytcnt
  495. listout_ex    clr.w    no_list
  496.         pull    d0-d3/a0-a1
  497.         rts
  498. listout_err    clr.w    no_list
  499.         pull    d0-d3/a0-a1
  500.         setc
  501.         rts
  502.  
  503. listout_prgc    moveq.l    #0,d0            Writes a 16-bit value into buf
  504.         move.b    d1,d0            Value in d1.
  505.         and.b    #15,d0
  506.         move.b    0(a0,d0.w),10(a1)    lowest nybble
  507.         lsr.w    #4,d1
  508.         move.b    d1,d0
  509.         and.b    #15,d0
  510.         move.b    0(a0,d0.w),9(a1)
  511.         lsr.w    #4,d1
  512.         move.b    d1,d0
  513.         and.b    #15,d0
  514.         move.b    0(a0,d0.w),8(a1)
  515.         lsr.w    #4,d1
  516.         move.b    d1,d0
  517.         and.b    #15,d0
  518.         move.b    0(a0,d0.w),7(a1)    highest nybble
  519.         rts
  520.  
  521.  
  522. LO_TRUE        dc.b    'TRUE',0
  523. LO_FALSE    dc.b    'FALSE',0
  524.         cnop    0,4
  525.  
  526.  
  527. list_clr    push    d0/a0            clear numeric bytes in buffer
  528.         move.l    libuf(pc),a0
  529.         moveq.l    #22,d0
  530. list_clr1    move.b    #' ',(a0)+
  531.         dbf    d0,list_clr1
  532.         pull    d0/a0
  533.         rts
  534.  
  535.  
  536. ;------------------------------------------------------------------------
  537.  
  538.  
  539. ohex        push    d0/d7/a0        output a byte in d7 in hex
  540.         lea    hextable(pc),a0
  541.         move.b    d7,d0
  542.         lsr.b    #4,d7
  543.         and.w    #15,d7
  544.         move.b    0(a0,d7),d7
  545.         bsr.s    ochr
  546.         and.w    #15,d0
  547.         move.b    0(a0,d0),d7
  548.         bsr.s    ochr
  549.         pull    d0/d7/a0
  550.         rts
  551.  
  552.  
  553. ochr        push    d0-d3/a0-a1        * output one char.
  554.         move.l    obuf(pc),a1        * Uses buffering.
  555.         cmp.l    #-1,d7            * Buffer is written to disk
  556.         beq.s    ochrflush        * if it becomes full or if
  557.         add.l    #OBUF,a1        * the character ochr'ed is
  558.         move.l    opoi(pc),a0        * -1.
  559.         move.b    d7,(a0)+
  560.         cmp.l    a1,a0
  561.         blt.s    ochrok1
  562.         move.l    obuf(pc),a0
  563.         move.l    outfile(pc),d1
  564.         move.l    a0,d2
  565.         move.l    #OBUF,d3
  566. ochrout        lib    Dos,Write
  567.         move.l    d2,a0
  568.         cmp.l    d3,d0
  569.         beq.s    ochrok1
  570.         error    #61
  571. ochrok1        move.l    a0,opoi
  572.         pull    d0-d3/a0-a1
  573.         rts
  574.  
  575. ochrflush    move.l    opoi(pc),a0
  576.         sub.l    a1,a0
  577.         move.l    outfile(pc),d1
  578.         move.l    a1,d2
  579.         move.l    a0,d3
  580.         bra.s    ochrout
  581.  
  582.  
  583. chr        push    a0            read one byte
  584.         move.l    txtptr(pc),a0
  585.         moveq.l    #0,d0
  586.         move.b    (a0)+,d0
  587.         cmp.b    #CR,d0
  588.         beq.s    chr_eol
  589.         cmp.b    #LF,d0
  590.         beq.s    chr_eol
  591.         move.l    a0,txtptr
  592. chr_eol        pull    a0
  593.         tst.b    d0
  594.         rts
  595.  
  596.  
  597. gc        push    a0
  598.         move.l    txtptr(pc),a0        get txtptr
  599.         moveq.l    #0,d0
  600. gc_sk        move.b    (a0)+,d0        get a byte
  601.         beq.s    gc_e
  602.         cmp.b    #';',d0            ; = line end
  603.         beq.s    gc_e
  604.         cmp.b    #' ',d0            >' ', legal char
  605.         bhi.s    gc_ok
  606.         cmp.b    #CR,d0            CR means line end
  607.         beq.s    gc_e
  608.         cmp.b    #LF,d0            LF means line end
  609.         beq.s    gc_e
  610.         bra.s    gc_sk            try next char
  611. gc_ok        move.l    a0,txtptr
  612.         pull    a0
  613.         cmp.b    #0,d0
  614.         rts
  615. gc_e        addq.b    #1,pat_pend        one LF fetched
  616.         pull    a0
  617.         moveq.l    #0,d0
  618.         rts
  619.  
  620.  
  621. gec        push    a0
  622.         move.l    txtptr(pc),a0        get txtptr
  623.         moveq.l    #0,d0
  624. gec_sk        move.b    (a0)+,d0        get a byte
  625.         beq.s    gec_e
  626.         cmp.b    #';',d0            ; = line end
  627.         beq.s    gec_e
  628.         cmp.b    #' ',d0            >' ', legal char
  629.         bhi.s    gec_ok
  630.         cmp.b    #CR,d0            CR means line end
  631.         beq.s    gec_e
  632.         cmp.b    #LF,d0            LF means line end
  633.         beq.s    gec_e
  634. gec_ok        move.l    a0,txtptr
  635.         pull    a0
  636.         cmp.b    #0,d0
  637.         rts
  638. gec_e        addq.b    #1,pat_pend        one LF fetched
  639.         pull    a0
  640.         moveq.l    #0,d0
  641.         rts
  642.  
  643.  
  644. gpeek        push    a0
  645.         move.l    txtptr(pc),a0
  646.         moveq.l    #0,d0
  647.         move.b    (a0),d0
  648.         pull    a0
  649.         tst.b    d0
  650.         rts
  651.  
  652. cg        tst.b    pat_pend
  653.         beq.s    cg_ok
  654.         subq.b    #1,pat_pend        one LF backwards
  655.         rts
  656. cg_ok        subq.l    #1,txtptr
  657. cg_ex        rts
  658.  
  659.  
  660. ck_stop        push    d0-d1/a0-a1        check if CTRL_C pressed
  661.         moveq.l    #0,d0
  662.         moveq.l    #0,d1
  663.         lib    Exec,SetSignal
  664.         btst    #CTRL_C,d0
  665.         beq.s    ck_nostop
  666.         moveq.l    #0,d0
  667.         moveq.l    #0,d1
  668.         bset    #CTRL_C,d1
  669.         lib    Exec,SetSignal        clear signal
  670.         moveq.l    #1,d0            NE: STOP!!!
  671.         move.w    d0,broken        set flag: STOPPED!!
  672.         pull    d0-d1/a0-a1
  673.         rts
  674. ck_nostop    moveq.l    #0,d0            EQ: no stop
  675.         pull    d0-d1/a0-a1
  676.         rts
  677.  
  678.  
  679. ;------------------------------------------------------------------------
  680.  
  681.  
  682. mulmul        push    d0/d2-d4
  683.         bsr    SetSignMD    d1 = d0 * d1
  684.         move.l    d0,d4        multiplication HL * hl
  685.         mulu.w    d1,d0        L*l
  686.         move.l    d0,d3        low word
  687.         move.l    d4,d0
  688.         swap    d0        high word
  689.         mulu.w    d1,d0        L*h
  690.         swap    d0
  691.         tst.w    d0
  692.         bne.s    mulmuler    result bigger than 32 bits
  693.         add.l    d0,d3        d3 contains L*(hl)
  694.         swap    d1        get low word
  695.         move.w    d4,d0
  696.         mulu.w    d1,d0        H*l
  697.         swap    d0        result to high word
  698.         tst.w    d0         (hw of mulu must be zero)
  699.         bne.s    mulmuler
  700.         add.l    d0,d3        d3 contains L*(hl)+H*l
  701.         bcs.s    mulmuler
  702.  
  703.         move.l    d4,d0
  704.         swap    d0        get low word
  705.         mulu.w    d1,d0        H*h (must be always zero)
  706.         bne.s    mulmuler
  707.         btst    #31,d3        bit #31 must be zero (sign)
  708.         bne.s    mulmuler
  709.  
  710.         move.l    d3,d1
  711.         tst.l    d2        set appropriate sign
  712.         bpl.s    mulmula
  713.         neg.l    d1
  714. mulmula        pull    d0/d2-d4
  715.         clrc
  716.         rts
  717. mulmuler    setc
  718.         pull    d0/d2-d4
  719.         rts
  720.  
  721.  
  722. divdiv        push    d0/d2-d5    d1 = d1 / d0
  723.         tst.l    d0        divisor = 0?
  724.         bne.s    divdiv1
  725.         error    #131
  726.         pull    d0/d2-d5
  727.         rts
  728.  
  729. divdiv1        bsr.s    SetSignMD
  730.         moveq.l    #0,d3
  731.         moveq.l    #31,d5        bit counter
  732. divdivloop    roxl.l    #1,d1
  733.         roxl.l    #1,d3        d3 is a 'working accum'
  734.         cmp.l    d0,d3
  735.         blo.s    divdivless
  736.         sub.l    d0,d3
  737.         setx
  738.         roxl.l    #1,d4        if subtracted, set bit
  739.         dbf    d5,divdivloop
  740.         bra.s    divdivdone
  741. divdivless    asl.l    #1,d4
  742.         dbf    d5,divdivloop
  743.  
  744. divdivdone    move.l    d4,d1        set appropriate sign
  745.         tst.l    d2
  746.         bpl.s    divdiv2
  747.         neg.l    d1
  748. divdiv2        pull    d0/d2-d5
  749.         clrc
  750.         rts
  751.  
  752.  
  753. SetSignMD    move.l    d0,d2        get sign of result into d2[31]
  754.         eor.l    d1,d2
  755.         tst.l    d0        make d0 positive if necessary
  756.         bpl.s    SetSign1
  757.         neg.l    d0
  758. SetSign1    tst.l    d1        make d1 positive
  759.         bpl.s    SetSign2
  760.         neg.l    d1
  761. SetSign2    rts
  762.  
  763.  
  764. ;------------------------------------------------------------------------
  765.  
  766.  
  767. errhandler    and.l    #$ffff,d0
  768.         move.w    d0,errornum
  769.         clrc
  770.         bsr    conv_10
  771.         lea    buf_10+7(pc),a0
  772.         lea    ERROR_NUM(pc),a1
  773.         bsr    copy_10
  774.         cmp.w    #100,errornum
  775.         blo    errhand0
  776.         move.l    linnum(pc),d0
  777.         clrc
  778.         bsr    conv_10
  779.         lea    buf_10+7(pc),a0
  780.         lea    ERROR_LIN(pc),a1
  781.         bsr    copy_10
  782.         printa    #ERROR_SC
  783.         move.l    nameptr(pc),a0
  784.         move.l    auxbuf(pc),a1
  785.         move.l    linnum(pc),d0    don't print line if line# = 0
  786.         beq.s    errhand2a
  787. err_cpname    move.b    (a0)+,d0
  788.         beq.s    err_nameok
  789.         cmp.b    #39,d0
  790.         beq.s    err_nameok
  791.         cmp.b    #' ',d0
  792.         beq.s    err_nameok
  793.         move.b    d0,(a1)+
  794.         bra.s    err_cpname
  795.  
  796. err_nameok    move.l    linstrt(pc),a0
  797.         move.b    #':',(a1)+
  798.         move.b    #'"',(a1)+
  799.         move.w    #128,d1        max # of chars
  800. errhand1    move.b    (a0)+,d0    copy line
  801.         bsr    ck_eol
  802.         bvs.s    errhand2
  803.         move.b    d0,(a1)+
  804.         dbf    d1,errhand1
  805. errhand2    move.b    #'"',(a1)+
  806. errhand2a    move.b    #LF,(a1)+
  807.         clr.b    (a1)
  808.         printa    auxbuf(pc)
  809.         move.l    listfile(pc),d0
  810.         beq.s    errhand0
  811.         printa    #ERROR_SC,d0        error
  812.         printa    auxbuf(pc),d0        line
  813. errhand0    bsr.s    print_error        msg
  814.         addq.l    #1,errcnt
  815.         setc
  816.         rts
  817.  
  818. ERROR_SC    dc.b    LF,'*** Error '
  819. ERROR_NUM    dc.b    '      on line '
  820. ERROR_LIN    dc.b    '      ***',LF,0
  821.         cnop    0,4
  822.  
  823.  
  824. print_error    moveq.l    #0,d0        reset high word
  825.         move.w    errornum(pc),d0
  826.         divu.w    #10,d0        calc main error#
  827.         lea    ermsgs(pc),a0
  828. print_err_lp    subq.w    #1,d0        find ermsg#d0
  829.         beq.s    print_errf
  830. print_err_seek    tst.b    (a0)+        find end of this msg
  831.         bne.s    print_err_seek
  832.         tst.b    (a0)        last one?
  833.         bpl.s    print_err_lp    no, continue
  834. print_err_err    print    <'### INTERNAL ERROR #1: Please report ###',LF>
  835.         bra.s    print_err_ex
  836. print_errf    tst.b    (a0)        if no ermsg for this number
  837.         beq.s    print_err_err
  838.         printa    a0
  839.         move.l    listfile(pc),d0
  840.         beq.s    print_err_ex
  841.         printa    a0,d0
  842. print_err_ex    rts
  843.  
  844.  
  845. ;------------------------------------------------------------------------
  846.  
  847.  
  848. copy_10        push    d0
  849. copy_10_l    move.b    (a0)+,d0
  850.         beq.s    copy_10_e
  851.         move.b    d0,(a1)+
  852.         bra.s    copy_10_l
  853. copy_10_e    pull    d0
  854.         rts
  855.  
  856.  
  857. sign_10        btst    #31,d0
  858.         beq.s    conv_10
  859.         neg.l    d0
  860.         clrc
  861.         bsr.s    conv_10
  862.         push    a0
  863.         lea    buf_10(pc),a0
  864. sign_10_1    cmp.b    #' ',(a0)+
  865.         beq.s    sign_10_1
  866.         move.b    #'-',-2(a0)
  867.         pull    a0
  868.         rts
  869.  
  870. print10        setc
  871.         bsr.s    conv_10        for testing purposes only
  872.         printa    #buf_10
  873.         print    <LF>
  874.         rts
  875.  
  876.  
  877.  
  878. conv_10        push    all        if carry clear, leading zeroes blanked
  879.         bcs.s    conv_10_0
  880.         moveq.l    #' ',d2
  881.         bra.s    conv_10_spc
  882. conv_10_0    moveq.l    #'0',d2
  883. conv_10_spc    lea    bcd_10+6(pc),a0
  884.         lea    res_10+6(pc),a1
  885.         moveq.l    #0,d1            clear result first
  886.         move.l    d1,-6(a0)
  887.         move.l    d1,-2(a0)
  888.         move.l    d1,-6(a1)
  889.         move.l    d1,-2(a1)
  890.         move.b    #1,-1(a0)        seed value
  891. conv_10_main    lsr.l    #1,d0
  892.         bcc.s    conv_10_next
  893.         move.l    a0,a2
  894.         move.l    a1,a3
  895.         clrx
  896.         abcd    -(a2),-(a3)        add seed value to result
  897.         abcd    -(a2),-(a3)
  898.         abcd    -(a2),-(a3)
  899.         abcd    -(a2),-(a3)
  900.         abcd    -(a2),-(a3)
  901.         abcd    -(a2),-(a3)
  902.         tst.l    d0
  903. conv_10_next    beq.s    conv_10_asc
  904.         move.l    a0,a2            multiply seed value by 2
  905.         move.l    a0,a3
  906.         clrx
  907.         abcd    -(a2),-(a3)
  908.         abcd    -(a2),-(a3)
  909.         abcd    -(a2),-(a3)
  910.         abcd    -(a2),-(a3)
  911.         abcd    -(a2),-(a3)
  912.         abcd    -(a2),-(a3)
  913.         bra.s    conv_10_main
  914. conv_10_asc    lea    res_10(pc),a0        convert to ascii
  915.         lea    buf_10(pc),a1
  916.         moveq.l    #5,d1
  917. conv_10_al    move.b    (a0)+,d3
  918.         move.b    d3,d0
  919.         lsr.b    #4,d0
  920.         beq.s    conv_10_al1
  921.         moveq.l    #'0',d2
  922. conv_10_al1    or.b    d2,d0
  923.         move.b    d0,(a1)+
  924.         and.b    #15,d3
  925.         beq.s    conv_10_al2
  926.         moveq.l    #'0',d2
  927. conv_10_al2    or.b    d2,d3
  928.         move.b    d3,(a1)+
  929.         dbf    d1,conv_10_al
  930.         or.b    #'0',d3
  931.         move.b    d3,-1(a1)
  932.         move.b    #0,(a1)
  933.         pull    all
  934.         rts
  935.  
  936. bcd_10        ds.l    2
  937. res_10        ds.l    2
  938. buf_10        ds.l    4
  939.  
  940.  
  941. sign_16        btst    #31,d0
  942.         beq.s    sign_16_plus
  943.         neg.l    d0
  944.         bsr.s    conv_16
  945.         move.b    #'-',buf_16+3
  946.         rts
  947. sign_16_plus    bsr.s    conv_16
  948.         move.b    #' ',buf_16+3
  949.         rts
  950.  
  951.  
  952. conv_16        push    d0-d2/a0-a1
  953.         lea    buf_16+8(pc),a0
  954.         lea    hextable(pc),a1
  955.         moveq.l    #3,d2
  956.         moveq.l    #0,d1
  957. conv_16_lp    move.b    d0,d1
  958.         and.b    #15,d1
  959.         move.b    0(a1,d1),-(a0)
  960.         lsr.l    #4,d0
  961.         move.b    d0,d1
  962.         and.b    #15,d1
  963.         move.b    0(a1,d1),-(a0)
  964.         lsr.l    #4,d0
  965.         dbf    d2,conv_16_lp
  966.         pull    d0-d2/a0-a1
  967.         rts
  968.  
  969. buf_16        ds.l    2
  970.         dc.w    0
  971.  
  972.  
  973. ck_opt        move.l    _CMDBuf(pc),a0        check for options on cmd line
  974.         move.l    obuf(pc),a1        copy filename into obuf
  975. ck_opt_lp1    move.b    (a0)+,d0        search for end of filename
  976.         move.b    d0,(a1)+        copy filename
  977.         beq.s    ck_opt_ex
  978.         bsr    ck_blk
  979.         bcc.s    ck_opt_lp1
  980.         clr.b    -1(a1)            add null to filename
  981. ck_opt_lp2    move.b    (a0)+,d0        find '-opt'
  982.         beq.s    ck_opt_ex
  983.         bsr    ck_blk
  984.         bcs.s    ck_opt_lp2        skip blanks
  985.         cmp.b    #'-',d0
  986.         bne.s    ck_opt_er
  987.         move.b    (a0)+,d0
  988.         bsr    ucase
  989.         cmp.b    #'L',d0            listmode?
  990.         bne.s    ck_opt_l
  991.         move.w    #1,userlmode        set default: listmode ON
  992.         move.w    #1,listmode
  993.         bra.s    ck_opt_lp2
  994. ck_opt_l    cmp.b    #'H',d0            hexmode?
  995.         bne.s    ck_opt_h
  996.         move.w    #1,hexmode
  997.         bra    ck_opt_lp2
  998. ck_opt_h    cmp.b    #'S',d0            symbolmode?
  999.         bne.s    ck_opt_s
  1000.         move.w    #1,symbolmode
  1001.         bra    ck_opt_lp2
  1002. ck_opt_s    cmp.b    #'C',d0            CMOSmode?
  1003.         bne    ck_opt_s
  1004.         move.w    #1,procmode
  1005.         bra    ck_opt_lp2
  1006. ck_opt_c
  1007.  
  1008. ck_opt_er    error    #91            option error
  1009.         rts
  1010. ck_opt_ex    clrc
  1011.         rts
  1012.  
  1013.  
  1014. ;------------------------------------------------------------------------
  1015.  
  1016.  
  1017. OpenFiles    bsr    ck_opt            parse options
  1018.         bcs    Open_err
  1019.         move.l    obuf(pc),a0        filename is here
  1020.         tst.b    (a0)
  1021.         bne    Open_name_ok
  1022.         error    #81
  1023.         printa    #USAGE
  1024.         bra    Open_err
  1025.  
  1026. USAGE        dc.b    CSI,'1mUsage: Asm65 ',60,'filename',62,' [-opt]'
  1027.         dc.b    CSI,'0m',LF
  1028.         dc.b    ' where -opt is:',LF
  1029.         dc.b    '  -c for 65c02 instruction set',LF
  1030.         dc.b    '  -s for symbol table listing',LF
  1031.         dc.b    '  -h for hexadecimal output file',LF
  1032.         dc.b    '  -l for listing file'
  1033. LFLF        dc.b    LF,LF,0
  1034.         cnop    0,4
  1035.  
  1036.  
  1037. Open_name_ok    move.l    _CMDBuf(pc),linstrt    addr of cmdline
  1038.         bsr    mkname            create output filenames
  1039.  
  1040.         print    <'Checking file lengths...',LF>
  1041.         move.l    auxbuf(pc),a0        main filename
  1042.         move.l    #0,a1            output ptr=0: check length
  1043.         moveq.l    #0,d7            nesting level
  1044.         bsr    MainLoad
  1045.         bcs    Open_err
  1046.  
  1047.         move.l    total_len(pc),d0    total length of files
  1048.         move.l    d0,d1
  1049.         asr.l    #1,d1            multiply by 1.5
  1050.         add.l    d1,d0            (allow 50% for macros)
  1051.         add.l    #MINSOURCE,d0        add minimum size
  1052.         move.l    d0,SOURCEBUF
  1053.  
  1054.         move.l    SOURCEBUF(pc),d0    this many RAM bytes needed
  1055.         move.l    d0,d2
  1056.         sub.l    #256,d2            for safety
  1057.         move.l    #MEMF_CLEAR,d1
  1058.         lib    Exec,AllocMem        ask for them
  1059.         move.l    d0,sourcebuf        save start addr
  1060.         beq    Open_mem_er        no mem, exit
  1061.         add.l    d2,d0
  1062.         move.l    d0,sourceend        end of buffer
  1063.  
  1064.         print    <'Processing macros...',LF>
  1065.         move.l    auxbuf(pc),a0        filename
  1066.         move.l    sourcebuf(pc),a1    output ptr
  1067.         moveq.l    #0,d7            nesting level
  1068.         bsr    MainLoad
  1069.         bcs    Open_err
  1070.  
  1071. Open_ok        move.l    multibuf(pc),d1        file to write
  1072.         move.l    #1006,d2        mode: create
  1073.         lib    Dos,Open        open it
  1074.         move.l    d0,outfile        save ptr
  1075.         bne.s    Open_list
  1076.         error    #51
  1077.         bra.s    Open_err
  1078.  
  1079. Open_list    move.w    listmode(pc),d0        if (listmode)
  1080.         beq.s    Open_l_ok
  1081.         move.l    listfile(pc),d0
  1082.         bne.s    Open_l_ok
  1083.         move.l    multibuf(pc),d1        listfile
  1084.         add.l    #NAME1BUF,d1
  1085.         move.l    #1006,d2        mode: create
  1086.         lib    Dos,Open        open it
  1087.         move.l    d0,listfile        save ptr
  1088.         bne.s    Open_l_ok
  1089.         error    #52
  1090.         bra.s    Open_err
  1091.  
  1092. Open_l_ok    clrc
  1093.         rts
  1094.  
  1095. Open_mem_er    error    #42            mem alloc error
  1096. Open_err    setc
  1097.         rts
  1098.  
  1099.  
  1100. mkname        push    d0/a0/a1        create in/output filename
  1101.         move.l    obuf(pc),a0
  1102.         move.l    auxbuf(pc),a1        filename.asm
  1103.         bsr    strcpy
  1104.         subq.l    #1,a1
  1105.         lea    ASM_EXT(pc),a0
  1106.         bsr    strcpy            appends '.asm'
  1107.         move.l    obuf(pc),a0
  1108.         move.l    multibuf(pc),a1
  1109.         bsr    strcpy
  1110.         move.w    hexmode(pc),d0        if not in hexmode, no '.hex'
  1111.         beq.s    mkname1
  1112.         subq.l    #1,a1
  1113.         lea    HEX_EXT(pc),a0
  1114.         bsr    strcpy            appends '.hex'
  1115. mkname1        move.l    obuf(pc),a0
  1116.         move.l    multibuf(pc),a1
  1117.         add.l    #NAME1BUF,a1
  1118.         bsr    strcpy
  1119.         subq.l    #1,a1
  1120.         lea    LST_EXT(pc),a0
  1121.         bsr    strcpy            appends '.lst'
  1122.         pull    d0/a0/a1
  1123.         rts
  1124. ASM_EXT        dc.b    '.asm',0
  1125. HEX_EXT        dc.b    '.hex',0
  1126. LST_EXT        dc.b    '.lst',0
  1127.         cnop    0,4
  1128.  
  1129.  
  1130. calc        clr.b    zpabs
  1131.         bsr.s    calcq
  1132.         bcs.s    calinaa
  1133.         cmp.l    #256,d0
  1134.         blo.s    calc0
  1135.         or.b    #1,zpabs
  1136. calc0        tst.l    d0
  1137. calinaa        rts
  1138.  
  1139. calcq        push    d1            calculates at (txtptr)
  1140.         bsr    gnumb            calc level #0
  1141.         bcs.s    calcqere
  1142.         move.l    d0,d1
  1143. calcq0        bsr    gc
  1144.         cmp.b    #'+',d0            addition
  1145.         bne.s    calcq1
  1146.         bsr    gnumb
  1147.         bcs.s    calcqere
  1148.         add.l    d0,d1
  1149.         bvc.s    calcq0
  1150.         moveq.l    #101,d0
  1151. calcqv        error
  1152. calcqere    pull    d1
  1153.         setc
  1154.         rts
  1155. calcq1        cmp.b    #'-',d0            subtraction
  1156.         bne.s    calcq2
  1157.         bsr.s    gnumb
  1158.         bcs.s    calcqere
  1159.         sub.l    d0,d1
  1160.         bvc.s    calcq0
  1161.         move.w    #102,d0
  1162.         bra.s    calcqv
  1163. calcq2        cmp.b    #'&',d0            andition
  1164.         bne.s    calcq3
  1165.         bsr.s    gnumb
  1166.         bcs.s    calcqere
  1167.         and.l    d0,d1
  1168.         bra    calcq0
  1169. calcq3        cmp.b    #'!',d0            orition
  1170.         bne.s    calcq4
  1171.         bsr.s    gnumb
  1172.         bcs    calcqere
  1173.         or.l    d0,d1
  1174.         bra    calcq0
  1175. calcq4        cmp.b    #'^',d0            xorition
  1176.         bne.s    calcq5
  1177.         bsr.s    gnumb
  1178.         bcs    calcqere
  1179.         eor.l    d0,d1
  1180.         bra    calcq0
  1181. calcq5        cmp.b    #'<',d0            leftertion
  1182.         bne.s    calcq6
  1183.         bsr.s    gnumb
  1184.         bcs    calcqere
  1185.         asl.l    d0,d1
  1186.         bvc    calcq0
  1187.         move.w    #103,d0
  1188.         bra    calcqv
  1189. calcq6        cmp.b    #'>',d0            rightertion
  1190.         bne.s    calcq7
  1191.         bsr.s    gnumb
  1192.         bcs    calcqere
  1193.         asr.l    d0,d1
  1194.         bra    calcq0
  1195. calcq7        bsr    cg
  1196.         move.l    d1,d0
  1197.         pull    d1
  1198.         clrc
  1199.         rts
  1200.  
  1201.  
  1202. gnumb        push    d1            calc level #1
  1203.         bsr    gnumbb
  1204.         bcs.s    gnumbere
  1205.         move.l    d0,d1
  1206. gnumb0        bsr    gc
  1207.         cmp.b    #'*',d0            multiplication
  1208.         bne.s    gnumb1
  1209.         bsr.s    gnumbb
  1210.         bcs.s    gnumbere
  1211.         bsr    mulmul
  1212.         bcc    gnumb0
  1213.         moveq.l    #111,d0
  1214. gnumbv        error
  1215. gnumbere    pull    d1
  1216.         setc
  1217.         rts
  1218. gnumb1        cmp.b    #'/',d0            division
  1219.         bne.s    gnumb2
  1220.         bsr.s    gnumbb
  1221.         bcs.s    gnumbere
  1222.         bsr    divdiv
  1223.         bcc    gnumb0
  1224.         move.w    #131,d0            div. by 0
  1225.         bra    gnumbv
  1226. gnumb2        cmp.b    #'\',d0            modulo-op
  1227.         bne.s    gnumb3
  1228.         bsr.s    gnumbb
  1229.         bcs    gnumbere
  1230.         tst.w    d0
  1231.         beq.s    modmoderr
  1232.         push    d2
  1233.         move.l    d1,d2
  1234.         divs.w    d0,d2
  1235.         bvs.s    modmodvs
  1236.         clr.w    d2
  1237.         swap    d2
  1238.         ext.l    d2
  1239.         move.l    d2,d1
  1240.         pull    d2
  1241.         bra    gnumb0
  1242. modmoderr    move.w    #132,d0
  1243.         bra    gnumbv
  1244. modmodvs    pull    d2
  1245.         move.w    #286,d0
  1246.         bra    gnumbv
  1247. gnumb3        bsr    cg
  1248.         move.l    d1,d0
  1249.         pull    d1
  1250.         clrc
  1251.         rts
  1252.  
  1253.  
  1254. gnumbb        push    d1
  1255.         bsr    gc
  1256.         cmp.b    #'-',d0
  1257.         bne.s    gnumbb1
  1258.         bsr    gnumbb
  1259.         bcs.s    gnumbbere
  1260.         neg.l    d0
  1261. gnumbbx        pull    d1
  1262.         clrc
  1263.         rts
  1264. gnumbbparmism    error    #141
  1265. gnumbbere    pull    d1
  1266.         setc
  1267.         rts
  1268. gnumbb1        cmp.b    #'~',d0
  1269.         bne.s    gnumbb1_5
  1270.         bsr    gnumbb
  1271.         bcs.s    gnumbbere
  1272.         not.l    d0
  1273.         bra.s    gnumbbx
  1274. gnumbb1_5    cmp.b    #'[',d0
  1275.         bne.s    gnumbb2
  1276.         bsr    calcq
  1277.         bcs    gnumbbere
  1278.         move.l    d0,d1
  1279.         bsr    gc
  1280.         cmp.b    #']',d0
  1281.         bne    gnumbbparmism
  1282.         move.l    d1,d0
  1283.         bra    gnumbbx
  1284. gnumbb2        cmp.b    #'<',d0
  1285.         bne.s    gnumbb3
  1286.         bsr    gnumbb
  1287.         bcs    gnumbbere
  1288.         and.l    #$ff,d0
  1289.         bra    gnumbbx
  1290. gnumbb3        cmp.b    #'>',d0
  1291.         bne.s    gnumbb3_5
  1292.         bsr    gnumbb
  1293.         bcs    gnumbbere
  1294.         lsr.l    #8,d0
  1295.         bra    gnumbbx
  1296. gnumbb3_5    cmp.b    #'@',d0
  1297.         bne.s    gnumbb4
  1298.         bsr    getmn
  1299.         bcc.s    gnumbb3_5b
  1300. gnumbb3_5c    error    #532
  1301.         bra    gnumbbere
  1302. gnumbb3_5b    cmp.l    #'MODE',d0
  1303.         bne.s    gnumbb3_5c
  1304.         bsr    getmode
  1305.         bra    gnumbbx
  1306. gnumbb4        cmp.b    #'$',d0
  1307.         bne.s    gnumbb5
  1308.         bsr.s    gethex
  1309.         bcs    gnumbbere
  1310.         bra    gnumbbx
  1311. gnumbb5        cmp.b    #'%',d0
  1312.         bne.s    gnumbb6
  1313.         bsr    getbin
  1314.         bcs    gnumbbere
  1315.         bra    gnumbbx
  1316. gnumbb6        cmp.b    #'&',d0
  1317.         bne.s    gnumbb6_5
  1318.         bsr    getoct
  1319.         bcs    gnumbbere
  1320.         bra    gnumbbx
  1321. gnumbb6_5    cmp.b    #'^',d0
  1322.         bne.s    gnumbb7
  1323.         bsr    getqui
  1324.         bcs    gnumbbere
  1325.         bra    gnumbbx
  1326. gnumbb7        cmp.b    #39,d0
  1327.         bne.s    gnumbb8
  1328.         bsr    getasc
  1329.         bcs    gnumbbere
  1330.         bra    gnumbbx
  1331. gnumbb8        cmp.b    #'0',d0
  1332.         blo.s    gnumbb9
  1333.         cmp.b    #'9',d0
  1334.         bhi.s    gnumbb9
  1335.         bsr    cg
  1336.         bsr    getdec
  1337.         bcs    gnumbbere
  1338.         bra    gnumbbx
  1339. gnumbb9        bsr    cg
  1340.         bsr    glabel
  1341.         bcs    gnumbbere
  1342.         bra    gnumbbx
  1343.  
  1344.  
  1345. gethex        push    d1
  1346.         moveq.l    #0,d1
  1347. gethex1        bsr    gc
  1348.         bsr    ucase
  1349.         cmp.b    #'F',d0
  1350.         bhi.s    gethexx
  1351.         sub.b    #'0',d0
  1352.         blo.s    gethexx
  1353.         cmp.b    #10,d0
  1354.         blo.s    gethex2
  1355.         sub.b    #7,d0
  1356. gethex2        asl.l    #4,d1
  1357.         bvs.s    gethexe
  1358.         or.b    d0,d1
  1359.         bra    gethex1
  1360. gethexx        bsr    cg
  1361.         move.l    d1,d0
  1362.         pull    d1
  1363.         clrc
  1364.         rts
  1365. gethexe        error    #121
  1366.         pull    d1/d1
  1367.         rts
  1368.  
  1369. getbin        push    d1
  1370.         moveq.l    #0,d1
  1371. getbin1        bsr    gc
  1372.         cmp.b    #'1',d0
  1373.         bhi.s    gethexx
  1374.         sub.b    #'0',d0
  1375.         blo.s    gethexx
  1376.         add.l    d1,d1
  1377.         bvs.s    getbine
  1378.         or.b    d0,d1
  1379.         bra.s    getbin1
  1380. getbine        error    #122
  1381.         pull    d1/d1
  1382.         rts
  1383.  
  1384. getoct        push    d1
  1385.         moveq.l    #0,d1
  1386. getoct1        bsr    gc
  1387.         cmp.b    #'7',d0
  1388.         bhi    gethexx
  1389.         sub.b    #'0',d0
  1390.         blo    gethexx
  1391.         asl.l    #3,d1
  1392.         bvs.s    getocte
  1393.         or.b    d0,d1
  1394.         bra.s    getoct1
  1395. getocte        error    #123
  1396.         pull    d1/d1
  1397.         rts
  1398.  
  1399. getqui        push    d1
  1400.         moveq.l    #0,d1
  1401. getqui1        bsr    gc
  1402.         cmp.b    #'3',d0
  1403.         bhi    gethexx
  1404.         sub.b    #'0',d0
  1405.         blo    gethexx
  1406.         asl.l    #2,d1
  1407.         bvs.s    getquie
  1408.         or.b    d0,d1
  1409.         bra.s    getqui1
  1410. getquie        error    #124
  1411.         pull    d1/d1
  1412.         rts
  1413.  
  1414.  
  1415. getdec        push    d1/d2        get a decimal number
  1416.         moveq.l    #0,d1        clear result
  1417.         bsr    gc        get a byte
  1418. getdecloop    and.b    #15,d0        convert to binary
  1419.         add.l    d1,d1        multiply old value by 10
  1420.         bvs.s    getdece        if overflow
  1421.         move.l    d1,d2
  1422.         asl.l    #2,d1
  1423.         bvs.s    getdece
  1424.         add.l    d2,d1
  1425.         bvs.s    getdece
  1426.         add.l    d0,d1        add new digit
  1427.         bvs.s    getdece
  1428.         bsr    gec        get next byte
  1429.         bsr.s    ck_dig        is it a digit?
  1430.         bcs.s    getdecloop
  1431.         bsr    cg        dec txtptr
  1432.         move.l    d1,d0
  1433.         clrc
  1434.         pull    d1/d2
  1435.         rts
  1436. getdece        error    #125
  1437.         pull    d1/d2
  1438.         rts
  1439.  
  1440.  
  1441. getasc        push    d1
  1442.         moveq.l    #0,d1
  1443. getasc1        bsr    chr
  1444.         cmp.b    #' ',d0
  1445.         blo    gethexe
  1446.         cmp.b    #39,d0
  1447.         beq.s    getascx
  1448.         asl.l    #8,d1
  1449.         bvs    gethexe
  1450.         or.b    d0,d1
  1451.         bra.s    getasc1
  1452. getascx        bsr    gc
  1453.         bra    gethexx
  1454.  
  1455.  
  1456. ck_dig        cmp.b    #'0',d0        is it a digit?
  1457.         blo.s    ck_dig_n
  1458.         cmp.b    #'9',d0
  1459.         bhi.s    ck_dig_n
  1460.         setc
  1461.         rts
  1462. ck_dig_n    clrc
  1463.         rts
  1464.  
  1465.  
  1466. ck_ap        cmp.b    #'A',d0        is it alpha?
  1467.         blo.s    ck_ap_n
  1468.         cmp.b    #'Z',d0
  1469.         bhi.s    ck_ap_n
  1470.         setc
  1471.         rts
  1472. ck_ap_n        clrc
  1473.         rts
  1474.  
  1475. gece        bsr    gec
  1476.         bra.s    ck_eol
  1477. gce        bsr    gc
  1478.  
  1479. ck_eol        tst.b    d0        is it end-of-line?
  1480.         beq.s    ck_eol_y
  1481.         cmp.b    #';',d0
  1482.         bhi.s    ck_eol_n
  1483.         beq.s    ck_eol_co
  1484.         cmp.b    #CR,d0
  1485.         beq.s    ck_eol_y
  1486.         cmp.b    #LF,d0
  1487.         beq.s    ck_eol_y
  1488. ck_eol_n    clrc
  1489.         clrv
  1490.         rts
  1491. ck_eol_y    setc
  1492.         setv            v=1: null/CR/LF
  1493.         rts
  1494. ck_eol_co    setc            c=1: ;/null/CR/LF
  1495.         clrv
  1496.         rts
  1497.  
  1498. ck_lc        cmp.b    #'A',d0        A...Z
  1499.         blo.s    ck_lc1
  1500.         cmp.b    #'Z',d0
  1501.         bls.s    ck_lc_y
  1502.         cmp.b    #'a',d0        a...z
  1503.         blo.s    ck_lc5
  1504.         cmp.b    #'z',d0
  1505.         bls.s    ck_lc_y
  1506. ck_lc_n        clrc            not a label char
  1507.         clrv
  1508.         rts
  1509. ck_lc1        cmp.b    #'0',d0        0...9
  1510.         blo.s    ck_lc2
  1511.         cmp.b    #'9',d0
  1512.         bls.s    ck_lc_yn
  1513. ck_lc2        cmp.b    #'.',d0        '.'
  1514.         bne.s    ck_lc_n
  1515. ck_lc_y        setc            label char, non-numeric
  1516.         clrv
  1517.         rts
  1518. ck_lc_yn    setc            label char, numeric
  1519.         setv
  1520.         rts
  1521. ck_lc5        cmp.b    #'_',d0        '_'
  1522.         beq.s    ck_lc_y
  1523.         bra.s    ck_lc_n
  1524.  
  1525.  
  1526. ck_blk        cmp.b    #' ',d0        check if blank
  1527.         beq.s    ck_blk_y
  1528.         cmp.b    #TAB,d0
  1529.         beq.s    ck_blk_y
  1530.         clrc
  1531.         rts
  1532. ck_blk_y    setc            blank detected!
  1533.         rts
  1534.  
  1535.  
  1536. ck_ibit        push    d1
  1537.         bsr    gc        check if '#0,'...'#7,'
  1538.         cmp.b    #'#',d0
  1539.         bne.s    ck_ibit_n    if not #
  1540.         bsr    gec
  1541.         cmp.b    #'0',d0        if not 0...7
  1542.         blo.s    ck_ibit_n
  1543.         cmp.b    #'7',d0
  1544.         bhi.s    ck_ibit_n
  1545.         and.b    #15,d0
  1546.         move.l    d0,d1
  1547.         bsr    gec
  1548.         cmp.b    #',',d0
  1549.         bne.s    ck_ibit_n    if not comma
  1550.         move.l    d1,d0
  1551.         pull    d1
  1552.         setc
  1553.         rts
  1554. ck_ibit_n    pull    d1
  1555.         clrc
  1556.         rts
  1557.  
  1558.  
  1559. ck_lim16    cmp.l    #-32768,d0    is it -32768...65535
  1560.         blt.s    ck_lim16_n
  1561.         cmp.l    #65535,d0
  1562.         bgt.s    ck_lim16_n
  1563.         setc            yes
  1564.         rts
  1565. ck_lim16_n    clrc            no
  1566.         rts
  1567.  
  1568.  
  1569. ck_lim8        cmp.l    #255,d0
  1570.         bgt.s    ck_lim8_n
  1571.         cmp.l    #-128,d0
  1572.         blt.s    ck_lim8_n
  1573.         setc
  1574.         rts
  1575. ck_lim8_n    clrc
  1576.         rts
  1577.  
  1578.  
  1579. ck_str        bsr    gce        get string addresses for ifc, ifnc
  1580.         bcs.s    ck_str_er    end of line
  1581.         cmp.b    #39,d0
  1582.         bne.s    ck_str_er
  1583.         move.l    txtptr(pc),a0    start of first string
  1584. ck_str_lp1    bsr    gce        search for end of string 1
  1585.         bcs.s    ck_str_er
  1586.         cmp.b    #39,d0
  1587.         bne.s    ck_str_lp1
  1588.         bsr    gce
  1589.         cmp.b    #',',d0        check for comma
  1590.         bne.s    ck_str_er
  1591.         bsr    gce
  1592.         cmp.b    #39,d0
  1593.         bne.s    ck_str_er
  1594.         move.l    txtptr(pc),a1
  1595. ck_str_lp2    bsr    gce        find final '
  1596.         bcs.s    ck_str_er
  1597.         cmp.b    #39,d0
  1598.         bne.s    ck_str_lp2
  1599.         clrc
  1600.         rts
  1601. ck_str_er    error    #531        sye
  1602.         rts
  1603.  
  1604.  
  1605. ck_ifc        push    a0-a1
  1606.         bsr    ck_str
  1607.         bcs.s    ck_ifc_er
  1608. ck_ifc_lp1    move.b    (a0)+,d0    compare until '
  1609.         cmp.b    (a1)+,d0
  1610.         bne.s    ck_ifc_nequ
  1611.         cmp.b    #39,d0
  1612.         bne.s    ck_ifc_lp1
  1613.         pull    a0-a1
  1614.         moveq.l    #0,d0        equal
  1615.         rts
  1616. ck_ifc_nequ    pull    a0-a1
  1617.         moveq.l    #1,d0        differ
  1618.         rts
  1619. ck_ifc_er    pull    a0-a1        error
  1620.         rts
  1621.  
  1622.  
  1623. ck_ifi        push    a0-a3/d1
  1624.         bsr    ck_str
  1625.         bcs    ck_ifc_er
  1626.         cmp.b    #39,(a0)
  1627.         beq.s    ck_ifif
  1628. ck_ifi0        move.l    a0,a2
  1629. ck_ifi1        move.b    (a1)+,d0
  1630.         cmp.b    #39,d0
  1631.         beq.s    ck_ifinf
  1632.         cmp.b    (a2)+,d0
  1633.         bne.s    ck_ifi0
  1634.         move.l    a1,a3
  1635. ck_ifi2        move.b    (a2)+,d1
  1636.         cmp.b    #39,d1
  1637.         beq.s    ck_ifif
  1638.         move.b    (a1)+,d0
  1639.         cmp.b    #39,d0
  1640.         beq.s    ck_ifinf
  1641.         cmp.b    d0,d1
  1642.         beq.s    ck_ifi2
  1643.         move.l    a3,a1
  1644.         bra.s    ck_ifi0
  1645. ck_ifinf    pull    a0-a3/d1
  1646.         moveq.l    #-1,d0
  1647.         rts
  1648. ck_ifif        pull    a0-a3/d1
  1649.         moveq.l    #0,d0
  1650.         rts
  1651.  
  1652. ck_ifi_er    pull    a0-a3/d1
  1653.         rts
  1654.  
  1655.  
  1656. ucase        cmp.b    #'a',d0
  1657.         blo.s    ucase1
  1658.         cmp.b    #'z',d0
  1659.         bhi.s    ucase1
  1660.         sub.b    #32,d0
  1661. ucase1        rts
  1662.  
  1663.  
  1664. strcmp        push    d1        check if s0 = s1
  1665. strcmp1        move.b    (a0)+,d0
  1666.         beq.s    strcmp_1e
  1667.         move.b    (a1)+,d1
  1668.         beq.s    strcmp_s1l    string 1 less
  1669.         cmp.b    d1,d0
  1670.         beq.s    strcmp1
  1671.         bhi.s    strcmp_s1l    string 1 less
  1672. strcmp_s0l    pull    d1
  1673.         moveq.l    #-1,d0
  1674.         setc
  1675.         rts            s0 < s1
  1676.  
  1677. strcmp_1e    move.b    (a1)+,d1
  1678.         bne.s    strcmp_s0l    string 0 less
  1679.         pull    d1
  1680.         moveq.l    #0,d0
  1681.         rts            s0 = s1
  1682.  
  1683. strcmp_s1l    pull    d1
  1684.         moveq.l    #1,d0
  1685.         clrc
  1686.         rts            s0 > s1
  1687.  
  1688.  
  1689. strcpy        move.b    (a0)+,(a1)+    copy s0 to s1
  1690.         bne.s    strcpy
  1691.         rts
  1692.  
  1693.  
  1694. pass1        push    all
  1695.         bsr    Clr_LBuf        clear labelbuf
  1696.         move.l    sourcebuf(pc),txtptr    set text pointer
  1697.         move.l    sourcebuf(pc),linstrt
  1698.         clr.b    pat_pend    no LF's fetched
  1699.         move.w    userlmode,listmode
  1700.         moveq.l    #0,d0
  1701.         move.l    d0,prgc
  1702.         move.w    d0,cond_level    no conditioning
  1703.         moveq.l    #1,d0
  1704.         move.l    d0,linnum
  1705.         move.l    _CMDBuf(pc),nameptr    main filename for errhandler()
  1706.         move.b    #1,pass
  1707.         print    <'Pass 1 - Creating Symbol Table',LF>
  1708.  
  1709. pass1_loop    bsr    ck_stop
  1710.         bne    pass1_stop
  1711.         bsr    gpeek
  1712.         beq.s    pass1_end
  1713.         cmp.w    #-1,incstrt    check if a macro starts
  1714.         bne.s    pass1_nomac
  1715.         bsr    slabel        save labels on macro usage lines
  1716.         bra.s    pass1_macskip
  1717. pass1_nomac    bsr    ck_eol
  1718.         bcs.s    pass1_next
  1719.         bsr    ck_blk        if blank: no label
  1720.         bcs.s    pass1_nolab
  1721.         bsr    slabel
  1722.         bcs.s    pass1_next
  1723.         bsr    gc
  1724.         bsr    ck_eol
  1725.         bcs.s    pass1_next
  1726.         bsr    cg
  1727.  
  1728. pass1_nolab    bsr    seek_op
  1729.         bcs.s    pass1_next
  1730.         add.l    d0,prgc
  1731.         move.l    prgc(pc),d0
  1732.         bsr    ck_lim16
  1733.         bcc    pass_pc_high
  1734.         bsr    gce        line end?
  1735.         bcs.s    pass1_next
  1736.         error    #201
  1737.         bra.s    pass1_next
  1738. pass1_macskip    move.w    #-2,incstrt
  1739. pass1_next    bsr    condition    check conditional assembly
  1740.         bsr    seek_nexl
  1741.         clr.b    pat_pend    no LF's fetched over line end
  1742.         bra    pass1_loop
  1743. pass1_end    move.l    errcnt(pc),d0
  1744.         beq    pass1_noer
  1745.         print    <'Assembly aborted...'>
  1746.         clrc
  1747.         bsr    conv_10
  1748.         printa    #buf_10
  1749.         print    <' error(s) detected.',LF>
  1750. pass1_stop    pull    all
  1751.         setc
  1752.         rts
  1753. pass1_noer    print    <'Symbol table complete.',LF>
  1754.         pull    all
  1755.         clrc
  1756.         rts
  1757.  
  1758. pass_pc_high    error    #291        pc > $ffff
  1759.         bra    pass1_end
  1760.  
  1761.  
  1762. pass2        push    all
  1763.         move.l    sourcebuf(pc),txtptr    set text pointer
  1764.         move.l    sourcebuf(pc),linstrt
  1765.         clr.b    pat_pend        no LF's fetched
  1766.         bsr    list_clr
  1767.         move.w    userlmode,listmode
  1768.         moveq.l    #0,d0
  1769.         move.l    d0,prgc            pc=0
  1770.         move.w    d0,idepth        no including done
  1771.         move.w    d0,no_list        listing allowed
  1772.         move.w    d0,cond_level        no conditions operative
  1773.         move.w    d0,condstrt        no conditions started
  1774.         moveq.l    #1,d0
  1775.         move.l    d0,linnum        line=1
  1776.         move.l    _CMDBuf(pc),nameptr    main filename for errhandler()
  1777.         move.b    #2,pass            pass=2
  1778.         print    <'Pass 2 - Assembling',LF>
  1779.  
  1780. pass2_loop    bsr    ck_stop
  1781.         bne    pass2_stop
  1782.         clr.l    equset        no labels set yet
  1783.         bsr    gpeek
  1784.         beq    pass2_end
  1785.         cmp.w    #-1,incstrt    check if start of a macro
  1786.         beq.s    pass2_macskip    if it is, skip this line
  1787.         bsr    ck_eol
  1788.         bcs.s    pass2_nxt
  1789.         bsr    ck_blk
  1790.         bcs.s    pass2_nolab
  1791.         bsr    slabel2
  1792.         bcs.s    pass2_nxt
  1793.         bsr    gc
  1794.         bsr    ck_eol
  1795.         bcs.s    pass2_nxt
  1796.         bsr    cg
  1797.  
  1798. pass2_nolab    bsr    seek_op
  1799.         bcs.s    pass2_next
  1800.         bsr    listout            write listing
  1801.         bcs.s    pass2_end
  1802.         add.l    d0,prgc
  1803.         add.l    d0,totalbyt        add to bytes of object
  1804.         move.l    prgc(pc),d0
  1805.         bsr    ck_lim16
  1806.         bcc    pass_pc_high
  1807.         bsr    gce            end of line?
  1808.         bcs.s    pass2_next
  1809.         error    #202
  1810.         bra.s    pass2_next
  1811. pass2_macskip    move.w    #-2,incstrt
  1812. pass2_nxt    bsr    listout
  1813. pass2_next    bsr    condition        check start of conditional assembly
  1814.         bsr    seek_nexl
  1815.         clr.b    pat_pend        no LF's fetched
  1816.         bra    pass2_loop
  1817. pass2_end    move.l    errcnt(pc),d0
  1818.         beq    pass2_noer
  1819.         print    <'Assembly incomplete...'>
  1820.         clrc
  1821.         bsr    conv_10
  1822.         printa    #buf_10
  1823.         print    <' error(s) detected.',LF>
  1824. pass2_stop    pull    all
  1825.         setc
  1826.         rts
  1827. pass2_noer    print    <'No errors detected during this assembly.',LF>
  1828.         pull    all
  1829.         clrc
  1830.         rts
  1831.  
  1832.  
  1833. seek_nexl    push    d0/a0        seek for next source line
  1834.         move.l    txtptr(pc),a0
  1835. seek_nexl1    move.b    (a0)+,d0    find next CR/LF/NULL
  1836.         beq.s    seek_nexlend
  1837.         cmp.b    #CR,d0
  1838.         beq.s    seek_nexlf
  1839.         cmp.b    #LF,d0
  1840.         bne    seek_nexl1
  1841.         bra.s    seek_nexlf
  1842. seek_nexlend    subq.l    #1,a0
  1843. seek_nexlf    move.l    a0,txtptr
  1844.         move.l    a0,linstrt
  1845.         move.w    incstrt(pc),d0    macro/include file flag
  1846.         bmi.s    seek_macro    if macro, don't increment linnum
  1847.         beq.s    seek_not_inc    start of a new include file? eq=no
  1848.         moveq.l    #0,d0
  1849.         move.w    d0,incstrt    clear flag
  1850.         move.l    d0,linnum    reset linenumber
  1851.         addq.w    #1,idepth    processing include file now
  1852. seek_not_inc    addq.l    #1,linnum    increment line number
  1853. seek_macro    pull    d0/a0
  1854.         rts
  1855.  
  1856.  
  1857. condition    move.w    cond_level(pc),d1
  1858.         lea    condflags(pc),a0 check current state: true/false
  1859.         move.b    0(a0,d1.w),d1
  1860.         bmi.s    condit_on    MI: no assembly!!
  1861.         move.w    incstrt(pc),d1
  1862.         bmi    mac_def
  1863.         rts
  1864.  
  1865. condit_on    bsr    seek_nexl    get next line
  1866.         clr.b    pat_pend    DO SOME PATENTING HERE if meant to work...
  1867.         move.l    txtptr(pc),a0
  1868.         move.b    (a0),d0
  1869.         beq    condit_end    end of program
  1870.  
  1871.         bsr    ck_eol
  1872.         bcs    condit_next    eol or comment -> next line!
  1873.  
  1874.         bsr    ck_blk        if blank, no label
  1875.         bcs.s    condit_nolbel    I SAID NO LABEL!
  1876.         move.l    txtptr(pc),a0
  1877.         bsr    getlb        skip label name
  1878.         move.l    a0,txtptr
  1879.  
  1880. condit_nolbel    bsr    gce        get char, skip blanks
  1881.         bcs.s    condit_next    if end/comment, next
  1882.         bsr    cg        one char backwards! Don't eat 'E' of ENDC
  1883.         bsr    getmn
  1884.         bsr    condit_ck_mi    check if macro/include
  1885.         cmp.l    #'ENDC',d0
  1886.         beq.s    condit_leave
  1887.         lea    PSEUDOS(pc),a0    check if new start of cond. assembly
  1888. condit_ck_ifany    move.l    (a0)+,d1    check if it is a PSEUDO
  1889.         beq.s    condit_next
  1890.         cmp.l    d0,d1
  1891.         beq.s    condit_ck_if
  1892.         addq.l    #4,a0
  1893.         bra.s    condit_ck_ifany
  1894. condit_ck_if    lsr.l    #8,d0        check if it starts with 'IF'
  1895.         cmp.l    #'IF',d0
  1896.         beq.s    condit_deeper
  1897.         lsr.l    #8,d0
  1898.         cmp.l    #'IF',d0
  1899.         bne.s    condit_next
  1900. condit_deeper    move.w    cond_level(pc),d0
  1901.         addq.w    #1,d0        one step deeper, please!
  1902.         move.w    d0,cond_level
  1903.         lea    condflags(pc),a0
  1904.         move.b    #-1,0(a0,d0.w)    condition: false!!
  1905.         bra.s    condit_next
  1906.  
  1907. condit_leave    bsr    gce        if not eol, error
  1908.         bcc.s    condit_sye
  1909.         move.w    cond_level(pc),d0
  1910.         beq.s    condit_interr    internal error, no active conditions
  1911.         subq.w    #1,d0        one step upwards
  1912.         beq.s    condit_ended    no more conditions in effect
  1913.         lea    condflags(pc),a0
  1914.         tst.b    0(a0,d0.w)
  1915.         bmi.s    condit_not_yet    still in FALSE block
  1916.  
  1917. condit_ended    move.w    d0,cond_level    turn on assembly
  1918.         bsr    listout
  1919.         rts
  1920.  
  1921. condit_not_yet    move.w    d0,cond_level    one step upwards
  1922. condit_next    bsr    listout
  1923.         bra    condit_on
  1924.  
  1925. condit_sye    error    #203        syntax error
  1926.         bra    condit_next
  1927. condit_interr    error    #512        ENDC without cond. Should never happen.
  1928.         rts
  1929. condit_end    error    #521        missing ENDC
  1930.         rts
  1931.  
  1932. mac_def        cmp.w    #-4,d1        macro definition?
  1933.         beq.s    mac_def_skip
  1934.         rts
  1935. mac_def_skip    bsr    seek_nexl
  1936.         move.l    txtptr(pc),a0
  1937.         tst.b    (a0)
  1938.         beq.s    mac_def_eop
  1939.         bsr    getlb
  1940.         move.l    a0,txtptr
  1941.         bsr    getmn
  1942.         cmp.l    #'ENDM',d0
  1943.         beq.s    mac_def_done
  1944.         bsr    listout
  1945.         addq.l    #1,linnum
  1946.         bra.s    mac_def_skip
  1947. mac_def_done    bsr    listout
  1948.         clr.w    incstrt
  1949. mac_def_eop    rts
  1950.  
  1951.  
  1952. ;------------------------------------------------------------------------
  1953.  
  1954.  
  1955. PSD1        equ    'INCL'
  1956. PSD2        equ    'I'<<24+ID<<16+'ND'
  1957. PSD3        equ    'M'<<24+ID<<16+'CD'
  1958. PSD4        equ    'M'<<24+ID<<16+'CU'
  1959. PSD5        equ    'ENDM'
  1960.  
  1961. condit_ck_mi    push    d0-d1/a0-a1        prevents internal mnemonics
  1962.         cmp.l    #PSD1,d0        and line number incrementing
  1963.         beq.s    eudo_IBEG        in macros if false condition
  1964.         cmp.l    #PSD2,d0
  1965.         beq.s    eudo_IEND
  1966.         cmp.l    #PSD3,d0
  1967.         beq.s    eudo_MACS1
  1968.         cmp.l    #PSD4,d0
  1969.         beq.s    eudo_MACS2
  1970.         cmp.l    #PSD5,d0
  1971.         beq.s    eudo_ENDM        k f p w b t y?
  1972. condit_ck_ok    pull    d0-d1/a0-a1
  1973.         rts
  1974.  
  1975. eudo_IBEG    bsr    cg
  1976.         bsr    getmn
  1977.         cmp.l    #'LUDE',d0        check the rest of the mnemonic
  1978.         bne.s    condit_ck_ok
  1979.         move.w    #1,incstrt        flag: include file starts
  1980.         bra.s    condit_ck_ok
  1981.  
  1982.  
  1983. eudo_IEND    move.w    #1,no_list        don't write this line into listfile!
  1984.         bra.s    condit_ck_ok
  1985.  
  1986.  
  1987. eudo_MACS1    move.w    #-4,incstrt        flag: macro definition starts
  1988.         move.w    #1,no_list
  1989.         bra.s    condit_ck_ok
  1990.  
  1991.  
  1992. eudo_MACS2    move.w    #-1,incstrt        flag: macro expansion starts
  1993.         move.w    #1,no_list
  1994.         bra.s    condit_ck_ok
  1995.  
  1996.  
  1997. eudo_ENDM    clr.w    incstrt            reset macro flag
  1998.         move.w    #1,no_list        if macro usage, don't list!
  1999.         bra.s    condit_ck_ok
  2000.  
  2001.  
  2002.  
  2003.  
  2004. *************************************************************************
  2005. *                                    *
  2006. * Uses this to evaluate symbol values during pass1 and to store symbols    *
  2007. * in buffer.                                *
  2008. *                                    *
  2009. *************************************************************************
  2010.  
  2011. slabel        push    all        save label in buffer
  2012.         bsr    gce        get char, check for line end
  2013.         bcs    slabel_okay    line end
  2014.         cmp.b    #'*',d0
  2015.         beq    slabel_star
  2016.  
  2017.         move.l    linstrt(pc),a0
  2018.         bsr    getlb
  2019.         bcs.s    slabel_err    illegal char
  2020.         bvs.s    slabel_err    too long name
  2021.         move.l    a0,txtptr
  2022.  
  2023.         moveq.l    #LABELSPC,d1    space needed for each symbol
  2024.         move.l    labelbuf(pc),a2    get buffer start addr
  2025.         move.l    a2,a3
  2026.         add.l    #LABELBUF-48,a3    end of buffer
  2027. slabel_seek    lea    tbuffer(pc),a1    symbol in program
  2028.         move.l    a2,a0        symbol in buffer
  2029.         tst.b    (a0)        no more labels in buffer?
  2030.         beq.s    slabel_ins    add new symbol here!
  2031.         bsr    strcmp        re-definition?
  2032.         beq.s    slabel_redef    yes, possible ermsg
  2033.         add.l    d1,a2        index to next symbol
  2034.         cmp.l    a3,a2        check if end of buffer
  2035.         blo.s    slabel_seek
  2036.         error    #301        out of symbol space
  2037. slabel_err    clr.w    sl_flag        not in slabel
  2038.         setc
  2039.         pull    all
  2040.         rts
  2041. slabel_redef    move.b    LINFO(a2),d0    get info byte
  2042.         btst    #0,d0        set by prgline? Then redefinition
  2043.         beq.s    slabel_noins    NOT allowed. Otherwise no need to insert name
  2044.         btst    #1,d0
  2045.         bne.s    slabel_noins    SET - no ermsg if redefined
  2046.  
  2047. slabel_re_err    error    #311        redefined
  2048.         bra.s    slabel_err
  2049. slabel_ins    move.l    a2,a1        copy name into buffer
  2050.         lea    tbuffer(pc),a0
  2051.         bsr    strcpy
  2052.         clr.b    LINFO(a2)    no flags set by default
  2053. slabel_noins    move.l    txtptr(pc),a5
  2054.         bsr    getmn        is it equ or set?
  2055.         bcs.s    slabel_nomnem    no mnemonic on this line
  2056.         beq.s    slabel_nomnem    no mnemonic on this line
  2057.         move.b    LINFO(a2),d2    Temporary LINFO for set/equ set here
  2058.         cmp.l    #'EQU',d0
  2059.         beq.s    slabel_iequ
  2060.         cmp.l    #'SET',d0
  2061.         beq.s    slabel_iset
  2062. slabel_nomnem    move.b    LINFO(a2),d0
  2063.         and.b    #%110,d0
  2064.         bne.s    slabel_eror1    set or equ used before -> error
  2065.         move.l    a5,txtptr
  2066.         move.l    prgc(pc),LVALUE(a2)
  2067.         bset    #0,LINFO(a2)    in prg: absolute value
  2068.         bra.s    slabel_okay    exit
  2069.  
  2070. slabel_iequ    bset    #2,d2        EQUted, temp flag because GLABEL still
  2071.         bra.s    slabel_ii     needs LINFO
  2072. slabel_iset    bset    #1,d2        SET
  2073. slabel_ii    btst    #2,LINFO(a2)
  2074.         bne.s    slabel_eror2    equ used before
  2075.         bset    #0,d2        set as ABSOLUTE for a while...
  2076.         move.w    #1,sl_flag    flag for glabel: equ or set
  2077.         bsr    calc
  2078.         bcs    slabel_err
  2079.         bsr    ck_lim16
  2080.         bcc.s    slabel_inv
  2081.         move.l    d0,LVALUE(a2)    save value!
  2082.         tst.b    zpabs
  2083.         bne.s    slabel_equset
  2084.         bclr    #0,d2        ... but reset if zp
  2085. slabel_equset    move.b    d2,LINFO(a2)    Set Real Label Info!
  2086. slabel_okay    clr.w    sl_flag        not in slabel
  2087.         pull    all
  2088.         rts
  2089.  
  2090. slabel_eror1    error    #361        illegal prg const
  2091.         bra    slabel_err
  2092. slabel_eror2    error    #351        EQU redefined
  2093.         bra    slabel_err
  2094. slabel_inv    error    #126        illegal value
  2095.         bra    slabel_err
  2096. slabel_pc_high    error    #292        pc > $ffff
  2097.         bra    slabel_err
  2098. slabel_sye    error    #204        syntax error
  2099.         bra    slabel_err
  2100. slabel_ste    error    #205        -  "  -
  2101.         bra    slabel_err
  2102. slabel_stnmn    error    #261        equ expected
  2103.         bra    slabel_err
  2104.  
  2105. slabel_star    bsr    getmn        must be 'equ'
  2106.         bcs    slabel_stnmn
  2107.         cmp.l    #'EQU',d0
  2108.         bne    slabel_ste
  2109.         move.w    #1,sl_flag    flag for glabel: equ or set
  2110.         bsr    calc
  2111.         bcs    slabel_err
  2112.         bsr    ck_lim16
  2113.         bcc    slabel_pc_high
  2114.         move.l    d0,prgc        set program counter
  2115.         bra    slabel_okay        
  2116.  
  2117.  
  2118.  
  2119. *************************************************************************
  2120. *                                    *
  2121. * Uses this to evaluate symbol values during pass2.            *
  2122. *                                    *
  2123. * Checks if non-equset values are same as during pass1.  Passes values    *
  2124. * to listing routines.                            *
  2125. *                                    *
  2126. *************************************************************************
  2127.  
  2128. slabel2        push    all        uses this during pass #2
  2129.         bsr    gce        get char, check for line end
  2130.         bcs    slabel2_okay    line end
  2131.         cmp.b    #'*',d0
  2132.         beq    slabel2_star
  2133.  
  2134.         move.l    linstrt(pc),a0
  2135.         bsr    getlb
  2136.         move.l    a0,txtptr
  2137.  
  2138.  
  2139. ; find old symbol, its value and LINFO:
  2140.  
  2141.         move.l    labelbuf(pc),a2
  2142.         moveq.l    #LABELSPC,d1    offset to next symbol
  2143. slabel2_seek    move.l    a2,a1        addr in symbol buffer
  2144.         lea    tbuffer(pc),a0    current name
  2145.         tst.b    (a1)        last label?
  2146.         beq    slabel2_nf    not found
  2147.         bsr    strcmp
  2148.         beq.s    slabel2_fnd    found
  2149.         add.l    d1,a2        get addr of next symbol in buffer
  2150.         bra.s    slabel2_seek
  2151.  
  2152. slabel2_fnd    move.b    LINFO(a2),d2    get old LINFO value for comparison
  2153.         move.l    LVALUE(a2),d3    get old LVALUE for comparison
  2154.  
  2155.         move.l    txtptr(pc),a5
  2156.         bsr    getmn        is it equ or set?
  2157.         bcs.s    slabel2_nomnem    no mnemonic on this line
  2158.         beq.s    slabel2_nomnem    no mnemonic on this line
  2159.         moveq.l    #0,d4        equset value for listing routines
  2160.         cmp.l    #'EQU',d0
  2161.         beq.s    slabel2_iequ
  2162.         cmp.l    #'SET',d0
  2163.         beq.s    slabel2_iset
  2164.  
  2165. slabel2_nomnem    move.l    a5,txtptr
  2166.         cmp.l    prgc(pc),d3    compare with old value
  2167.         bne.s    slabel2_a_mism    absolute address mismatch
  2168.         btst    #0,d2        check if absolute during pass1
  2169.         bne    slabel2_okay    if it was, then exit
  2170. slabel2_a_mism    move.w    absmism(pc),d0    print this message only once!
  2171.         bne    slabel2_err
  2172.         move.w    #1,absmism
  2173.         error    #381        abs addr mismatch
  2174.         bra.s    slabel2_err
  2175. slabel2_e_mism    error    #391        set/equ value mismatch
  2176.         bra.s    slabel2_err
  2177.  
  2178. slabel2_iequ    bset    #31,d4        needs the old value during calc()
  2179.         move.w    #1,sl_flag    flag for glabel: equ or set
  2180.         bsr    calc
  2181.         bcs.s    slabel2_err
  2182.         bsr    ck_lim16
  2183.         bcc    slabel_inv
  2184.         btst    #1,d2
  2185.         bne.s    slabel2_set_va    write pass2 value to SET symbols
  2186.         bra.s    slabel2_va_ck    check values
  2187.  
  2188. slabel2_iset    bset    #30,d4        equset may never be zero after EQU/SET
  2189.         move.w    #1,sl_flag    flag for glabel: equ or set
  2190.         bsr    calc
  2191.         bcs.s    slabel2_err
  2192.         bsr    ck_lim16
  2193.         bcc    slabel_inv
  2194. slabel2_set_va    move.l    d0,d3        use pass2 value for SET symbols
  2195.         move.l    d0,LVALUE(a2)    update SET value in pass2, too
  2196.  
  2197. slabel2_va_ck    cmp.l    d0,d3        compare pass1 and pass2 values
  2198.         bne    slabel2_e_mism     if <> -> error
  2199.         move.w    d3,d4        correct value for listing routines
  2200.         move.l    d4,equset    Pass the LVALUE and flags to lst rtns
  2201. slabel2_okay    clr.w    sl_flag        not in slabel2
  2202.         pull    all
  2203.         rts
  2204.  
  2205. slabel2_nf    error    #342        symbol not found in buffer
  2206. slabel2_err    clr.w    sl_flag        not in slabel2
  2207.         setc
  2208.         pull    all
  2209.         rts
  2210.  
  2211. slabel2_star    bsr    getmn        must be 'equ'
  2212.         move.w    #1,sl_flag    flag for glabel: equ or set
  2213.         bsr    calc
  2214.         bcs    slabel2_err
  2215.         bsr    ck_lim16
  2216.         bcc    slabel_pc_high
  2217.         move.l    d0,prgc        set program counter
  2218.         move.l    #$c0000000,d2
  2219.         move.w    d0,d2
  2220.         move.l    d2,equset
  2221.         bra    slabel2_okay
  2222.  
  2223.  
  2224.  
  2225. *************************************************************************
  2226. *                                    *
  2227. * Finds a symbol in buffer and get its value & zpabs.            *
  2228. *                                    *
  2229. *************************************************************************
  2230.  
  2231. glabel        push    d1-d2/a0-a2
  2232.         bsr    gce        is it '* + sth'?
  2233.         bcs    glabel_nam_miss    line end = error
  2234.         cmp.b    #'*',d0
  2235.         beq    glabel_star
  2236.  
  2237.         move.l    txtptr(pc),a0
  2238.         subq.l    #1,a0
  2239.         bsr    getlb
  2240.         bcs    glabel_nam_ierr    if not a legal label
  2241.         bvs    glabel_err    if name too long
  2242.         move.l    a0,txtptr
  2243.  
  2244. glabel_copied    move.l    labelbuf(pc),a2
  2245.         moveq.l    #LABELSPC,d1    offset to next symbol
  2246. glabel_seek    move.l    a2,a1        addr in symbol buffer
  2247.         lea    tbuffer(pc),a0    current name
  2248.         tst.b    (a1)        last label?
  2249.         beq.s    glabel_nf    not found
  2250.         bsr    strcmp
  2251.         beq.s    glabel_fnd    found
  2252.         add.l    d1,a2        get addr of next symbol in buffer
  2253.         bra.s    glabel_seek
  2254. glabel_nf    move.b    #1,zpabs    not zero page
  2255.         move.w    #1,lnf        label not found for ifd/ifnd
  2256.         moveq.l    #0,d0        return value zero
  2257.         move.w    sl_flag(pc),d1    if from slabel, must print error always
  2258.         bmi.s    glabel_ok    if from ifd/ifnd, never complain!
  2259.         bne.s    glabel_nf_e
  2260.         cmp.b    #1,pass        if pass#1, no error
  2261.         beq.s    glabel_ok
  2262. glabel_nf_e    error    #341        unknown symbol
  2263.         bra.s    glabel_err
  2264. glabel_fnd    move.l    LVALUE(a2),d0    get symbol value
  2265.         move.b    LINFO(a2),d1    get info
  2266.         and.b    #1,d1        only zpabs
  2267.         or.b    d1,zpabs
  2268.         cmp.b    #1,pass        if pass#1, don't increment lusage
  2269.         beq.s    glabel_ok
  2270.         addq.l    #1,LUSAGE(a2)
  2271. glabel_ok    clrc
  2272.         pull    d1-d2/a0-a2
  2273.         rts
  2274.  
  2275. glabel_nam_miss    error    #371
  2276.         bra.s    glabel_err
  2277. glabel_nam_ierr    error    #321
  2278. glabel_err    pull    d1-d2/a0-a2
  2279.         setc
  2280.         rts
  2281.  
  2282. glabel_star    move.l    prgc(pc),d0    current pc
  2283.         or.b    #1,zpabs
  2284.         bra    glabel_ok
  2285.  
  2286.  
  2287.  
  2288. *************************************************************************
  2289. *                                    *
  2290. * Print all symbol values in alphabetical order along their values.    *
  2291. * If listmode then print to listfile, too.                *
  2292. *                                    *
  2293. *************************************************************************
  2294.  
  2295. dumplabels    tst.w    symbolmode
  2296.         bne.s    dumplabels_y
  2297.         rts
  2298. dumplabels_y    push    all
  2299.         move.w    #100,prtline        change page!
  2300.         bsr    header
  2301.         printa    #DUMPL_HD
  2302. dumpl_hd    move.w    listmode(pc),d0
  2303.         beq.s    dumpl_loop
  2304.         printa    #DUMPL_HD,listfile(pc)
  2305. dumpl_loop    bsr    ck_stop            check if panic!
  2306.         bne.s    dumpl_exit
  2307.         move.l    libuf(pc),a1        write ptr
  2308.         move.l    a1,a2
  2309.         bsr    dump_one
  2310.         beq.s    dumpl_exit
  2311.         add.l    #17,a2
  2312.         bsr    fill_spc
  2313.         bsr    dump_one
  2314.         move.b    #LF,(a1)+
  2315.         clr.b    (a1)
  2316.         printa    libuf(pc)
  2317.         move.w    listmode(pc),d0
  2318.         beq.s    dumpl_nolist
  2319.         printa    libuf(pc),listfile(pc)
  2320. dumpl_nolist    bsr    header
  2321.         tst.w    prtline
  2322.         beq    dumpl_hd
  2323.         bra.s    dumpl_loop
  2324.  
  2325. dumpl_exit    pull    all
  2326.         rts
  2327.  
  2328. DUMPL_HD    dc.b    LF,'symbol_name      value type usage'
  2329.         dc.b    '           symbol_name      value type usage'
  2330.         dc.b    LF,0
  2331.         cnop    0,4
  2332.  
  2333.  
  2334. dump_one    bsr.s    next_lab        find smallest name
  2335.         beq.s    dump_onex
  2336.         move.l    a0,a3            save name ptr
  2337.         add.l    #17,a2
  2338.         bsr    strcpy            symbol name
  2339.         subq.l    #1,a1
  2340.         bsr    fill_spc
  2341.         move.l    LVALUE(a3),d0
  2342.         bsr    sign_16
  2343.         lea    buf_16+3(pc),a0
  2344.         bsr    strcpy            value
  2345.         moveq.l    #' ',d0
  2346.         move.b    d0,-1(a1)
  2347.         move.b    d0,(a1)+
  2348.         move.b    d0,(a1)+
  2349.         move.b    d0,(a1)+
  2350.         move.b    d0,(a1)+
  2351.         move.b    LINFO(a3),d0        info
  2352.         btst    #0,d0            zpabs
  2353.         bne.s    dumpo_nz
  2354.         move.b    #'z',-3(a1)        zero page
  2355. dumpo_nz    btst    #1,d0            set
  2356.         beq.s    dumpo_ns
  2357.         move.b    #'s',-1(a1)
  2358. dumpo_ns    btst    #2,d0            equ
  2359.         beq.s    dumpo_ne
  2360.         move.b    #'e',-2(a1)
  2361. dumpo_ne    add.l    #10,a2
  2362.         move.l    LUSAGE(a3),d0
  2363.         clrc
  2364.         bsr    conv_10
  2365.         lea    buf_10+6(pc),a0
  2366.         bsr    strcpy            usage
  2367.         subq.l    #1,a1
  2368.         moveq.l    #1,d0            clr z-flag
  2369. dump_onex    rts
  2370.  
  2371.  
  2372. next_lab    push    d0-d1/a1-a3
  2373.         move.l    labelbuf(pc),a2
  2374.         lea    VeryBIG(pc),a3        The biggest string in the world!
  2375.         moveq.l    #0,d1            d1 is flag: smaller found
  2376.         bra.s    next_lab1
  2377.  
  2378. next_lab_next    add.l    #LABELSPC,a2
  2379. next_lab1    move.l    a2,a0            labelbufptr
  2380.         move.l    a3,a1            smallestptr
  2381.         tst.b    (a0)
  2382.         beq.s    next_lext
  2383.         tst.b    LINFO(a0)
  2384.         bmi.s    next_lab_next
  2385.         bsr    strcmp
  2386.         tst.b    d0
  2387.         bpl.s    next_lab_next
  2388.         move.l    a2,a3            smaller found
  2389.         moveq.l    #1,d1            set flag
  2390.         bra.s    next_lab_next
  2391.  
  2392. next_lext    tst.l    d1            eq if no labels left
  2393.         beq.s    next_lexit        do NOT set LINFO of VeryBIG!!!
  2394.         move.l    a3,a0
  2395.         bset    #7,LINFO(a0)        this label used
  2396. next_lexit    tst.l    d1            eq if no labels left
  2397.         pull    d0-d1/a1-a3
  2398.         rts
  2399.  
  2400. VeryBIG        dc.w    $ffff,0
  2401.  
  2402.  
  2403. fill_spc    move.b    #' ',(a1)+
  2404.         cmp.l    a2,a1
  2405.         blo.s    fill_spc
  2406.         rts
  2407.  
  2408.  
  2409. header        tst.w    listmode
  2410.         beq.s    header_ex
  2411.         push    all
  2412.         move.w    prtline(pc),d0
  2413.         cmp.w    maxline(pc),d0
  2414.         bhi.s    header_new_pg
  2415.         addq.l    #1,d0
  2416.         move.w    d0,prtline
  2417.         pull    all
  2418. header_ex    rts
  2419. header_new_pg    move.w    prtpage(pc),d0        if first page, no FF
  2420.         beq.s    header_new
  2421.         lea    FFPAGEMSG(pc),a2
  2422. header_new_ex    addq.l    #1,d0
  2423.         move.w    d0,prtpage
  2424.         clr.w    prtline
  2425.         moveq.l    #0,d0
  2426.         move.w    prtpage(pc),d0
  2427.         clrc
  2428.         bsr    conv_10
  2429.         lea    buf_10+7(pc),a0
  2430.         lea    PAGENUM(pc),a1
  2431.         bsr    copy_10
  2432.         printa    a2,listfile(pc)
  2433.         pull    all
  2434.         rts
  2435. header_new    lea    PAGEMSG(pc),a2
  2436.         bra.s    header_new_ex
  2437.  
  2438. FFPAGEMSG    dc.b    FF
  2439. PAGEMSG        dc.b    ' 65c02 Cross Assembler '
  2440.         VERSION
  2441.         dc.b    '  (c) J. & T. Marin 1988 '
  2442. PAGENULL    dc.b    0,'                --  Page #'
  2443. PAGENUM        dc.b    '     '
  2444.         dc.b    '  --',LF,LF,0
  2445.         cnop    0,4
  2446.  
  2447.  
  2448.  
  2449. *************************************************************************
  2450. *                                    *
  2451. * Resolve mnemonic and addressing mode.  Calls PSEUDOS to handle pseudo    *
  2452. * mnemonics.                                *
  2453. *                                    *
  2454. *************************************************************************
  2455.  
  2456. seek_op        push    d1-d7/a0-a1        search for op codes
  2457.         lea    OpCodes(pc),a0        addr of table
  2458.         moveq.l    #Op_Codes-OpCodes,d2    bytes betw. mnemonics in table
  2459.         bsr    getmn
  2460.         beq    seek_end    line end gives zero bytes
  2461.         bcs    seek_op_e1
  2462.         move.l    d0,d1
  2463. seek_m_ok    move.l    (a0),d0        here d1/d0 contain current mnemonic
  2464.         beq    seek_nf        not found
  2465.         cmp.l    d1,d0
  2466.         beq.s    seek_found
  2467.         add.l    d2,a0        index to next entry in table
  2468.         bra.s    seek_m_ok    continue search
  2469. seek_found    clrx            not jmp-processing
  2470.         bsr    amode        resolve addressing mode (d0)
  2471.         bcs    seek_op_er
  2472.         move.b    4(a0,d0),d1    fetch opcode
  2473.         beq.s    seek_op_rel    if null, is it relative then? Or zp,y?
  2474.         moveq.l    #0,d2
  2475.         lea    OpLen(pc),a1
  2476.         move.b    0(a1,d0),d2    fetch byte#
  2477.         bra.s    seek_rdy
  2478.  
  2479. seek_op_rel    cmp.b    #ABS,d0        check if absolute (it could be relative)
  2480.         bne    seek_op_zpy    no, not abs/rel. Is it zp,y?
  2481.         move.b    4+REL(a0),d1    get relative opcode
  2482.         beq    seek_op_ae    if it's null, relative not available
  2483.         moveq.l    #2,d2        length is 2 bytes for rel
  2484.         cmp.b    #1,pass        don't test offset during pass#1
  2485.         beq.s    seek_rdy
  2486.         move.l    par1(pc),d3    get dest addr
  2487.         sub.l    prgc(pc),d3    substract current addr
  2488.         subq.l    #2,d3
  2489.         cmp.l    #-128,d3
  2490.         blt    seek_op_rele    offset too small
  2491.         cmp.l    #127,d3
  2492.         bgt    seek_op_rele    offset too large
  2493.         move.l    d3,par1        store actual parameter or offset
  2494. seek_rdy    moveq.l    #0,d3        calc index/bit into 65c02 check list
  2495.         move.b    d1,d3        opcode into d3
  2496.         move.l    d3,d4        and d4
  2497.         and.b    #15,d4
  2498.         eor.b    #15,d4        d4 = bit#
  2499.         lsr.b    #3,d3        d3 = index
  2500.         and.b    #%11111110,d3    address must be even
  2501.         lea    CPU(pc),a1
  2502.         move.w    0(a1,d3),d3
  2503.         btst    d4,d3
  2504.         beq.s    seek_write
  2505.         move.w    procmode(pc),d0    if CMOS mode, no error
  2506.         bne.s    seek_write
  2507.         error    #231        65c02 only
  2508. seek_write    move.l    par1(pc),d3    get possible parameter
  2509.         cmp.b    #1,pass
  2510.         beq.s    seek_done
  2511.         moveq.l    #0,d7
  2512.         move.b    d1,d7
  2513.         bsr    output        sends opcode
  2514.         cmp.b    #1,d2
  2515.         beq.s    seek_done
  2516.         move.b    d3,d7
  2517.         bsr    output        sends first param byte
  2518.         cmp.b    #2,d2
  2519.         beq.s    seek_done
  2520.         lsr.l    #8,d3
  2521.         move.b    d3,d7
  2522.         bsr    output        sends second param byte
  2523.  
  2524. seek_done    move.l    d2,d0        length
  2525.         clrc
  2526.         pull    d1-d7/a0-a1
  2527.         rts
  2528. seek_end    moveq.l    #0,d2        length zero
  2529.         bra    seek_done
  2530. seek_op_e1    error    #206        syntax error
  2531.         bra.s    seek_op_er
  2532. seek_op_e2    error    #207        syntax error
  2533.         bra.s    seek_op_er
  2534. seek_op_e3    error    #208        syntax error
  2535. seek_op_er    pull    d1-d7/a0-a1
  2536.         moveq.l    #0,d0        destination length: zero
  2537.         setc
  2538.         rts
  2539. seek_op_ae    error    #211        unknown addressing mode
  2540.         bra    seek_op_er
  2541. seek_op_zp    error    #221        zp expected
  2542.         bra    seek_op_er
  2543. seek_op_ie    error    #251        illegal addressing mode
  2544.         bra    seek_op_er
  2545. seek_op_rele    error    #241        offset too large
  2546.         bra    seek_op_er
  2547.  
  2548. seek_op_zpy    cmp.b    #ZPY,d0        if zpy, replace with abs,y
  2549.         bne    seek_op_ae
  2550.         move.b    4+ABSY(a0),d1    get abs,y opcode
  2551.         beq    seek_op_ae    if it's null, abs,y not available
  2552.         moveq.l    #3,d2        length is 3 bytes for abs,y
  2553.         bra    seek_rdy
  2554.  
  2555. seek_nf        move.l    d1,d7        preserve current mnemonic
  2556.         cmp.l    #'BRK',d1
  2557.         bne.s    seek_cJMP
  2558.         clrx            not jmp-processing
  2559.         bsr    amode
  2560.         bcs    seek_op_er
  2561.         cmp.b    #IMP,d0        BRK is always implied!
  2562.         bne    seek_op_ie
  2563.         moveq.l    #0,d1
  2564.         moveq.l    #1,d2        length
  2565.         bra    seek_write    d1 = opcode
  2566.  
  2567. seek_cJMP    cmp.l    #'JMP',d1
  2568.         bne.s    seek_cBBR
  2569.         setx            now processing a jmp instruction
  2570.         bsr    amode
  2571.         bcs    seek_op_er
  2572.         lea    OpJMP(pc),a1
  2573.         move.b    0(a1,d0),d1    fetch opcode
  2574.         beq    seek_op_ae    illegal addr mode
  2575.         moveq.l    #3,d2        length
  2576.         bra    seek_rdy
  2577.  
  2578. seek_cBBR    cmp.l    #'BBR',d1
  2579.         beq.s    seek_yBBR
  2580.         cmp.l    #'BBS',d1
  2581.         bne    seek_cRMB
  2582.         bsr    ck_ibit        check if immediate bit number
  2583.         bcc    seek_op_e2    sye
  2584.         move.l    d0,d1        bit#
  2585.         asl.b    #4,d1        into upper nybble
  2586.         or.b    #%10001111,d1    set opcode to $8f+bit
  2587.         bra.s    seek_yBBx
  2588. seek_yBBR    bsr    ck_ibit        check if immediate bit number
  2589.         bcc    seek_op_e2    sye
  2590.         move.l    d0,d1        bit#
  2591.         asl.b    #4,d1        into upper nybble
  2592.         or.b    #%00001111,d1    set opcode to $0f+bit
  2593. seek_yBBx    bsr    calc
  2594.         bcs    seek_op_er
  2595.         tst.b    zpabs        must be zero page
  2596.         bne    seek_op_zp
  2597.         move.l    d0,d3        mem loc addr into d3
  2598.         bsr    gc
  2599.         cmp.b    #',',d0
  2600.         bne    seek_op_e2
  2601.         bsr    calc        get dest addr
  2602.         bcs    seek_op_er
  2603.         moveq.l    #3,d2        length is 3 bytes for these
  2604.         cmp.b    #1,pass        don't test offset during pass#1
  2605.         beq    seek_rdy
  2606.         sub.l    prgc(pc),d0    subtract current addr
  2607.         subq.l    #3,d0
  2608.         cmp.l    #-128,d0
  2609.         blt    seek_op_rele    offset too small
  2610.         cmp.l    #127,d0
  2611.         bgt    seek_op_rele    offset too large
  2612.         asl.l    #8,d0        make space for mem loc addr
  2613.         or.b    d3,d0
  2614.         move.l    d0,par1        store actual parameter or offset
  2615.         moveq.l    #3,d2        length
  2616.         bra    seek_rdy    d1 contains opcode
  2617.  
  2618. seek_cRMB    cmp.l    #'RMB',d1
  2619.         beq.s    seek_yRMB
  2620.         cmp.l    #'SMB',d1
  2621.         bne.s    seek_PSEUDOS
  2622.         bsr    ck_ibit
  2623.         bcc    seek_op_e3    get bit#
  2624.         move.l    d0,d1
  2625.         asl.b    #4,d1        shift bit#
  2626.         or.b    #%10000111,d1    convert to opcode
  2627.         bra.s    seek_yxMB
  2628. seek_yRMB    bsr    ck_ibit
  2629.         bcc    seek_op_e3    get bit#
  2630.         move.l    d0,d1
  2631.         asl.b    #4,d1        shift bit# into right place
  2632.         or.b    #%00000111,d1    make it an opcode
  2633. seek_yxMB    bsr    calc        get addr for SMB/RMB
  2634.         bcs    seek_op_er
  2635.         tst.b    zpabs        must be on zp
  2636.         bne    seek_op_zp
  2637.         move.l    d0,par1        store it
  2638.         moveq.l    #2,d2        length
  2639.         bra    seek_rdy    d1 = opcode
  2640.  
  2641. seek_PSEUDOS    moveq.l    #0,d2        length: null
  2642.         lea    PSEUDOS(pc),a0    table
  2643. seek_PS_lp    move.l    (a0)+,d0
  2644.         beq.s    seek_PS_err
  2645.         cmp.l    d0,d1
  2646.         beq.s    seek_PS_found
  2647.         addq.l    #4,a0        skip address
  2648.         bra.s    seek_PS_lp
  2649.  
  2650. seek_PS_found    move.l    (a0),a0        get jump address
  2651.         jmp    (a0)
  2652.  
  2653. seek_PS_err    error    #271        unknown mnemonic
  2654.         setc
  2655.         bra    seek_op_er
  2656.  
  2657. PSEUDOS        dc.l    'DB',DB_main_loop
  2658.         dc.l    'DW',DW_loop
  2659.         dc.l    'DL',DL_loop
  2660.         dc.l    'MODE',MODE_loop
  2661.         dc.l    'INCL',pseudo_IBEG
  2662.  
  2663.         dc.b    'I',ID,'ND'
  2664.         dc.l    pseudo_IEND
  2665.  
  2666.         dc.l    'IFEQ',pseudo_IFEQ
  2667.         dc.l    'IFNE',pseudo_IFNE
  2668.         dc.l    'IFGT',pseudo_IFGT
  2669.         dc.l    'IFLT',pseudo_IFLT
  2670.         dc.l    'IFGE',pseudo_IFGE
  2671.         dc.l    'IFLE',pseudo_IFLE
  2672.         dc.l    'IFD',pseudo_IFD
  2673.         dc.l    'IFND',pseudo_IFND
  2674.         dc.l    'IFC',pseudo_IFC
  2675.         dc.l    'IFNC',pseudo_IFNC
  2676.         dc.l    'IFI',pseudo_IFI
  2677.         dc.l    'IFNI',pseudo_IFNI
  2678.         dc.l    'ENDC',pseudo_ENDC
  2679.         dc.l    'FAIL',pseudo_FAIL
  2680.         dc.l    'PAGE',pseudo_PAGE
  2681.  
  2682.         dc.b    'M',ID,'CD'
  2683.         dc.l    pseudo_MACS1
  2684.  
  2685.         dc.b    'M',ID,'CU'
  2686.         dc.l    pseudo_MACS2
  2687.  
  2688.         dc.l    'ENDM',pseudo_ENDM
  2689.         dc.l    0,0
  2690.  
  2691.  
  2692.  
  2693.  
  2694. DB_main_loop    bsr    gce        define 8-bit values
  2695.         bcs    DB_serr
  2696.         cmp.b    #39,d0
  2697.         bne.s    DB_nquo
  2698. DB_quotes    bsr    chr
  2699.         cmp.b    #39,d0
  2700.         beq.s    DB_double
  2701.         bsr    ck_eol
  2702.         bvs.s    DB_qerr        line end before closing '
  2703.         move.b    d0,d7
  2704.         bsr    output
  2705.         addq.l    #1,d2
  2706.         bra    DB_quotes
  2707. DB_double    move.l    txtptr(pc),a0    ''?
  2708.         cmp.b    #39,(a0)
  2709.         bne.s    DB_comma
  2710.         moveq.l    #39,d7
  2711.         bsr    output
  2712.         addq.l    #1,d2
  2713.         bsr    chr
  2714.         bra    DB_quotes
  2715. DB_nquo        bsr    cg        txtptr--
  2716.         bsr    calc
  2717.         bcs.s    DB_err        calc error
  2718.         bsr    ck_lim8
  2719.         bcc.s    DB_ierr        illegal value
  2720.         move.b    d0,d7
  2721.         bsr    output
  2722.         addq.l    #1,d2
  2723. DB_comma    bsr    gce
  2724.         bcs.s    DB_ok
  2725.         cmp.b    #',',d0
  2726.         bne.s    DB_serr        syntax
  2727.         bra    DB_main_loop
  2728. DB_ierr        error    #223
  2729.         bra.s    DB_err
  2730. DB_qerr        error    #151        quotes upset
  2731.         bra.s    DB_err
  2732. DB_serr        error    #209
  2733. DB_err        setc
  2734.         bra    seek_op_er
  2735. DB_ok0        moveq.l    #0,d2        Produce ZERO bytes of code!!!
  2736. DB_ok        bra    seek_done    normally bytecount in d2.
  2737.  
  2738.  
  2739. DW_loop        bsr    gce
  2740.         bcs    DB_serr
  2741.         bsr    cg
  2742.         bsr    calc
  2743.         bcs    DB_err
  2744.         bsr    ck_lim16
  2745.         bcc.s    DW_ierr
  2746.         move.l    d0,d7
  2747.         bsr    output
  2748.         lsr.w    #8,d7
  2749.         bsr    output
  2750.         addq.l    #2,d2
  2751.         bsr    gce
  2752.         bcs    DB_ok
  2753.         cmp.b    #',',d0
  2754.         beq    DW_loop
  2755.         bra    DB_serr
  2756. DW_ierr        error    #128
  2757.         bra    DB_err
  2758.  
  2759.  
  2760. DL_loop        bsr    gce
  2761.         bcs    DB_serr
  2762.         bsr    cg
  2763.         bsr    calc
  2764.         bcs    DB_err
  2765.         move.l    d0,d7
  2766.         bsr    output
  2767.         lsr.l    #8,d7
  2768.         bsr    output
  2769.         lsr.l    #8,d7
  2770.         bsr    output
  2771.         lsr.l    #8,d7
  2772.         bsr    output
  2773.         addq.l    #4,d2
  2774.         bsr    gce
  2775.         bcs    DB_ok
  2776.         cmp.b    #',',d0
  2777.         beq    DL_loop
  2778.         bra    DB_serr
  2779.  
  2780.  
  2781. MODE_loop    bsr    gce
  2782.         bcs    DB_ok0
  2783.         move.l    d0,d1
  2784.         lsr.l    #5,d1
  2785.         eor.b    #1,d1
  2786.         and.b    #1,d1        d1 = flag: 0=off, 1=on
  2787.         bsr    ucase
  2788.         cmp.b    #'C',d0        CMOS
  2789.         bne.s    MODE_1
  2790.         move.w    d1,procmode
  2791.         bra    MODE_loop
  2792. MODE_1        cmp.b    #'L',d0        LIST
  2793.         bne.s    MODE_2
  2794.         move.w    d1,no_list    don't write MODE l/L cmds into listfile
  2795.         beq.s    MODE_1a
  2796.         move.w    userlmode(pc),d1 get cmdline option value
  2797.         move.w    d1,listmode    turn on listing if -l option was used
  2798.         bsr    Open_list    open listfile if necessary
  2799.         bcs    seek_op_er
  2800.         bra    MODE_loop
  2801. MODE_1a        clr.w    listmode    turn off listing in any case
  2802.         bra    MODE_loop
  2803. MODE_2        cmp.b    #'S',d0        SYMBOL TABLE
  2804.         bne.s    MODE_3
  2805.         move.w    d1,symbolmode
  2806.         bra    MODE_loop
  2807. MODE_3        cmp.b    #'H',d0        HEX
  2808.         bne.s    MODE_4
  2809.         move.w    d1,hexmode
  2810.         bra    MODE_loop
  2811. MODE_4        bra    DB_serr
  2812.  
  2813.  
  2814.  
  2815. pseudo_IBEG    bsr    cg
  2816.         bsr    getmn
  2817.         cmp.l    #'LUDE',d0        check the rest of the mnemonic
  2818.         bne    seek_PS_err
  2819.         bsr    gc            skip '
  2820.         move.w    idepth(pc),d0        current nesting level
  2821.         add.w    d0,d0
  2822.         add.w    d0,d0            compute index into nameptr table
  2823.         lea    incnames(pc),a0        nameptr table
  2824.         move.l    nameptr(pc),0(a0,d0.w)    save current name
  2825.         move.l    txtptr(pc),nameptr    ptr to new name
  2826.         move.w    #1,incstrt        flag: include file starts
  2827. IBEG_skip    bsr    gce
  2828.         bcc    IBEG_skip
  2829.         bra    DB_ok0
  2830.  
  2831.  
  2832. pseudo_IEND    bsr    calc
  2833.         bcs.s    IEND_err
  2834.         move.l    d0,linnum    set linenumber for this file
  2835.         move.w    #1,no_list    don't write this line into listfile!
  2836.         move.w    idepth(pc),d0
  2837.         subq.w    #1,d0        stop processing this include file
  2838.         bpl.s    IEND_ok
  2839. IEND_err    error    #461
  2840.         bra    DB_err
  2841. IEND_ok        move.w    d0,idepth    save new depth
  2842.         add.w    d0,d0
  2843.         add.w    d0,d0
  2844.         lea    incnames(pc),a0
  2845.         move.l    0(a0,d0.w),nameptr    restore previous name
  2846.         bra    DB_ok0
  2847.  
  2848.  
  2849. pseudo_MACS1    move.w    #-4,incstrt        flag: macro definition starts
  2850.         move.w    #1,no_list
  2851.         bra    DB_ok0
  2852.  
  2853.  
  2854. pseudo_MACS2    move.w    #-1,incstrt        flag: macro expansion starts
  2855.         move.w    #1,no_list
  2856.         bra    DB_ok0
  2857.  
  2858.  
  2859. pseudo_ENDM    move.w    incstrt(pc),d0        if no macro, error!
  2860.         bpl.s    ENDM_err
  2861.         clr.w    incstrt            reset macro flag
  2862.         move.w    #1,no_list        if macro usage, don't list!
  2863.         bra    DB_ok0
  2864. ENDM_err    error    #601
  2865.         bra    DB_err
  2866.  
  2867.  
  2868. pseudo_PAGE    move.w    #HUGELINE,prtline    forced FF
  2869.         bra    DB_err
  2870.  
  2871.  
  2872. pseudo_IFEQ    move.w    cond_level(pc),d1    depth of conditions (norm. 0)
  2873.         bsr    calc
  2874.         bcs    DB_err
  2875.         tst.l    d0
  2876.         bne.s    COND_n
  2877. COND_y        addq.w    #1,d1            increase depth
  2878.         cmp.w    #CONDNESTING,d1
  2879.         bge.s    IFEQ_err        too deep
  2880.         move.w    #1,condstrt        new cond. part begins: true
  2881.  
  2882.         lea    condflags(pc),a0
  2883.         move.b    #1,0(a0,d1.w)        condition TRUE
  2884.         bra.s    IFEQ_ok
  2885.  
  2886. COND_n        addq.w    #1,d1            increase depth
  2887.         cmp.w    #CONDNESTING,d1
  2888.         bge.s    IFEQ_err        too deep
  2889.         move.w    #-1,condstrt        new cond. part begins: false
  2890.  
  2891.         lea    condflags(pc),a0    stop assembly, because
  2892.         move.b    #-1,0(a0,d1.w)        condition FALSE
  2893.  
  2894. IFEQ_ok        move.w    d1,cond_level        update depth
  2895.         bra    DB_ok0
  2896. IFEQ_err    error    #501
  2897.         bra    DB_err
  2898.  
  2899. pseudo_IFNE    move.w    cond_level(pc),d1
  2900.         bsr    calc
  2901.         bcs    DB_err
  2902.         tst.l    d0
  2903.         bne    COND_y
  2904.         bra    COND_n
  2905.  
  2906. pseudo_IFGT    move.w    cond_level(pc),d1
  2907.         bsr    calc
  2908.         bcs    DB_err
  2909.         cmp.l    #0,d0
  2910.         bgt    COND_y
  2911.         bra    COND_n
  2912.  
  2913. pseudo_IFLT    move.w    cond_level(pc),d1
  2914.         bsr    calc
  2915.         bcs    DB_err
  2916.         cmp.l    #0,d0
  2917.         blt    COND_y
  2918.         bra    COND_n
  2919.  
  2920. pseudo_IFGE    move.w    cond_level(pc),d1
  2921.         bsr    calc
  2922.         bcs    DB_err
  2923.         cmp.l    #0,d0
  2924.         bge    COND_y
  2925.         bra    COND_n
  2926.  
  2927. pseudo_IFLE    move.w    cond_level(pc),d1
  2928.         bsr    calc
  2929.         bcs    DB_err
  2930.         cmp.l    #0,d0
  2931.         ble    COND_y
  2932.         bra    COND_n
  2933.  
  2934. pseudo_IFD    move.w    cond_level(pc),d1
  2935.         clr.w    lnf
  2936.         move.w    #-1,sl_flag        prevents error msg if symbol
  2937.         bsr    glabel            not defined
  2938.         clr.w    sl_flag
  2939.         move.w    lnf(pc),d0        equ: defined
  2940.         beq    COND_y
  2941.         bra    COND_n
  2942.  
  2943. pseudo_IFND    move.w    cond_level(pc),d1
  2944.         clr.w    lnf
  2945.         move.w    #-1,sl_flag        prevents error msg if symbol
  2946.         bsr    glabel              not defined
  2947.         clr.w    sl_flag
  2948.         move.w    lnf(pc),d0        equ: defined
  2949.         bne    COND_y
  2950.         bra    COND_n
  2951.  
  2952.  
  2953. pseudo_IFC    move.w    cond_level(pc),d1
  2954.         bsr    ck_ifc            compare strings
  2955.         bcs    DB_err
  2956.         beq    COND_y
  2957.         bra    COND_n
  2958.  
  2959. pseudo_IFNC    move.w    cond_level(pc),d1
  2960.         bsr    ck_ifc            compare strings
  2961.         bcs    DB_err
  2962.         bne    COND_y
  2963.         bra    COND_n
  2964.  
  2965.  
  2966. pseudo_IFI    move.w    cond_level(pc),d1
  2967.         bsr    ck_ifi            INSTR strings (sub, main)
  2968.         bcs    DB_err
  2969.         beq    COND_y
  2970.         bra    COND_n
  2971.  
  2972. pseudo_IFNI    move.w    cond_level(pc),d1
  2973.         bsr    ck_ifi            INSTR strings
  2974.         bcs    DB_err
  2975.         bne    COND_y
  2976.         bra    COND_n
  2977.  
  2978.  
  2979. pseudo_ENDC    move.w    cond_level(pc),d0    if no cond active, error
  2980.         beq.s    ENDC_err
  2981.         subq.w    #1,d0            just decrement level
  2982.         move.w    d0,cond_level
  2983.         bra    DB_ok0
  2984. ENDC_err    error    #511            no condition
  2985.         bra    DB_err
  2986.  
  2987.  
  2988. pseudo_FAIL    error    #541            fail error
  2989.         bra    DB_err
  2990.  
  2991.  
  2992.  
  2993.  
  2994. getmode        push    d1
  2995.         moveq.l    #0,d0
  2996.         tst.w    idepth        into bit 4
  2997.         sne.b    d1
  2998.         lsr.b    #1,d1
  2999.         roxl.b    #1,d0
  3000.  
  3001.         tst.w    listmode    into bit 3
  3002.         sne.b    d1
  3003.         lsr.b    #1,d1
  3004.         roxl.b    #1,d0
  3005.  
  3006.         tst.w    symbolmode    into bit 2
  3007.         sne.b    d1
  3008.         lsr.b    #1,d1
  3009.         roxl.b    #1,d0
  3010.  
  3011.         tst.w    hexmode        into bit 1
  3012.         sne.b    d1
  3013.         lsr.b    #1,d1
  3014.         roxl.b    #1,d0
  3015.  
  3016.         tst.w    procmode    into bit 0
  3017.         sne.b    d1
  3018.         lsr.b    #1,d1
  3019.         roxl.b    #1,d0
  3020.  
  3021.         pull    d1
  3022.         rts
  3023.  
  3024.  
  3025. amode        push    d1-d4/a5
  3026.         moveq.l    #0,d4
  3027.         roxl.b    #1,d4        x->d4[0] flag: processing jmp
  3028.         move.l    txtptr(pc),a5    save txtptr
  3029.         bsr    gce        if no params, implied
  3030.         bcs    amode_imp    implied
  3031.  
  3032.         bsr    ucase
  3033.         cmp.b    #'A',d0
  3034.         bne.s    amode10
  3035.         bsr    gce        if a plain a, accum
  3036.         bcs    amode_acc    accum
  3037.  
  3038. amode10        move.l    a5,txtptr    back to start
  3039.         bsr    gc
  3040.         cmp.b    #'#',d0
  3041.         bne.s    amode11
  3042.         bsr    calc
  3043.         bcs    amodee
  3044.         move.l    d0,par1
  3045.         bsr    ck_lim8
  3046.         bcc    amodezpe
  3047.         bra    amode_imm    immediate if -129<value<256
  3048. amode11        cmp.b    #'(',d0
  3049.         bne    amode20        not indirect
  3050.         bsr    calc
  3051.         bcs.s    amodee        error?
  3052.         bsr    ck_lim16
  3053.         bcc    amodeabe
  3054.         move.l    d0,par1
  3055.         bsr    gc
  3056.         cmp.b    #')',d0
  3057.         beq.s    amode14        (ind) or (ind),y
  3058.         cmp.b    #',',d0
  3059.         bne.s    amodesye    syntax error
  3060.         bsr    gc
  3061.         bsr    ucase
  3062.         cmp.b    #'X',d0
  3063.         bne.s    amodesye
  3064.         bsr    gc
  3065.         cmp.b    #')',d0
  3066.         bne.s    amodesye
  3067.         tst.b    d4
  3068.         bne    amode_indx    if jmp (ind,x), absolute allowed
  3069.         tst.b    zpabs
  3070.         bne.s    amodezpe
  3071.         bra    amode_indx    (ind,x)
  3072.  
  3073. amode14        bsr    gce
  3074.         bcs.s    amode16        (ind) or (abs ind)
  3075.         cmp.b    #',',d0
  3076.         bne.s    amodesye
  3077.         bsr    gce
  3078.         bsr    ucase
  3079.         cmp.b    #'Y',d0
  3080.         beq.s    amode15
  3081. amodesye    error    #212        syntax terror
  3082. amodee        setc
  3083.         pull    d1-d4/a5
  3084.         rts
  3085. amodezpe    error    #222        zero page expected
  3086.         bra    amodee
  3087. amodeabe    error    #281
  3088.         bra    amodee
  3089.  
  3090. amode15        tst.b    zpabs        zero page?
  3091.         bne    amodezpe    if not, error
  3092.         bra    amode_indy    (ind),y
  3093.  
  3094. amode16        tst.b    zpabs        (ind) and (abs ind) processed here
  3095.         beq.s    amode_ind
  3096.         tst.b    d4
  3097.         bne.s    amode_ind    if jmp (ind), absolute allowed
  3098.         bra    amodezpe    otherwise must be zero page
  3099.  
  3100. amode20        move.l    a5,txtptr    not indirect or immediate, nor implied
  3101.         bsr    calc
  3102.         bcs    amodee        if calc error
  3103.         bsr    ck_lim16
  3104.         bcc    amodeabe
  3105.         move.l    d0,par1
  3106.         bsr    gce
  3107.         bcs.s    amode24        abs or zp
  3108.         cmp.b    #',',d0
  3109.         bne    amodesye
  3110.         bsr    gc
  3111.         bsr    ucase
  3112.         cmp.b    #'X',d0
  3113.         beq.s    amode26        abs,x or zp,x
  3114.  
  3115.         cmp.b    #'Y',d0
  3116.         bne    amodesye
  3117.         tst.b    zpabs
  3118.         beq.s    amode_zpy    zp,y
  3119. amode_absy    moveq.l    #ABSY,d0    abs,y
  3120.         bra.s    amodex
  3121. amode_zpy    moveq.l    #ZPY,d0
  3122.         bra.s    amodex
  3123.  
  3124. amode24        tst.b    zpabs
  3125.         beq.s    amode_zp    zp
  3126. amode_abs    moveq.l    #ABS,d0        abs
  3127.         bra.s    amodex
  3128. amode_zp    moveq.l    #ZP,d0
  3129.         bra.s    amodex
  3130.  
  3131. amode26        tst.b    zpabs
  3132.         beq.s    amode_zpx    zp,x
  3133. amode_absx    moveq.l    #ABSX,d0    abs,x
  3134.         bra.s    amodex
  3135. amode_zpx    moveq.l    #ZPX,d0
  3136.         bra.s    amodex
  3137.  
  3138. amode_ind    moveq.l    #IND,d0
  3139.         bra.s    amodex
  3140. amode_indx    moveq.l    #INDX,d0
  3141.         bra.s    amodex
  3142. amode_indy    moveq.l    #INDY,d0    
  3143.         bra.s    amodex
  3144.  
  3145. amode_imp    moveq.l    #IMP,d0
  3146.         bra.s    amodex
  3147. amode_acc    moveq.l    #ACC,d0
  3148.         bra.s    amodex
  3149. amode_imm    moveq.l    #IMM,d0
  3150.  
  3151. amodex        clrc
  3152.         pull    d1-d4/a5
  3153.         rts
  3154.  
  3155.  
  3156. getmn        push    d1        get mnemonic at (txtptr) into d0
  3157.         moveq.l    #0,d1        temp storage d1
  3158.         bsr    gce        get first char
  3159.         bcs.s    seek_mn_ok    line end causes no error
  3160.         bsr    ucase        convert to upper case
  3161.         bsr    ck_ap
  3162.         bcc.s    seek_mn_e    illegal char .c=0 if not alpha
  3163.         move.b    d0,d1
  3164.         bsr    gec        second char
  3165.         cmp.b    #ID,d0
  3166.         beq.s    getmn_id    identifier for internal reserved mns
  3167.         bsr    ucase
  3168.         bsr    ck_ap
  3169.         bcc.s    seek_mn_e
  3170. getmn_id    asl.l    #8,d1
  3171.         move.b    d0,d1
  3172.         bsr    gec        third char
  3173.         bsr    ucase
  3174.         bsr    ck_ap
  3175.         bcc.s    seek_mn_ok    mnemonic ready
  3176.         asl.l    #8,d1
  3177.         move.b    d0,d1
  3178.         bsr    gec        fourth char
  3179.         bsr    ucase
  3180.         bsr    ck_ap
  3181.         bcc.s    seek_mn_ok    mnemonic ready
  3182.         asl.l    #8,d1
  3183.         move.b    d0,d1
  3184.         bra.s    seek_mn_rdy
  3185. seek_mn_ok    bsr    cg
  3186. seek_mn_rdy    clrc
  3187.         move.l    d1,d0        result into d0
  3188.         pull    d1
  3189.         tst.l    d0
  3190.         rts
  3191. seek_mn_e    bsr    cg
  3192.         pull    d1
  3193.         setc
  3194.         rts
  3195.  
  3196.  
  3197.  
  3198. *************************************************************************
  3199. *                                    *
  3200. * Loads in the files and calculates total length.            *
  3201. *                                    *
  3202. * a0 points to filename                            *
  3203. * a1 points to sourcebuf (file is written there)            *
  3204. *    If a1=0, just checks total length of files.            *
  3205. *    Result in total_len.                        *
  3206. * d7 holds the including depth.                        *
  3207. *                                    *
  3208. *************************************************************************
  3209.  
  3210. MainLoad    push    d0-d7/a2-a6    save regs
  3211.         moveq.l    #0,d5
  3212.         move.l    d5,a5        no mem reserved
  3213.         move.l    d5,d6        no file opened
  3214.         move.l    a1,a4        writeptr
  3215.         move.l    txtptr(pc),a3    save txtptr
  3216.         move.l    a0,d1        nameptr
  3217.         move.l    a0,d3        save nameptr, use still prev. name
  3218.         move.l    #1005,d2    mode_oldfile
  3219.         lib    Dos,Open
  3220.         move.l    d0,d6        fileptr
  3221.         beq    ML_not_found
  3222.  
  3223.         move.l    d3,nameptr    set new nameptr for error()
  3224.  
  3225.         move.l    d6,d1        fileptr
  3226.         moveq.l    #0,d2        pos
  3227.         moveq.l    #1,d3        mode=end
  3228.         lib    Dos,Seek    seek for end of file
  3229.  
  3230.         move.l    d6,d1        file
  3231.         moveq.l    #0,d2        pos
  3232.         moveq.l    #-1,d3        mode=beg
  3233.         lib    Dos,Seek    seek for beginning
  3234.         move.l    d0,d5        bytes needed for buffer
  3235.         bne.s    ML_Fok
  3236.         move.l    d6,d1        if file is empty
  3237.         lib    Dos,Close
  3238.         bra    ML_exit
  3239.  
  3240. ML_Fok        add.l    d5,total_len    add to total source length
  3241.         move.l    d5,d0        allocate buffer
  3242.         addq.l    #4,d0
  3243.         move.l    #MEMF_PUBLIC,d1    no need for MEMF_CLR
  3244.         lib    Exec,AllocMem
  3245.         move.l    d0,a5        buffer addr
  3246.         tst.l    d0
  3247.         beq    ML_oom        out of memory
  3248.  
  3249.         move.l    d6,d1        fileptr
  3250.         move.l    a5,d2        buffer
  3251.         move.l    d5,d3        length
  3252.         lib    Dos,Read
  3253.         cmp.l    d0,d3
  3254.         bne    ML_read_er
  3255.         clr.b    0(a5,d0.l)    add null
  3256.  
  3257.         move.l    d6,d1        close file
  3258.         lib    Dos,Close
  3259.         moveq.l    #0,d6
  3260.  
  3261.         move.l    a5,txtptr    set txtptr to beg of buffer
  3262.         move.l    a5,linstrt
  3263.         clr.l    linnum        reset linenumber
  3264.  
  3265. ML_line        bsr    ck_stop        check if CTRL_C
  3266.         bne    ML_error     yes, exit immediately!
  3267.         move.l    txtptr(pc),a0    start addr of line into a0
  3268.         move.b    (a0),d0
  3269.         beq    ML_exit
  3270.         bsr    ck_blk
  3271.         bcc    ML_copy        if not blank, copy line
  3272.         bsr    getmn
  3273.         bcs    ML_copy        if not a mnemonic, copy line
  3274.         cmp.l    #'INCL',d0
  3275.         bne    ML_copy
  3276.         bsr    cg
  3277.         bsr    getmn
  3278.         cmp.l    #'LUDE',d0
  3279.         bne    ML_copy
  3280. ML_seek_fq    bsr    gce        seek for a '
  3281.         bcs    ML_sye
  3282.         cmp.b    #39,d0
  3283.         bne    ML_sye
  3284.         move.l    txtptr(pc),a2    a2 is a filename ptr
  3285. ML_seek_sq    bsr    gece        seek for another '
  3286.         bcs    ML_sye
  3287.         cmp.b    #39,d0
  3288.         bne    ML_seek_sq
  3289.  
  3290. ML_send        move.l    a4,d1
  3291.         beq.s    ML_no_send    just checking file length
  3292. ML_send_loop    move.b    (a0)+,d0    copy INCLUDE-line
  3293.         bsr    ck_eol
  3294.         bvs.s    ML_send_end
  3295.         move.b    d0,(a4)+
  3296.         bra    ML_send_loop
  3297. ML_send_end    move.b    #LF,(a4)+
  3298.  
  3299. ML_no_send    move.l    txtptr(pc),a0    ptr to end of filename'+1
  3300.         clr.b    -1(a0)        add null to filename in buffer
  3301.         bsr    seek_nexl    find end of line
  3302.  
  3303.         move.l    a2,a0        nameptr
  3304.         addq.l    #1,d7        increment depth
  3305.         cmp.w    #INCNESTING,d7    check depth
  3306.         bhi    ML_neste    too deep
  3307.         move.l    a4,a1        writeptr
  3308.         move.l    linnum(pc),d2    save linnum
  3309.         move.l    a2,linstrt    filename for the case it's not found
  3310.  
  3311.         bsr    MainLoad    gosub next level
  3312.         bcs    ML_error
  3313.  
  3314.         move.l    a1,a4        update writeptr
  3315.         move.l    d2,linnum    restore linenumber
  3316.         move.l    a4,d0
  3317.         beq    ML_line        if writeptr=0, do not send anything
  3318.         move.l    d2,d0
  3319.         clrc
  3320.         bsr    conv_10
  3321.         lea    buf_10+6(pc),a0    write current linenumber
  3322.         lea    ML_LINE(pc),a1
  3323.         bsr    copy_10
  3324.         lea    ML_PRUW(pc),a0
  3325.         bsr.s    ML_write    send 'PRUW linnum' (end of this include)
  3326.         bra    ML_line
  3327.  
  3328. ML_write    move.b    (a0)+,d0
  3329.         beq.s    ML_write_ex
  3330.         move.b    d0,(a4)+
  3331.         bra    ML_write
  3332. ML_write_ex    rts
  3333.  
  3334. ML_PRUW        dc.b    ' I',ID,'ND '
  3335. ML_LINE        dc.b    '      ',LF,0
  3336. ML_MACS1    dc.b    ' M',ID,'CD',LF,0    macro definition
  3337. ML_MACS2    dc.b    ' M',ID,'CU',LF,0    macro usage
  3338. ML_ENDM        dc.b    ' ENDM',LF
  3339. NULLSTR        dc.b    0,0            null string
  3340.         cnop    0,4
  3341.  
  3342. ML_copy        move.l    sourceend(pc),d1
  3343.         addq.l    #1,linnum
  3344.         move.l    a4,d2
  3345.         beq.s    ML_copy_lp
  3346.         bsr    ML_macros
  3347.         move.l    a0,txtptr
  3348.         bra    ML_line
  3349.  
  3350. ML_copy_lp    cmp.l    d1,a4
  3351.         bhs    ML_long        source too long
  3352.         move.b    (a0)+,d0
  3353.         beq    ML_exit
  3354.         bsr    ck_eol
  3355.         bvc    ML_copy_lp
  3356.         move.l    a0,txtptr
  3357.         bra    ML_line
  3358.  
  3359.  
  3360. ML_not_found    tst.l    d7        check if main level (main file)
  3361.         bne.s    ML_not_fnd1    no, include error
  3362.         error    #71        yes, main file not found
  3363.         bra.s    ML_not_f
  3364. ML_not_fnd1    error    #411        file not found
  3365.         bra.s    ML_not_f
  3366.  
  3367. ML_oom        error    #441        out of mem
  3368.         bra.s    ML_err
  3369. ML_read_er    error    #431        read error
  3370. ML_err        move.l    d6,d1        close file, too!
  3371.         lib    Dos,Close
  3372.         bra.s    ML_error
  3373.  
  3374. ML_sye        error    #401        incomplete
  3375.         bra.s    ML_error
  3376.  
  3377. ML_neste    error    #421        nesting error
  3378.         bra.s    ML_error
  3379.  
  3380. ML_long        error    #451        too long source
  3381.  
  3382. ML_error    bsr.s    ML_free
  3383. ML_not_f    move.l    a3,txtptr
  3384.         move.l    a4,a1
  3385.         pull    d0-d7/a2-a6
  3386.         subq.l    #1,d7        dec depth
  3387.         setc
  3388.         rts
  3389.  
  3390. ML_exit        bsr.s    ML_free
  3391.         move.l    a3,txtptr
  3392.         move.l    a4,a1
  3393.         pull    d0-d7/a2-a6
  3394.         subq.l    #1,d7        dec depth
  3395.         clrc
  3396.         rts
  3397.  
  3398. ML_free        move.l    a5,d0
  3399.         beq.s    ML_free_ex
  3400.         move.l    a5,a1
  3401.         move.l    d5,d0
  3402.         addq.l    #4,d0
  3403.         lib    Exec,FreeMem
  3404.         move.l    #0,a5
  3405. ML_free_ex    rts
  3406.  
  3407.  
  3408. ML_macros    push    d0-d7/a1-a3
  3409.         move.l    a0,a3        ptr to the start of line
  3410.         move.l    a0,txtptr
  3411.         move.l    a0,linstrt    line start for ermsgs
  3412.  
  3413.         bsr    getlb
  3414.         bvs    ML_nothing    too long symbol ***** - what to do?
  3415.         bcs    ML_no_lab    no label = no macro definition
  3416.         move.l    a0,txtptr
  3417.         bsr    ck_MACRO    mnemonic=MACRO?
  3418.         bcc    ML_no_def    not a macro definition
  3419.  
  3420.         bsr    ML_Redef    check if already defined
  3421.         bcs    ML_re_err
  3422.  
  3423. ML_save_macro    move.l    a0,a1        ptr to free storage
  3424.         lea    tbuffer(pc),a0    name
  3425.         bsr    strcpy        save name
  3426.         bsr    seek_nexl    get next line
  3427.  
  3428. ML_save_body    move.l    txtptr(pc),a0
  3429.         bsr    getlb        skip possible label
  3430.         move.l    a0,txtptr
  3431.         bsr    ck_MACRO
  3432.         bcs    ML_within    definition within definition
  3433.         bsr    getmn
  3434.         cmp.l    #'ENDM',d0
  3435.         beq.s    ML_body_saved
  3436.         move.l    linstrt(pc),a0
  3437. ML_copy_body    move.b    (a0)+,d0
  3438.         beq    ML_no_ENDM    ENDM missing
  3439.         move.b    d0,(a1)+
  3440.         bsr    ck_eol        copy until eol
  3441.         bvc    ML_copy_body
  3442.         addq.l    #1,linnum
  3443.         bsr    seek_nexl
  3444.         bra    ML_save_body
  3445.  
  3446. ML_body_saved    clr.b    (a1)+        add null = end of macro
  3447.         bsr    seek_nexl
  3448.         lea    ML_MACS1(pc),a0    mnem: macro definition
  3449.         bsr    ML_write
  3450.         move.l    txtptr(pc),a2
  3451.         move.l    a3,a1        start of a macro
  3452. ML_write_mac    move.b    (a1)+,(a4)+    copy into source buffer
  3453.         cmpa.l    a2,a1        all done?
  3454.         blo    ML_write_mac
  3455.         move.l    a2,a0
  3456.         pull    d0-d7/a1-a3
  3457.         clrc
  3458.         rts
  3459.  
  3460. ML_no_lab    bsr    ck_MACRO    if MACRO without name, error
  3461.         bcs    ML_no_name
  3462. ML_no_def    move.l    txtptr(pc),a0    get addr of mnemonic
  3463. ML_get_mnem    move.b    (a0)+,d0    skip until mnemonic starts
  3464.         bsr    ck_blk
  3465.         bcs    ML_get_mnem
  3466.  
  3467.         subq.l    #1,a0        starting position
  3468.         bsr    getlb        copies macro/mnem into tbuffer
  3469.         movea.l    a0,a2        start of parameters
  3470.         bcs.s    ML_nothing    ******* what to do?
  3471.         bsr    ML_Redef    check if macro defined
  3472.         bcc.s    ML_nothing    if not defined, it may be normal opcode
  3473.  
  3474.         move.l    a0,a1
  3475.         lea    ML_MACS2(pc),a0    mnem: macro usage
  3476.         bsr    ML_write
  3477.  
  3478.         move.l    a3,a0        start of macro usage line
  3479. ML_usage_cpy    move.b    (a0)+,d0
  3480.         move.b    d0,(a4)+
  3481.         bsr    ck_eol
  3482.         bvc    ML_usage_cpy
  3483.  
  3484. ML_us_copied    lea    NULLSTR(pc),a0
  3485.         move.l    a0,d0        reset parameter ptrs
  3486.         move.l    a0,d1
  3487.         move.l    a0,d2
  3488.         move.l    a0,d3
  3489.         move.l    a2,a0
  3490.         bsr    ML_blk
  3491.         move.l    a0,d0
  3492.         bsr    ML_nx_pr    search for next parameter
  3493.         bcs.s    ML_us_pok
  3494.         move.l    a0,d1
  3495.         bsr    ML_nx_pr    search for next parameter
  3496.         bcs.s    ML_us_pok
  3497.         move.l    a0,d2
  3498.         bsr    ML_nx_pr    search for next parameter
  3499.         bcs.s    ML_us_pok
  3500.         move.l    a0,d3
  3501.  
  3502. ML_us_pok    move.l    a1,a0
  3503.  
  3504. ML_expand    bsr    McExpand    expand!
  3505.  
  3506.         lea    ML_ENDM(pc),a0
  3507.         bsr    ML_write
  3508.  
  3509.         bsr    seek_nexl
  3510.         move.l    txtptr(pc),a0
  3511.         pull    d0-d7/a1-a3
  3512.         clrc
  3513.         rts
  3514.  
  3515. ML_nothing    move.b    (a3)+,d0    copy normal lines normally
  3516.         beq.s    ML_nothnull
  3517.         move.b    d0,(a4)+
  3518.         bsr    ck_eol
  3519.         bvc    ML_nothing
  3520.         bra.s    ML_noth_done
  3521. ML_nothnull    subq.l    #1,a3        don't eat nulls!
  3522. ML_noth_done    move.l    a3,a0
  3523.         pull    d0-d7/a1-a3
  3524.         clrc
  3525.         rts
  3526.  
  3527.  
  3528. ML_within    error    #621
  3529.         bra.s    ML_mac_err
  3530. ML_no_name    error    #631
  3531.         bra.s    ML_mac_err
  3532. ML_no_ENDM    error    #641
  3533.         bra.s    ML_mac_err
  3534. ML_re_err    error    #611        redefined
  3535. ML_mac_err    bsr    seek_nexl
  3536.         move.l    txtptr(pc),a0
  3537.         pull    d0-d7/a1-a3
  3538.         setc
  3539.         rts
  3540.  
  3541.  
  3542. ML_nx_pr    push    d0-d3
  3543. ML_nx_lp1    move.b    (a0)+,d0    skip current parameter
  3544.         beq.s    ML_nx_eol
  3545.         bsr    ck_eol
  3546.         bcs.s    ML_nx_eol
  3547.         cmp.b    #'<',d0
  3548.         beq.s    ML_nx_enc    many values as a single parameter
  3549.         cmp.b    #39,d0
  3550.         beq.s    ML_nx_enc
  3551.         cmp.b    #',',d0        comma as a separator
  3552.         bne    ML_nx_lp1
  3553. ML_nx_blk    move.b    (a0)+,d0
  3554.         beq.s    ML_nx_sye
  3555.         bsr    ck_eol
  3556.         bcs.s    ML_nx_sye
  3557.         bsr    ck_blk
  3558.         bcs    ML_nx_blk
  3559.         subq.l    #1,a0
  3560.         pull    d0-d3
  3561.         clrv
  3562.         rts
  3563.  
  3564. ML_nx_enc    move.b    d0,d1
  3565.         cmp.b    #'<',d0
  3566.         bne.s    ML_nx_lp2
  3567.         moveq.l    #'>',d1
  3568. ML_nx_lp2    move.b    (a0)+,d0
  3569.         beq.s    ML_nx_sye_a
  3570.         bsr    ck_eol
  3571.         bcs.s    ML_nx_sye_a
  3572.         cmp.b    d1,d0
  3573.         bne    ML_nx_lp2
  3574.         bra    ML_nx_lp1
  3575.  
  3576. ML_nx_sye    error    #651        param error
  3577. ML_nx_sye_a    subq.l    #1,a0
  3578.         pull    d0-d3
  3579.         setc
  3580.         setv            V=1: error
  3581.         rts
  3582.  
  3583. ML_nx_eol    subq.l    #1,a0
  3584.         pull    d0-d3
  3585.         setc
  3586.         clrv
  3587.         rts
  3588.  
  3589. ML_blk        push    d0
  3590. ML_blk_lp    move.b    (a0)+,d0
  3591.         bsr    ck_blk
  3592.         bcs    ML_blk_lp
  3593.         subq.l    #1,a0
  3594.         pull    d0
  3595.         rts
  3596.  
  3597.  
  3598. McExpand    push    d4-d7/a1-a3
  3599.         link    a5,#-16
  3600.         move.l    d3,-4(a5)
  3601.         move.l    d2,-8(a5)
  3602.         move.l    d1,-12(a5)
  3603.         move.l    d0,-16(a5)
  3604.         addq.l    #1,McExpCnt    add 1 to \@nnn cntr
  3605. McExMLp        move.l    a0,a3        startptr
  3606.         move.b    (a0),d0
  3607.         beq    McExEop
  3608.         bsr    ck_blk
  3609.         bcs.s    McEx_nolb
  3610.         bsr    McExpLab    expand a label
  3611.  
  3612. McEx_nolb    move.l    a4,a2        save write ptr
  3613. McEx_sk1    move.b    (a0)+,d0    copy blanks after label
  3614.         move.b    d0,(a4)+
  3615.         bsr    ck_blk
  3616.         bcs    McEx_sk1
  3617.         subq.l    #1,a0
  3618.         subq.l    #1,a4
  3619.         move.l    a0,a3        processed this far
  3620.         bsr    getlb        get mnemonic/macro name
  3621.         movea.l    a0,a1        save start of parameters
  3622.         bcs    McExNoMac    no mnemonic/macro
  3623.  
  3624.         bsr    ML_Redef    is it a macro?
  3625.         bcc    McExNoMac    no, branch.
  3626.  
  3627.         move.l    a2,a4        remove blanks if mac(mac)
  3628.         clr.b    (a4)        null for safety
  3629.  
  3630.         push    a0        save macro start addr in buffer
  3631.  
  3632.         push    a4        save output pointer
  3633.         move.l    obuf(pc),a4    buffer for parameters
  3634.         moveq.l    #0,d0
  3635.         move.w    McNesting(pc),d0
  3636.         asl.l    #8,d0
  3637.         add.l    d0,a4
  3638.         move.l    a4,a2        start of string in obuf
  3639.         move.l    a1,a0        start of parameters
  3640.         bsr    McCopy        expand parameters into obuf!
  3641.  
  3642.         pull    a4        restore output pointer
  3643.  
  3644.         lea    NULLSTR(pc),a0
  3645.         move.l    a0,d0        reset parameter ptrs
  3646.         move.l    a0,d1
  3647.         move.l    a0,d2
  3648.         move.l    a0,d3
  3649.         move.l    a2,a0        get param string address
  3650.         bsr    ML_blk
  3651.         move.l    a0,d0
  3652.         bsr    ML_nx_pr    search for next parameter
  3653.         bcs.s    ML_mac_pok
  3654.         move.l    a0,d1
  3655.         bsr    ML_nx_pr    search for next parameter
  3656.         bcs.s    ML_mac_pok
  3657.         move.l    a0,d2
  3658.         bsr    ML_nx_pr    search for next parameter
  3659.         bcs.s    ML_mac_pok
  3660.         move.l    a0,d3
  3661.  
  3662. ML_mac_pok    pull    a0        a0 points to a new macro in buffer
  3663.  
  3664.         addq.w    #1,McNesting
  3665.         cmp.w    #MCNESTING,McNesting
  3666.         bls.s    McExNestOk
  3667.         error    #661        macro nesting too deep
  3668.         bra.s    McEx_Xpanded
  3669. McExNestOk    bsr    McExpand
  3670. McEx_Xpanded    subq.w    #1,McNesting
  3671. McEx_sk2    move.b    (a3)+,d0    skip until end of line
  3672.         bsr    ck_eol
  3673.         bvc    McEx_sk2
  3674.         move.l    a3,a0
  3675.         tst.b    d0
  3676.         bne    McExMLp
  3677.         bra.s    McExEop
  3678.  
  3679. *
  3680. * handles a macro in macro -situation
  3681. *
  3682.  
  3683. McExNoMac    move.l    a3,a0
  3684.         bsr.s    McCopy
  3685.         tst.b    (a0)
  3686.         bne    McExMLp
  3687. McExEop        unlk    a5
  3688.         pull    d4-d7/a1-a3
  3689.         rts
  3690.  
  3691.  
  3692. McCopy        push    a1
  3693. McCopylp    move.b    (a0)+,d0
  3694.         beq.s    McCopy_eop
  3695.         cmp.b    #'\',d0
  3696.         beq.s    McCopy_par
  3697. McCopyw        move.b    d0,(a4)+
  3698.         bsr    ck_eol
  3699.         bcc    McCopylp
  3700.         bra.s    McCopy_e
  3701. McCopy_par    move.b    (a0),d0
  3702.  
  3703.         bsr.s    McExpander
  3704.         bra    McCopylp
  3705.  
  3706. McCopy_np    moveq.l    #'\',d0        write as it is
  3707.         bra    McCopyw
  3708.  
  3709. McCopy_eop    subq.l    #1,a0        don't eat nulls!
  3710. McCopy_e    pull    a1/a1
  3711.         rts
  3712.  
  3713.  
  3714. McExpander    cmp.b    #'@',d0
  3715.         beq    McExTail
  3716.         bsr    ck_dig
  3717.         bcc    McExp_np
  3718.         cmp.b    #'4',d0
  3719.         bhi    McExp_np
  3720.         addq.l    #1,a0        skip param number
  3721.         and.w    #15,d0
  3722.         add.w    d0,d0
  3723.         add.w    d0,d0
  3724.         move.l    -20(a5,d0.w),a1    get right param ptr here!!!!!
  3725.  
  3726. McExp_par_cpy    move.b    (a1)+,d0
  3727.         bsr    ck_eol
  3728.         bcs    McExpOk        end of param
  3729.         bsr    ck_blk
  3730.         bcs    McExpOk        end of param
  3731.         cmp.b    #',',d0
  3732.         beq    McExpOk        end of param
  3733.         cmp.b    #'<',d0
  3734.         beq.s    McExpBigPar    parameter enclosed in <>
  3735.         cmp.b    #39,d0
  3736.         beq.s    McExpQuote    string parameter within quotes
  3737.         move.b    d0,(a4)+    copy a char
  3738.         bra    McExp_par_cpy
  3739.  
  3740. McExpBigPar    move.b    (a1)+,d0
  3741.         bsr    ck_eol
  3742.         bvs.s    McExpBigEr    no line end allowed within <>
  3743.         cmp.b    #'>',d0
  3744.         beq.s    McExpOk        > ends this parameter
  3745.         cmp.b    #'<',d0
  3746.         beq.s    McExpBigNes    no <> nesting allowed!
  3747.         move.b    d0,(a4)+
  3748.         bra    McExpBigPar
  3749. McExpBigEr    error    #652
  3750.         bra.s    McExpOk
  3751. McExpBigNes    error    #671
  3752.         bra.s    McExpOk
  3753. McExpQuoterr    error    #681        missing quote
  3754.         bra.s    McExpOk
  3755.  
  3756.  
  3757. McExpQuote    move.b    d0,(a4)+    write opening quote
  3758. McExpQuotel    move.b    (a1)+,d0    blanks also allowed within ''
  3759.         bsr    ck_eol
  3760.         bvs    McExpQuoterr    no line end allowed within ''
  3761.         move.b    d0,(a4)+
  3762.         cmp.b    #39,d0        ' ends this parameter
  3763.         bne    McExpQuotel
  3764.         bra.s    McExpOk
  3765.  
  3766. McExTail    addq.l    #1,a0        skip @
  3767.         move.l    McExpCnt(pc),d0
  3768.         setc            zeroes needed, too!
  3769.         bsr    conv_10
  3770.         move.b    buf_10+8(pc),(a4)+
  3771.         move.b    buf_10+9(pc),(a4)+
  3772.         move.b    buf_10+10(pc),(a4)+
  3773.         move.b    buf_10+11(pc),(a4)+
  3774.         bra.s    McExpOk
  3775.  
  3776. McExp_np    move.b    #'\',(a4)+
  3777.         move.b    d0,(a4)+
  3778.         addq.l    #1,a0
  3779. McExpOk        rts
  3780.  
  3781.  
  3782.  
  3783. McExpLab    push    d0        expand a label with possible \@
  3784. McExpLabLp    move.b    (a0)+,d0
  3785.         cmp.b    #'\',d0
  3786.         beq.s    McExpLab_cka    test for @
  3787.         bsr    ck_lc
  3788.         bcc.s    McExpLab_e    end
  3789. McExpLab_cont    move.b    d0,(a4)+    copy a char
  3790.         bra    McExpLabLp
  3791. McExpLab_cka    move.b    (a0),d0
  3792.         bsr    McExpander
  3793.         bra    McExpLabLp
  3794.  
  3795. McExpLab_e    move.b    d0,(a4)+    don't eat this!
  3796.         pull    d0
  3797.         rts
  3798.  
  3799.  
  3800. ML_Redef    push    a1-a2        check if macro defined
  3801.         move.l    labelbuf(pc),a2
  3802. ML_R_search    lea    tbuffer(pc),a0    current name
  3803.         move.l    a2,a1        ptr into macrobuffer
  3804.         tst.b    (a1)
  3805.         beq.s    ML_R_notfound    name not found
  3806.         bsr    strcmp
  3807.         beq.s    ML_R_found
  3808.         moveq.l    #1,d0
  3809. ML_R_skip    tst.b    (a2)+        skip current name+macro in buffer
  3810.         bne    ML_R_skip
  3811.         dbf    d0,ML_R_skip
  3812.         bra    ML_R_search
  3813. ML_R_found    move.l    a1,a0        ptr to macro
  3814.         pull    a1-a2
  3815.         setc
  3816.         rts
  3817. ML_R_notfound    move.l    a1,a0        ptr to free macro space
  3818.         pull    a1-a2
  3819.         clrc
  3820.         rts
  3821.  
  3822.  
  3823. ck_MACRO    push    a5
  3824.         move.l    txtptr(pc),a5
  3825.         bsr    getmn        get mnemonic
  3826.         bcs.s    ck_MAC_n
  3827.         cmp.l    #'MACR',d0
  3828.         bne.s    ck_MAC_n    not 'MACRO'
  3829.         bsr    cg
  3830.         bsr    getmn
  3831.         cmp.l    #'RO',d0
  3832.         beq.s    ck_MAC_y    it is 'MACRO'
  3833.  
  3834. ck_MAC_n    move.l    a5,txtptr
  3835.         pull    a5
  3836.         clrc
  3837.         rts
  3838. ck_MAC_y    pull    a5
  3839.         setc
  3840.         rts
  3841.  
  3842.  
  3843. Clr_LBuf    move.l    labelbuf(pc),a0        fill labelbuf with nulls
  3844.         move.l    #LABELBUF,d0
  3845.         moveq.l    #0,d1
  3846. Clr_LBufLoop    move.b    d1,(a0)+
  3847.         subq.l    #1,d0
  3848.         bne    Clr_LBufLoop
  3849.         rts
  3850.  
  3851.  
  3852. getlb        push    d0-d1/a1    get label at a0
  3853.         move.b    (a0)+,d0    get a symbol name into tbuffer
  3854.         bsr    ck_lc        legal char for a label?
  3855.         bcc.s    getlb_ill    if not alphanumeric
  3856.         bvs.s    getlb_ill    if first char is numeric
  3857.         lea    tbuffer(pc),a1
  3858.         move.b    d0,(a1)+    save first char
  3859.         moveq.l    #LABELLEN-1,d1
  3860. getlb_cpy    move.b    (a0)+,d0    one char
  3861.         bsr    ck_lc        suitable for labels?
  3862.         bcc.s    getlb_copied
  3863.         move.b    d0,(a1)+
  3864.         dbf    d1,getlb_cpy
  3865.         error    #331        name too long
  3866.         bra.s    getlb_err
  3867. getlb_copied    clr.b    (a1)        add null
  3868.         subq.l    #1,a0        restore pointer at first char after label
  3869.         pull    d0-d1/a1
  3870.         clrc
  3871.         clrv
  3872.         rts
  3873.  
  3874. getlb_ill    subq.l    #1,a0        restore pointer at beginning
  3875.         pull    d0-d1/a1
  3876.         setc
  3877.         rts
  3878. getlb_err    pull    d0-d1/a1
  3879.         setv
  3880.         clrc
  3881.         rts
  3882.  
  3883.  
  3884.  
  3885.  
  3886.  
  3887.  
  3888.  
  3889.  
  3890.  
  3891. *****************************************************************
  3892. *                                *
  3893. *             MNEMONICS AND OPCODES            *
  3894. *             =====================            *
  3895. *                                *
  3896. * OpLen - Contains byte# for each addressing mode        *
  3897. *                                *
  3898. *                                *
  3899. * OpCodes - Table format:                    *
  3900. * mnemonic                            *
  3901. * imm; abs; zp; accum; implied; (ind,x); (ind),y; zpx        *
  3902. * absx; absy; rel; (ind); zp,y; (aind);                *
  3903. *                                *
  3904. *****************************************************************
  3905.  
  3906. OpLen        dc.b    2,3,2,1,1,2,2,2,3,3,2,2,2,0,0,0
  3907. OpJMP        dc.b    $00,$4c,$4c,$00,$00,$7c,$00,$00
  3908.         dc.b    $00,$00,$00,$6c,$00,$00
  3909.  
  3910. OpCodes        dc.l    'LDA'
  3911.         dc.b    $a9,$ad,$a5,$00,$00,$a1,$b1,$b5
  3912.         dc.b    $bd,$b9,$00,$b2,$00,$00
  3913.  
  3914. Op_Codes    dc.l    'STA'
  3915.         dc.b    $00,$8d,$85,$00,$00,$81,$91,$95
  3916.         dc.b    $9d,$99,$00,$92,$00,$00
  3917.  
  3918.         dc.l    'JSR'
  3919.         dc.b    $00,$20,$00,$00,$00,$00,$00,$00
  3920.         dc.b    $00,$00,$00,$00,$00,$00
  3921.  
  3922.         dc.l    'BRA'
  3923.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  3924.         dc.b    $00,$00,$80,$00,$00,$00
  3925.  
  3926.         dc.l    'CMP'
  3927.         dc.b    $c9,$cd,$c5,$00,$00,$c1,$d1,$d5
  3928.         dc.b    $dd,$d9,$00,$d2,$00,$00
  3929.  
  3930.         dc.l    'BNE'
  3931.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  3932.         dc.b    $00,$00,$d0,$00,$00,$00
  3933.  
  3934.         dc.l    'BEQ'
  3935.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  3936.         dc.b    $00,$00,$f0,$00,$00,$00
  3937.  
  3938.         dc.l    'LDX'
  3939.         dc.b    $a2,$ae,$a6,$00,$00,$00,$00,$00
  3940.         dc.b    $00,$be,$00,$00,$b6,$00
  3941.  
  3942.         dc.l    'RTS'
  3943.         dc.b    $00,$00,$00,$00,$60,$00,$00,$00
  3944.         dc.b    $00,$00,$00,$00,$00,$00
  3945.  
  3946.         dc.l    'LDY'
  3947.         dc.b    $a0,$ac,$a4,$00,$00,$00,$00,$b4
  3948.         dc.b    $bc,$00,$00,$00,$00,$00
  3949.  
  3950.         dc.l    'INY'
  3951.         dc.b    $00,$00,$00,$00,$c8,$00,$00,$00
  3952.         dc.b    $00,$00,$00,$00,$00,$00
  3953.  
  3954.         dc.l    'STX'
  3955.         dc.b    $00,$8e,$86,$00,$00,$00,$00,$00
  3956.         dc.b    $00,$00,$00,$00,$96,$00
  3957.  
  3958.         dc.l    'BCC'
  3959.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  3960.         dc.b    $00,$00,$90,$00,$00,$00
  3961.  
  3962.         dc.l    'BCS'
  3963.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  3964.         dc.b    $00,$00,$b0,$00,$00,$00
  3965.  
  3966.         dc.l    'STY'
  3967.         dc.b    $00,$8c,$84,$00,$00,$00,$00,$94
  3968.         dc.b    $00,$00,$00,$00,$00,$00
  3969.  
  3970.         dc.l    'STZ'
  3971.         dc.b    $00,$9c,$64,$00,$00,$00,$00,$74
  3972.         dc.b    $9e,$00,$00,$00,$00,$00
  3973.  
  3974.         dc.l    'INX'
  3975.         dc.b    $00,$00,$00,$00,$e8,$00,$00,$00
  3976.         dc.b    $00,$00,$00,$00,$00,$00
  3977.  
  3978.         dc.l    'PHA'
  3979.         dc.b    $00,$00,$00,$00,$48,$00,$00,$00
  3980.         dc.b    $00,$00,$00,$00,$00,$00
  3981.  
  3982.         dc.l    'PHX'
  3983.         dc.b    $00,$00,$00,$00,$da,$00,$00,$00
  3984.         dc.b    $00,$00,$00,$00,$00,$00
  3985.  
  3986.         dc.l    'PHY'
  3987.         dc.b    $00,$00,$00,$00,$5a,$00,$00,$00
  3988.         dc.b    $00,$00,$00,$00,$00,$00
  3989.  
  3990.         dc.l    'ADC'
  3991.         dc.b    $69,$6d,$65,$00,$00,$61,$71,$75
  3992.         dc.b    $7d,$79,$00,$72,$00,$00
  3993.  
  3994.         dc.l    'PLA'
  3995.         dc.b    $00,$00,$00,$00,$68,$00,$00,$00
  3996.         dc.b    $00,$00,$00,$00,$00,$00
  3997.  
  3998.         dc.l    'PLX'
  3999.         dc.b    $00,$00,$00,$00,$fa,$00,$00,$00
  4000.         dc.b    $00,$00,$00,$00,$00,$00
  4001.  
  4002.         dc.l    'PLY'
  4003.         dc.b    $00,$00,$00,$00,$7a,$00,$00,$00
  4004.         dc.b    $00,$00,$00,$00,$00,$00
  4005.  
  4006.         dc.l    'INC'
  4007.         dc.b    $00,$ee,$e6,$1a,$1a,$00,$00,$f6
  4008.         dc.b    $fe,$00,$00,$00,$00,$00
  4009.  
  4010.         dc.l    'SEC'
  4011.         dc.b    $00,$00,$00,$00,$38,$00,$00,$00
  4012.         dc.b    $00,$00,$00,$00,$00,$00
  4013.  
  4014.         dc.l    'CLC'
  4015.         dc.b    $00,$00,$00,$00,$18,$00,$00,$00
  4016.         dc.b    $00,$00,$00,$00,$00,$00
  4017.  
  4018.         dc.l    'SBC'
  4019.         dc.b    $e9,$ed,$e5,$00,$00,$e1,$f1,$f5
  4020.         dc.b    $fd,$f9,$00,$f2,$00,$00
  4021.  
  4022.         dc.l    'ORA'
  4023.         dc.b    $09,$0d,$05,$00,$00,$01,$11,$15
  4024.         dc.b    $1d,$19,$00,$12,$00,$00
  4025.  
  4026.         dc.l    'AND'
  4027.         dc.b    $29,$2d,$25,$00,$00,$21,$31,$35
  4028.         dc.b    $3d,$39,$00,$32,$00,$00
  4029.  
  4030.         dc.l    'BMI'
  4031.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  4032.         dc.b    $00,$00,$30,$00,$00,$00
  4033.  
  4034.         dc.l    'TAX'
  4035.         dc.b    $00,$00,$00,$00,$aa,$00,$00,$00
  4036.         dc.b    $00,$00,$00,$00,$00,$00
  4037.  
  4038.         dc.l    'CPX'
  4039.         dc.b    $e0,$ec,$e4,$00,$00,$00,$00,$00
  4040.         dc.b    $00,$00,$00,$00,$00,$00
  4041.  
  4042.         dc.l    'DEX'
  4043.         dc.b    $00,$00,$00,$00,$ca,$00,$00,$00
  4044.         dc.b    $00,$00,$00,$00,$00,$00
  4045.  
  4046.         dc.l    'ASL'
  4047.         dc.b    $00,$0e,$06,$0a,$0a,$00,$00,$16
  4048.         dc.b    $1e,$00,$00,$00,$00,$00
  4049.  
  4050.         dc.l    'LSR'
  4051.         dc.b    $00,$4e,$46,$4a,$4a,$00,$00,$46
  4052.         dc.b    $4e,$00,$00,$00,$00,$00
  4053.  
  4054.         dc.l    'TXA'
  4055.         dc.b    $00,$00,$00,$00,$8a,$00,$00,$00
  4056.         dc.b    $00,$00,$00,$00,$00,$00
  4057.  
  4058.         dc.l    'CPY'
  4059.         dc.b    $c0,$cc,$c4,$00,$00,$00,$00,$00
  4060.         dc.b    $00,$00,$00,$00,$00,$00
  4061.  
  4062.         dc.l    'BPL'
  4063.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  4064.         dc.b    $00,$00,$10,$00,$00,$00
  4065.  
  4066.         dc.l    'TAY'
  4067.         dc.b    $00,$00,$00,$00,$a8,$00,$00,$00
  4068.         dc.b    $00,$00,$00,$00,$00,$00
  4069.  
  4070.         dc.l    'BIT'
  4071.         dc.b    $89,$2c,$24,$00,$00,$00,$00,$34
  4072.         dc.b    $3c,$00,$00,$00,$00,$00
  4073.  
  4074.         dc.l    'ROL'
  4075.         dc.b    $00,$2e,$26,$2a,$2a,$00,$00,$36
  4076.         dc.b    $3e,$00,$00,$00,$00,$00
  4077.  
  4078.         dc.l    'DEY'
  4079.         dc.b    $00,$00,$00,$00,$88,$00,$00,$00
  4080.         dc.b    $00,$00,$00,$00,$00,$00
  4081.  
  4082.         dc.l    'PHP'
  4083.         dc.b    $00,$00,$00,$00,$08,$00,$00,$00
  4084.         dc.b    $00,$00,$00,$00,$00,$00
  4085.  
  4086.         dc.l    'TRB'
  4087.         dc.b    $00,$1c,$14,$00,$00,$00,$00,$00
  4088.         dc.b    $00,$00,$00,$00,$00,$00
  4089.  
  4090.         dc.l    'TSB'
  4091.         dc.b    $00,$0c,$04,$00,$00,$00,$00,$00
  4092.         dc.b    $00,$00,$00,$00,$00,$00
  4093.  
  4094.         dc.l    'DEC'
  4095.         dc.b    $00,$ce,$c6,$3a,$3a,$00,$00,$d6
  4096.         dc.b    $de,$00,$00,$00,$00,$00
  4097.  
  4098.         dc.l    'TYA'
  4099.         dc.b    $00,$00,$00,$00,$98,$00,$00,$00
  4100.         dc.b    $00,$00,$00,$00,$00,$00
  4101.  
  4102.         dc.l    'PLP'
  4103.         dc.b    $00,$00,$00,$00,$28,$00,$00,$00
  4104.         dc.b    $00,$00,$00,$00,$00,$00
  4105.  
  4106.         dc.l    'EOR'
  4107.         dc.b    $49,$4d,$45,$00,$00,$41,$51,$55
  4108.         dc.b    $5d,$59,$00,$52,$00,$00
  4109.  
  4110.         dc.l    'NOP'
  4111.         dc.b    $00,$00,$00,$00,$ea,$00,$00,$00
  4112.         dc.b    $00,$00,$00,$00,$00,$00
  4113.  
  4114.         dc.l    'TXS'
  4115.         dc.b    $00,$00,$00,$00,$9a,$00,$00,$00
  4116.         dc.b    $00,$00,$00,$00,$00,$00
  4117.  
  4118.         dc.l    'SEI'
  4119.         dc.b    $00,$00,$00,$00,$78,$00,$00,$00
  4120.         dc.b    $00,$00,$00,$00,$00,$00
  4121.  
  4122.         dc.l    'CLI'
  4123.         dc.b    $00,$00,$00,$00,$58,$00,$00,$00
  4124.         dc.b    $00,$00,$00,$00,$00,$00
  4125.  
  4126.         dc.l    'ROR'
  4127.         dc.b    $00,$6e,$66,$6a,$6a,$00,$00,$76
  4128.         dc.b    $7e,$00,$00,$00,$00,$00
  4129.  
  4130.         dc.l    'BVS'
  4131.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  4132.         dc.b    $00,$00,$70,$00,$00,$00
  4133.  
  4134.         dc.l    'BVC'
  4135.         dc.b    $00,$00,$00,$00,$00,$00,$00,$00
  4136.         dc.b    $00,$00,$50,$00,$00,$00
  4137.  
  4138.         dc.l    'SED'
  4139.         dc.b    $00,$00,$00,$00,$f8,$00,$00,$00
  4140.         dc.b    $00,$00,$00,$00,$00,$00
  4141.  
  4142.         dc.l    'CLD'
  4143.         dc.b    $00,$00,$00,$00,$d8,$00,$00,$00
  4144.         dc.b    $00,$00,$00,$00,$00,$00
  4145.  
  4146.         dc.l    'RTI'
  4147.         dc.b    $00,$00,$00,$00,$40,$00,$00,$00
  4148.         dc.b    $00,$00,$00,$00,$00,$00
  4149.  
  4150.         dc.l    'TSX'
  4151.         dc.b    $00,$00,$00,$00,$ba,$00,$00,$00
  4152.         dc.b    $00,$00,$00,$00,$00,$00
  4153.  
  4154.         dc.l    'CLV'
  4155.         dc.b    $00,$00,$00,$00,$b8,$00,$00,$00
  4156.         dc.b    $00,$00,$00,$00,$00,$00
  4157.  
  4158. ; JMP special case
  4159.  
  4160. ; BRK special case!
  4161.  
  4162. ; RMB, SMB special cases
  4163.  
  4164. ; BBR, BBS special cases
  4165.  
  4166.         dc.l    0,0
  4167.  
  4168. CPU        dc.w    %0000100100001001    ;00
  4169.         dc.w    %0010100100101001    ;01
  4170.         dc.w    %0000000100000001    ;02
  4171.         dc.w    %0010100100101001    ;03
  4172.         dc.w    %0000000100000001    ;04
  4173.         dc.w    %0010000100100001    ;05
  4174.         dc.w    %0000100100000001    ;06
  4175.         dc.w    %0010100100101001    ;07
  4176.         dc.w    %1000000101000001    ;08
  4177.         dc.w    %0010000100001011    ;09
  4178.         dc.w    %0000000100000001    ;10
  4179.         dc.w    %0010000100000001    ;11
  4180.         dc.w    %0000000100000001    ;12
  4181.         dc.w    %0010000100100001    ;13
  4182.         dc.w    %0000000100000001    ;14
  4183.         dc.w    %0010000100100001    ;15
  4184.  
  4185.  
  4186. ermsgs        dc.b    0        1
  4187.         dc.b    0        2
  4188.         dc.b    0        3
  4189.         dc.b    'Memory allocation error',LF,0        4
  4190.         dc.b    'Cannot create file',LF,0        5
  4191.         dc.b    'Error writing file',LF,0        6
  4192.         dc.b    'File not found',LF,0            7
  4193.         dc.b    'No filename',LF,0            8
  4194.         dc.b    'Options error',LF,0            9
  4195.         dc.b    'Level 0 calculation error',LF,0    10
  4196.         dc.b    'Level 1 calculation error',LF,0    11
  4197.         dc.b    'Illegal numeric value',LF,0        12
  4198.         dc.b    'Division by zero',LF,0            13
  4199.         dc.b    'Parenthesis mismatch',LF,0        14
  4200.         dc.b    'Quotes upset',LF,0            15
  4201.         dc.b    0        16
  4202.         dc.b    0        17
  4203.         dc.b    0        18
  4204.         dc.b    0        19
  4205.         dc.b    'Syntax error',LF,0            20
  4206.         dc.b    'Unknown addressing mode',LF,0        21
  4207.         dc.b    'An 8-bit value expected',LF,0        22
  4208.         dc.b    '65c02 mode only',LF,0            23
  4209.         dc.b    'Branch too long',LF,0            24
  4210.         dc.b    'Illegal adressing mode',LF,0        25
  4211.         dc.b    'EQU expected',LF,0            26
  4212.         dc.b    'Unknown mnemonic',LF,0            27
  4213.         dc.b    'A 16-bit value expected',LF,0        28
  4214.         dc.b    'PC-value too large',LF,0        29
  4215.         dc.b    'Out of symbol buffer',LF,0        30
  4216.         dc.b    'Redefined symbol',LF,0            31
  4217.         dc.b    'Illegal symbol name',LF,0        32
  4218.         dc.b    'Symbol too long',LF,0            33
  4219.         dc.b    'Undefined symbol',LF,0            34
  4220.         dc.b    'EQU symbol cannot be redefined',LF,0    35
  4221.         dc.b    'Symbol already set by SET/EQU',LF,0    36
  4222.         dc.b    'Missing symbol name',LF,0        37
  4223.         dc.b    'Absolute symbol value mismatch',LF,0    38
  4224.         dc.b    'SET/EQU symbol value mismatch',LF,0    39
  4225.         dc.b    'Incomplete statement',LF,0        40
  4226.         dc.b    'File not found',LF,0            41
  4227.         dc.b    'Include nesting too deep',LF,0        42
  4228.         dc.b    'Read error',LF,0            43
  4229.         dc.b    'Out of memory error',LF,0        44
  4230.         dc.b    'Source file too long',LF,0        45
  4231.         dc.b    'Illegal usage of IEND symbol',LF,0    46
  4232.         dc.b    0        47
  4233.         dc.b    0        48
  4234.         dc.b    0        49
  4235.         dc.b    'Condition level overflow',LF,0        50
  4236.         dc.b    'ENDC without condition',LF,0        51
  4237.         dc.b    'Missing ENDC',LF,0            52
  4238.         dc.b    'Syntax error',LF,0            53
  4239.         dc.b    'FAIL error',LF,0            54
  4240.         dc.b    0        55
  4241.         dc.b    0        56
  4242.         dc.b    0        57
  4243.         dc.b    0        58
  4244.         dc.b    0        59
  4245.         dc.b    'ENDM without MACRO',LF,0        60
  4246.         dc.b    'Redefined Macro',LF,0            61
  4247.         dc.b    'Illegal macro definition',LF,0        62
  4248.         dc.b    'Missing macro name',LF,0        63
  4249.         dc.b    'ENDM missing',LF,0            64
  4250.         dc.b    'Macro parameter mismatch',LF,0        65
  4251.         dc.b    'Macro nesting too deep',LF,0        66
  4252.         dc.b    'No <<>> nesting allowed',LF,0        67
  4253.         dc.b    'Missing quote or syntax error',LF,0    68
  4254.         dc.b    0        69
  4255.         dc.b    -1
  4256.  
  4257.  
  4258.  
  4259. hextable    dc.b    '0123456789abcdef'    needs no comments
  4260.         cnop    0,4
  4261.  
  4262. obuf        dc.l    0        output buffer start address
  4263. opoi        dc.l    0        output buffer pointer
  4264. _CMDLen        dc.l    0        command line length
  4265. _CMDBuf        dc.l    0        command line start address
  4266. outfile        dc.l    0        output filehandle
  4267. infile        dc.l    0        input filehandle
  4268. clifile        dc.l    0        clifilehandle
  4269. listfile    dc.l    0        listing filehandle
  4270. sourcebuf    dc.l    0        source buffer start address
  4271. sourceend    dc.l    $0fffffff    source buffer end address
  4272. total_len    dc.l    0        total length of all included files
  4273. SOURCEBUF    dc.l    1000        source buffer size
  4274. auxbuf        dc.l    0        auxiliary buffer start (filenames)
  4275. multibuf    dc.l    0        buffer for filenames & errhandler & listout
  4276. libuf        dc.l    0        start of list buffer
  4277. labelbuf    dc.l    0        start address of label buffer
  4278. txtptr        dc.l    0        pointer into source buffer
  4279. par1        dc.l    0        65c02 parameter storage
  4280. prgc        dc.l    0        65c02 program counter storage
  4281. totalbyt    dc.l    0        65c02 object length in bytes
  4282. checksum    dc.l    0        65c02 object checksum
  4283. tbuffer        ds.b    32        temp buffer
  4284. zpabs        dc.b    0        flag: zeropage/absolute
  4285. pass        dc.b    0        pass identifier
  4286. errcnt        dc.l    0        error counter
  4287. errornum    dc.w    0        current error number
  4288. linnum        dc.l    0        current linenumber
  4289. linstrt        dc.l    0        current line start address
  4290. nameptr        dc.l    0        current filename ptr
  4291. McExpCnt    dc.l    0        counts \@'s during macro processing
  4292. McNesting    dc.w    0        current macro nesting level
  4293. pat_pend    dc.w    0        helps cg()
  4294. hexmode        dc.w    0        flag: build hexadecimal output file
  4295. procmode    dc.w    0        flag: 65c02 mode
  4296. userlmode    dc.w    0        flag: listmode set using option -l
  4297. listmode    dc.w    0        flag: build listing file (taken from userlmode)
  4298. no_list        dc.w    0        flag: don't list this line
  4299. idepth        dc.w    0        flag: compiling an include file
  4300. incstrt        dc.w    0        flag: new include file starts (set by INCLUDE)
  4301. condstrt    dc.w    0        flag: new conditional part starts
  4302. symbolmode    dc.w    0        flag: print symbol table
  4303. cond_level    dc.w    0        current conditional assembly level
  4304. lnf        dc.w    0        flag: label not found (for ifd/ifnd)
  4305. hexbytcnt    dc.w    3        counter: 3 hexbytes/listing line
  4306. broken        dc.w    0        flag: program stopped by user
  4307. absmism        dc.w    0        flag: absolute value mism already printed
  4308.  
  4309. sl_flag        dc.w    0        flag: glabel called from slabel
  4310. equset        dc.l    0        flag/value: a symbol set/equted on this line
  4311.  
  4312. prtline        dc.w    HUGELINE    current printer line
  4313. maxline        dc.w    MAXLINE        maximum printer line
  4314. prtpage        dc.w    0        current printer page
  4315.  
  4316. incnames    ds.l    INCNESTING+1    nameptrs for including
  4317. condflags    ds.b    CONDNESTING+1    true/false flags for each level
  4318.         cnop    0,2
  4319.  
  4320.         libnames        library names & base pointers
  4321.  
  4322.         end
  4323.  
  4324.