Visual Basic Controls/Visual Basic Controls.iso/vbcontrol/spchauto/data1.cab/Samples/Visual_Basic/SpellCheckerDLL/VbDLL.frm

Visual Basic Form | 1999-07-16 | 5.3 KB | 131 lines

VERSION 5.00
Begin VB.Form Form1
   Caption         =   "Polar Spell Checker DLL Demo"
   ClientHeight    =   5190
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   8040
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   ScaleHeight     =   5190
   ScaleWidth      =   8040
   StartUpPosition =   3  'Windows Default
   Begin VB.CommandButton btnDownload
      Caption         =   "&Download..."
      Height          =   375
      Left            =   6360
      TabIndex        =   3
      Top             =   1200
      Width           =   1575
   End
   Begin VB.CommandButton btnCheckSel
      Caption         =   "Check &Selection..."
      Height          =   375
      Left            =   6360
      TabIndex        =   2
      Top             =   600
      Width           =   1575
   End
   Begin VB.CommandButton btnCheckAll
      Caption         =   "&Check All..."
      Height          =   375
      Left            =   6360
      TabIndex        =   1
      Top             =   120
      Width           =   1575
   End
   Begin VB.TextBox Text1
      Height          =   5175
      Left            =   0
      MultiLine       =   -1  'True
      TabIndex        =   0
      Text            =   "VbDLL.frx":0000
      Top             =   0
      Width           =   6255
   End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Private Declare Function PS_Init Lib "polspell.dll" () As Long
Private Declare Sub PS_Destroy Lib "polspell.dll" (ByVal hSpell As Long)
Private Declare Function PS_OpenDictionary Lib "polspell.dll" (ByVal hSpell As Long, ByVal pszMainDictFileName As String, ByVal pszCustomDictFileName As String) As Boolean
Private Declare Sub PS_CloseDictionary Lib "polspell.dll" (ByVal hSpell As Long)
Private Declare Function PS_CheckText Lib "polspell.dll" (ByVal hSpell As Long, ByVal pszText As String, pnExitStatus As Integer) As Long
Private Declare Function PS_DownloadDictionaries Lib "polspell.dll" (ByVal hSpell As Long, ByVal pszUpdateURL As String, ByVal pszInstallDir As String) As Boolean
Private Declare Function PS_OptionsDialog Lib "polspell.dll" (ByVal pszDictionaryDir As String, ByVal pszCustomDicFileName As String, ByVal pszCurDicFileName As String, ByVal pszDownloadURL As String, ByVal bInternetSupport As Boolean) As Boolean
Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function GlobalFree Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" (Dest As Any, Source As Any, ByVal NumBytes As Long)
Private Declare Function lstrlen Lib "kernel32" Alias "lstrlenA" (ByVal lpstr As Any) As Long
Private Declare Sub lstrcpy Lib "kernel32" Alias "lstrcpyA" (ByVal Dest As Any, ByVal src As Any)
Dim g_strMainDictFileName As String
Dim g_strCustomDictFileName As String
Dim g_hSpell As Long
Private Sub btnCheckAll_Click()
    Dim Text As String
    Dim hglbMem As Long
    Dim psz As Long
    Dim ExitStatus As Integer
    ' Open dictionary
    If PS_OpenDictionary(g_hSpell, App.Path + "\" + g_strMainDictFileName, g_strCustomDictFileName) <> False Then
       Text = Text1.Text
       ' Check text
       hglbMem = PS_CheckText(g_hSpell, Text, ExitStatus)
       psz = GlobalLock(hglbMem)
       Text = Space$(lstrlen(psz) + 1)
       lstrcpy Text, psz
       GlobalUnlock hglbMem
       GlobalFree hglbMem
       ' Set checked text to text box
       Text1.Text = Text
       ' Close dictionary
       PS_CloseDictionary (g_hSpell)
    Else
       MsgBox ("Cannot open dictionary " + App.Path + "\" + g_strMainDictFileName)
    End If
End Sub
Private Sub btnCheckSel_Click()
    Dim Text As String
    Dim hglbMem As Long
    Dim psz As Long
    Dim ExitStatus As Integer
    Text = Text1.SelText
    If (Text = "") Then
        MsgBox "Nothing is selected."
        Exit Sub
    End If
    ' Open dictionary
    If PS_OpenDictionary(g_hSpell, App.Path + "\" + g_strMainDictFileName, g_strCustomDictFileName) <> False Then
       ' Check text
       hglbMem = PS_CheckText(g_hSpell, Text, ExitStatus)
       psz = GlobalLock(hglbMem)
       Text = Space$(lstrlen(psz))
       lstrcpy Text, psz
       GlobalUnlock hglbMem
       GlobalFree hglbMem
       ' Set checked text to text box
       Text1.SelText = Text
       ' Close dictionary
        PS_CloseDictionary (g_hSpell)
    Else
       MsgBox ("Cannot open dictionary " + App.Path + "\" + g_strMainDictFileName)
    End If
End Sub
Private Sub btnDownload_Click()
   PS_DownloadDictionaries g_hSpell, "http://www.polarsoftware.com/install/dictionaries.ins", App.Path
End Sub
Private Sub btnOptions_Click()
   PS_OptionsDialog App.Path, g_strCustomDictFileName, g_strMainDictFileName, "http://www.polarsoftware.com/install/dictionaries.ins", True
End Sub
Private Sub Form_Load()
   g_strMainDictFileName = "SpellUs.lex"
   g_strCustomDictFileName = App.Path + "\custom.dic"
   g_hSpell = PS_Init()
End Sub
Private Sub Form_Unload(Cancel As Integer)
   PS_Destroy (g_hSpell)
End Sub