home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 13 / 13.iso / p / p024 / 5.img / R11SUPP.EXE / EDGE.LSP < prev    next >
Encoding:
Lisp/Scheme  |  1990-07-30  |  6.9 KB  |  217 lines
  1. ;;; --------------------------------------------------------------------------;
  2. ;;; EDGE.LSP            
  3. ;;;   Copyright (C) 1990 by Autodesk, Inc.
  4. ;;;  
  5. ;;;   Permission to use, copy, modify, and distribute this software and its
  6. ;;;   documentation for any purpose and without fee is hereby granted.  
  7. ;;;
  8. ;;;   THIS SOFTWARE IS PROVIDED "AS IS" WITHOUT EXPRESS OR IMPLIED WARRANTY. 
  9. ;;;   ALL IMPLIED WARRANTIES OF FITNESS FOR ANY PARTICULAR PURPOSE AND OF 
  10. ;;;   MERCHANTABILITY ARE HEREBY DISCLAIMED.
  11. ;;; 
  12. ;;;   by Larry Knott   Version 2.2   7/12/88                                 
  13. ;;;
  14. ;;; --------------------------------------------------------------------------;
  15. ;;; DESCRIPTION
  16. ;;;
  17. ;;;   Interactive editor for changing the visibility of 3DFACE edges.           
  18. ;;;   Prompt:         "Display/<Select edge>: "                                 
  19. ;;;
  20. ;;;   Features:                                                                 
  21. ;;;    > "Display" -  Allows selective regeneration of 3DFACE's highlighting    
  22. ;;;                   invisible edges.                                          
  23. ;;;    >  Select   -  Reverses the visibility of each edge found.               
  24. ;;;
  25. ;;;   Note:                                                                     
  26. ;;;    >  EDGE uses Osnap MIDpoint as the center of a small crossing box        
  27. ;;;       when selecting edges.                                                 
  28. ;;;    >  Only edges displayed (or highlighted) can be modified.  (Use          
  29. ;;;       "Display" to display a 3DFACE.)                                       
  30. ;;;    >  Invisible edges will always be displayed if the system variable       
  31. ;;;       SPLFRAME is set to 1.                                                 
  32. ;;;
  33. ;;; --------------------------------------------------------------------------;
  34.  
  35. ;;; ----------------------------- CREATE NEW *ERROR* -------------------------;
  36.  
  37. (defun edge-er (n) 
  38.   (if (/= s "Function cancelled") 
  39.     (princ (strcat "\nError: " n))
  40.   ) 
  41.   (command) 
  42.   (command "ucs" "p") 
  43.   (setvar "osmode" o1)
  44.   (setvar "gridmode" g1)
  45.   (setvar "aperture" a1)
  46.   (setvar "splframe" v1)
  47.   (setvar "ucsfollow" u1)
  48.   (command "undo" "e") 
  49.   (setvar "cmdecho" s1)
  50.   (setq n1 -1)
  51.   (repeat (sslength faclst) 
  52.     (redraw (entupd (ssname faclst (setq n1 (1+ n1)))))
  53.   ) 
  54.   (setq *error* lisp-er)
  55.   (prin1)
  56. ) 
  57. ;;; ---------------------------- COMMONLY USED MACROS ------------------------;
  58.  
  59. (defun getval (n e) 
  60.   (cdr (assoc n e))
  61. ) 
  62.  
  63. (defun fltfac (ss / n1) 
  64.   (setq n1 0)
  65.   (if ss 
  66.     (repeat (sslength ss) 
  67.       (if (/= (getval 0 (entget (setq e1 (ssname ss n1)))) "3DFACE") 
  68.         (ssdel e1 ss) 
  69.         (setq n1 (1+ n1))
  70.       )
  71.     )
  72.   ) 
  73.   ss
  74. ) 
  75.  
  76. ;;; ------------------------- FORCE DISPLAY OF ALL EDGES ---------------------;
  77.  
  78. (defun dsply (/ ss n1 t1) 
  79.   (setvar "osmode" 0)
  80.   (initget "All Select") 
  81.   (setq ss (if (eq (getkword "\nSelect/<All>: ") "Select") 
  82.              (fltfac (ssget)) 
  83.              (ssget "x" '((0 . "3dface")))
  84.            ) 
  85.         n1 -1)
  86.   (setvar "osmode" 2)
  87.   (cond (ss (princ "\n** Regenerating 3DFACE entities...") 
  88.             (repeat (sslength ss) 
  89.               (ssadd (setq t1 (ssname ss (setq n1 (1+ n1)))) faclst) 
  90.               (shohdn (entget (entupd t1)))) 
  91.             (princ "done.") T) 
  92.     (T (princ "\nNo 3DFACE entities found.") nil)
  93.   )
  94. ) 
  95. ;;; ----------------------------- SHOW HIDDEN EDGES --------------------------;
  96.  
  97. (defun shohdn (e / b1 p1 p2 p3 p4) 
  98.   (setq b1 (getval 70 e))
  99.   (mapcar '(lambda (j k) (set j (getval k e))) 
  100.           '(p1 p2 p3 p4) 
  101.           '(10 11 12 13)) 
  102.   (if (= (logand b1 1) 1) 
  103.     (grdraw p1 p2 c1 1)
  104.   ) 
  105.   (if (= (logand b1 2) 2) 
  106.     (grdraw p2 p3 c1 1)
  107.   ) 
  108.   (if (= (logand b1 4) 4) 
  109.     (grdraw p3 p4 c1 1)
  110.   ) 
  111.   (if (= (logand b1 8) 8) 
  112.     (grdraw p4 p1 c1 1)
  113.   )
  114. ) 
  115.  
  116. ;;; --------------------------- GET ENTITY TO EDIT ---------------------------;
  117.  
  118. (defun getfce (pt / ll ur n1 ss e1 p1) 
  119.   (setq p1 (trans pt 0 2) 
  120.         ll (trans (polar P1 (/ (* pi 5) 4) h1) 2 0) 
  121.         ur (trans (polar P1 (/ pi 4) h1) 2 0) 
  122.         n1 0)
  123.   (setvar "osmode" 0)
  124.   (if (setq ss (ssget "c" ll ur))
  125.     (setq ss (fltfac ss))
  126.   ) 
  127.   (setvar "osmode" 2)
  128.   ss
  129. ) 
  130.  
  131. ;;; --------------------- MODIFY 3DFACE EDGE VISIBILITY FLAG -----------------;
  132.  
  133. (defun modfce (ss pt / n1 e1 e0 p0 b1 b2 b3) 
  134.   (setq n1 0)
  135.   (repeat (sslength ss) 
  136.     (setq e1 (entget (ssname ss n1)) 
  137.           e0 (getval -1 e1))
  138.     (ssadd e0 faclst) 
  139.     (mapcar '(lambda (j k) (set j (getval k e1))) 
  140.             '(p1 p2 p3 p4) 
  141.             '(10 11 12 13)) 
  142.     (setq p0 (if (equal (distance p3 p4) 0 1e-8) 
  143.                (mapcar '(lambda (j k l) (/ (+ j k l) 3)) p1 p2 p3) 
  144.                (mapcar '(lambda (j k l m) (/ (+ j k l m) 4)) p1 p2 p3 p4)
  145.              ))
  146.     (setq b1 (getval 70 e1) 
  147.           b2 (cond ((equal pt (inters p0 pt p1 p2) h1) 1) 
  148.                ((equal pt (inters p0 pt p2 p3) h1) 2) 
  149.                ((equal pt (inters p0 pt p3 p4) h1) 4) 
  150.                ((equal pt (inters p0 pt p4 p1) h1) 8) 
  151.                (T 0)
  152.              ) 
  153.           b3 (+ b1 (if (= (logand b1 b2) b2) 
  154.                      (- b2) 
  155.                      b2
  156.                    )
  157.              ) 
  158.           e1 (shohdn (entmod (subst (cons 70 b3) (assoc 70 e1) e1))) 
  159.           n1 (1+ n1))
  160.   ) 
  161.   T
  162. ) 
  163. ;;; ------------------------------ MAIN PROGRAM ------------------------------;
  164.  
  165. (defun c:EDGE (/ lisp-er s1 o1 g1 a1 v1 h1 u1 faclst c1 r1 t1 ss pt n e n1) 
  166.   (setq lisp-er *error* 
  167.         *error* edge-er 
  168.         s1 (getvar "cmdecho") 
  169.         o1 (getvar "osmode") 
  170.         g1 (getvar "gridmode") 
  171.         a1 (getvar "aperture") 
  172.         v1 (getvar "splframe") 
  173.         u1 (getvar "ucsfollow") 
  174.         h1 (/ (getvar "viewsize") 100) 
  175.         faclst (ssadd) 
  176.         c1 7 
  177.         r1 T)
  178.   (setvar "cmdecho" 0)
  179.   (command "undo" "group") 
  180.   (setvar "osmode" 2)
  181.   (setvar "gridmode" 0)
  182.   (setvar "aperture" 5)
  183.   (setvar "splframe" 1)
  184.   (setvar "ucsfollow" 0)
  185.   (command "ucs" "W") 
  186.   (while r1 
  187.     (initget "Display") 
  188.     (setq t1 (getpoint "\nDisplay/<Select edge>: ") 
  189.           r1 (cond ((eq t1 "Display") (dsply)) 
  190.                ((eq (type t1) 'LIST) (setq ss (getfce t1))
  191.                 (cond ((null ss) (princ " No 3DFACE edges found.")) 
  192.                   ((= (sslength ss) 0) (princ " Entity is not a 3DFACE.")) 
  193.                   (t (modfce ss t1))
  194.                 )
  195.                ) 
  196.                (T nil)
  197.              ))
  198.   ) 
  199.   (command "ucs" "p") 
  200.   (setvar "osmode" o1)
  201.   (setvar "gridmode" g1)
  202.   (setvar "aperture" a1)
  203.   (setvar "splframe" v1)
  204.   (setvar "ucsfollow" u1)
  205.   (command "undo" "e") 
  206.   (setvar "cmdecho" s1)
  207.   (setq n1 -1)
  208.   (repeat (sslength faclst) 
  209.     (redraw (entupd (ssname faclst (setq n1 (1+ n1)))))
  210.   ) 
  211.   (setq *error* lisp-er)
  212.   (prin1)
  213. ) 
  214.  
  215. ;;; --------------------------------------------------------------------------;
  216.  
  217.