home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 16 / 16.iso / t / t141 / 1.img / NDPTYPE.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-06-24  |  4.0 KB  |  96 lines
  1. ;****************************************************************************
  2. ; NDPTYPE determines whether or not a math coprocessor is installed and
  3. ; identifies it as an 8087, 80287, or 80387.  On return, ERRORLEVEL is
  4. ; set as follows:
  5. ;
  6. ;       0       No coprocessor installed
  7. ;       1       8087
  8. ;       2       80287
  9. ;       3       80387
  10. ;
  11. ; 486-based PCs will report that an 80387 is installed because the 486
  12. ; has the equivalent of an 80387 built in.
  13. ;****************************************************************************
  14.  
  15.                 .8087
  16.  
  17. code            segment
  18.                 assume  cs:code,ds:code
  19.                 org     100h
  20. begin:          jmp     short main
  21.  
  22. no_ndp          db      13,10,"No coprocessor installed",13,10,"$"
  23. ndp_is          db      13,10,"Coprocessor is an 80$"
  24. ndp_8087        db      "87$"
  25. ndp_80287       db      "287$"
  26. ndp_80387       db      "387$"
  27. crlf            db      13,10,"$"
  28. cword           dw      0
  29. errorlevel      db      1
  30.  
  31. ;****************************************************************************
  32. ; Procedure MAIN
  33. ;****************************************************************************
  34.  
  35. main            proc    near
  36.                 fninit                          ;Check for coprocessor
  37.                 fnstcw  cword                   ;  by initializing it
  38.                 cmp     byte ptr [cword+1],3    ;  and checking to see
  39.                 je      ndp_installed           ;  if FNINIT works
  40.                 mov     ah,09h                  ;Print "No coprocessor
  41.                 mov     dx,offset no_ndp        ;  installed" message
  42.                 int     21h
  43.                 mov     ax,4C00h                ;Set ERRORLEVEL and exit
  44.                 int     21h
  45. ;
  46. ; Test for an 8087 by seeing if the FDISI instruction sets the IEM bit
  47. ; in the coprocessor control word.
  48. ;
  49. ndp_installed:  mov     ah,09h                  ;Print opening message
  50.                 mov     dx,offset ndp_is
  51.                 int     21h
  52.  
  53.                 mov     dx,offset ndp_8087
  54.                 and     cword,0FF7Fh
  55.                 fldcw   cword                   ;Load control word
  56.                 fdisi                           ;Disable NDP interrupts
  57.                 fstcw   cword                   ;Store control word
  58.                 test    cword,0080h             ;Test bit 7
  59.                 jnz     exit                    ;Exit if set
  60. ;
  61. ; Separate 287s from 387s by seeing whether the coprocessor defaults to
  62. ; affine (387) or projective closure (287)
  63. ;
  64.                 mov     dx,offset ndp_80287
  65.                 inc     errorlevel
  66.                 finit                           ;Initialize the coprocessor
  67.                 fld1                            ;Push 1.0 onto the stack
  68.                 fldz                            ;Push 0.0 onto the stack
  69.                 fdiv                            ;Divide 1.0 by 0.0
  70.                 fld     st                      ;Duplicate infinity
  71.                 fchs                            ;Change the sign of one
  72.                 fcompp                          ;Compare the two infinities
  73.                 fstsw   cword                   ;Get status word from compare
  74.                 fwait
  75.                 mov     ax,cword                ;Transfer it to FLAGS
  76.                 sahf
  77.                 jz      exit                    ;287 if infinities equal
  78.  
  79.                 mov     dx,offset ndp_80387     ;It's a 387!
  80.                 inc     errorlevel
  81. ;
  82. ; Display NDP type, set return code, and exit.
  83. ;
  84. exit:           mov     ah,09h                  ;Display NDP type
  85.                 int     21h
  86.                 mov     ah,09h
  87.                 mov     dx,offset crlf
  88.                 int     21h
  89.                 mov     ah,4Ch                  ;Exit with ERRORLEVEL set
  90.                 mov     al,errorlevel           ;  indicating NDP type
  91.                 int     21h
  92. main            endp
  93.  
  94. code            ends
  95.                 end     begin
  96.