home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 11 / 11.iso / m / m110 / 3.ddi / GRPCT2.EXE / CDCMD.TXT < prev    next >
Encoding:
Text File  |  1990-02-12  |  7.0 KB  |  306 lines
  1. ;       CDCMD.TXT - GRASP 3.5 CD Command Routines - January 1990
  2. ;
  3. ; This program file contains routines for controlling audio CD play on
  4. ; CDROM devices:
  5. ;
  6. ; CDINIT     checks whether cd-rom drive and driver are set up
  7. ; CDSTATUS   returns CD status information
  8. ; PRTSTATUS  analyzes CD status info and reports device capabilities
  9. ; CDPLAY     plays starting at a given track for a given time
  10. ; CDPLAYTO   plays from one track to a second track
  11. ; CDSTOP     stops play
  12. ; CDRESUME   resumes play from the last CDSTOP
  13. ; CDSEEK     moves the cd head to a given track
  14. ; CDTRACK    returns the location of a track
  15. ; CDEJECT    opens the drive door/tray
  16. ; CDCLOSE    closes the drive door/tray
  17. ;
  18. ; CDCMD      a general-purpose command routine which makes the call
  19. ;            (setting memory and issuing the interrupt) for the other
  20. ;            subroutines
  21. ; CDCHECK    reports any errors encountered by CDCMD
  22. ;
  23. ; Other commands supported by a given drive may be implemented by passing
  24. ; values to CDCMD. To determine the correct values, consult the reference
  25. ; or programming guide for your drive.
  26. ;
  27. ; Some older drives do not support all of the commands implemented here.
  28. ;
  29. ; Here's a small sample program that uses a CD player.  Note that the first
  30. ; three commands set up variables which are used by the other routines.
  31. ; These must be issued before calling CDINIT.  They were omitted from the
  32. ; CDROM example in the manual (page 3-41) by mistake.
  33. ; 
  34.   set first 0       ;first track on current CD
  35.   set last 255      ;last track on current CD
  36.   set drive ""      ;drive letter of CD-ROM drive
  37.   cdinit            ;check whether CD driver is loaded
  38.   if !len(@drive)
  39.     text "CD ROM Driver not loaded"
  40.     waitkey
  41.     exit
  42.   endif
  43.   text "CD is drive "$@drive$":"$chr(10)$chr(10)
  44.   cdstatus          ;get drive status
  45.   prtstatus @0      ;print out drive status
  46.   cdplay 2 120      ;play track 2 for 120 seconds
  47.   waitkey           ;wait for a keypress
  48.   cdstop            ;stop playing
  49. exit
  50.  
  51.  
  52. ;CDINIT
  53. ;
  54. ; Checks for CD driver software and sets drive name.
  55. ;
  56. cdinit:
  57.     int 0x2f 0x1500,0
  58.     if @bx
  59.         set drive chr(@cx+asc("A"))
  60.     endif
  61.     return
  62.  
  63.  
  64. ; CDSTATUS
  65. ;
  66. ; Returns CD Drive status and sets global variables @first and @last.
  67. ;
  68. cdstatus:
  69.     local    buf ofs("123456")
  70.     local    bseg seg(@buf);
  71.     poke    @bseg @buf 10                ;Audio Disk Info
  72.     cdcmd    3,@buf|(@bseg<<16),6            ;READ IOCTL Input
  73.     cdcheck    @0,cdstatus
  74.     set    first peek(@bseg,@buf+1)+0
  75.     set    last  peek(@bseg,@buf+2)+0
  76.     poke    @bseg @buf 6                ;Device status
  77.     cdcmd    3,@buf|(@bseg<<16),5            ;READ IOCTL Input
  78.     cdcheck    @0,cdstatus
  79.     return    peekl(@bseg,@buf+1)
  80.  
  81.  
  82. ; PRTSTATUS
  83. ;
  84. ; Displays device characteristics and status.
  85. ;
  86. prtstatus:
  87.     if @1&1
  88.         text "Door Open"$chr(10)
  89.     else
  90.         text "Door Closed"$chr(10)
  91.     endif
  92.  
  93.     if @1&2
  94.         text "Door unlocked"$chr(10)
  95.     else
  96.         text "Door locked"$chr(10)
  97.     endif
  98.  
  99.     if @1&4
  100.         text "Supports cooked and raw reading"$chr(10)
  101.     else
  102.         text "Supports only cooked reading"$chr(10)
  103.     endif
  104.  
  105.     if @1&8
  106.         text "Read/write"$chr(10)
  107.     else
  108.         text "Read only"$chr(10)
  109.     endif
  110.  
  111.     if @1&16
  112.         text "Data read and plays audio/video tracks"$chr(10)
  113.     else
  114.         text "Data read only"$chr(10)
  115.     endif
  116.  
  117.     if @1&32
  118.         text "Supports ISO-9660 interleaving using interleave size and skip factor"$chr(10)
  119.     else
  120.         text "No interleaving"$chr(10)
  121.     endif
  122.  
  123.     if @1&128
  124.         text "Supports prefetching requests"$chr(10)
  125.     else
  126.         text "No Prefetching"$chr(10)
  127.     endif
  128.  
  129.     if @1&256
  130.         text "Supports audio channel manipulation"$chr(10)
  131.     else
  132.         text "No audio channel manipulation"$chr(10)
  133.     endif
  134.  
  135.     if @1&512
  136.         text "Supports HSG and Red Book addressing modes"$chr(10)
  137.     else
  138.         text "Supports HSG addressing mode"$chr(10)
  139.     endif
  140.  
  141.     if @1&2048
  142.         text "No disc is present in the drive"$chr(10)
  143.     else
  144.         text "Disc is present in the drive"$chr(10)
  145.     endif
  146.  
  147.     return
  148.  
  149.  
  150. ; CDPLAY TRACK NUM_SECONDS [MINUTES SECONDS FRAMES]
  151. ;
  152. ; Starts playing at TRACK for NUM_SECONDS duration.
  153. ; MINUTES, SECONDS, and FRAMES (which are a 1/75th of
  154. ; a second) are optional offsets into the specified track
  155. ; to begin playing.
  156. ;
  157. cdplay:
  158.     cdtrack    @1 @3 @4 @5
  159.     cdcmd    132,@0,@2*75
  160.     cdcheck    @0,cdplay
  161.     return
  162.  
  163.  
  164. ; CDPLAYTO TRACK MINUTES SECONDS FRAMES TRACK MINUTES SECONDS FRAMES
  165. ;
  166. ; Plays from one TRACK (at offset MINUTES SECONDS FRAMES into it)
  167. ; to the second TRACK (at the second offsets into it).
  168. ;
  169. cdplayto:
  170.     cdtrack    @1 @2 @3 @4
  171.     local    begin @0
  172.     cdtrack    @5 @6 @7 @8
  173.     local    end @0
  174.     cdcmd    132,@begin,@end-@begin
  175.     cdcheck    @0,cdplayto
  176.     return
  177.  
  178.  
  179. ; CDSTOP
  180. ;
  181. ; Stops playing immediately.
  182. ;
  183. cdstop:
  184.     cdcmd    133,0,0
  185.     cdcheck    @0,cdstop
  186.     return
  187.  
  188.  
  189. ; CDRESUME
  190. ;
  191. ; Resumes playing from the last CDSTOP.
  192. ;
  193. cdresume:
  194.     cdcmd    136,0,0
  195.     cdcheck    @0,cdresume
  196.     return
  197.  
  198.  
  199. ; CDSEEK TRACK [MINUTES SECONDS FRAMES]
  200. ;
  201. ; Moves the playing head to a given track to minimize startup time.
  202. ; Parameters are the same as CDPLAY.
  203. ;
  204. cdseek:
  205.     cdtrack @1 @2 @3 @4
  206.     cdcmd 131,@0,0
  207.     cdcheck    @0,cdseek
  208.     return
  209.  
  210.  
  211. ; CDTRACK TRACK MINUTES SECONDS FRAMES
  212. ;
  213. ; Returns the absolute sector number of a track.
  214. ;
  215. cdtrack:
  216.     local    buf ofs("1234567")
  217.     local    bseg seg(@buf);
  218.     poke    @bseg @buf 11                ;Get Audio Track Info
  219.     poke    @bseg @buf+1 @1             ;track number
  220.     cdcmd    3,@buf|(@bseg<<16),7            ;READ IOCTL Input
  221.     cdcheck    @0,cdtrack
  222.     return    peekl(@bseg,@buf+2)+(@2*60+@3)*75+@4    ;return track address
  223.  
  224.  
  225. ; CDEJECT
  226. ;
  227. ; Opens the CD drive's tray/door.
  228. ;
  229. cdeject:
  230.     local    buf ofs("1")
  231.     local    bseg seg(@buf);
  232.     poke    @bseg @buf 0                ;Eject Disk
  233.     cdcmd    12,@buf|(@bseg<<16),1            ;WRITE IOCTL Output
  234.     cdcheck    @0,cdeject
  235.     return
  236.  
  237.  
  238. ; CDCLOSE
  239. ;
  240. ; Closes the CD's drive tray/door.
  241. ;
  242. cdclose:
  243.     local    buf ofs("1")
  244.     local    bseg seg(@buf);
  245.     poke    @bseg @buf 5                ;Close Tray
  246.     cdcmd    12,@buf|(@bseg<<16),1            ;WRITE IOCTL Output
  247.     cdcheck    @0,cdclose
  248.     return
  249.  
  250.  
  251. ; CDCMD
  252. ;
  253. ; Sets up command data in memory and calls the CD player software.
  254. ;
  255. cdcmd:
  256.     local req ofs("12345678901234567890123456")
  257.     local rseg seg(@req)
  258.     poke  @rseg @req 13                ;param length
  259.     poke  @rseg @req+1 0                ;subunit
  260.     poke  @rseg @req+2 @1                ;command code
  261.     pokew @rseg @req+3 0                ;status
  262.     pokel @rseg @req+5 0 0                ;reserved
  263.     poke  @rseg @req+13 1                ;address mode
  264.     pokel @rseg @req+14 @2                ;begin
  265.     pokel @rseg @req+18 @3                ;length
  266.     pokel @rseg @req+22 0                ;reserved
  267.     int 0x2f 0x1510,@req,asc(@drive)-asc("A"),,,,,seg(@req)
  268.     if peek(@rseg,@req+4)&0x80
  269.         databegin
  270.             "Unknown Error"
  271.             "Write-protect violation"
  272.             "Unknown unit"
  273.             "Drive not Ready"
  274.             "Unknown command"
  275.             "CRC error"
  276.             "Bad drive request structure length"
  277.             "Seek Error"
  278.             "Unknown media"
  279.             "Sector not found"
  280.             "Printer out of paper"
  281.             "Write Fault"
  282.             "Read Fault"
  283.             "General failure"
  284.             "Reserved 1"
  285.             "Reserved 2"
  286.             "Invalid disk change"
  287.         dataend
  288.         if peek(@rseg,@req+3)<16
  289.             dataskip peek(@rseg,@req+3)+1
  290.         endif
  291.         return @
  292.     else
  293.         return ""
  294.     endif
  295.  
  296.  
  297. ; CDCHECK
  298. ;
  299. ; Reports any errors encountered by CDCMD.
  300. ; 
  301. cdcheck:
  302.     if @1!=""
  303.         text chr(10)$@2$": "$@1$chr(10)
  304.     endif
  305.     return
  306.