home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 13 / 13.iso / p / p063_1 / 1.ddi / EVAL.CIR < prev    next >
Encoding:
Text File  |  1991-01-31  |  8.0 KB  |  183 lines
  1. EVAL.cir - An Illustration of PSpice Capabilities
  2. * 
  3. * This circuit, a differential pair driving a comparator and a counter,
  4. * shows many of the capabilities of PSpice.
  5. * It creates a large amount of output for such a small circuit.  Normally,
  6. * only a few kinds of analysis, such as transient analysis, would be run.
  7. * 
  8. * This command sets options for the run.
  9. .OPT ACCT NOMOD NOPAGE RELTOL=.001
  10.  
  11. * Sets the width of the output to 80 columns.
  12. .WIDTH OUT=80
  13.  
  14. * Sets the temperature for the run to 35 degrees celsius.
  15. .TEMP 35
  16.  
  17. * This command does a DC sweep.  The voltage source VIN is swept from
  18. *   -0.125 volts to 0.125 volts in steps of 0.005 volts.  The non-linear
  19. *   device equations are used.
  20. .DC VIN -0.125 0.125 0.005
  21.  
  22. * There is no command to do a small-signal bias point calculation.  It
  23. *   is done automatically after the DC sweep is finished.  The non-linear
  24. *   device equations are used to find the bias point.  Then, the linearized,
  25. *   small-signal equivalent circuit at the bias point is saved for the .TF,
  26. *   .SENS, .AC, and .NOISE analysis.  This command prints out the small-
  27. *   signal parameters for each device.
  28. .OP
  29.  
  30. * This command does a small-signal transfer function calculation assuming
  31. *   VIN is the input and V(5), the voltage at node 5, is the output.
  32. .TF V(5) VIN
  33.  
  34. * This does an AC analysis.  The real and imaginary response of the circuit
  35. *   is calculated as the inputs are swept from 100 kilohertz to 10 gigahertz
  36. *   by decades with 10 points per decade.  The only AC input this circuit has
  37. *   is VIN.  This is a linear analysis.
  38. .AC DEC 10 100KHZ 10GHZ
  39.  
  40. * This command does noise calculations during the AC analysis.  Each
  41. *   device's noise contribution is calculated and propogated to node 5.
  42. *   All the contributions are rms-summed at node 5.  Besides the total
  43. *   output noise printout done for every frequency, a detailed table of
  44. *   each device's contribution is done every 30'th frequency.
  45. .NOISE V(5) VIN 30
  46.  
  47. * This command does a transient analysis.  It first re-calculates the
  48. *   circuit's bias point, then calculates the circuit's time response
  49. *   from 0 nanoseconds to 1 microsecond using the full, non-linear device
  50. *   equations, including non-linear capacitances.  PSpice uses a variable
  51. *   time step for the calculations, but this command causes the results
  52. *   to be interpolated onto a 5 nanosecond print interval.  Transient
  53. *   analysis is the most frequently used analysis in PSpice.
  54. .TRAN 20NS 5uS
  55.  
  56. * This does a harmonic decomposition on the waveform V(5) calculated
  57. *   during transient analysis.  It calculates the magnitude and phase
  58. *   of the fundamental (5 megahertz) and the first eight harmonics.
  59. *   The graphics post-processor, Probe, goes further and contains
  60. *   a full FFT, allowing complete spectra to be displayed.
  61. .FOUR 1MEG V(5)
  62.  
  63. * This command does a Monte Carlo analysis of the circuit.  It runs
  64. *   the DC sweep 5 times using the tolerances in .MODEL statements
  65. *   and compares the waveform V(4,5) from each run against the nominal
  66. *   V(4,5).  It then lists a table of each run's deviation from the 
  67. *   nominal.  The Monte Carlo option can also do Worst Case and Sensitivity
  68. *   analysis.
  69. .MC 5 DC V(4,5) YMAX
  70.  
  71. * PSpice allows parameters to be defined and used in expressions
  72. *   throughout the circuit file.  Parameters may also be passed into
  73. *   subcircuits as arguments and used inside.  Here, we define a
  74. *   fudge factor for the supply voltages.
  75. .PARAM FACTOR=1.2
  76.  
  77. * The following statements describe the circuit to PSpice.  It is a
  78. *   simple differential pair, with +12 and -12 volts as the supplies.
  79.  
  80. * VIN is the input for this circuit.  It has an amplitude during AC analysis
  81. *   of 1 volt and a sine waveform during transient of .1 volt at 5 megahertz.
  82. VIN 100 0 AC 1 SIN(0 0.1 1MEG)
  83.  
  84. * The power supplies are + and - SUPPLY volts.  As mentioned above,
  85. *   expressions containing parameters can be used for values throughout
  86. *   the circuit file.  Expressions are enclosed by "{" and "}" and allow
  87. *   arithmetic expressions.
  88. VCC 101 0 DC {10*FACTOR}
  89. VEE 102 0 {-10*FACTOR}
  90.  
  91. * The transistors' nodes are in the order collector - base - emitter.
  92. *   All transistors must refer to a model (QNL in this case).
  93. Q1 4 2 6 QNL
  94. Q2 5 3 6 QNL
  95.  
  96. * Models for resistors are optional.  If used they can specify such things
  97. *   as scaling, temperature coefficients, and tolerances.
  98. RS1 100 2 1K 
  99. RS2 3 0 1K
  100. RC1 4 101 CRES 10K
  101. RC2 5 101 CRES 10K
  102. Q3 6 7 102 QNL
  103. Q4 7 7 102 QNL
  104. RBIAS 7 101 20K
  105. CLOAD 4 5 5PF
  106.  
  107. * This statement describes the CRES resistor by giving the values for
  108. *   the parameters.  Each type of model has its own set of parameters.
  109. *   All parameters have default values.  In CRES we have set the scaling
  110. *   factor to 1, the linear temperature coefficient to .02, and the
  111. *   quadratic temperature coefficient to .0045, and given each resistor
  112. *   a 5% tolerance on its value during Monte Carlo analysis.
  113. .model CRES res (
  114. +    R=1 DEV 5%    TC1=.02
  115. +    TC2=.0045
  116. +    )
  117. * The bipolar transistor model is the Gummel-Poon model.  It uses the
  118. *   same equations as in the UC Berkeley Spice program.  There are
  119. *   actually 55 model parameters, but most of these are for second-order
  120. *   effects that are rarely used.  Most bipolar models for realistic
  121. *   circuits specify between 12 and 25 parameters and default the rest.
  122. *   Here, we have set the forward beta to 80, the base resistance to
  123. *   100 ohms, the collector-substrate capacitance to 2 picofarads, the
  124. *   forward transit time to 0.3 nanoseconds, the reverse transit time to
  125. *   6 nanoseconds, the base-emitter capacitance to 3 picofarads, the
  126. *   base-collector capacitance to 2 picofarads, and the forward Early
  127. *   voltage to 50 volts.  The capacitances are actually voltage dependent.
  128. *   These numbers are the zero-bias values.
  129. .model QNL npn (
  130. +    BF=80    RB=100
  131. +    CCS=2PF    TF=0.3NS
  132. +    TR=6NS    CJE=3PF
  133. +    CJC=2PF    VA=50
  134. +    )
  135. * The Analog Behavioral Modeling option allows one to define a transfer
  136. *   function by formula and/or by table.  Here, we implement an ideal
  137. *   comparator to convert the differential output across nodes 4 and 5 into
  138. *   a TTL output on node 'comp_out'.  The voltage across 4 and 5 is
  139. *   multiplied by 1e3 and that value is looked up in the table.  The
  140. *   table has an output of 0v for inputs < -5, 5v for inputs > 5,
  141. *   and output=input in between. So, the comparator has a gain of 1,000 
  142. *   and saturates at 0v and 5v.
  143. * Although not shown here, one can also define linear transfer functions
  144. *   by Laplace transform formulas or by frequency response tables.
  145. E1    10 0    TABLE {V(4,5)*1e3}    (-5v,0v 5v,5v)
  146. RE1    10 comp_out    200     ; Output series resistance
  147. CCOMP   comp_out   0    20pf    ; Output load capacitance
  148.  
  149. * Power supply for digital circuits.  We use the library digital power
  150. * supply subcircuit.
  151. XDIGPWR  0 DPWR 0   DIGIFPWR   PARAMS: VOLTAGE = 5V
  152.  
  153. * The Digital Simulation option simulates digital components.  Instead
  154. *   of voltages and waveforms, it calculates 1's and 0's and propogation
  155. *   delays.  PSpice automatically creates interface components between
  156. *   analog and digital sections or circuitry.  Here, we drive a 74393,
  157. *   4-bit, ripple counter from the output of the comparator (XCOMP or RE1).
  158. X1  comp_out 110 QA QB QC QD DPWR 0 74393
  159.  
  160. * This is a digital stimulus which resets the counter
  161. U2 stim(1,1) DPWR 0     ; digital power supplies
  162. +    110 
  163. +    IO_STM  ; use the library digital IO model for a stimulus device
  164. +    0NS    1
  165. +    40NS    0
  166.  
  167. * These commands provide print and plot output for selected voltages
  168. *   and currents.  The plots are the so-called "line printer" plots.
  169. *   That is, plots made out of characters.  To get real, high-resolution
  170. *   plots you need to use Probe; it is invoked by the .PROBE command.
  171. .PRINT DC V(4) V(5)
  172. .PLOT DC IC(Q2) 
  173. .PLOT AC VCM(Q2) VCP(Q2)
  174. .PLOT NOISE INOISE ONOISE 
  175. .PLOT TRAN V(4,5) V([comp_out])    D(QA) D(QB)
  176. * This .PROBE statement will save all analog and digital voltage and current
  177. * values for use by Probe.
  178. .PROBE
  179.  
  180. .LIB eval.lib   ; Read models from the library
  181.  
  182. .END
  183.