Amiga Special: Spiele Hits/Hits-CD.iso/apc&tcp/demoversionen/videotitler/install

Text File | 1996-02-28 | 7.4 KB | 317 lines

; Installer installation script for VideoTitler
; $VER:Install Videotitler 20.02 (25.02.96)



(set @default-dest "")
(set vttdir "VTT1:Videotitler/")
(set vttsource "")

;================================================================================
; English strings

(set #bad-kick
        (cat "\nYou must have installed Kickstart 2.04 or higher to use VideoTitler!")
)

(set #welcome
        (cat "\nVideoTitler installation\n\n\n"
             "This script installs VideoTitler V2.1\n"
             "on your Amiga.\n\n\n\n"
             "VideoTitler V2.1 ©1996 by Andreas Ackermann\n"
             "All rights reserved\n\n"
             "(MUI-System © by Stefan Stuntz)")
)

(set #where-vtt
        (cat "\nIn wich drawer should the VideoTitler be \n"
              "installed ? (A new drawer named\n"
              "VideoTitler will be generated there.)\n"
        )
)

(set #icon_type
        (cat "\nWhich type of icons do you want to install ?\n")
)

(set #which-language
        (cat "\nWhich language should be installed?\n")
)
(set #which-language-help
        (cat "\nThe Amiga can be operated in many different languages. "
             "If you want VideoTitler to use the same language as the Amiga "
             "Workbench a catalog file must be copied to your harddisk "
             "for each language supported.\n"
        )
)
(set #exit_string
        (cat "Please install the provided MUI-package\n"
             "which is to be found on disk two as well.\n\n"
             "Have fun using VideoTtitler !\n"
        )
)

(set #askfont
        (cat "\nDo you want to install the supplied\n"
             "fonts as well ?\n"
        )
)


(set #documentationtype
        (cat "\nWhich type of documentation do you\n"
             "want to install?\n"
             "(Guides are only recommended for\n"
             "for OS 3.0 and above!)\n"
        )
)

(set #fonthelp
        (cat "\nSpecifying 'yes' makes the installer copy the fonts\n"
             "to your FONTS: directory.\n"
        )
)

;================================================================================
; make sure we are running under a 2.04 ROM


