home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 13 / 13.iso / p / p030 / 2.ddi / EDGE.LSP < prev    next >
Encoding:
Lisp/Scheme  |  1988-08-30  |  6.6 KB  |  166 lines
  1. ;-----------------------------------------------------------------------------+
  2. ;                                                                             |
  3. ;                       EDGE.lsp   Version 2.2   7/12/88                      |
  4. ;                                                                             |
  5. ;                                 Larry Knott                                 |
  6. ;                                                                             |
  7. ;   Interactive editor for changing the visibility of 3DFACE edges.           |
  8. ;                                                                             |
  9. ;   Prompt:         "Display/<Select edge>: "                                 |
  10. ;                                                                             |
  11. ;   Features:                                                                 |
  12. ;    > "Display" -  Allows selective regeneration of 3DFACE's highlighting    |
  13. ;                   invisible edges.                                          |
  14. ;    >  Select   -  Reverses the visibility of each edge found.               |
  15. ;                                                                             |
  16. ;   Note:                                                                     |
  17. ;    >  EDGE uses Osnap MIDpoint as the center of a small crossing box        |
  18. ;       when selecting edges.                                                 |
  19. ;    >  Only edges displayed (or highlighted) can be modified.  (Use          |
  20. ;       "Display" to display a 3DFACE.)                                       |
  21. ;    >  Invisible edges will always be displayed if the system variable       |
  22. ;       SPLFRAME is set to 1.                                                 |
  23. ;                                                                             |
  24. ;-----------------------------------------------------------------------------+
  25.  
  26. ;----------------------------- CREATE NEW *ERROR* ----------------------------|
  27.  
  28. (defun edge-er (n)
  29. (if (/= s "Function cancelled")
  30.   (princ (strcat "\nError: " n))
  31. )
  32. (command)
  33. (command "ucs" "p")
  34. (setvar "osmode"   o1)
  35. (setvar "gridmode" g1)    (setvar "aperture" a1)
  36. (setvar "splframe" v1)    (setvar "ucsfollow" u1)
  37. (command "undo" "e")
  38. (setvar "cmdecho"  s1)
  39. (setq n1 -1)
  40. (repeat (sslength faclst)
  41.   (redraw (entupd (ssname faclst (setq n1 (1+ n1))))))
  42. (setq *error* lisp-er)
  43. (prin1))
  44.  
  45. ;---------------------------- COMMONLY USED MACROS ---------------------------|
  46.  
  47. (defun getval (n e) (cdr (assoc n e)))
  48.  
  49. (defun fltfac (ss / n1)
  50. (setq n1 0)
  51. (if ss
  52.   (repeat (sslength ss)
  53.      (if (/= (getval 0 (entget (setq e1 (ssname ss n1)))) "3DFACE")
  54.         (ssdel e1 ss)
  55.         (setq n1 (1+ n1))))) ss)
  56.  
  57. ;------------------------- FORCE DISPLAY OF ALL EDGES ------------------------|
  58.  
  59. (defun dsply (/ ss n1 t1)
  60. (setvar "osmode" 0)
  61. (initget "All Select")
  62. (setq ss (if (eq (getkword "\nSelect/<All>: ") "Select")
  63.              (fltfac (ssget))
  64.              (ssget "x" '((0 . "3dface"))))
  65.       n1 -1)
  66. (setvar "osmode" 2)
  67. (cond (ss (princ "\n** Regenerating 3DFACE entities...")
  68.           (repeat (sslength ss)
  69.             (ssadd (setq t1 (ssname ss (setq n1 (1+ n1)))) faclst)
  70.             (shohdn (entget (entupd t1))))
  71.           (princ "done.") T)
  72.       (T  (princ "\nNo 3DFACE entities found.") nil)))
  73.  
  74. ;----------------------------- SHOW HIDDEN EDGES -----------------------------|
  75.  
  76. (defun shohdn (e / b1 p1 p2 p3 p4)
  77. (setq b1 (getval 70 e))
  78. (mapcar '(lambda (j k) (set j (getval k e)))
  79.         '(p1 p2 p3 p4)
  80.         '(10 11 12 13))
  81. (if (= (logand b1 1) 1) (grdraw p1 p2 c1 1))
  82. (if (= (logand b1 2) 2) (grdraw p2 p3 c1 1))
  83. (if (= (logand b1 4) 4) (grdraw p3 p4 c1 1))
  84. (if (= (logand b1 8) 8) (grdraw p4 p1 c1 1)))
  85.  
  86. ;----------------------------- GET ENTITY TO EDIT ----------------------------|
  87.  
  88. (defun getfce (pt / ll ur n1 ss e1 p1)
  89. (setq p1 (trans pt 0 2)
  90.       ll (trans (polar P1 (/ (* pi 5) 4) h1) 2 0)
  91.       ur (trans (polar P1 (/ pi 4) h1) 2 0)
  92.       n1 0)
  93. (setvar "osmode" 0)
  94. (if (setq ss (ssget "c" ll ur))
  95.   (setq ss (fltfac ss)))
  96. (setvar "osmode" 2) ss)
  97.  
  98. ;--------------------- MODIFY 3DFACE EDGE VISIBILITY FLAG --------------------|
  99.  
  100. (defun modfce (ss pt / n1 e1 e0 p0 b1 b2 b3)
  101. (setq n1 0)
  102. (repeat (sslength ss)
  103.   (setq e1 (entget (ssname ss n1))
  104.         e0 (getval -1 e1))
  105.   (ssadd e0 faclst)
  106.   (mapcar '(lambda (j k) (set j (getval k e1)))
  107.               '(p1 p2 p3 p4)
  108.               '(10 11 12 13))
  109.   (setq p0 (if (equal (distance p3 p4) 0 1e-8)
  110.              (mapcar '(lambda (j k l) (/ (+ j k l) 3)) p1 p2 p3)
  111.              (mapcar '(lambda (j k l m) (/ (+ j k l m) 4)) p1 p2 p3 p4)))
  112.   (setq b1 (getval 70 e1)
  113.         b2 (cond ((equal pt (inters p0 pt p1 p2) h1) 1)
  114.                  ((equal pt (inters p0 pt p2 p3) h1) 2)
  115.                  ((equal pt (inters p0 pt p3 p4) h1) 4)
  116.                  ((equal pt (inters p0 pt p4 p1) h1) 8)
  117.                  (T 0))
  118.         b3 (+ b1 (if (= (logand b1 b2) b2) (- b2) b2))
  119.         e1 (shohdn (entmod (subst (cons 70 b3) (assoc 70 e1) e1)))
  120.         n1 (1+ n1)))
  121. T)
  122.  
  123. ;-------------------------------- MAIN PROGRAM -------------------------------|
  124.  
  125. (defun c:EDGE (/ lisp-er s1 o1 g1 a1 v1 h1 u1 faclst c1 r1 t1 ss pt n e n1)
  126. (setq lisp-er *error*
  127.       *error* edge-er
  128.       s1      (getvar "cmdecho")            o1    (getvar "osmode")
  129.       g1      (getvar "gridmode")           a1    (getvar "aperture")
  130.       v1      (getvar "splframe")           u1    (getvar "ucsfollow")
  131.       h1      (/ (getvar "viewsize") 100)
  132.       faclst  (ssadd)
  133.       c1      7
  134.       r1      T)
  135. (setvar "cmdecho"  0)   
  136. (command "undo" "group")
  137. (setvar "osmode"   2)
  138. (setvar "gridmode" 0)     (setvar "aperture" 5)
  139. (setvar "splframe" 1)     (setvar "ucsfollow" 0)
  140. (command "ucs" "W")
  141. (while r1
  142.   (initget "Display")
  143.   (setq t1 (getpoint "\nDisplay/<Select edge>: ")
  144.         r1 (cond
  145.               ((eq t1 "Display") (dsply))
  146.               ((eq (type t1) 'LIST)
  147.                  (setq ss (getfce t1))
  148.                  (cond 
  149.                     ((null ss) (princ " No 3DFACE edges found."))
  150.                     ((= (sslength ss) 0) (princ " Entity is not a 3DFACE."))             
  151.                     (t (modfce ss t1))))
  152.               (T nil))))
  153. (command "ucs" "p") 
  154. (setvar "osmode"   o1)
  155. (setvar "gridmode" g1)    (setvar "aperture" a1)
  156. (setvar "splframe" v1)    (setvar "ucsfollow" u1)
  157. (command "undo" "e")
  158. (setvar "cmdecho"  s1)
  159. (setq n1 -1)
  160. (repeat (sslength faclst)
  161.   (redraw (entupd (ssname faclst (setq n1 (1+ n1))))))
  162. (setq *error* lisp-er)
  163. (prin1))
  164.  
  165. ;------------------------------------ END ------------------------------------|
  166.