home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 1.ddi / DOLLARS.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  4.5 KB  |  116 lines
  1.   ' ************************************************
  2.   ' **  Name:          DOLLARS                    **
  3.   ' **  Type:          Toolbox                    **
  4.   ' **  Module:        DOLLARS.BAS                **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' USAGE:         No command line parameters
  9.   ' .MAK FILE:     (none)
  10.   ' PARAMETERS:    (none)
  11.   ' VARIABLES:     n#         Number for demonstration of the functions
  12.   
  13.     DECLARE FUNCTION Comma$ (n#)
  14.     DECLARE FUNCTION DollarString$ (amount#, length%)
  15.     DECLARE FUNCTION Round# (n#, powerOfTen%)
  16.   
  17.     CLS
  18.     n# = 1234567.76543#
  19.     PRINT "Number n#:", , n#
  20.     PRINT "Comma$(n#)", , Comma$(n#)
  21.     PRINT "Comma$(Round#(n#, -2))", Comma$(Round#(n#, -2))
  22.     PRINT
  23.     PRINT "DollarString$(n#, 20)", ":"; DollarString$(n#, 20); ":"
  24.     PRINT , , " 12345678901234567890"
  25.     PRINT
  26.   
  27.     PRINT "Round#(n#, -3)", Round#(n#, -3)
  28.     PRINT "Round#(n#, -2)", Round#(n#, -2)
  29.     PRINT "Round#(n#, -1)", Round#(n#, -1)
  30.     PRINT "Round#(n#, 0)", , Round#(n#, 0)
  31.     PRINT "Round#(n#, 1)", , Round#(n#, 1)
  32.     PRINT "Round#(n#, 2)", , Round#(n#, 2)
  33.  
  34.   ' ************************************************
  35.   ' **  Name:          Comma$                     **
  36.   ' **  Type:          Function                   **
  37.   ' **  Module:        DOLLARS.BAS                **
  38.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  39.   ' ************************************************
  40.   '
  41.   ' Creates a string representing a double-precision
  42.   ' number, with commas inserted every three digits.
  43.   '
  44.   ' EXAMPLE OF USE:    n$  =  Comma$(n#)
  45.   ' PARAMETERS:        n#     Number to be formatted
  46.   ' VARIABLES:         tn$    Temporary string of the number
  47.   '                    dp%    Position of the decimal point
  48.   '                    i%     Index into tn$
  49.   ' MODULE LEVEL
  50.   '   DECLARATIONS:           DECLARE FUNCTION Comma$ (n#)
  51.   '
  52.     FUNCTION Comma$ (n#) STATIC
  53.         tn$ = STR$(n#)
  54.         dp% = INSTR(tn$, ".")
  55.         IF dp% = 0 THEN
  56.             dp% = LEN(tn$) + 1
  57.         END IF
  58.         IF dp% > 4 THEN
  59.             FOR i% = dp% - 3 TO 3 STEP -3
  60.                 tn$ = LEFT$(tn$, i% - 1) + "," + MID$(tn$, i%)
  61.             NEXT i%
  62.         END IF
  63.         Comma$ = LTRIM$(tn$)
  64.     END FUNCTION
  65.  
  66.   ' ************************************************
  67.   ' **  Name:          DollarString$              **
  68.   ' **  Type:          Function                   **
  69.   ' **  Module:        DOLLARS.BAS                **
  70.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  71.   ' ************************************************
  72.   '
  73.   ' Returns a string representation of a dollar amount,
  74.   ' rounded to the nearest cent, with commas separating
  75.   ' groups of three digits, and with a preceding dollar sign.
  76.   '
  77.   ' EXAMPLE OF USE:    d$ = DollarString$(dollars#)
  78.   ' PARAMETERS:        dollars#   Amount of money
  79.   ' VARIABLES:         tmp$       Temporary working string
  80.   ' MODULE LEVEL
  81.   '   DECLARATIONS:    DECLARE FUNCTION Comma$ (n#)
  82.   '                    DECLARE FUNCTION DollarString$ (amount#, length%)
  83.   '                    DECLARE FUNCTION Round# (n#, powerOfTen%)
  84.   '
  85.     FUNCTION DollarString$ (amount#, length%) STATIC
  86.         tmp$ = SPACE$(length%) + "$" + Comma$(Round#(amount#, -2))
  87.         DollarString$ = RIGHT$(tmp$, length%)
  88.         tmp$ = ""
  89.     END FUNCTION
  90.  
  91.   ' ************************************************
  92.   ' **  Name:          Round#                     **
  93.   ' **  Type:          Function                   **
  94.   ' **  Module:        DOLLARS.BAS                **
  95.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  96.   ' ************************************************
  97.   '
  98.   ' Rounds a number at the power of 10 decimal place.
  99.   '
  100.   ' EXAMPLE OF USE:  x# = Round#(n#, powerOfTen%)
  101.   ' EXAMPLES:        Round#(12.3456#, -2) = 12.35#
  102.   '                  Round#(12.3456#, -1) = 12.3#
  103.   '                  Round#(12.3456#, 0)  = 12#
  104.   '                  Round#(12.3456#, 1)  = 10#
  105.   ' PARAMETERS:      n#           Number to be rounded
  106.   '                  powerOfTen%  Power of 10 for rounding the number
  107.   ' VARIABLES:       pTen#        10 raised to the indicated power of 10
  108.   ' MODULE LEVEL
  109.   '   DECLARATIONS:             DECLARE FUNCTION Round# (n#, powerOfTen%)
  110.   '
  111.     FUNCTION Round# (n#, powerOfTen%) STATIC
  112.         pTen# = 10# ^ powerOfTen%
  113.         Round# = INT(n# / pTen# + .5#) * pTen#
  114.     END FUNCTION
  115.  
  116.