home *** CD-ROM | disk | FTP | other *** search
/ HTBasic 9.3 / HTBasic 9.3.iso / 83win / data1.cab / Basic_Plus_Examples / CTXTHELP < prev    next >
Encoding:
Text File  |  2001-03-02  |  2.6 KB  |  70 lines
  1. 10    ! ********************************************************
  2. 20    ! Example: Context-Sensitive Help
  3. 30    !
  4. 40    ! This program displays three pushbuttons (Fire Phasers,
  5. 50    ! Fire Photon Torpedoes, and Stand Down). You can display
  6. 60    ! the definitions of these pushbuttons by placing the cursor
  7. 70    ! on the desired pushbutton and clicking the RIGHT mouse
  8. 80    ! button.
  9. 90    !
  10. 100   ! *********************************************************
  11. 110   !
  12. 120       DIM S$[256]                      ! GP string
  13. 130       S$="help_ex/weapons.hlp"         ! Help file name
  14. 140   !
  15. 150   ! Create the PANEL widget
  16. 160   !
  17. 170       ASSIGN @Main TO WIDGET "PANEL";SET ("VISIBLE":0)
  18. 180       CONTROL @Main;SET ("X":50,"Y":25,"WIDTH":300,"HEIGHT":175)
  19. 190       CONTROL @Main;SET ("TITLE":" Example: Context-Sensitive Help","SYSTEM MENU":"Quit")
  20. 200       CONTROL @Main;SET ("HELP FILE":S$,"HELP TOPIC":"weapons.TOC")
  21. 210   !
  22. 220   ! Set up buttons
  23. 230   !
  24. 240       ASSIGN @Phasers TO WIDGET "PUSHBUTTON";PARENT @Main
  25. 250       CONTROL @Phasers;SET ("X":45,"Y":15,"WIDTH":200,"HEIGHT":30)
  26. 260       CONTROL @Phasers;SET ("LABEL":"Fire Phasers")
  27. 270       CONTROL @Phasers;SET ("HELP FILE":S$,"HELP TOPIC":"weapons.phasers")
  28. 280   !
  29. 290       ASSIGN @Torps TO WIDGET "PUSHBUTTON";PARENT @Main
  30. 300       CONTROL @Torps;SET ("X":45,"Y":55,"WIDTH":200,"HEIGHT":30)
  31. 310       CONTROL @Torps;SET ("LABEL":"Fire Photon Torpedoes")
  32. 320       CONTROL @Torps;SET ("HELP FILE":S$,"HELP TOPIC":"weapons.torp")
  33. 330   !
  34. 340       ASSIGN @Off TO WIDGET "PUSHBUTTON";PARENT @Main
  35. 350       CONTROL @Off;SET ("X":45,"Y":100,"WIDTH":200,"HEIGHT":30)
  36. 360       CONTROL @Off;SET ("LABEL":"Stand Down")
  37. 370       CONTROL @Off;SET ("HELP FILE":S$,"HELP TOPIC":"weapons.off")
  38. 380   !
  39. 390   ! Set up events and loop
  40. 400   !
  41. 410       ON EVENT @Phasers,"ACTIVATED" GOSUB Phasers
  42. 420       ON EVENT @Torps,"ACTIVATED" GOSUB Torps
  43. 430       ON EVENT @Off,"ACTIVATED" GOSUB Off
  44. 440       ON EVENT @Main,"SYSTEM MENU" GOTO Finis
  45. 450   !
  46. 460       CONTROL @Main;SET ("VISIBLE":1)
  47. 470   !
  48. 480       LOOP
  49. 490           WAIT FOR EVENT
  50. 500       END LOOP
  51. 510       STOP
  52. 520   !
  53. 530   ! ********************* Subroutines Start Here ************************
  54. 540   !
  55. 550  Phasers:!
  56. 560       DIALOG "INFORMATION","Fired phasers!"
  57. 570       RETURN
  58. 580   !
  59. 590  Torps:!
  60. 600       DIALOG "INFORMATION","Fired photon torpedoes!"
  61. 610       RETURN
  62. 620   !
  63. 630  Off:!
  64. 640       DIALOG "INFORMATION","Weapons system standing down."
  65. 650       RETURN
  66. 660   !
  67. 670  Finis:!
  68. 680       ASSIGN @Main TO *! Delete PANEL widget
  69. 690       END
  70.