home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 2.ddi / PROBSTAT.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  8.8 KB  |  255 lines
  1.   ' ************************************************
  2.   ' **  Name:          PROBSTAT                   **
  3.   ' **  Type:          Toolbox                    **
  4.   ' **  Module:        PROBSTAT.BAS               **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' Demonstrates several probability and statistics-
  9.   ' related mathematical functions.
  10.   '
  11.   ' USAGE:          No command line parameters
  12.   ' .MAK FILE:      (none)
  13.   ' PARAMETERS:     (none)
  14.   ' VARIABLES:      a#()       Array of numbers to be processed
  15.   '                 i%         Index into array
  16.   '                 n&         Number of items for combinations and permutations
  17.   '                 r&         Quantity for combinations and permutations
  18.   
  19.   
  20.     DECLARE FUNCTION Combinations# (n&, r&)
  21.     DECLARE FUNCTION Factorial# (n&)
  22.     DECLARE FUNCTION Permutations# (n&, r&)
  23.     DECLARE FUNCTION GeometricMean# (a#())
  24.     DECLARE FUNCTION HarmonicMean# (a#())
  25.     DECLARE FUNCTION ArithmeticMean# (a#())
  26.     DECLARE FUNCTION QuadraticMean# (a#())
  27.   
  28.   ' Demonstrations
  29.     CLS
  30.     PRINT "PROBSTAT"
  31.     PRINT
  32.     PRINT "Array of numbers..."
  33.     DIM a#(-3 TO 6)
  34.     FOR i% = -3 TO 6
  35.         READ a#(i%)
  36.         PRINT a#(i%),
  37.     NEXT i%
  38.     PRINT
  39.     DATA  1.2,3.4,5.6,7.8,9.1,2.3,4.5,6.7,8.9,1.2
  40.   
  41.     PRINT
  42.     PRINT "Arithmetic mean = "; ArithmeticMean#(a#())
  43.     PRINT "Geometric mean  = "; GeometricMean#(a#())
  44.     PRINT "Harmonic mean   = "; HarmonicMean#(a#())
  45.     PRINT "Quadratic mean  = "; QuadraticMean#(a#())
  46.     PRINT
  47.   
  48.     n& = 17
  49.     r& = 5
  50.     PRINT "Combinations of"; n&; "objects taken";
  51.     PRINT r&; "at a time = "; Combinations#(n&, r&)
  52.   
  53.     PRINT "Permutations of"; n&; "objects taken";
  54.     PRINT r&; "at a time = "; Permutations#(n&, r&)
  55.   
  56.     PRINT
  57.     PRINT "Factorial of 17 = "; Factorial#(17&)
  58.   
  59.   ' All done
  60.     END
  61.   
  62.  
  63.   ' ************************************************
  64.   ' **  Name:          ArithmeticMean#            **
  65.   ' **  Type:          Function                   **
  66.   ' **  Module:        PROBSTAT.BAS               **
  67.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  68.   ' ************************************************
  69.   '
  70.   ' Returns the arithmetic mean of an array of numbers.
  71.   '
  72.   ' EXAMPLE OF USE:  ArithmeticMean# a#()
  73.   ' PARAMETERS:      a#()       Array of double-precision numbers to be
  74.   '                             processed
  75.   ' VARIABLES:       n%         Count of array entries
  76.   '                  sum#       Sum of the array entries
  77.   '                  i%         Looping index
  78.   ' MODULE LEVEL
  79.   '   DECLARATIONS:  DECLARE FUNCTION ArithmeticMean# (a#())
  80.   '
  81.     FUNCTION ArithmeticMean# (a#()) STATIC
  82.         n% = 0
  83.         sum# = 0
  84.         FOR i% = LBOUND(a#) TO UBOUND(a#)
  85.             n% = n% + 1
  86.             sum# = sum# + a#(i%)
  87.         NEXT i%
  88.         ArithmeticMean# = sum# / n%
  89.     END FUNCTION
  90.  
  91.   ' ************************************************
  92.   ' **  Name:          Combinations#              **
  93.   ' **  Type:          Function                   **
  94.   ' **  Module:        PROBSTAT.BAS               **
  95.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  96.   ' ************************************************
  97.   '
  98.   ' Returns the number of combinations of n& items
  99.   ' taken r& at a time.
  100.   '
  101.   ' EXAMPLE OF USE:  c# = Combinations#(n&, r&)
  102.   ' PARAMETERS:      n&         Number of items
  103.   '                  r&         Taken r& at a time
  104.   ' VARIABLES:       result#    Working result variable
  105.   '                  j&         Working copy of r&
  106.   '                  k&         Difference between n& and r&
  107.   '                  h&         Values from r& through n&
  108.   '                  i&         Values from 1 through j&
  109.   ' MODULE LEVEL
  110.   '   DECLARATIONS:  DECLARE FUNCTION Combinations# (n&, r&)
  111.   '
  112.     FUNCTION Combinations# (n&, r&) STATIC
  113.         result# = 1
  114.         j& = r&
  115.         k& = n& - r&
  116.         h& = n&
  117.         IF j& > k& THEN
  118.             SWAP j&, k&
  119.         END IF
  120.         FOR i& = 1 TO j&
  121.             result# = (result# * h&) / i&
  122.             h& = h& - 1
  123.         NEXT i&
  124.         Combinations# = result#
  125.     END FUNCTION
  126.  
  127.   ' ************************************************
  128.   ' **  Name:          Factorial#                 **
  129.   ' **  Type:          Function                   **
  130.   ' **  Module:        PROBSTAT.BAS               **
  131.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  132.   ' ************************************************
  133.   '
  134.   ' Returns the factorial of n& (recursive).
  135.   '
  136.   ' EXAMPLE OF USE:  f# = Factorial#(n&)
  137.   ' PARAMETERS:      n&         Number to be evaluated
  138.   ' VARIABLES:       (none)
  139.   ' MODULE LEVEL
  140.   '   DECLARATIONS:  DECLARE FUNCTION Factorial# (n&)
  141.   '
  142.     FUNCTION Factorial# (n&)
  143.         IF n& > 1 THEN
  144.             Factorial# = n& * Factorial#(n& - 1)
  145.         ELSE
  146.             Factorial# = 1
  147.         END IF
  148.     END FUNCTION
  149.  
  150.   ' ************************************************
  151.   ' **  Name:          GeometricMean#             **
  152.   ' **  Type:          Function                   **
  153.   ' **  Module:        PROBSTAT.BAS               **
  154.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  155.   ' ************************************************
  156.   '
  157.   ' Returns the geometric mean of an array of numbers.
  158.   '
  159.   ' EXAMPLE OF USE:  gm# = GeometricMean#(a#())
  160.   ' PARAMETERS:      a#()       Array of numbers to be processed
  161.   ' VARIABLES:       n%         Count of numbers
  162.   '                  product#   Product of all the numbers
  163.   '                  i%         Index to array entries
  164.   ' MODULE LEVEL
  165.   '   DECLARATIONS:  DECLARE FUNCTION GeometricMean# (a#())
  166.   '
  167.     FUNCTION GeometricMean# (a#()) STATIC
  168.         n% = 0
  169.         product# = 1
  170.         FOR i% = LBOUND(a#) TO UBOUND(a#)
  171.             n% = n% + 1
  172.             product# = product# * a#(i%)
  173.         NEXT i%
  174.         GeometricMean# = product# ^ (1 / n%)
  175.     END FUNCTION
  176.  
  177.   ' ************************************************
  178.   ' **  Name:          HarmonicMean#              **
  179.   ' **  Type:          Function                   **
  180.   ' **  Module:        PROBSTAT.BAS               **
  181.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  182.   ' ************************************************
  183.   '
  184.   ' Returns the harmonic mean of an array of numbers.
  185.   '
  186.   ' EXAMPLE OF USE:  hm# = HarmonicMean#(a#())
  187.   ' PARAMETERS:      a#()       Array of numbers to be processed
  188.   ' VARIABLES:       n%         Number of array entries
  189.   '                  sum#       Sum of the reciprocal of each number
  190.   '                  i%         Index to each array entry
  191.   ' MODULE LEVEL
  192.   '   DECLARATIONS:  DECLARE FUNCTION HarmonicMean# (a#())
  193.   '
  194.     FUNCTION HarmonicMean# (a#()) STATIC
  195.         n% = 0
  196.         sum# = 0
  197.         FOR i% = LBOUND(a#) TO UBOUND(a#)
  198.             n% = n% + 1
  199.             sum# = sum# + 1# / a#(i%)
  200.         NEXT i%
  201.         HarmonicMean# = n% / sum#
  202.     END FUNCTION
  203.  
  204.   ' ************************************************
  205.   ' **  Name:          Permutations#              **
  206.   ' **  Type:          Function                   **
  207.   ' **  Module:        PROBSTAT.BAS               **
  208.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  209.   ' ************************************************
  210.   '
  211.   ' Returns the permutations of n& items taken r& at a time.
  212.   '
  213.   ' EXAMPLE OF USE:  perm# = Permutations#(n&, r&)
  214.   ' PARAMETERS:      n&         Number of items
  215.   '                  r&         Taken r& at a time
  216.   ' VARIABLES:       p#         Working variable for permutations
  217.   '                  i&         Loop index
  218.   ' MODULE LEVEL
  219.   '   DECLARATIONS:  DECLARE FUNCTION Permutations# (n&, r&)
  220.   '
  221.     FUNCTION Permutations# (n&, r&) STATIC
  222.         p# = 1
  223.         FOR i& = n& - r& + 1 TO n&
  224.             p# = p# * i&
  225.         NEXT i&
  226.         Permutations# = p#
  227.     END FUNCTION
  228.  
  229.   ' ************************************************
  230.   ' **  Name:          QuadraticMean#             **
  231.   ' **  Type:          Function                   **
  232.   ' **  Module:        PROBSTAT.BAS               **
  233.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  234.   ' ************************************************
  235.   '
  236.   ' Returns the quadratic mean of an array of numbers.
  237.   '
  238.   ' EXAMPLE OF USE:  qm# = QuadraticMean#(a#())
  239.   ' PARAMETERS:      a#()       Array of numbers to be processed
  240.   ' VARIABLES:       n%         Count of array entries
  241.   '                  sum#       Sum of the square of each number
  242.   ' MODULE LEVEL
  243.   '   DECLARATIONS:  DECLARE FUNCTION QuadraticMean# (a#())
  244.   '
  245.     FUNCTION QuadraticMean# (a#()) STATIC
  246.         n% = 0
  247.         sum# = 0
  248.         FOR i% = LBOUND(a#) TO UBOUND(a#)
  249.             n% = n% + 1
  250.             sum# = sum# + a#(i%) ^ 2
  251.         NEXT i%
  252.         QuadraticMean# = SQR(sum# / n%)
  253.     END FUNCTION
  254.  
  255.