home *** CD-ROM | disk | FTP | other *** search
/ CLIX - Fazer Clix Custa Nix / CLIX-CD.cdr / mac / lib / AutoSplit.pm < prev    next >
Encoding:
Perl POD Document  |  1997-06-02  |  12.4 KB  |  391 lines  |  [TEXT/McPL]
  1. package AutoSplit;
  2.  
  3. require 5.000;
  4. require Exporter;
  5.  
  6. use Config;
  7. use Carp;
  8. use File::Path qw(mkpath);
  9.  
  10. @ISA = qw(Exporter);
  11. @EXPORT = qw(&autosplit &autosplit_lib_modules);
  12. @EXPORT_OK = qw($Verbose $Keep $Maxlen $CheckForAutoloader $CheckModTime);
  13.  
  14. =head1 NAME
  15.  
  16. AutoSplit - split a package for autoloading
  17.  
  18. =head1 SYNOPSIS
  19.  
  20.  perl -e 'use AutoSplit; autosplit_lib_modules(@ARGV)' ...
  21.  
  22.  use AutoSplit; autosplit($file, $dir, $keep, $check, $modtime);
  23.  
  24. for perl versions 5.002 and later:
  25.  
  26.  perl -MAutoSplit -e 'autosplit($ARGV[0], $ARGV[1], $k, $chk, $modtime)' ...
  27.  
  28. =head1 DESCRIPTION
  29.  
  30. This function will split up your program into files that the AutoLoader
  31. module can handle. It is used by both the standard perl libraries and by
  32. the MakeMaker utility, to automatically configure libraries for autoloading.
  33.  
  34. The C<autosplit> interface splits the specified file into a hierarchy 
  35. rooted at the directory C<$dir>. It creates directories as needed to reflect
  36. class hierarchy, and creates the file F<autosplit.ix>. This file acts as
  37. both forward declaration of all package routines, and as timestamp for the
  38. last update of the hierarchy.
  39.  
  40. The remaining three arguments to C<autosplit> govern other options to the
  41. autosplitter. If the third argument, I<$keep>, is false, then any pre-existing
  42. C<*.al> files in the autoload directory are removed if they are no longer
  43. part of the module (obsoleted functions). The fourth argument, I<$check>,
  44. instructs C<autosplit> to check the module currently being split to ensure
  45. that it does include a C<use> specification for the AutoLoader module, and
  46. skips the module if AutoLoader is not detected. Lastly, the I<$modtime>
  47. argument specifies that C<autosplit> is to check the modification time of the
  48. module against that of the C<autosplit.ix> file, and only split the module
  49. if it is newer.
  50.  
  51. Typical use of AutoSplit in the perl MakeMaker utility is via the command-line
  52. with:
  53.  
  54.  perl -e 'use AutoSplit; autosplit($ARGV[0], $ARGV[1], 0, 1, 1)'
  55.  
  56. Defined as a Make macro, it is invoked with file and directory arguments;
  57. C<autosplit> will split the specified file into the specified directory and
  58. delete obsolete C<.al> files, after checking first that the module does use
  59. the AutoLoader, and ensuring that the module is not already currently split
  60. in its current form (the modtime test).
  61.  
  62. The C<autosplit_lib_modules> form is used in the building of perl. It takes
  63. as input a list of files (modules) that are assumed to reside in a directory
  64. B<lib> relative to the current directory. Each file is sent to the 
  65. autosplitter one at a time, to be split into the directory B<lib/auto>.
  66.  
  67. In both usages of the autosplitter, only subroutines defined following the
  68. perl special marker I<__END__> are split out into separate files. Some
  69. routines may be placed prior to this marker to force their immediate loading
  70. and parsing.
  71.  
  72. =head1 CAVEATS
  73.  
  74. Currently, C<AutoSplit> cannot handle multiple package specifications
  75. within one file.
  76.  
  77. =head1 DIAGNOSTICS
  78.  
  79. C<AutoSplit> will inform the user if it is necessary to create the top-level
  80. directory specified in the invocation. It is preferred that the script or
  81. installation process that invokes C<AutoSplit> have created the full directory
  82. path ahead of time. This warning may indicate that the module is being split
  83. into an incorrect path.
  84.  
  85. C<AutoSplit> will warn the user of all subroutines whose name causes potential
  86. file naming conflicts on machines with drastically limited (8 characters or
  87. less) file name length. Since the subroutine name is used as the file name,
  88. these warnings can aid in portability to such systems.
  89.  
  90. Warnings are issued and the file skipped if C<AutoSplit> cannot locate either
  91. the I<__END__> marker or a "package Name;"-style specification.
  92.  
  93. C<AutoSplit> will also emit general diagnostics for inability to create
  94. directories or files.
  95.  
  96. =cut
  97.  
  98. # for portability warn about names longer than $maxlen
  99. $Maxlen  = 8;    # 8 for dos, 11 (14-".al") for SYSVR3
  100. $Verbose = 2;    # 0=none, 1=minimal, 2=list .al files
  101. $Keep    = 0;
  102. $CheckForAutoloader = 1;
  103. $CheckModTime = 1;
  104.  
  105. $IndexFile = "autosplit.ix";    # file also serves as timestamp
  106. $maxflen = 255;
  107. $maxflen = 14 if $Config{'d_flexfnam'} ne 'define';
  108. $Is_VMS = ($^O eq 'VMS');
  109. $Is_MacOS = ($^O eq 'MacOS');
  110.  
  111.  
  112. sub autosplit{
  113.     my($file, $autodir,  $k, $ckal, $ckmt) = @_;
  114.     # $file    - the perl source file to be split (after __END__)
  115.     # $autodir - the ".../auto" dir below which to write split subs
  116.     # Handle optional flags:
  117.     $keep = $Keep unless defined $k;
  118.     $ckal = $CheckForAutoloader unless defined $ckal;
  119.     $ckmt = $CheckModTime unless defined $ckmt;
  120.     autosplit_file($file, $autodir, $keep, $ckal, $ckmt);
  121. }
  122.  
  123.  
  124. # This function is used during perl building/installation
  125. # ./miniperl -e 'use AutoSplit; autosplit_lib_modules(@ARGV)' ...
  126.  
  127. sub autosplit_lib_modules{
  128.     my(@modules) = @_; # list of Module names
  129.  
  130.     while ($_ = shift @modules){
  131.     s#::#:#g if $Is_MacOS;
  132.     s#::#/#g;    # incase specified as ABC::XYZ
  133.     s|\\|/|g;    # bug in ksh OS/2
  134.     s#^:lib:## if $Is_MacOS;
  135.     s#^lib/##; # incase specified as lib/*.pm
  136.     if ($Is_VMS && /[:>\]]/) { # may need to convert VMS-style filespecs
  137.         my ($dir,$name) = (/(.*])(.*)/);
  138.         $dir =~ s/.*lib[\.\]]//;
  139.         $dir =~ s#[\.\]]#/#g;
  140.         $_ = $dir . $name;
  141.     }
  142.     if ($Is_MacOS) {
  143.         autosplit_file(":lib:$_", ":lib:auto", $Keep, $CheckForAutoloader, $CheckModTime);
  144.     } else {
  145.         autosplit_file("lib/$_", "lib/auto", $Keep, $CheckForAutoloader, $CheckModTime);
  146.     }
  147.     }
  148.     0;
  149. }
  150.  
  151.  
  152. # private functions
  153.  
  154. sub autosplit_file{
  155.     my($filename, $autodir, $keep, $check_for_autoloader, $check_mod_time) = @_;
  156.     my(@names);
  157.  
  158.     # where to write output files
  159.     if ($Is_MacOS) {
  160.         $autodir =~ s/:$//;
  161.     $autodir =  ":lib:auto" unless $autodir;
  162.     } else {
  163.         $autodir = "lib/auto" unless $autodir;
  164.     }
  165.     if ($Is_VMS) {
  166.     ($autodir = VMS::Filespec::unixpath($autodir)) =~ s{/$}{};
  167.     $filename = VMS::Filespec::unixify($filename); # may have dirs
  168.     }
  169.     unless (-d $autodir){
  170.     mkpath($autodir,0,0755);
  171.     # We should never need to create the auto dir here. installperl
  172.     # (or similar) should have done it. Expecting it to exist is a valuable
  173.     # sanity check against autosplitting into some random directory by mistake.
  174.     print "Warning: AutoSplit had to create top-level $autodir unexpectedly.\n";
  175.     }
  176.  
  177.     # allow just a package name to be used
  178.     $filename .= ".pm" unless ($filename =~ m/\.pm$/);
  179.  
  180.     open(IN, "<$filename") || die "AutoSplit: Can't open $filename: $!\n";
  181.     my($pm_mod_time) = (stat($filename))[9];
  182.     my($autoloader_seen) = 0;
  183.     my($in_pod) = 0;
  184.     while (<IN>) {
  185.     # Skip pod text.
  186.     $in_pod = 1 if /^=/;
  187.     $in_pod = 0 if /^=cut/;
  188.     next if ($in_pod || /^=cut/);
  189.  
  190.     # record last package name seen
  191.     $package = $1 if (m/^\s*package\s+([\w:]+)\s*;/);
  192.     ++$autoloader_seen if m/^\s*(use|require)\s+AutoLoader\b/;
  193.     ++$autoloader_seen if m/\bISA\s*=.*\bAutoLoader\b/;
  194.     last if /^__END__/;
  195.     }
  196.     if ($check_for_autoloader && !$autoloader_seen){
  197.     print "AutoSplit skipped $filename: no AutoLoader used\n" if ($Verbose>=2);
  198.     return 0
  199.     }
  200.     $_ or die "Can't find __END__ in $filename\n";
  201.  
  202.     $package or die "Can't find 'package Name;' in $filename\n";
  203.  
  204.     my($modpname) = $package; 
  205.     my($al_idx_file) = "$autodir/$modpname/$IndexFile";
  206.     if ($Is_MacOS) {
  207.     $modpname =~ s#::#:#g; 
  208.           $al_idx_file = "$autodir:$modpname:$IndexFile";
  209.     }
  210.     elsif ($^O eq 'MSWin32') {
  211.     $modpname =~ s#::#\\#g; 
  212.         my($al_idx_file) = "$autodir/$modpname/$IndexFile";
  213.     } else {
  214.     $modpname =~ s#::#/#g;
  215.     }
  216.  
  217.     die "Package $package ($modpname.pm) does not match filename $filename"
  218.         unless ($filename =~ m/\Q$modpname.pm\E$/ or
  219.             ($^O eq "msdos") or ($^O eq 'MSWin32') or
  220.                 $Is_VMS or $Is_MacOS && $filename =~ m/$modpname.pm/i);
  221.  
  222.  
  223.     if ($check_mod_time){
  224.     my($al_ts_time) = (stat("$al_idx_file"))[9] || 1;
  225.     if ($al_ts_time >= $pm_mod_time){
  226.         print "AutoSplit skipped ($al_idx_file newer that $filename)\n"
  227.         if ($Verbose >= 2);
  228.         return undef;    # one undef, not a list
  229.     }
  230.     }
  231.  
  232.     my($from) = ($Verbose>=2) ? "$filename => " : "";
  233.     if ($Is_MacOS) {
  234.     print "AutoSplitting $package ($from$autodir:$modpname)\n"
  235.         if $Verbose;
  236.  
  237.     unless (-d "$autodir:$modpname"){
  238.         mkpath("$autodir:$modpname",0,0777);
  239.     }
  240.     } else {
  241.     print "AutoSplitting $package ($from$autodir/$modpname)\n"
  242.         if $Verbose;
  243.  
  244.         unless (-d "$autodir/$modpname"){
  245.         mkpath("$autodir/$modpname",0,0777);
  246.     }
  247.     }
  248.  
  249.     # We must try to deal with some SVR3 systems with a limit of 14
  250.     # characters for file names. Sadly we *cannot* simply truncate all
  251.     # file names to 14 characters on these systems because we *must*
  252.     # create filenames which exactly match the names used by AutoLoader.pm.
  253.     # This is a problem because some systems silently truncate the file
  254.     # names while others treat long file names as an error.
  255.  
  256.     # We do not yet deal with multiple packages within one file.
  257.     # Ideally both of these styles should work.
  258.     #
  259.     #   package NAME;
  260.     #   __END__
  261.     #   sub AAA { ... }
  262.     #   package NAME::option1;
  263.     #   sub BBB { ... }
  264.     #   package NAME::option2;
  265.     #   sub BBB { ... }
  266.     #
  267.     #   package NAME;
  268.     #   __END__
  269.     #   sub AAA { ... }
  270.     #   sub NAME::option1::BBB { ... }
  271.     #   sub NAME::option2::BBB { ... }
  272.     #
  273.     # For now both of these produce warnings.
  274.  
  275.     open(OUT,">/dev/null") || open(OUT,">nla0:") || open(OUT, "Dev:Null"); # avoid 'not opened' warning
  276.     my(@subnames, %proto);
  277.     my @cache = ();
  278.     my $caching = 1;
  279.     while (<IN>) {
  280.     next if /^=\w/ .. /^=cut/;
  281.     if (/^package ([\w:]+)\s*;/) {
  282.         warn "package $1; in AutoSplit section ignored. Not currently supported.";
  283.     }
  284.     if (/^sub\s+([\w:]+)(\s*\(.*?\))?/) {
  285.         print OUT "1;\n";
  286.         my $subname = $1;
  287.         $proto{$1} = $2 || '';
  288.         if ($subname =~ m/::/){
  289.         warn "subs with package names not currently supported in AutoSplit section";
  290.         }
  291.         push(@subnames, $subname);
  292.         my($lname, $sname) = ($subname, substr($subname,0,$maxflen-3));
  293.         my($lpath) = $Is_MacOS ? "$autodir:$modpname:$lname.al" : "$autodir/$modpname/$lname.al";
  294.         my($spath) = $Is_MacOS ? "$autodir:$modpname:$sname.al" : "$autodir/$modpname/$sname.al";
  295.         unless(open(OUT, ">$lpath")){
  296.         open(OUT, ">$spath") or die "Can't create $spath: $!\n";
  297.         push(@names, $sname);
  298.         print "  writing $spath (with truncated name)\n"
  299.             if ($Verbose>=1);
  300.         }else{
  301.         push(@names, $lname);
  302.         print "  writing $lpath\n" if ($Verbose>=2);
  303.         }
  304.         print OUT "# NOTE: Derived from $filename.  ",
  305.             "Changes made here will be lost.\n";
  306.         print OUT "package $package;\n\n";
  307.         print OUT @cache;
  308.         @cache = ();
  309.         $caching = 0;
  310.     }
  311.     if($caching) {
  312.         push(@cache, $_) if @cache || /\S/;
  313.     }
  314.     else {
  315.         print OUT $_;
  316.     }
  317.     if(/^}/) {
  318.         if($caching) {
  319.         print OUT @cache;
  320.         @cache = ();
  321.         }
  322.         print OUT "\n";
  323.         $caching = 1;
  324.     }
  325.     }
  326.     print OUT @cache,"1;\n";
  327.     close(OUT);
  328.     close(IN);
  329.  
  330.     if (!$keep){  # don't keep any obsolete *.al files in the directory
  331.     my(%names);
  332.     @names{@names} = @names;
  333.     opendir(OUTDIR, $Is_MacOS ? "$autodir:$modpname" : "$autodir/$modpname");
  334.     foreach(sort readdir(OUTDIR)){
  335.         next unless /\.al$/;
  336.         my($subname) = m/(.*)\.al$/;
  337.         next if $names{substr($subname,0,$maxflen-3)};
  338.         my($file) = $Is_MacOS ? "$autodir:$modpname:$_" : "$autodir/$modpname/$_";
  339.         print "  deleting $file\n" if ($Verbose>=2);
  340.         my($deleted,$thistime);  # catch all versions on VMS
  341.         do { $deleted += ($thistime = unlink $file) } while ($thistime);
  342.         carp "Unable to delete $file: $!" unless $deleted;
  343.     }
  344.     closedir(OUTDIR);
  345.     }
  346.  
  347.     open(TS,">$al_idx_file") or
  348.     carp "AutoSplit: unable to create timestamp file ($al_idx_file): $!";
  349.     print TS "# Index created by AutoSplit for $filename (file acts as timestamp)\n";
  350.     print TS "package $package;\n";
  351.     print TS map("sub $_$proto{$_} ;\n", @subnames);
  352.     print TS "1;\n";
  353.     close(TS);
  354.  
  355.     check_unique($package, $Maxlen, 1, @names);
  356.  
  357.     @names;
  358. }
  359.  
  360.  
  361. sub check_unique{
  362.     my($module, $maxlen, $warn, @names) = @_;
  363.     my(%notuniq) = ();
  364.     my(%shorts)  = ();
  365.     my(@toolong) = grep(length > $maxlen, @names);
  366.  
  367.     foreach(@toolong){
  368.     my($trunc) = substr($_,0,$maxlen);
  369.     $notuniq{$trunc}=1 if $shorts{$trunc};
  370.     $shorts{$trunc} = ($shorts{$trunc}) ? "$shorts{$trunc}, $_" : $_;
  371.     }
  372.     if (%notuniq && $warn){
  373.     print "$module: some names are not unique when truncated to $maxlen characters:\n";
  374.     foreach(keys %notuniq){
  375.         print " $shorts{$_} truncate to $_\n";
  376.     }
  377.     }
  378.     %notuniq;
  379. }
  380.  
  381. 1;
  382. __END__
  383.  
  384. # test functions so AutoSplit.pm can be applied to itself:
  385. sub test1{ "test 1\n"; }
  386. sub test2{ "test 2\n"; }
  387. sub test3{ "test 3\n"; }
  388. sub test4{ "test 4\n"; }
  389.  
  390.  
  391.