EuroCD 3/EuroCD 3.iso/Utilities/Scanner/ScanTrax/Install.bat

DOS Batch File | 1998-06-24 | 7.4 KB | 303 lines

; ScanTrax Install-Script $VER: ScanTrax installer-script V1.1

(complete 0)
(set st-version "1.2")
(set st-date "Jun 01 1997")
(set os-version (/ (getversion) 65536))
(user 1)
(set germ (= @language "deutsch"))
(set engl (= germ 0))


(if germ (set loctxt "\n\nOS-30 oder höher nicht gefunden!\n\n\nInstallation wird abgebrochen!"))
(if engl    (set loctxt "\n\nOS-30 or higher not found!\n\nInstallation will be abort!"))
(if (< os-version 39) (abort loctxt) )

(if germ (set loctxt (cat   "\nWillkommen bei der Installation von \n\n\"ScanTrax V"
                     st-version " ("st-date ")\"!\n\n"
                    "Dieses Programm ist ShareWare.\n\n"
                    "© Copyright 1997 Klaus Krause")))
(if engl (set loctxt (cat   "\nWelcome to the installation of \n\n\"ScanTrax V"
                     st-version " ("st-date ")\"!\n\n"
                    "This Program is ShareWare.\n\n"
                    "© Copyright 1997 Klaus Krause")))
(message loctxt)

(welcome)
(set userlevel @user-level)

(user 1)
(set root
    (askdir
        (if germ (prompt "Bitte das Verzeichnis wählen, in dem das \"ScanTrax-Verzeichnis\" erstellt werden soll."))
        (if engl (prompt "Please choose the directory, where to be create the \"ScanTrax-directory\"."))
        (help @askdir-help)
        (default "")
        (disk)
    )
)

(set path (tackon root "ScanTrax"))
(makedir path
    (infos)
)
(set @default-dest path)

(user userlevel)
;backup old possible-usermodified icon
(if (exists (tackon @default-dest "ScanTrax.info"))
    (
        (set oldicon 1)
        (copyfiles
            (source (tackon @default-dest "ScanTrax.info"))
            (dest "T:")
        )
    )
    (set oldicon 0)
)
;backup old possible-usermodified ScanMode.prefs
(if (exists (tackon @default-dest "ScanMode.prefs"))
    (
        (set oldprefs 1)
        (copyfiles
            (source (tackon @default-dest "ScanMode.prefs"))
            (dest "T:")
        )
    )
    (set oldprefs 0)
)
(copyfiles
    (if germ (prompt "Kopiere nun die Programmdateien."))
    (if engl (prompt "Now copying the program-files."))
    (help @copyfiles-help)
    (source "main")
    (dest path)
    (all)
    (confirm)
)
(copyfiles
    (if germ (prompt "Kopiere nun die Dokumentation."))
    (if engl (prompt "Now copying the document."))
    (help @copyfiles-help)
    (source "")
    (dest path)
    (files)
    (pattern "#?.guide")
    (confirm)
)
(copyfiles
    (if germ (prompt "Kopiere nun die Icons."))
    (if engl (prompt "Now copying the icons."))
    (help @copyfiles-help)
    (source "icons")
    (dest root)
    (all)
    (confirm)
)
;restore old icon
(if oldicon
    (
        (copyfiles
            (source "T:ScanTrax.info")
            (dest @default-dest)
        )
        (delete ("T:ScanTrax.info"))
    )
)
;restore old ScanMode.prefs
(if oldprefs
    (
        (copyfiles
            (source "T:ScanMode.prefs")
            (dest @default-dest)
        )
        (delete ("T:ScanMode.prefs"))
    )
)
(complete 25)


(user 1)
(if germ (set loctxt "ScanTrax kann eigene Mauszeiger für den Vorschau-Rahmen verwenden. Sie haben hier folgende Auswahl:"))
(if engl (set loctxt "ScanTrax has the ability to use his own Mousepointer for the preview-frame. You have the following choice:"))
(if (exists (tackon @default-dest "Pointer_AD.pre"))
    (set pointers
        (askchoice
            (prompt loctxt)
            (help @askchoice-help)
            (if germ (choices "HiRes Zeiger (für A1200,A4000)" "LoRes Zeiger" "Keine Zeiger (vorhandene löschen)" "Alte Zeiger behalten!"))
            (if engl (choices "HiRes Pointer (for A1200,A4000)" "LoRes Pointer" "No Pointer" "Hold old pointer!"))
            (default 3)
        )
    )
    (set pointers
        (askchoice
            (prompt loctxt)
            (help @askchoice-help)
            (if germ (choices "HiRes Zeiger (für A1200,A4000)" "LoRes Zeiger" "Keine Zeiger"))
            (if engl (choices "HiRes pointer (for A1200,A4000)" "LoRes Pointer" "No Pointer"))
            (default 0)
        )
    )
)
(user userlevel)

