home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 1.ddi / MONTH.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  3.6 KB  |  117 lines
  1.   ' ************************************************
  2.   ' **  Name:          MONTH                      **
  3.   ' **  Type:          Program                    **
  4.   ' **  Module:        MONTH.BAS                  **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' Creates and displays a three-month calendar.
  9.   ' USAGE:           No command line parameters
  10.   ' .MAK FILE:       MONTH.BAS
  11.   '                  CALENDAR.BAS
  12.   ' PARAMETERS:      (none)
  13.   ' VARIABLES:       year%      Year of concern
  14.   '                  month%     Month of concern
  15.   '                  quitFlag%  Indicates that program is to terminate
  16.   '                  day%       Day near middle of the month
  17.   '                  d2$        Date for second calendar month
  18.   '                  j2&        Julian day number for second calendar month
  19.   '                  d1$        Date for first calendar month
  20.   '                  j1&        Julian day number for first calendar month
  21.   '                  d3$        Date for third calendar month
  22.   '                  j3&        Julian day number for third calendar month
  23.   '                  k$         Key press character
  24.   
  25.   ' Constants
  26.     CONST FALSE = 0
  27.     CONST TRUE = NOT FALSE
  28.   
  29.   ' Functions
  30.     DECLARE FUNCTION Date2Julian& (dat$)
  31.     DECLARE FUNCTION MDY2Date$ (month%, day%, year%)
  32.     DECLARE FUNCTION Date2Year% (dat$)
  33.     DECLARE FUNCTION Date2Month% (dat$)
  34.     DECLARE FUNCTION Julian2Date$ (julian&)
  35.   
  36.   ' Subprograms
  37.     DECLARE SUB OneMonthCalendar (dat$, row%, col%)
  38.   
  39.   ' Get today's month and year
  40.     year% = Date2Year%(DATE$)
  41.     month% = Date2Month%(DATE$)
  42.   
  43.   ' Make calendars until the Esc key is pressed
  44.     DO UNTIL quitFlag%
  45.       
  46.       ' Get Julian day number for about the middle of the month
  47.         day% = 15
  48.         d2$ = MDY2Date$(month%, day%, year%)
  49.         j2& = Date2Julian&(d2$)
  50.       
  51.       ' Get last month's date
  52.         j1& = j2& - 30
  53.         d1$ = Julian2Date$(j1&)
  54.       
  55.       ' Get next month's date
  56.         j3& = j2& + 30
  57.         d3$ = Julian2Date$(j3&)
  58.       
  59.       ' Display the heading
  60.         CLS
  61.         LOCATE 1, 57
  62.         PRINT "THREE-MONTH CALENDAR"
  63.         LOCATE 2, 57
  64.         PRINT "QuickBASIC 4.0"
  65.       
  66.       ' Create the three calendar sheets
  67.         OneMonthCalendar d1$, 1, 1
  68.         OneMonthCalendar d2$, 8, 25
  69.         OneMonthCalendar d3$, 15, 49
  70.       
  71.       ' Display the instructions
  72.         LOCATE 17, 1
  73.         PRINT "Press <Y> to increment the year"
  74.         LOCATE 18, 1
  75.         PRINT "Press <y> to decrement the year"
  76.         LOCATE 19, 1
  77.         PRINT "Press <M> to increment the months"
  78.         LOCATE 20, 1
  79.         PRINT "Press <m> to decrement the months"
  80.         LOCATE 22, 1
  81.         PRINT "Press the Esc key to quit"
  82.       
  83.       ' Wait for a keystroke
  84.         DO
  85.             k$ = INKEY$
  86.         LOOP UNTIL k$ <> ""
  87.       
  88.       ' Check for appropriate keystroke
  89.         SELECT CASE k$
  90.         CASE "y"
  91.             year% = year% - 1
  92.         CASE "Y"
  93.             year% = year% + 1
  94.         CASE "m"
  95.             month% = month% - 3
  96.         CASE "M"
  97.             month% = month% + 3
  98.         CASE CHR$(27)
  99.             quitFlag% = TRUE
  100.         CASE ELSE
  101.         END SELECT
  102.       
  103.       ' Adjust month for proper range
  104.         IF month% < 1 THEN
  105.             month% = month% + 12
  106.             year% = year% - 1
  107.         ELSEIF month% > 12 THEN
  108.             month% = month% - 12
  109.             year% = year% + 1
  110.         END IF
  111.       
  112.     LOOP
  113.   
  114.   ' All done
  115.     END
  116.   
  117.