home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 13 / 13.iso / p / p064 / 8.ddi / OPTO.LIB < prev    next >
Encoding:
Text File  |  1991-07-01  |  6.2 KB  |  194 lines
  1. * Library of optocoupler models
  2.  
  3. * Copyright 1989 by MicroSim Corporation
  4. *   Neither this library nor any part may be copied without the express
  5. *   written consent of MicroSim Corporation
  6.  
  7. * $Revision:   1.3  $
  8. * $Author:   pwt  $
  9. * $Date:   16 Mar 1990 11:02:12  $
  10.  
  11. * The parameters in this model library were derived from the data sheets for
  12. * each part.
  13.  
  14. *.model A4N25
  15. * 6-pin DIP: pin #1   #2   #4   #5   #6
  16. *         |    |    |    |    |
  17. .subckt A4N25    pin1 pin2 pin4 pin5 pin6    params: rel_CTR=1
  18. *        Motorola    pid=4N25
  19. *        88-01-04 pwt
  20. *        88-01-18 pwt    rework Cje approximation
  21.  
  22. * The data sheet used for this model is from Motorola: it was the most
  23. * complete for DC and switching parameters, and is was easy to find the
  24. * component IR-LED and phototransistor as separate devices for further
  25. * specifications.
  26.  
  27.   d_MainLED    pin1 pin2    MainLED
  28.   d_PhotoLED    pin1 1        PhotoLED .001
  29.   v_PhotoLED    1 pin2        0
  30.  
  31.   f_TempComp    0 2        v_PhotoLED 1
  32.   r_TempComp    2 0        TempComp {rel_CTR}
  33.  
  34.   g_BaseSrc    5 6 2 0        .9
  35.   q_PhotoBJT    5 6 4        PhotoBJT
  36.   r_C        5 pin5        .1
  37.   r_B        6 pin6        .1
  38.   r_E        4 pin4        .1
  39.  
  40. * Since active devices dominate pin-to-pin capacitance on each "side" of the
  41. * optocoupler, isolation is modeled by identical capacitances and resistances
  42. * linked to a common point; this gives isolation of .5pF and 1E+11 ohms
  43.   c_1        pin1 7        .4p
  44.   r_1        pin1 7        .12T
  45.   c_2        pin2 7        .4p
  46.   r_2        pin2 7        .12T
  47.   c_4        pin4 7        .4p
  48.   r_4        pin4 7        .12T
  49.   c_5        pin5 7        .4p
  50.   r_5        pin5 7        .12T
  51.   c_6        pin6 7        .4p
  52.   r_6        pin6 7        .12T
  53.  
  54. * Similar to Motorola MLED15.
  55. .model MainLED  D(Is=1.1p Rs=.66 Ikf=30m N=1.9 Xti=3 Cjo=40p M=.34 Vj=.75
  56. +        Isr=30n Nr=3.8 Bv=6 Ibv=100u Tt=.5u)
  57.  
  58. * Models photon generation: same as MainLED except no AC effects, no breakdown.
  59. .model PhotoLED D(Is=1.1p Rs=.66 Ikf=30m N=1.9 Xti=3 Cjo=0   M=.34 Vj=.75
  60. +        Isr=30n Nr=3.8 Bv=0 Tt=0)
  61.  
  62. * Temperature compensation for system: 1.38x @ -55'C, .54x @ +100'C, all @ 10mA
  63. * Note: the photo BJT has its own temperature corrections, which must be kept
  64. * as the transistor is electrically available.
  65. .model TempComp    RES(R=1 Tc1=-11.27m Tc2=43.46u)
  66.  
  67. * Similar to Motorola MDR3050; Hfe=325 @ Ic=500uA, Vce=5V
  68. * Use beta variation (w/Parts) to model change in current-transfer ratio (CTR).
  69. * Hand adjust reverse beta (Br) to match saturation characteristics.
  70. * Set Isc to model dark current.
  71. * Hand adjust Cjc to match fall time @ Ic=10mA (which yields rise time, too).
  72. * Hand adjust reverse transit-time (Tr) to match storage time @ Ic=10mA.
  73. * Delay time set by LED I-V and C-V characteristics; set Cje to 25% of Cjc,
  74. * inspection of phototransistor chip layouts show the emitter area is 20%-25%
  75. * that of the collector area.  The same layouts show that base resistance is
  76. * made negligible by design; also, the operating currents are small.
  77. * Hand adjust forward transit-time (Tf) to match MDR3050 pulse data.  Check
  78. * against 4N25 frequency response (Fig 11, 12).
  79. .model PhotoBJT NPN(Is=10f Xti=3 Vaf=60
  80. +        Bf=400 Ne=3.75 Ise=580p Ikf=.26 Xtb=1.5
  81. +        Br=.04 Nc=2    Isc=3.5n
  82. +        Cjc=10p  Mjc=.3333 Vjc=.75 Tr=88u
  83. +        Cje=2.5p Mje=.3333 Vje=.75 Tf=1.5n)
  84. .ends
  85.  
  86. *.model A4N25A
  87. * 6-pin DIP: pin #1   #2   #4   #5   #6
  88. *                |    |    |    |    |
  89. .subckt A4N25A    pin1 pin2 pin4 pin5 pin6
  90. *        88-01-05 pwt
  91. * Same as 4N25 (UL recognized).
  92.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  93. .ends
  94.  
  95. *.model A4N26
  96. * 6-pin DIP: pin #1   #2   #4   #5   #6
  97. *                |    |    |    |    |
  98. .subckt A4N26    pin1 pin2 pin4 pin5 pin6
  99. *        88-01-05 pwt
  100. * Same as 4N25, lower isolation breakdown voltage.
  101.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  102. .ends
  103.  
  104. *.model A4N27
  105. * 6-pin DIP: pin #1   #2   #4   #5   #6
  106. *                |    |    |    |    |
  107. .subckt A4N27    pin1 pin2 pin4 pin5 pin6
  108. *        88-01-05 pwt
  109. * Same as 4N25, lower CTR, lower isolation breakdown voltage.
  110.   x1 pin1 pin2 pin4 pin5 pin6 A4N25 params: rel_CTR=.5
  111. .ends
  112.  
  113. *.model A4N28
  114. * 6-pin DIP: pin #1   #2   #4   #5   #6
  115. *                |    |    |    |    |
  116. .subckt A4N28    pin1 pin2 pin4 pin5 pin6
  117. *        88-01-05 pwt
  118. * Same as 4N25, lower CTR, lower isolation breakdown voltage.
  119.   x1 pin1 pin2 pin4 pin5 pin6 A4N25 params: rel_CTR=.5
  120. .ends
  121.  
  122. *.model H11A2
  123. * 6-pin DIP: pin #1   #2   #4   #5   #6
  124. *                |    |    |    |    |
  125. .subckt H11A2    pin1 pin2 pin4 pin5 pin6
  126. *        88-01-05 pwt
  127. * Every manufacturer seems to use their own 4N25 as an equivalent device.
  128.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  129. .ends
  130.  
  131. *.model H11A3
  132. * 6-pin DIP: pin #1   #2   #4   #5   #6
  133. *                |    |    |    |    |
  134. .subckt H11A3    pin1 pin2 pin4 pin5 pin6
  135. *        88-01-05 pwt
  136. * Same as H11A2, higher isolation breakdown voltage.
  137.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  138. .ends
  139.  
  140. *.model H11A4
  141. * 6-pin DIP: pin #1   #2   #4   #5   #6
  142. *                |    |    |    |    |
  143. .subckt H11A4    pin1 pin2 pin4 pin5 pin6
  144. *        88-01-05 pwt
  145. * Every manufacturer seems to use their own 4N27 as an equivalent device.
  146.   x1 pin1 pin2 pin4 pin5 pin6 A4N27
  147. .ends
  148.  
  149. *.model H11A520
  150. * 6-pin DIP: pin #1   #2   #4   #5   #6
  151. *                |    |    |    |    |
  152. .subckt H11A520    pin1 pin2 pin4 pin5 pin6
  153. *        88-01-05 pwt
  154. * Same as H11A2, higher isolation breakdown voltage.
  155.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  156. .ends
  157.  
  158. *.model MCT2
  159. * 6-pin DIP: pin #1   #2   #4   #5   #6
  160. *                |    |    |    |    |
  161. .subckt MCT2    pin1 pin2 pin4 pin5 pin6
  162. *        88-01-05 pwt
  163. * Every manufacturer seems to use their own 4N25 as an equivalent to the
  164. * General Instruments device.
  165.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  166. .ends
  167.  
  168. *.model MCT2E
  169. * 6-pin DIP: pin #1   #2   #4   #5   #6
  170. *                |    |    |    |    |
  171. .subckt MCT2E    pin1 pin2 pin4 pin5 pin6
  172. *        88-01-05 pwt
  173. * Same as MTC2E, higher isolation breakdown voltage.
  174.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  175. .ends
  176.  
  177. *.model MOC1005
  178. * 6-pin DIP: pin #1   #2   #4   #5   #6
  179. *                |    |    |    |    |
  180. .subckt MOC1005    pin1 pin2 pin4 pin5 pin6
  181. *        88-01-05 pwt
  182. * Motorola equivalent of 4N25
  183.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  184. .ends
  185.  
  186. *.model MOC1006
  187. * 6-pin DIP: pin #1   #2   #4   #5   #6
  188. *                |    |    |    |    |
  189. .subckt MOC1006    pin1 pin2 pin4 pin5 pin6
  190. *        88-01-05 pwt
  191. * Motorola equivalent of 4N27
  192.   x1 pin1 pin2 pin4 pin5 pin6 A4N27
  193. .ends
  194.