(select pointers
    (copyfiles
        (if germ (prompt "Kopiere nun die HiRes-Mauszeiger."))
        (if engl (prompt "Now copying the HiRes-Mousepointer."))
        (help @copyfiles-help)
        (source "pointerhires")
        (dest path)
        (pattern "#?")
        (files)
        (infos)
        (confirm)
    )

    (copyfiles
        (if germ (prompt "Kopiere nun die LoRes-Mauszeiger."))
        (if engl (prompt "Now copying the LoRes-Mousepointer."))
        (help @copyfiles-help)
        (source "pointerlores")
        (dest path)
        (pattern "#?")
        (files)
        (infos)
        (confirm)
    )

    (delete (tackon @default-dest "Pointer#?")
        (if germ (prompt "Ihre alten Mauszeiger werden nun gelöscht!\n\nWenn Sie diese behalten möchten überspringen Sie diesen Teil!"))
        (if engl (prompt "Your old Mousepointer are to be delete!\n\nIf you hold these, skip this part!"))
        (if germ (help "Das Programm wird ihre alten Mauszeiger verwenden wenn Sie diese nicht aus dem Programm-Verzeichnis entfernen!"))
        (if engl (help "The program will use your old Mousepointer if you don't delete them from the program-directory!"))
        (confirm)
    )

    (set pointers 0)
)

(complete 50)
(set icon (tackon @default-dest "ScanTrax"))
(user 1)
(set text
    (askstring
        (if germ (prompt "Geben Sie nun den SCSI-Treibernamen an."))
        (if engl (prompt "Now enter the SCSI-Drivername."))
        (help @askstring-help)
        (default "scsi.device")
    )
)
(tooltype
    (dest icon)
    (settooltype "SCSI_DEVICE" text)
)

(set text
    (select
        (askchoice
            (if germ (prompt "Bitte wählen Sie die SCSI-ID ihres Scanners."))
            (if engl (prompt "Please choose the SCSI-ID of your Scanner."))
            (help @askchoice-help)
            (choices    0 1 2 3 4 5 6)
        )
        "0" "1" "2" "3" "4" "5" "6")
)
(tooltype
    (dest icon)
    (settooltype "SCSI_UNIT" text)
)
(user userlevel)

(tooltype
    (dest icon)
    (settooltype "SCSI_LUN" "0")
)
(tooltype
    (dest icon)
    (settooltype "SCSI_BOARD" "0")
)


(set text
    (select
        (askchoice
            (if germ (prompt "Wählen Sie nun die Größe des Arbeitspuffers.\n"))
            (if engl (prompt "Now choose the workbuffer size.\n"))
            (if germ (help "Soll der Puffer noch größer werden, ändern Sie später die Programm-ToolTypes von Hand."))
            (if engl (help "To make a greater buffer, change the program-tooltypes later by hand."))
            (choices    "1 MB" "2 MB" "3 MB")
        )
        "1048576" "2097152" "3145728")
)
(tooltype
    (dest icon)
    (settooltype "BUFFER_SIZE" text)
)

(complete 75)
(set temppath
    (askdir
        (if germ (prompt "Wo sollen temporäre Vorschau-Dateien abgelegt werden?"))
        (if engl (prompt "Where should temporary preview-files be stored?"))
        (if germ (help "Vorschau-Dateien haben in der Regel eine Größe bis ca. 3 MegaByte."))
        (if engl (help "Preview-files normally have a size of approx. 3 MegaByte."))
        (default "PROGDIR:")
        (disk)
    )
)
(tooltype
    (dest icon)
    (settooltype "TEMPDIR_PREVIEW" temppath)
)

(user 1)
(set temppath
    (askdir
        (if germ (prompt "Wo sollen temporäre Bild-Dateien abgelegt werden?"))
        (if engl (prompt "Where should temporary picture-files be stored?"))
        (if germ (help "Bild-Dateien können in ihrer Größe mehre 10-MegaByte groß werden.\nDiese sollten daher auf Festplatte gespeichert werden."))
        (if engl (help "Picture-files can become several 10-MegaByte big at their size.\nTherefor these should be stored on Harddisk."))
        (default "PROGDIR:")
        (disk)
    )
)
(tooltype
    (dest icon)
    (settooltype "TEMPDIR_CONVERT" temppath)
)

(set text
    (select
        (askchoice
            (if germ (prompt "Verwenden Sie einen ScanJet 5p?"))
            (if engl (prompt "Do you use a ScanJet 5p?"))
            (help @askchoice-help)
            (if germ (choices    "JA" "NEIN"))
            (if engl (choices    "YES" "NO"))
        )
        "SCANJET_5P" "(SCANJET_5P)"
    )
)
(tooltype
    (dest icon)
    (settooltype text "")
)






(user userlevel)

(copylib
    (prompt "Kopiere nun die Library \"gtlayout.library\".")
    (help @copy-lib)
    (confirm)
    (source "libs/gtlayout.library")
    (dest "LIBS:")
)
(complete 100)