(if (< (/ (getversion) 65536) 37)
  (
    (abort #bad-kick)
  )
)


(if (< (/ (getversion) 65536) 39)
  (SET guide_tool "sys:utilities/amigaguide" )
  (SET guide_tool "sys:utilities/multiview" )
)
(if (< (/ (getversion) 65536) 38)
  (SET guide_tool "sys:utilities/more" )
)


;================================================================================
;

(complete 0)

(message #welcome)

(welcome)
(set old_level @user-level)

(set vttdir
        (askdir
                (prompt #where-vtt)
                (help @askdir-help)
                (default "RAM:")
        )
)




(set iconsource
        (ASKCHOICE
                (PROMPT #icon_type)
                (CHOICES
                         "Standard"
                         "MagicWB")
                (DEFAULT 0)
                (HELP @askchoice-help)
        )
)

(if     (= iconsource 1 )
        ( SET iconsource "magicwb" )
        ( SET iconsource "standard" )
)


(MAKEDIR  (TACKON vttdir "VideoTitler"))
(COPYFILES(
          (SOURCE (CAT vttsource "icons/" iconsource "/VideoTitler_drawer.info"))
          (DEST vttdir)
          (NEWNAME "VideoTitler.info")
          ))
(SET vttdir_dummy (TACKON vttdir "VideoTitler"))
(SET vttdir vttdir_dummy)

(complete 10)
(copyfiles
        (source (CAT vttsource "Videotitler"))
        (dest vttdir)
)

(copyfiles
        (source (cat vttsource "icons/" iconsource "/VideoTitler.info"))
        (dest vttdir)
        (noposition)
)


(complete 30)


(MAKEDIR  (TACKON vttdir "scripts"))
(COPYFILES(
          (SOURCE (CAT vttsource "icons/" iconsource  "/scripts.info"))
          (DEST vttdir )
          ))
(MAKEDIR  (TACKON vttdir "icons"))
(MAKEDIR  (TACKON vttdir "anims"))
(COPYFILES(
          (SOURCE (CAT vttsource "icons/" iconsource "/Anims.info"))
          (DEST vttdir )
          ))
(MAKEDIR  (TACKON vttdir "brushes"))
(COPYFILES(
          (SOURCE (CAT vttsource "icons/" iconsource "/Brushes.info"))
          (DEST vttdir )
          ))
(copyfiles
        (source (cat vttsource "icons/" iconsource "/videotitler_project.info"))
        (dest (TACKON vttdir "icons"))
        (noposition)
)

(copyfiles
        (source (cat vttsource "icons/" iconsource "/videotitler_iconification.info"))
        (dest (TACKON vttdir "icons"))
        (noposition)
)

(TOOLTYPE (DEST (TACKON vttdir "icons/videotitler_project"))
          (SETDEFAULTTOOL (TACKON  vttdir "VideoTitler"))
          (NOPOSITION)
          )

(FOREACH (CAT vttsource "scripts") "#?.vtt"
          (COPYFILES(
                     (SOURCE (TACKON (CAT vttsource "scripts") @each-name))
                     (DEST (TACKON  vttdir "scripts"))
                     )
          )
          (COPYFILES(
                     (SOURCE (TACKON vttdir "icons/videotitler_project.info"))
                     (DEST (TACKON  vttdir "scripts"))
                     (NEWNAME (CAT @each-name ".info"))
                     )
          )
)

(complete 40)
(FOREACH (CAT vttsource "anims") "#?"
          (COPYFILES(
                     (SOURCE (TACKON (CAT vttsource "anims") @each-name))
                     (DEST (TACKON  vttdir "anims"))
                     )
          )
)
(complete 70)

(FOREACH (CAT vttsource "brushes") "#?"
          (COPYFILES(
                     (SOURCE (TACKON (CAT vttsource "brushes") @each-name))
                     (DEST (TACKON  vttdir "brushes"))
                     )
          )
)
(complete 90)

(user 2)
(set lang
(askchoice
         (prompt #which-language)
         (help #which-language-help @askoptions-help)
         (choices
                 "English"
                 "Deutsch")
         )
)
(user old_level)
(if( = lang 1 ) (SET language "deutsch" ) (SET language "english"))

(if (EXISTS("SYS:LOCALE") )
    (if (<> language "english")
           (
               (makedir (TACKON vttdir "catalogs" ))
               (makedir (TACKON vttdir (cat "catalogs/" language)))
               (copyfiles (SOURCE (cat vttsource "catalogs/" language))
                          (DEST (TACKON vttdir (cat "catalogs/" language)))
               (all))
           )
    )
)

(set doctype
(askchoice
         (prompt #documentation-type)
         (help @askchoice-help)
         (choices
                 "Normal Doc-File"
                 "Amiga-Guide")
         )
)

(if (= doctype 1)

 ((copyfiles
          (source (cat vttsource "docs/videotitler_" language ".guide"))
          (dest vttdir)
          (NEWNAME "VideoTitler.guide")
  )
  (copyfiles
          (source (cat vttsource "icons/" iconsource "/guide.info"))
          (dest vttdir)
          (NEWNAME "VideoTitler.guide.info")
  )
  (TOOLTYPE (DEST (TACKON vttdir "VideoTitler.guide"))
            (SETDEFAULTTOOL guide_tool )
            )
 )
 (
  (run (cat "/c/guide2doc "
            vttsource "docs/videotitler_" language ".guide "
            ">" (TACKON vttdir "VideoTitler.doc")))
  (copyfiles
          (source (cat vttsource "icons/" iconsource "/vtt_doc.info"))
          (dest vttdir)
          (NEWNAME "VideoTitler.doc.info")
  )



 )
)

(if (exists "/vtt.key")
        (copyfiles
           (source "/vtt.key")
           (dest "DEVS:")
        )
)

(if(=
 (ASKBOOL
        ( PROMPT #askfont )
        ( HELP #fonthelp )
        ( DEFAULT 0 )
 )
 1 )
 (copyfiles
        (source (CAT vttsource "fonts"))
        (dest "Fonts:")
        (ALL)
 )
)

(complete 100)
(exit #exit_string )