home *** CD-ROM | disk | FTP | other *** search
/ Liren Large Software Subsidy 9 / 09.iso / l / l180 / 1.ddi / BIOSCALL.BAS < prev    next >
Encoding:
BASIC Source File  |  1989-02-07  |  14.5 KB  |  405 lines
  1.   ' ************************************************
  2.   ' **  Name:          BIOSCALL                   **
  3.   ' **  Type:          Toolbox                    **
  4.   ' **  Module:        BIOSCALL.BAS               **
  5.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  6.   ' ************************************************
  7.   '
  8.   ' Demonstrates several interrupt calls to the ROM BIOS.
  9.   '
  10.   ' USAGE: No command line parameters
  11.   ' REQUIREMENTS:    MIXED.QLB/.LIB
  12.   ' .MAK FILE:       (none)
  13.   ' PARAMETERS:      (none)
  14.   ' VARIABLES:       i%         Loop index for creating lines to scroll
  15.   '                  equip      Structure of type EquipmentType
  16.   '                  mode%      Video mode returned by VideoState
  17.   '                  columns%   Video columns returned by VideoState
  18.   '                  page%      Video page returned by VideoState
  19.   '                  shift      Structure of type ShiftType
  20.   
  21.   
  22.   ' Constants
  23.     CONST FALSE = 0
  24.     CONST TRUE = NOT FALSE
  25.   
  26.   ' Declare the Type structures
  27.     TYPE RegType
  28.         ax    AS INTEGER
  29.         bx    AS INTEGER
  30.         cx    AS INTEGER
  31.         dx    AS INTEGER
  32.         Bp    AS INTEGER
  33.         si    AS INTEGER
  34.         di    AS INTEGER
  35.         flags AS INTEGER
  36.     END TYPE
  37.   
  38.     TYPE RegTypeX
  39.         ax    AS INTEGER
  40.         bx    AS INTEGER
  41.         cx    AS INTEGER
  42.         dx    AS INTEGER
  43.         Bp    AS INTEGER
  44.         si    AS INTEGER
  45.         di    AS INTEGER
  46.         flags AS INTEGER
  47.         ds    AS INTEGER
  48.         es    AS INTEGER
  49.     END TYPE
  50.   
  51.     TYPE EquipmentType
  52.         printers     AS INTEGER
  53.         gameAdapter  AS INTEGER
  54.         serial       AS INTEGER
  55.         floppies     AS INTEGER
  56.         initialVideo AS INTEGER
  57.         coprocessor  AS INTEGER
  58.     END TYPE
  59.   
  60.     TYPE ShiftType
  61.         right           AS INTEGER
  62.         left            AS INTEGER
  63.         ctrl            AS INTEGER
  64.         alt             AS INTEGER
  65.         scrollLockState AS INTEGER
  66.         numLockState    AS INTEGER
  67.         capsLockState   AS INTEGER
  68.         insertState     AS INTEGER
  69.     END TYPE
  70.   
  71.     DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  72.     DECLARE SUB InterruptX (intnum%, inreg AS RegTypeX, outreg AS RegTypeX)
  73.     DECLARE SUB PrintScreen ()
  74.     DECLARE SUB Scroll (row1%, col1%, row2%, col2%, lines%, attribute%)
  75.     DECLARE SUB Equipment (equip AS EquipmentType)
  76.     DECLARE SUB VideoState (mode%, columns%, page%)
  77.     DECLARE SUB GetShiftStates (shift AS ShiftType)
  78.     DECLARE SUB ReBoot ()
  79.   
  80.   ' Demonstrate the Scroll subprogram
  81.     CLS
  82.     FOR i% = 1 TO 15
  83.         COLOR i%, i% - 1
  84.         PRINT STRING$(25, i% + 64)
  85.     NEXT i%
  86.     COLOR 7, 0
  87.     PRINT
  88.     PRINT "Press <Enter> to scroll part of the screen"
  89.     DO
  90.     LOOP UNTIL INKEY$ = CHR$(13)
  91.     Scroll 2, 3, 6, 16, 3, SCREEN(2, 3, 1)
  92.   
  93.   ' Wait for user before continuing
  94.     PRINT
  95.     PRINT "Press any key to continue"
  96.     DO
  97.     LOOP UNTIL INKEY$ <> ""
  98.     CLS
  99.   
  100.   ' Determine the equipment information
  101.     DIM equip AS EquipmentType
  102.     Equipment equip
  103.     PRINT "Printers:", equip.printers
  104.     PRINT "Game adapter:", equip.gameAdapter
  105.     PRINT "Serial IO:", equip.serial
  106.     PRINT "Floppies:", equip.floppies
  107.     PRINT "Video:", equip.initialVideo
  108.     PRINT "Coprocessor:", equip.coprocessor
  109.   
  110.   ' Determine the current video state
  111.     PRINT
  112.     VideoState mode%, columns%, page%
  113.     PRINT "Video mode:", mode%
  114.     PRINT "Text columns:", columns%
  115.     PRINT "Video page:", page%
  116.   
  117.   ' Wait for user before continuing
  118.     PRINT
  119.     PRINT "Press any key to continue"
  120.     DO
  121.     LOOP UNTIL INKEY$ <> ""
  122.   
  123.   ' Demonstrate the shift key states
  124.     CLS
  125.     PRINT "(Press shift keys, then <Enter> to continue...)"
  126.     DIM shift AS ShiftType
  127.     DO
  128.         LOCATE 4, 1
  129.         PRINT "Shift states:"
  130.         GetShiftStates shift
  131.         PRINT
  132.         PRINT "Left shift:", shift.left
  133.         PRINT "Right shift:", shift.right
  134.         PRINT "Ctrl:", shift.ctrl
  135.         PRINT "Alt:", shift.alt
  136.         PRINT "Scroll Lock:", shift.scrollLockState
  137.         PRINT "Num Lock:", shift.numLockState
  138.         PRINT "Caps Lock:", shift.capsLockState
  139.         PRINT "Insert:", shift.insertState
  140.     LOOP UNTIL INKEY$ = CHR$(13)
  141.   
  142.   ' Uncomment the following line to cause a screen dump to printer....
  143.   ' PrintScreen
  144.   
  145.   ' Uncomment the following line only if you want to reboot....
  146.   ' ReBoot
  147.   
  148.     END
  149.   
  150.  
  151.   ' ************************************************
  152.   ' **  Name:          Equipment                  **
  153.   ' **  Type:          Subprogram                 **
  154.   ' **  Module:        BIOSCALL.BAS               **
  155.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  156.   ' ************************************************
  157.   '
  158.   ' Returns equipment configuration information from BIOS.
  159.   '
  160.   ' EXAMPLE OF USE:  Equipment equip
  161.   ' PARAMETERS:      equip      Structure of type EquipmentType
  162.   ' VARIABLES:       reg        Structure of type RegType
  163.   ' MODULE LEVEL
  164.   '   DECLARATIONS:  TYPE RegType
  165.   '                     ax    AS INTEGER
  166.   '                     bx    AS INTEGER
  167.   '                     cx    AS INTEGER
  168.   '                     dx    AS INTEGER
  169.   '                     Bp    AS INTEGER
  170.   '                     si    AS INTEGER
  171.   '                     di    AS INTEGER
  172.   '                     flags AS INTEGER
  173.   '                  END TYPE
  174.   '
  175.   '                  TYPE EquipmentType
  176.   '                     printers     AS INTEGER
  177.   '                     gameAdapter  AS INTEGER
  178.   '                     serial       AS INTEGER
  179.   '                     floppies     AS INTEGER
  180.   '                     initialVideo AS INTEGER
  181.   '                     coprocessor  AS INTEGER
  182.   '                  END TYPE
  183.   '
  184.   '     DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  185.   '     DECLARE SUB Equipment (equip AS EquipmentType)
  186.   '
  187.     SUB Equipment (equip AS EquipmentType) STATIC
  188.         DIM reg AS RegType
  189.         Interrupt &H11, reg, reg
  190.         equip.printers = (reg.ax AND &HC000&) \ 16384
  191.         equip.gameAdapter = (reg.ax AND &H1000) \ 4096
  192.         equip.serial = (reg.ax AND &HE00) \ 512
  193.         equip.floppies = (reg.ax AND &HC0) \ 64 + 1
  194.         equip.initialVideo = (reg.ax AND &H30) \ 16
  195.         equip.coprocessor = (reg.ax AND 2) \ 2
  196.     END SUB
  197.  
  198.   ' ************************************************
  199.   ' **  Name:          GetShiftStates             **
  200.   ' **  Type:          Subprogram                 **
  201.   ' **  Module:        BIOSCALL.BAS               **
  202.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  203.   ' ************************************************
  204.   '
  205.   ' Return state of the various shift keys.
  206.   '
  207.   ' EXAMPLE OF USE:  GetShiftStates shift
  208.   ' PARAMETERS:      shift      Structure of type ShiftType
  209.   ' VARIABLES:       reg        Structure of type RegType
  210.   ' MODULE LEVEL
  211.   '   DECLARATIONS:  TYPE RegType
  212.   '                     ax    AS INTEGER
  213.   '                     bx    AS INTEGER
  214.   '                     cx    AS INTEGER
  215.   '                     dx    AS INTEGER
  216.   '                     Bp    AS INTEGER
  217.   '                     si    AS INTEGER
  218.   '                     di    AS INTEGER
  219.   '                     flags AS INTEGER
  220.   '                  END TYPE
  221.   '
  222.   '                  TYPE ShiftType
  223.   '                     right           AS INTEGER
  224.   '                     left            AS INTEGER
  225.   '                     ctrl            AS INTEGER
  226.   '                     alt             AS INTEGER
  227.   '                     scrollLockState AS INTEGER
  228.   '                     numLockState    AS INTEGER
  229.   '                     capsLockState   AS INTEGER
  230.   '                     insertState     AS INTEGER
  231.   '                  END TYPE
  232.   '
  233.   '      DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  234.   '      DECLARE SUB GetShiftStates (shift AS ShiftType)
  235.   '
  236.     SUB GetShiftStates (shift AS ShiftType) STATIC
  237.         DIM reg AS RegType
  238.         reg.ax = &H200
  239.         Interrupt &H16, reg, reg
  240.         shift.right = reg.ax AND 1
  241.         shift.left = (reg.ax AND 2) \ 2
  242.         shift.ctrl = (reg.ax AND 4) \ 4
  243.         shift.alt = (reg.ax AND 8) \ 8
  244.         shift.scrollLockState = (reg.ax AND 16) \ 16
  245.         shift.numLockState = (reg.ax AND 32) \ 32
  246.         shift.capsLockState = (reg.ax AND 64) \ 64
  247.         shift.insertState = (reg.ax AND 128) \ 128
  248.     END SUB
  249.  
  250.   ' ************************************************
  251.   ' **  Name:          PrintScreen                **
  252.   ' **  Type:          Subprogram                 **
  253.   ' **  Module:        BIOSCALL.BAS               **
  254.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  255.   ' ************************************************
  256.   '
  257.   ' Activates interrupt 5 to cause a dump of the
  258.   ' screen's contents to the printer.
  259.   '
  260.   ' EXAMPLE OF USE:  PrintScreen
  261.   ' PARAMETERS:      (none)
  262.   ' VARIABLES:       reg        Structure of type RegType
  263.   ' MODULE LEVEL
  264.   '   DECLARATIONS:  TYPE RegType
  265.   '                     ax    AS INTEGER
  266.   '                     bx    AS INTEGER
  267.   '                     cx    AS INTEGER
  268.   '                     dx    AS INTEGER
  269.   '                     Bp    AS INTEGER
  270.   '                     si    AS INTEGER
  271.   '                     di    AS INTEGER
  272.   '                     flags AS INTEGER
  273.   '                  END TYPE
  274.   '
  275.   '      DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  276.   '      DECLARE SUB PrintScreen ()
  277.   '
  278.     SUB PrintScreen STATIC
  279.         DIM reg AS RegType
  280.         Interrupt 5, reg, reg
  281.     END SUB
  282.  
  283.   ' ************************************************
  284.   ' **  Name:          ReBoot                     **
  285.   ' **  Type:          Subprogram                 **
  286.   ' **  Module:        BIOSCALL.BAS               **
  287.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  288.   ' ************************************************
  289.   '
  290.   ' Causes the computer to reboot.
  291.   '
  292.   ' EXAMPLE OF USE:  ReBoot
  293.   ' PARAMETERS:      (none)
  294.   ' VARIABLES:       reg        Structure of type RegType
  295.   ' MODULE LEVEL
  296.   '   DECLARATIONS:  TYPE RegType
  297.   '                     ax    AS INTEGER
  298.   '                     bx    AS INTEGER
  299.   '                     cx    AS INTEGER
  300.   '                     dx    AS INTEGER
  301.   '                     Bp    AS INTEGER
  302.   '                     si    AS INTEGER
  303.   '                     di    AS INTEGER
  304.   '                     flags AS INTEGER
  305.   '                  END TYPE
  306.   '
  307.   '      DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  308.   '      DECLARE SUB ReBoot ()
  309.   '
  310.     SUB ReBoot STATIC
  311.         DIM reg AS RegType
  312.         Interrupt &H19, reg, reg
  313.     END SUB
  314.  
  315.   ' ************************************************
  316.   ' **  Name:          Scroll                     **
  317.   ' **  Type:          Subprogram                 **
  318.   ' **  Module:        BIOSCALL.BAS               **
  319.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  320.   ' ************************************************
  321.   '
  322.   ' Scrolls the screen in the rectangular area defined
  323.   ' by the row and col parameters.  Positive line count
  324.   ' moves the lines up, leaving blank lines at bottom;
  325.   ' negative line count moves the lines down.
  326.   '
  327.   ' EXAMPLE OF USE:  Scroll row1%, col1%, row2%, col2%, lines%, attr%
  328.   ' PARAMETERS:      row1%    Upper left character row defining rectangular
  329.   '                           scroll area
  330.   '                  col1     Upper left character column defining rectangular
  331.   '                           scroll area
  332.   '                  row2%    Lower right character row defining rectangular
  333.   '                           scroll area
  334.   '                  col2%    Lower right character column defining
  335.   '                           rectangular scroll area
  336.   '                  lines%   Number of character lines to scroll
  337.   '                  attr%    Color attribute byte to be used in new text
  338.   '                           lines scrolled onto the screen
  339.   ' VARIABLES:       reg      Structure of type RegType
  340.   ' MODULE LEVEL
  341.   '   DECLARATIONS:  TYPE RegType
  342.   '                     ax    AS INTEGER
  343.   '                     bx    AS INTEGER
  344.   '                     cx    AS INTEGER
  345.   '                     dx    AS INTEGER
  346.   '                     Bp    AS INTEGER
  347.   '                     si    AS INTEGER
  348.   '                     di    AS INTEGER
  349.   '                     flags AS INTEGER
  350.   '                  END TYPE
  351.   '      DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  352.   '      DECLARE SUB Scroll (row1%, col1%, row2%, col2%, lines%, attribute%)
  353.   '
  354.     SUB Scroll (row1%, col1%, row2%, col2%, lines%, attribute%) STATIC
  355.         DIM reg AS RegType
  356.         IF lines% > 0 THEN
  357.             reg.ax = &H600 + lines% MOD 256
  358.         ELSE
  359.             reg.ax = &H700 + ABS(lines%) MOD 256
  360.         END IF
  361.         reg.bx = (attribute% * 256&) AND &HFF00
  362.         reg.cx = (row1% - 1) * 256 + col1% - 1
  363.         reg.dx = (row2% - 1) * 256 + col2% - 1
  364.         Interrupt &H10, reg, reg
  365.     END SUB
  366.  
  367.   ' ************************************************
  368.   ' **  Name:          VideoState                 **
  369.   ' **  Type:          Subprogram                 **
  370.   ' **  Module:        BIOSCALL.BAS               **
  371.   ' **  Language:      Microsoft QuickBASIC 4.00  **
  372.   ' ************************************************
  373.   '
  374.   ' Determines the current video mode parameters.
  375.   '
  376.   ' EXAMPLE OF USE:  VideoState mode%, columns%, page%
  377.   ' PARAMETERS:      mode%      Current video mode
  378.   '                  columns%   Current number of text columns
  379.   '                  page%      Current active display page
  380.   ' VARIABLES:       reg        Structure of type RegType
  381.   ' MODULE LEVEL
  382.   '   DECLARATIONS:  TYPE RegType
  383.   '                     ax    AS INTEGER
  384.   '                     bx    AS INTEGER
  385.   '                     cx    AS INTEGER
  386.   '                     dx    AS INTEGER
  387.   '                     Bp    AS INTEGER
  388.   '                     si    AS INTEGER
  389.   '                     di    AS INTEGER
  390.   '                     flags AS INTEGER
  391.   '                  END TYPE
  392.   '
  393.   '      DECLARE SUB Interrupt (intnum%, inreg AS RegType, outreg AS RegType)
  394.   '      DECLARE SUB VideoState (mode%, columns%, page%)
  395.   '
  396.     SUB VideoState (mode%, columns%, page%) STATIC
  397.         DIM reg AS RegType
  398.         reg.ax = &HF00
  399.         Interrupt &H10, reg, reg
  400.         mode% = reg.ax AND &HFF
  401.         columns% = (CLNG(reg.ax) AND &HFF00) \ 256
  402.         page% = (CLNG(reg.bx) AND &HFF00) \ 256
  403.     END SUB
  404.  
  405.