home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 1.ddi / CARTESIA.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  5.5 KB  |  156 lines
  1.   ' ************************************************
  2.   ' **  Name:          CARTESIA                   **
  3.   ' **  Type:          Toolbox                    **
  4.   ' **  Module:        CARTESIA.BAS               **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' Demonstrates a set of functions and subprograms
  9.   ' dealing with Cartesian coordinates.
  10.   '
  11.   ' USAGE:           No command line parameters
  12.   ' .MAK FILE:       (none)
  13.   ' PARAMETERS:      (none)
  14.   ' VARIABLES:       x!     X value of Cartesian coordinate
  15.   '                  y!     Y value of Cartesian coordinate
  16.   '                  r!     Polar notation distance from origin
  17.   '                  theta! Polar notation angle from X axis
  18.   
  19.     DECLARE FUNCTION Angle! (x!, y!)
  20.     DECLARE FUNCTION Magnitude! (x!, y!)
  21.   
  22.     DECLARE SUB Pol2Rec (r!, theta!, x!, y!)
  23.     DECLARE SUB Rec2Pol (x!, y!, r!, theta!)
  24.   
  25.     CLS
  26.     INPUT "Enter X  ", x!
  27.     INPUT "Enter Y  ", y!
  28.     PRINT
  29.     PRINT "Magnitude!(x!, y!)", Magnitude!(x!, y!)
  30.     PRINT "Angle!(x!, y!)", Angle!(x!, y!)
  31.     PRINT
  32.     Rec2Pol x!, y!, r!, theta!
  33.     PRINT "Rec2Pol", , r!; theta!
  34.     Pol2Rec r!, theta!, x!, y!
  35.     PRINT "Pol2Rec", , x!; y!
  36.  
  37.   ' ************************************************
  38.   ' **  Name:          Angle!                     **
  39.   ' **  Type:          Function                   **
  40.   ' **  Module:        CARTESIA.BAS               **
  41.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  42.   ' ************************************************
  43.   '
  44.   ' Returns the angle (in radians) between the X axis
  45.   ' and the line from the origin to the point x!,y!
  46.   '
  47.   ' EXAMPLE OF USE:  a! = Angle!(x!, y!)
  48.   ' PARAMETERS:      x!         X part of the Cartesian coordinate
  49.   '                  y!         Y part of the Cartesian coordinate
  50.   ' VARIABLES:       (none)
  51.   ' MODULE LEVEL
  52.   '   DECLARATIONS:  DECLARE FUNCTION Angle! (x!, y!)
  53.   '
  54.     FUNCTION Angle! (x!, y!) STATIC
  55.       
  56.         CONST PI = 3.141593
  57.         CONST HALFPI = PI / 2
  58.       
  59.         IF x! = 0! THEN
  60.             IF y! > 0! THEN
  61.                 Angle! = HALFPI
  62.             ELSEIF y! < 0! THEN
  63.                 Angle! = -HALFPI
  64.             ELSE
  65.                 Angle! = 0!
  66.             END IF
  67.         ELSEIF y! = 0! THEN
  68.             IF x! < 0! THEN
  69.                 Angle! = PI
  70.             ELSE
  71.                 Angle! = 0!
  72.             END IF
  73.         ELSE
  74.             IF x! < 0! THEN
  75.                 IF y! > 0! THEN
  76.                     Angle! = ATN(y! / x!) + PI
  77.                 ELSE
  78.                     Angle! = ATN(y! / x!) - PI
  79.                 END IF
  80.             ELSE
  81.                 Angle! = ATN(y! / x!)
  82.             END IF
  83.         END IF
  84.       
  85.     END FUNCTION
  86.  
  87.   ' ************************************************
  88.   ' **  Name:          Magnitude!                 **
  89.   ' **  Type:          Function                   **
  90.   ' **  Module:        CARTESIA.BAS               **
  91.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  92.   ' ************************************************
  93.   '
  94.   ' Returns the distance from the origin to the
  95.   ' point x!,y!
  96.   '
  97.   ' EXAMPLE OF USE:  r! =  Magnitude!(x!, y!)
  98.   ' PARAMETERS:      x!         X part of the Cartesian coordinate
  99.   '                  y!         Y part of the Cartesian coordinate
  100.   ' VARIABLES:       (none)
  101.   ' MODULE LEVEL
  102.   '   DECLARATIONS:  DECLARE FUNCTION Magnitude! (x!, y!)
  103.   '
  104.     FUNCTION Magnitude! (x!, y!) STATIC
  105.         Magnitude! = SQR(x! * x! + y! * y!)
  106.     END FUNCTION
  107.  
  108.   ' ************************************************
  109.   ' **  Name:          Pol2rec                    **
  110.   ' **  Type:          Subprogram                 **
  111.   ' **  Module:        CARTESIA.BAS               **
  112.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  113.   ' ************************************************
  114.   '
  115.   ' Converts polar coordinates to Cartesian notation.
  116.   '
  117.   ' EXAMPLE OF USE:  Pol2Rec r!, theta!, x!, y!
  118.   ' PARAMETERS:      r!         Distance of point from the origin
  119.   '                  theta!     Angle of point from the X axis
  120.   '                  x!         X coordinate of the point
  121.   '                  y!         Y coordinate of the point
  122.   ' VARIABLES:       (none)
  123.   ' MODULE LEVEL
  124.   '   DECLARATIONS:  DECLARE SUB Pol2Rec (r!, theta!, x!, y!)
  125.   '
  126.     SUB Pol2Rec (r!, theta!, x!, y!) STATIC
  127.         x! = r! * COS(theta!)
  128.         y! = r! * SIN(theta!)
  129.     END SUB
  130.  
  131.   ' ************************************************
  132.   ' **  Name:          Rec2pol                    **
  133.   ' **  Type:          Subprogram                 **
  134.   ' **  Module:        CARTESIA.BAS               **
  135.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  136.   ' ************************************************
  137.   '
  138.   ' Converts Cartesian coordinates to polar notation.
  139.   '
  140.   ' EXAMPLE OF USE:  Rec2Pol x!, y!, r!, theta!
  141.   ' PARAMETERS:      x!         X coordinate of the point
  142.   '                  y!         Y coordinate of the point
  143.   '                  r!         Distance of point from the origin
  144.   '                  theta!     Angle of point from the X axis
  145.   ' VARIABLES:       (none)
  146.   ' MODULE LEVEL
  147.   '   DECLARATIONS:  DECLARE FUNCTION Angle! (x!, y!)
  148.   '                  DECLARE FUNCTION Magnitude! (x!, y!)
  149.   '                  DECLARE SUB Rec2Pol (x!, y!, r!, theta!)
  150.   '
  151.     SUB Rec2Pol (x!, y!, r!, theta!) STATIC
  152.         r! = Magnitude!(x!, y!)
  153.         theta! = Angle!(x!, y!)
  154.     END SUB
  155.  
  156.